/ 
/ 
/                   FIRST PRINTING, FEBRUARY 1974
/ 
/ THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO 
/ CHANGE WITHOUT NOTICE AND SHOULD NOT BE CONSTRUED
/ AS A COMMITMENT BY DIGITAL EQUIPMENT CORPORATION.
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPON-
/ SIBILITY FOR ANY ERRORS THAT MAY APPEAR IN THIS
/ DOCUMENT.
/ 
/ THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FUR-
/ NISHED TO THE PURCHASER UNDER A LICENSE FOR USE ON
/ A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH
/ INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR 
/ USE IN SUCH SYSTEM, EXCEPT AS MAY OTHERWISE BE PRO-
/ VIDED IN WRITING BY DIGITAL.
/ 
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/ FOR THE USE OR RELIABILITY OF ITS SOFTWARE ON EQUIP-
/ MENT THAT IS NOT SUPPLIED BY DIGITAL.
/ 
/ COPYRIGHT (C) 1974, BY DIGITAL EQUIPMENT CORPORATION
/ 
/ 
        .EJECT
/
/ EDIT # 3
/				3/5/71
/ COPYRIGHT 1971, DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/
/	.FTSB CONVERT 5-7 ASCII TO SIXBT
/		BLANK'S ARE CONVERTED TO NULL'S
/
/
	.GLOBL	.FTSB
.FTSB	0
	LAC*	.FTSB	/SAVE FROM ADDRESS
	DAC	FADR
	LAC*	FADR	/PICK UP ARRAY ADDRESS
	DAC	FADR	/SAVE IT
	ISZ	.FTSB
	LAC*	.FTSB
	DAC	TADR	/SAVE IN  ADDRESS
	CLQ		/CLEAR MQ
	LAC*	FADR
	ISZ	FADR	/POINT TO NEXT WORD
	LRS	3
	RAR
	JMS	CKFBL	/CHECK FOR BLANKS
	LRS	6	/SECOND CHAR
	RAR
	JMS	CKFBL	/CHECK FOR BLANKS AND REMOVE
	LRS	6	/FIRST CHAR
	LACQ		/PUT FIRST 14 BITS IN AC
	DAC	TMP	/SAVE IT
	LAC*	FADR	/PICK UP SECOND WORD
	LRS	17
	AND	(7)	/MASKOFF FIRST THREE BITS
	XOR	TMP	/ADD IT TO THE PREVIOUS 15 BITS
	JMS	CKFBL	/CHECK FOR BLANKS
	DAC*	TADR	/STORE FIRST SIXBT WORD
	ISZ	TADR	/POINT TO SECOND WORD
	LAC*	FADR
	CLQ
	RAR
	JMS	CKFBL	/CHECK FOR BLANKS
	LRS	6
	RAR
	JMS	CKFBL	/CHECK FOR BLANKS
	LRS	6
	LACQ		/STORE SECOND SIXBT WORD
	DAC*	TADR
	ISZ	.FTSB	/RETURN AT JMS	+3
	JMP*	.FTSB
/
/  CDFBL -  SUBROUTINE TO CHECK FOR BLANKS AND
/             CHANGE BLANK'S TO NULL'S
/
CKFBL	0
	DAC	SVAC	/SAVE AC
	AND	(77)	/MASK OFF SIXBT CHARACTER
	SAD	(040)	/IS IT A 40?
	JMP	CKXOR	/YES MAKE IT A 0
	LAC	SVAC	/NO RESTORE AND RETURN
	JMP*	CKFBL
CKXOR	LAC	SVAC	/PICK UP AC
	XOR	(040)	/REMOVE BLANK
	JMP*	CKFBL
SVAC	0		/TEMP AC STORAGE
TMP	0	/TEMPORARY STORAGE
TADR	0
FADR	0	/FROM ADDRESS
	.END	.FTSB
