/ 
/ 
/                   FIRST PRINTING, FEBRUARY 1974
/ 
/ THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO 
/ CHANGE WITHOUT NOTICE AND SHOULD NOT BE CONSTRUED
/ AS A COMMITMENT BY DIGITAL EQUIPMENT CORPORATION.
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPON-
/ SIBILITY FOR ANY ERRORS THAT MAY APPEAR IN THIS
/ DOCUMENT.
/ 
/ THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FUR-
/ NISHED TO THE PURCHASER UNDER A LICENSE FOR USE ON
/ A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH
/ INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR 
/ USE IN SUCH SYSTEM, EXCEPT AS MAY OTHERWISE BE PRO-
/ VIDED IN WRITING BY DIGITAL.
/ 
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/ FOR THE USE OR RELIABILITY OF ITS SOFTWARE ON EQUIP-
/ MENT THAT IS NOT SUPPLIED BY DIGITAL.
/ 
/ COPYRIGHT (C) 1974, BY DIGITAL EQUIPMENT CORPORATION
/ 
/ 
        .EJECT
/
/ EDIT #1
/
/ COPYWRITE 1973 DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/
/ DATE OF LAST EDIT: NOV 27 1973     M. HEBENSTREIT
/
/ EXECUTE -- FORTRAN CALLABLE SUBROUTINE TO EXECUTE A TASK
/ 
/	CALLING SEQUENCE:
/		CALL XQT(TSKNM,PRIO,LUN,PARTNM,(EV))
/			TSKNM IS AN ARRAY HAVING A 1-5 CHAR TASK NAME
/			PRIO IS THE DEFAULT PRIORITY
/			LUN IS THE LUN ON WHICH THE TASK RESIDES
/			PARTNM IS AN ARRAY HAVING A 1-5 CHAR PART NAME
/			EV IS THE EVENT VARIABLE
/ 
/
	.GLOBL XQT,.DAA,.FTSB
/
XQT	0
	JMS*	.DAA		/PICK UP THE ARGUMENT ADDRESSES
	JMP	ARGEND
TSKNM	0
PRIO	0
LUN	0
PARTN	0
EV	0
ARGEND	LAC	EV		/PICK UP THE EVENT VARIABLE ADDRESS
	DAC	XQTEV		/AND STORE IT IN THE CPB
	DZM	EV		/CLEAR EV SINCE ITS OPTIONAL
	LAC*	LUN		/SAVE THE LUN
	DAC	XQTLUN
	LAC*	PRIO		/SAVE THE PRIORITY
	DAC	XQTPRI
	JMS*	.FTSB		/CONVERT THE TASK NAME TO SIXBIT
	TSKNM
	XQTTNM
	JMS*	.FTSB		/CONVERT THE PARTITION NAME TO SIXBIT
	PARTN
	XQTPNM
	CAL	XQTCPB		/ISSUE THE 'EXECUTE' DIRECTIVE
	JMP*	XQT		/RETURN TO MAIN PROGRAM
XQTCPB	34
XQTEV	0
XQTTNM	0
	0
XQTPRI	0
XQTLUN	0
XQTPNM	0
	0
	.END
