
 .ABS
 .TITLE PLTEST
 .LOC 0
L0       000030
START    KSF
         JMP L1
         KRB
         TAD C1       / C1= -260 = 777520
         DAC TEMP1
         LAS
         CMA
         DAC TEMP2
L2       ISZ TEMP2
         SKP
         JMP LOOP
         LAC TEMP1
         JMS PLOT
         JMP L2
L1       CAF
         ION
         JMP* 0
LOOP     ION
         NOP
         JMP .-1
C1       777520
TEMP1    0
TEMP2    0
KSF=700301
KRB=700312
             /SUBROUTINE PLOT
PLOT      DAC TEM
          AND MASK     / MASK=000007
          RTR
          RTR
          PLSF         / TEST PLOTTER FLAG
          JMP .-1
          LBUFF        / LOAD SERIAL TRANSFER BUFFER
          GATE         / SET THE F-F TO GATE IN THE
                       / DATA AND CLOCK PULSES
          CLKON        / START SERIAL DATA CLOCK
          RTL
          RTL
          TAD C2       / C2= -5 = 777773
          SPA          / SKP IF Y MOVEMENT IS REQUIRED
          JMP* PLOT
          TAD C3       / C3= -1
          SMA
          JMP CLY
          LAC YSTEP
          TAD COUNT    / COUNT = 4
          DAC YSTEP
OUTY      RTL
          RTL
          RTL
          DACEU         / ENABLE DACY UNSIGNED
          DACY          / AC 0-11 >/-> DACY
          LAC TEM
          JMP* PLOT
CLY       SNA
          JMP DOWNY
          LAC YZERO
          DAC YSTEP
          JMP OUTY
DOWNY     LAC YSTEP
          TAD MCOUNT    / MCOUNT = -4
          DAC YSTEP
          JMP OUTY
TEM       0
MASK      000007
C2        777773
C3        777777
YSTEP     001000
COUNT     000004
YZERO     001000
MCOUNT    777774
PLSF=705561
LBUFF=705222
GATE=705562
CLKON=705201
DACEU=701561
DACY=701524
 .END L1
