/ 
/ 
/                   FIRST PRINTING, FEBRUARY 1974
/ 
/ THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO 
/ CHANGE WITHOUT NOTICE AND SHOULD NOT BE CONSTRUED
/ AS A COMMITMENT BY DIGITAL EQUIPMENT CORPORATION.
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPON-
/ SIBILITY FOR ANY ERRORS THAT MAY APPEAR IN THIS
/ DOCUMENT.
/ 
/ THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FUR-
/ NISHED TO THE PURCHASER UNDER A LICENSE FOR USE ON
/ A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH
/ INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR 
/ USE IN SUCH SYSTEM, EXCEPT AS MAY OTHERWISE BE PRO-
/ VIDED IN WRITING BY DIGITAL.
/ 
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/ FOR THE USE OR RELIABILITY OF ITS SOFTWARE ON EQUIP-
/ MENT THAT IS NOT SUPPLIED BY DIGITAL.
/ 
/ COPYRIGHT (C) 1974, BY DIGITAL EQUIPMENT CORPORATION
/ 
/ 
        .EJECT
/ EDIT #5
/
/ COPYRIGHT 1971,1972,1973,1974 DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/
/ DTRUN                 8 JAN 74              H. KREJCI
/						M. HEBENSTREIT
/
/ RSX CHECKOUT PACKAGE 
/
/ PROGRAM TO GENERATE A FILE CALLED "DTRUN@BIN" ON LUN 37,
/ AND TO READ AND VERIFY IT.
/
	.GLOBL	DTASGN,DTENTR,DTWRIT,DTCLOS
	.GLOBL	DTSEEK,DTREAD,DTDUMY,LOG
/
	.IFUND	NUM	/NUMBER OF RECORDS PER FILE
NUM=2000
	.ENDC
/
DTRUN	JMS*	LOG	/LOG ON
	.ASCII	"BEGIN DT I/O TEST"<15>
/
	JMS*	DTASGN	/WAIT FOR CORRECT ASSIGNMENT OF LUN 37
	JMS*	DTENTR	/ENTER FILE "DTRUN@BIN"
	DZM	REC+2	/SETUP FIRST TWO DATA 
	LAW	-NUM	/WORDS OF RECORD
	DAC	REC+3
LP1	JMS*	DTWRIT	/WRITE RECORD
	REC
	JMS*	DTDUMY
	ISZ	REC+2
	ISZ	REC+3	/LAST RECORD?
	JMP	LP1	/NO -- CONTINUE IN LOOP
	JMS*	DTCLOS	/YES -- CLOSE FILE
/
	JMS*	DTSEEK	/SEEK FILE "DTRUN@BIN" ON LUN 37
	DZM	C1	/SETUP COUNTS
	LAW	-NUM
	DAC	C2
LP2	JMS*	DTREAD	/READ RECORD
	REC
	JMS*	DTDUMY
	LAC	REC+0	/EOF?
	AND	(17)
	SAD	(05)
	JMP	EOF	/YES -- LOG OFF
	LAC	REC+2	/NO -- ARE FIRST TWO DATA WORDS CORRECT?
	SAD	C1
	SKP
	JMP	CERR
	LAC	REC+3
	SAD	C2
	SKP
	JMP	CERR
	ISZ	C1	/YES -- AUGMENT COUNTS
	ISZ	C2
	NOP
	JMP	LP2	/READ NEXT RECORD
/
CERR	JMS*	LOG	/NO -- LOG OFF
	.ASCII	"DT COMPARE ERROR _____________________________"<15>
	CAL	CLOSE
	CAL	(10)
/
EOF	JMS*	LOG	/EOF READ -- LOG OFF, CLOSE FILE & EXIT
	.ASCII	"END DT I/O TEST"<15>
	CAL	CLOSE
	CAL	(10)
/
CLOSE	3400
	0
	37
/
C1	0
C2	0
/
REC	020000		/BINARY RECORD
	000000
	.BLOCK 36
/
	.END	DTRUN
