/INITIAL DIALOG FOR U/W-FOCAL      -JVZ-

	JMP I LOOKER	/SELF-SAVER
	*202
	LINE11

	*213
MVR,	MOVER
CHG,	CHANGE
MID,	MIDDLE
CKW,	CKWRDS
	JMS I MVR	/ENTRY POINT
	    UPPER
	CDI 10
	JMP I UPPER

	*224
UPPER,	4540		/AFTER 'UPDATE'
	NOPUNCH
	*4540
	ENPUNCH
	DCA NAGSW	/SET 'GROUP'
	TAD ENDT	/='1.2'
	DCA LINENO
	PUSHJ
	    DO+3
	TAD ENDT	/ERASE THE PROGRAM
	DCA BUFR
	JMP .+5		/'RETURN'
MIDDLE,	LOWER
	DCA EFOP	/SAVE NAME
	PUSHJ		/LOOK IT UP
	    GS1
	CDI
	JMP I MIDDLE	/L=1 IF FOUND
	STOP

	*UPPER+20
LOWER,	4566		/'WAITUP'
	DCA LINE0
	DCA LIBBLK
	DCA NUDATE+3	/FOR SHORTER DATE
	LOOKUP
	    2717	/WORDS
	SKP CLA
	CMA
	DCA GOSW	/-1 FOR 3 WORDS

EXTEND,	LOOKUP
	    0530	/EXTENDED
	JMP OPENER
	JMS I MVR
	    NOLOGS
	JMS I CHG
	    NOEXPS
TRIG,	LOOKUP
	    2422	/TRIGFNS
	JMP OPENER
	JMS I MVR
	    NOTRIG
	JMS I CHG
	    NOFNS

OPENER,	LOOKUP
	    1720	/OPEN
	JMP EQUAL
	DCA DEVHLD
	JMS I CHG
	    NOOHS

EQUAL,	LOOKUP
	    0521	/EQUAL
	JMP SPACER
	JMS I CHG
	    TADEQL
	JMP AMPER

SPACER,	LOOKUP
	    2320	/SPACE
	JMP AMPER
	JMS I CHG
	    NOSPAC

AMPER,	LOOKUP
	    0115	/AMPER
	JMP COLON
	JMS I CHG
	    ANDSGN

COLON,	LOOKUP
	    0317	/COLON
	JMP PDP8E
	JMS I CHG
	     ECHOIT

PDP8E,	LOOKUP
	    2004	/PDP8E
	JMP EAE
	DCA CHR		/CLEAR THE FLAG
	JMS I MVR
	    BSWER
	JMS I MVR
	    KCFER
	JMS I CHG
	    KCCER
	JMS I MVR
	    NUMULT
EAE,	LOOKUP
	    0501	/EAE
	SKP CLA
	CMA
	DCA ATEM
	TAD (UPDATE	/RESET POINTERS
	DCA K177
	CDF 10
	TAD I (GLOOP-2
	IAC
	DCA I (END
	CDF
	JMS I MVR
	    PIE
	JMS I CHG
	    RESTART
	JMP I CKW

LOOKUP=	JMS .
LOOKER,	SAVE+1
	TAD I LOOKER
	CDI 10
	JMS I MID
	SZL
	ISZ LOOKER	/2ND EXIT=FOUND
	ISZ LOOKER
	JMP I LOOKER

	PAGE

CKWRDS,	TAD GOSW	/CHECK FOR 3 WORD CHANGES
	SNA CLA
	JMP CKEAE
	CDF 10
	ISZ I .+1	/ALTER SYMBOL TABLE LIMIT
	TOP
	CDF
	JMS CHANGE
	    THREEW
	TAD ATEM
	SZA CLA
	JMP CKEAE
	JMS CHANGE
	    THREAD
	JMS MOVER
	    NUDIV
CKEAE,	ISZ ATEM	/TEST FLAG
	JMP I 160	/DONE - CALL MONITOR
	JMS MOVER
	    CLASS8	/CLASSIC-8 EAE PATCH
	IAC CLL RTL
	TAD 154		/-4
	SZA CLA
	JMP I 160
	JMS MOVER	/DO COMMON STUFF
	    PRNTX
	JMS MOVER
	    EXPON
	JMS CHANGE
	    PTENP3
	TAD CHR		/CHECK IF 8/E
	SNA CLA
	JMP EAE8E
	JMS MOVER
	    PART1
	JMS MOVER
	    PART2
	ISZ GOSW	/CHECK # OF WORDS
	JMP I 160	/GO AWAY
	JMS MOVER
	    PART3
	JMS CHANGE
	    EAE3W
	JMP I 160	/FINALLY!

	SWBA
	REKOVR
EAE8E,	TAD .-2
	DCA I .-2
	JMS MOVER
	    NUSTUF
	JMS MOVER
	    NYSTUF
	JMS MOVER
	    NIEUW
	JMS CHANGE
	    POINTRS
	ISZ GOSW	/THREE WORD VERSION ?
	JMP I 160	/NOPE
	JMS MOVER
	    QUICKR
	JMS MOVER
	    SHORTR
	JMS CHANGE
	    SMALER
	JMP I 160	/GOOD-BYE!
/MOVING ROUTINES: ONE FOR SINGLES & ONE FOR BUNCHES

CHANGE,	0
	CLA CMA
	TAD I CHANGE
	ISZ CHANGE
	DCA AUTO

CLOOP,	TAD I AUTO
	SNA
	JMP I CHANGE
	DCA MOVER
	TAD I AUTO
	CDF 10
	DCA I MOVER
	CDF
	JMP CLOOP

	GO=0



MOVER,	0
	CLA CMA
	TAD I MOVER
	DCA AUTO
	CMA
	TAD I AUTO
	DCA AUTO 1
	ISZ MOVER

MLOOP,	TAD I AUTO
	CMA
	SNA
	JMP I MOVER
	CMA
	CDF 10
	DCA I AUTO 1
	CDF
	JMP MLOOP

	STOP=-1

DOT=.
	*54
	5723		/DSK

	*66
	FILENAME DIALOG.FC
	*6436
	MONITOR		/RETURN FROM SAVE
	*DOT
NOFNS,	TOP
	PCD-WORDS-1
	GO
NOEXPS,	TOP
	FCOS-WORDS-1
	GO
NOOHS,	BOTTOM		/PDL POINTERS
	PCHK-1
	TXTEND
	5576
	373
	ERROR5		/NO 'FLEN'
	ON-1
	WRITE-1
	ON+4
	NOP
	GO
NOSPAC,	OUTDG+6
	CLA
	GO
TADEQL,	OUTDG+5
	NOPUNCH
	*6141
	ENPUNCH
	TAD OUTDG-1
	GO
	*TADEQL+3
ANDSGN,	5662
	-"&
	CHRT
	"&
	6301
	-"&
	GO
ECHOIT,	1221
	JMS I ECHO
	GO
KCCER,	2667
	KCC
	GO
SMALER,	7164
	-27
	GO
PTENP3,	PTEN+3
	3147
	GO
THREAD,	DMULT4
	5263		/JMP DMDONE
	7072
	DCA OVER2
	MIF
	-27
	GO
THREEW,	GINC
	5		/WORDS+2
	P7
	7
	ZEXIT+2
	POPJ
	XINC
	4		/WORDS+1
	R6
	TAD P7
	MD
	-6		/-DIGITS
	DCOUNT
	-6-1		/-DIGITS-1
	PTEN+2
	3147
	FPNT+2
	DCA OVER1
	6455
	JMP I JUMP
	6476
	5201		/'JMP FPNT+1'
	6540
	DCA OVER1
	TEST2
	27
	GO

RESTART,PT1
	RNDM
	XI33+1
	ISZ I PT1
	PACK2
	NUDATE-1
	PACKIT
	7715
	GLOOK
	2011
	GO

POINTRS,6304
	RISOLV
	6565
	MINUS
	6576
	FLDV
	6752
	RISOLV
	GO

EAE3W,	BE+3
	MQL MUY
	BD+6
	MQL
	GO
NOLOGS,	365
	ERROR5
	ERROR5
	ERROR5
	STOP

NOTRIG,	363
	ERROR5
	ERROR5
	STOP

BSWER,	2355
	BSW
	NOP
	STOP

KCFER,	2637
	NOPUNCH
	*2637
	ENPUNCH
	TAD .+4
	DCA INBUF
	KCF
	JMP XINT
	206		/^F
	STOP

	*KCFER+7
CLASS8,	MP4+3
	NOPUNCH
	*7203
	ENPUNCH
	DCA .+3
	TAD MP2
	MQL MUY
	0
	DCA MP5
	MQA
	DCA MP3
	JMP .+15
/	ZBLOCK 14
	STOP

	*CLASS8+12
PIE,	FLAC
	   2
	3110
	3755
	2421
	STOP

/8-E SYMBOLS

	BSW=7002
	KCF=6030
NUMULT,	MP4+1		/FOCAL8-280
	NOPUNCH
	*7201
	ENPUNCH
	SNA
	JMP I MP4
	SWP
	DCA MP5
	TAD THIR
	DCA MP3
	TAD I MP4
	STL CIA
	TAD DATUMA
	DCA MP1
	TAD I MP1
	SWP

CYCLE,	RAR
	SWP
	SNL
	JMP .+3
	CLL
	TAD MP2
	RAR
	SWP
	ISZ MP3
	JMP CYCLE
	RAR
	DCA I MP1

	TAD MP5
	SWP
	ISZ MP1
	TAD I MP1
	DCA I MP1
	SNL
	JMP I MP4
	ISZ MP1
	ISZ I MP1
	JMP I MP4
	JMP .-3
/	ZBLOCK 6
	STOP

	*NUMULT+45
PART3,	DMULT+6
	NOPUNCH
	*7012
	ENPUNCH
	STL RAR
	JMP BE-1
	STOP

	P7=124
	P4000=124
	*PART3+4
NUDIV,	7271
	NOPUNCH
	*7271
	ENPUNCH
	TAD AC1L
	TAD LORD
	DCA MP2
	RAL
	TAD HORD
	TAD AC1H
	SNL
	JMP .+4
	DCA HORD
	TAD MP2
	DCA LORD
	CLA
	TAD MP1
	RAL
	DCA MP1
	TAD MP4
	RAL
	DCA MP4
	ISZ MP3
	JMP DV3
	TAD MP1
	DCA LORD
	TAD MP4
	DCA HORD
	JMP I DUBDIV
	STOP

	*NUDIV+33
PRNTX,	PRNT+1
	NOPUNCH
	*2443
	ENPUNCH
	AND P177
	MQL DVI
	    12
	SWP
	JMS I ODG
	SWP
	JMS I ODG
	JMP I PRNT
/	ZBLOCK 14
	STOP
	*PRNTX+12
EXPON,	FGO6+12
	NOPUNCH
	*6113
	ENPUNCH
	MQL DVI
	    144
	SWP
	SZA
	JMS OUTDG
	SWP
	JMS I .+2
	JMP I FGO6
	PRNT
/	ZBLOCK 7
	STOP

	*EXPON+13
PART2,	MP4+1
	NOPUNCH
	*7201
	ENPUNCH
	MQL
	RAL
	DCA OVER2
	TAD HORD
	DCA .+3
	TAD AC1L
	SWP MUY
	0
	TAD OVER2
	DCA OVER2
BD,	TAD LORD
	DCA .+3
	TAD AC1H
	SWP MUY
	0
	TAD OVER2
	SWP
	DCA OVER2
	JMP I MP4
/	ZBLOCK 30
	STOP

	*PART2+25
PART1,	DMULT+6		/FOCAL8-283
	NOPUNCH
	*7012
	ENPUNCH
	TAD OVER2
	DCA .+3
	TAD OVER1
	MQL MUY
	0
	MQL
	TAD LORD
	DCA .+3
	TAD OVER1
	SWP MUY
	0
	TAD P4000
	DCA MULDIV
	RAL
	DCA SIGN
	TAD OVER2
	DCA .+3
	TAD AC1L
	SWP MUY
	0
	TAD MULDIV
	MQL
	SZL
	ISZ SIGN
	TAD HORD
	DCA .+3
	TAD OVER1
	SWP MUY
	0
	TAD SIGN
	DCA SIGN
	TAD OVER2
	DCA .+3
	TAD AC1H
	SWP MUY
	0
	TAD SIGN
	DCA SIGN
BE,	TAD LORD
	DCA .+3
	TAD AC1L
	SWP MUY
	0
	TAD SIGN
	JMS I 7152
	TAD HORD
	DCA .+3
	TAD AC1H
	SWP MUY
	0
	DCA HORD
	SWP
	DCA LORD
	JMS MULDIV
	JMP I DMULT
MULDIV,	STOP
	*PART1+71
SHORTR,	7014
	NOPUNCH
	*7014
	ENPUNCH
	TAD LORD
	MQL MUY
	    AC1L
	MQL
	TAD HORD
	SWP MUY
	    AC1L
	DCA AC1L
	TAD LORD
	SWP MUY
	    AC1H
	SWP
	SPA CLA
	ISZ AC1L
	MQA
	TAD AC1L
	MQL
	TAD HORD
	SWP MUY
	    AC1H
	SWP DST
	    HORD
	JMS I .+3
	JMS RISOLV
	JMP I DMULT
	DNORM

/	ZBLOCK 35

	STOP

/EAE SYMBOLS

	MUY=7405
	DVI=7407
	NMI=7411
	SHL=7413
	MQL=7421
	SWAB=7431
	SCA=7441
	DAD=7443
	DST=7445
	SWBA=7447
	DPSZ=7451
	MQA=7501
	SWP=7521
	DCM=7575
	CAM=7621
	DLD=7663
	ACL=7701
	*SHORTR+34
QUICKR,	7176
	NOPUNCH
	*7176
	ENPUNCH
	TAD AC1L
	SWAB
	TAD AC1H
	DST
	    AC1H
	DLD
	    LORD
	DCA LORD
	TAD HORD
	JMP .+5
DLUP,	DLD
	    QHI
	SHL
	    1
	DST
	    QHI
	DAD
	    AC1H
	SNL
	JMP .+3
	DST
	    QHI
	CAM
	TAD LORD
	RAL
	DCA LORD
	TAD HORD
	RAL
	DCA HORD
	ISZ EX1
	JMP DLUP
	JMS DNORM
	JMS I .+2
	JMP I .+2
	RISOLV
	FPNT+1
	STOP		/ZBLOCK 6

/USEFUL PATCHING SYMBOLS

	SHIFTL=4527
	DMULT=7004
	MP3=7255
	MP5=7253
	DATUMA=7252
	DUBDIV=7261
	THIR=7257
	DV3=7267
	EX1=40
	EXP=44
	*QUICKR+46
NUSTUF,	DMULT+1		/FOCAL8-284
	NOPUNCH
	*7005
	ENPUNCH
	TAD EX1
	JMS SGN
	SNA
	JMP ZIRO
	SPA CLA
	JMS MINUS
	SWAB
	TAD OVER2
	MQL MUY
	OVER1
	MQL
	TAD LORD
	SWP MUY
	OVER1
	TAD P4000
	DCA RISOLV
	RAL
	DCA MINUS
	TAD OVER2
	SWP MUY
	AC1L
	TAD RISOLV
	MQL
	SZL
	ISZ MINUS
	TAD HORD
	SWP MUY
	OVER1
	TAD MINUS
	DCA MINUS
	TAD OVER2
	SWP MUY
	AC1H
	TAD MINUS
	DCA MINUS
	TAD LORD
	SWP MUY
	AC1L
	TAD MINUS
	MQL
	RAL
	DCA SGN
	TAD HORD
	SWP MUY
	AC1L
	TAD SGN
	DCA SGN
	TAD LORD
	SWP MUY
	AC1H
	TAD SGN
	SWP
	DCA OVER2
	TAD HORD
	SWP MUY
	AC1H
	SWP DST
	HORD
	JMS I .+3
	JMS RISOLV
	JMP I DMULT
	DNORM
/	ZBLOCK 13
	STOP
	*NUSTUF+100
NYSTUF,	7116
	NOPUNCH
	*7116
	ENPUNCH
SGN,	0
	IAC
	TAD EXP
	DCA EXP
	STL RAR
	AND AC1H
	TAD HORD
	DCA SIGNF
	TAD HORD
	SNA
	JMP ZIRO
	SPA CLA
	NEGATE
	TAD AC1H
	JMP I SGN
ZIRO,	DCA FLAC
	DCA HORD
	DCA LORD
	JMP I .+1
	FPNT+3
MINUS,	0
	TAD OVER1
	SWAB
	TAD AC1L
	DCM
	SWP DST
	AC1L
	SWBA
	CLA CML RAL
	TAD AC1H
	CIA
	DCA AC1H
	JMP I MINUS
RISOLV,	0
	TAD SIGNF
	SPA CLA
	NEGATE
	JMP I RISOLV

M43,	-43
FLDV,	TAD EX1
	CIA
	JMS SGN
	SNA
	ERROR2
	SMA CLA
	JMS MINUS
	TAD M43
	DCA EX1
	SWAB
	SKP

DLOOP,	SHIFTL
	CLL
	TAD OVER1
	TAD OVER2
	DCA DNORM
	RAL
	TAD AC1L
	TAD LORD
	DCA SCNT
	RAL
	TAD AC1H
	TAD HORD
	SNL
	JMP .+6
	DCA HORD
	TAD SCNT
	DCA LORD
	TAD DNORM
	DCA OVER2
	ACL
	RAL
	MQL
	TAD QLO
	RAL
	DCA QLO
	TAD QHI
	RAL
	DCA QHI
	ISZ EX1
	JMP DLOOP
	TAD QHI
	DCA HORD
	TAD QLO
	SWP DST
	LORD
	JMS DNORM
	JMS I .+3
	JMP I .+1
	FPNT+1
	RISOLV
/	ZBLOCK 56
	STOP

	*NYSTUF+134
NIEUW,	7326
	NOPUNCH
	*7326
	ENPUNCH
GT13,	NMI
	SWP DST
	HORD
	CAM SCA
	TAD P14
	JMP ALL0-2
P14,	14
DNORM,	0
	CLA CLL
	TAD LORD
	MQL
	TAD HORD
	SWBA
	NMI
	SWAB
	SCA
	DPSZ
	CLL CIA
	TAD P14
	CLA SCA
	DCA SCNT
	TAD OVER2
	SWP DPSZ
	SKP
	JMP ALL0
	DCA HORD
	TAD LORD
	SNL
	JMP GT13
	SHL
SCNT,	0
	DCA LORD
	TAD SCNT
	CIA
	TAD EXP
ALL0,	DCA EXP
	SWP
	DCA OVER2
	SWBA
	JMP I DNORM
QHI,	0
QLO,	0
	STOP
	*NIEUW+54
	DECIMAL

LINE11,	LINE12
	128+10
TEXT ^O I TTY:;S #=FIN();I (#-206),1.6;I (#-217)1.1,1.7,1.1?M^
LINE12,	LINE13
	128+20
TEXT ^O C;T :7"* * * U/W-FOCAL INITIAL DIALOG * * *"!!;Z?M^
LINE13,	LINE14
	128+30
TEXT ^T "PLEASE ANSWER QUESTIONS WITH Y (=YES) OR N (=NO)"!?M^
LINE14,	LINE15
	128+40
TEXT ^T "DO YOU WISH TO RETAIN THE STANDARD FEATURES_";O (F(1))2,2.8?M^
LINE15,	LINE16
	128+50
TEXT ^T !:7"* * * INITIALIZATION COMPLETED * * *"!;R?M^
LINE16,	LINE17
	128+60
TEXT ^O I TTY:,E;O O TTY:;T " NO"!;X -1;R?M^
LINE17,LINE18
	128+70
TEXT ^O I TTY:,E;O O TTY:;T " YES"!;X 0;R?M^
LINE18,	LINE19
	128+80
TEXT ^C INITIAL DIALOG FOR U/W-FOCAL WRITTEN 2/16/74 BY JIM VAN ZEE/?M^
LINE19,	LINE20
	128+90
TEXT ^DEPT. OF CHEMISTRY/UNIVERSITY OF WASHINGTON/SEATTLE, WA. 98195?M^
LINE20,	LINE21
	256+00
TEXT ^T "0) CHANGE TO 6-DIGIT PRECISION_";I (F(1))2.1;Z WORDS?M^
LINE21,	LINE22
	256+10
TEXT ^T "1) REMOVE FLOG, FEXP & FATN_";I (F(1))2.3;Z EXTENDED?M^
LINE22,	LINE23
	256+20
TEXT ^T "2) REMOVE FSIN AND FCOS_";I (F(1))2.3;Z TRIGFNS?M^
LINE23,	LINE24
	256+30
TEXT ^T "3) REMOVE THE FILE COMMANDS_";I (F(1))2.4;Z OPEN?M^
LINE24,	LINE25
	256+40
TEXT ^T "4) REMOVE THE LEADING SPACE FROM 'TYPE'_";I (F(1))2.6;Z SPACE?M^
LINE25,	LINE26
	256+50
TEXT ^T "5) REPLACE THE LEADING SPACE WITH AN '='_";I (F(1))2.6;Z EQUAL?M^
LINE26,	LINE27
	256+60
TEXT ^T "6) USE '&' IN PLACE OF 'E' FOR EXPONENTS_";I (F(1))2.7;Z AMPER?M^
LINE27,	LINE28
	256+70
TEXT ^T "7) ADD THE ':' PRINTOUT TO 'ASK'_";I (F(1))2.8;Z COLON?M^
LINE28,	LINE29
	256+80
TEXT ^T "8) ADD THE 8/E PATCH_";I (F(1))2.9;Z PDP8E;G 2.9?M^
LINE29,	0000
	256+90
TEXT ^T "9) ADD THE EAE PATCH_";I (F(1))1.8;Z EAE?M^
NXTXT=.;OCTAL
	FIELD 1
	*60
	NXTXT
	NOPUNCH
	XLIST
