/ 
/ 
/                   FIRST PRINTING, FEBRUARY 1974
/ 
/ THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO 
/ CHANGE WITHOUT NOTICE AND SHOULD NOT BE CONSTRUED
/ AS A COMMITMENT BY DIGITAL EQUIPMENT CORPORATION.
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPON-
/ SIBILITY FOR ANY ERRORS THAT MAY APPEAR IN THIS
/ DOCUMENT.
/ 
/ THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FUR-
/ NISHED TO THE PURCHASER UNDER A LICENSE FOR USE ON
/ A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH
/ INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR 
/ USE IN SUCH SYSTEM, EXCEPT AS MAY OTHERWISE BE PRO-
/ VIDED IN WRITING BY DIGITAL.
/ 
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/ FOR THE USE OR RELIABILITY OF ITS SOFTWARE ON EQUIP-
/ MENT THAT IS NOT SUPPLIED BY DIGITAL.
/ 
/ COPYRIGHT (C) 1974, BY DIGITAL EQUIPMENT CORPORATION
/ 
/ 
        .EJECT
/	EDIT #6
/
/ COPYRIGHT 1971, 1973,  DIGITAL EQUIPMENT CORP., MAYNARD,MASS.
/
/			4/13/71	R. MCLEAN
/			14 JUN 73	T. MURRAY
/			28 JAN 74	M. HEBENSTREIT
/
/	DSKAL -- FORTRAN CALLABLE SUBROUTINE
/	   TO ISSUE A REQUEST TO ALLOCATE
/	   DISK SPACE
/
/	CALLING SEQUENCE:
/	   CALL DSKAL (ITA,NW,DVCODE,UNIT,IEV)
/	     ITA=DEVICE CONTROL TABLE
/	      EL1=ACTUAL AMOUNT OF SPACE ALLOCATED
/	      EL2=DISK PLATTER NUMBER (EXTENSION OF EL3)
/   	      EL3=ABSOLUTE DISK STARTING ADDRESS
/ 	     NW=NUMBER OF WORDS TO BE ALLOCATED
/		DVCODE=DISK DEVICE CODE
/			0=SYSTEM DISK
/			2=RF  3=RP  24=RK
/		UNIT=UNIT NUMBER OF DISK DEVICE
/	    IEV=EVENT VARIABLE
/
/
IDX=ISZ
	.GLOBL	DSKAL,.DAA
DSKAL	0	
	JMS*	.DAA
	JMP	ARGEND	/PICK UP THE CALLER'S ARGUMENTS
TBLADR	0
NUMWDS	0
DVCODE	0
UNIT	0
EVNTV	0
ARGEND	LAC	EVNTV	/PUT EVENT VARIABLE ADDRESS IN
	DAC	REQEV	/REQUEST CPB
	DZM	EVNTV	/AND IN WAIT CPB
	LAC*	DVCODE	/MOVE DEVICE CODE TO 5TH WORD
	DAC	DSKTYP	/OF CPB
	LAC	TBLADR	/DEFINE CNTR TABL ADDRESS IN CPB
	DAC	TBLPTR
	DAC	TABTMP	/SAVE ADDR AS A POINTER TO CONTROL TABLE
	LAC*	NUMWDS	/GET THE NUMBER OF WORDS
	DAC*	TABTMP	/MOVE NUMBER OF WORDS TO 1ST WORD OF CTB
	IDX	TABTMP
	LAC*	UNIT	/GET UNIT NUMBER
	CLL!RTR		/LEFT JUSTIFY IN BITS 0,1,2
	RTR
	DAC*	TABTMP	/MOVE TO SECOND WORD OF CTB
	CAL	ALLCPB
	JMP*	DSKAL	/RETURN
/
TABTMP	0		/POINTER TO CONTROL TABLE
ALLCPB	11500		/MULTI-DISK ALLOCATE
REQEV	0		/EVENT VARIABLE ADDRESS
	1		/LUN-1
TBLPTR	0		/CONTROL TABLE (CTB) ADDRESS
DSKTYP	0		/DISK DEVICE CODE
	.END	DSKAL
	.EJECT
