/
/ COPYRIGHT (C) 1975
/ DIGITAL EQUIPMENT CORPORATION, MAYNARD, MASS.
/
/ THIS SOFTWARE IS FURNISHED UNDER A LICENSE FOR USE ONLY
/ ON A SINGLE COMPUTER SYSTEM AND MAY BE COPIED ONLY WITH
/ THE INCLUSION OF THE ABOVE COPYRIGHT NOTICE.  THIS
/ SOFTWARE, OR ANY OTHER COPIES THEREOF, MAY NOT BE PRO-
/ VIDED OR OTHERWISE MADE AVAILABLE TO ANY OTHER PERSON
/ EXCEPT FOR USE ON SUCH SYSTEM AND TO ONE WHO AGREES TO
/ THESE LICENSE TERMS.  TITLE TO AND OWNERSHIP OF THE
/ SOFTWARE SHALL AT ALL TIMES REMAIN IN DEC.
/
/ THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE
/ WITHOUT NOTICE AND SHOULD NOT BE CONSTRUED AS A COM-
/ MITMENT BY DIGITAL EQUIPMENT CORPORATION.
/
/ DEC ASSUMES NO RESPONSIBILITY FOR THE USE OR RELIABILITY
/ OF ITS SOFTWARE ON EQUIPMENT WHICH IS NOT SUPPLIED BY
/ DEC.
/
	.EJECT
/
/ EDIT #1	M. HEBENSTREIT		12/15/75
/
/ MODE14: TAKE THE VALUE IN IFLAG SPECIFIED BY FLAG
/ AND OUTPUT THE VALUE (MEMSIZ IN K WORDS) AS SOME
/ NUMBER OF OCTAL BLOCKS. THE OUTPUT BUFFER
/ MUST HAVE A MULTIPLE OF 5 CHARS EXCLUDING CR.
/
	.GLOBL	MODE14,PACK,IPACK
BASE	.CBD	.XX 200
OFF.FL=4
OFF.IF=35
MODE14	0
	LAC	BASE		/GET BASE ADDR OF COMMON
	AAC	OFF.FL		/ADD OFFSET FOR FLAG
	DAC	TEMP		/SAVE FOR INDIRECT ADDRESSING
	LAC*	TEMP		/GET THE VALUE IN FLAG -- ITS VECTOR COMPONENT
	TAD	BASE		/ADD BASE OF COMMON
	AAC	OFF.IF		/NOW AC SHOULD HAVE ADDRESS OF MEMSIZ
	AAC	-1
	DAC	TEMP
	LAC*	TEMP
	CLL
	MUL			/CONVERT TO OCTAL BLOCKS
	4
	LACQ			/GET NO. OF OCTAL BLOCKS
	DAC	NUM		/SAVE THIS RESULT
	LAC	(BUFF		/INIT BUFFER
	JMS*	IPACK
	LAC	(40		/PACK IN 4 SPACES
	JMS*	PACK
	LAC	(40
	JMS*	PACK
	LAC	(40
	JMS*	PACK
	LAC	(40
	JMS*	PACK
	LAC	NUM		/PREPARE TO PACK NUMBER
	LMQ
	LAW	-6
	DAC	COUNT		/SET UP CHAR COUNTER
LOC1	CLA			/PACK A DIGIT
	LLS	3
	AAC	60
	JMS*	PACK
	ISZ	COUNT		/DONE?
	JMP	LOC1		/NO -- PACK ANOTHER DIGIT
	LAC	(15		/PACK CR
	JMS*	PACK
	.WRITE	2,2,BUFF,6
	.WAIT	2
	JMP*	MODE14		/RETURN
/
NUM	0
COUNT	0
TEMP	0
BUFF	.BLOCK 10
	.END
