
 .ABS
 .LOC 100
/
 .TITLE DRUM-LOAD     /PDP DRUM TO NOVA WRITER
/
IOF=70002
RRB=700112
RSF=700101
RSA=700104
EBA=707764
DRDA=707004
DRSF=707001
IORS=700314
/
 HLT
 LAS
 DAC DRMAD
 RSA      /ENABLE PT. READER
 EBA
 IOF
BEGIN LAC (BUFFER-1
 DAC 12
 DAC 17765
 -3000
 DAC TST
 DAC 17764
 DZM EOT
RLOOP CLA
 JMS READ    /1ST. CHAR. - MSB
 SWHA
 JMS READ   /2ND. CHAR. - LSB
 DAC* 12
 ISZ TST
 JMP RLOOP
DRM LAC DRMAD   /WRITE OUT DRUM
 DRDA
 DRSF
 JMP .-1
 LAC EOT
 SZA
 JMP FIN
 LAC DRMAD
 TAD (3000
 DAC DRMAD
 JMP BEGIN
/
ENDTP CLA!CMA
 DAC EOT
 JMP DRM
/
FIN LAC DRMAD
 TAD (3000
 HLT
/
READ 0
 DAC CHAR
 IORS
 AND (1000
 SZA
 JMP ENDTP
 RSF
 JMP .-1
 RRB
 RSA
 XOR CHAR
 JMP* READ
/
CHAR 0
TST 0
EOT 0
DRMAD 0
BUFFER .BLOCK 3000
 .END 100
