/ 
/ 
/                   FIRST PRINTING, FEBRUARY 1974
/ 
/ THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO 
/ CHANGE WITHOUT NOTICE AND SHOULD NOT BE CONSTRUED
/ AS A COMMITMENT BY DIGITAL EQUIPMENT CORPORATION.
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPON-
/ SIBILITY FOR ANY ERRORS THAT MAY APPEAR IN THIS
/ DOCUMENT.
/ 
/ THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FUR-
/ NISHED TO THE PURCHASER UNDER A LICENSE FOR USE ON
/ A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH
/ INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR 
/ USE IN SUCH SYSTEM, EXCEPT AS MAY OTHERWISE BE PRO-
/ VIDED IN WRITING BY DIGITAL.
/ 
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/ FOR THE USE OR RELIABILITY OF ITS SOFTWARE ON EQUIP-
/ MENT THAT IS NOT SUPPLIED BY DIGITAL.
/ 
/ COPYRIGHT (C) 1974, BY DIGITAL EQUIPMENT CORPORATION
/ 
/ 
        .EJECT
/COPYRIGHT 1970, DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/EDIT 6   9-9-71
       .TITLE PAUSE
/OBJECT TIME PAUSE STATEMENT PROCESSOR.
/FOR RSX VERSION,DEFINE RSX
/CALLING SEQUENCE--LAC   NUMBER TO BE PRINTED.
/                  JMS*  .PA
	/IF BACKGROUND-FOREGROUND MONITOR DEFINE BF
	.IFUND RSX
       .GLOBL .PA,.SP
	.GLOBL PAUSE
	.IFDEF BF
	.GLOBL PACPF
	.ENDC
PAUSE=.
.PA    CAL    0
       JMS*   .SP            /PRINT MESSAGE.
       .DSA   PA1            / CONTROL RETURN
       LAW    120            /P
       LAW    101            /A
       LAW    125            /U
       LAW    123            /S
       LAW    105            /E
       LAW    040            /BLANK
	.IFUND BF
       JMP    .              /HALT EXECUTION UNTIL ^P
	.ENDC
	.IFDEF	BF
/DETERMINE IF BG OR FG IN BF ENVIRONMENT
/.SCOM+26=0 IF FG,=1 IF BG
PACYC	LAC*	PACPF		/CHECK ^P FLAG
	SNA			/NOT = IF ON
	JMP	PA2		/NO
	DZM*	PACPF		/CLEAR FLAG AND EXIT
	JMP*	.PA		/EXIT
PA2	LAC*	PA3		/IF IN FG, DO AN .IDLEC
	SZA
	JMP	PACYC		/RECYCLE AND AWAIT ^P
	CAL	1000		/IDLEC
		17
	JMP	PACYC		/RECYCLE AND AWAIT ^P
PA3	126			/.SCOM+26
	.ENDC
PA1    JMP*   .PA            /RETURN TO PROGRAM--ASSIGNED TO INT. GLOBL PAUSE
	.ENDC
	.IFDEF RSX
	.GLOBL	.PA
	.GLOBL	.SP
	.GLOBL	PAUSE
PAUSE=.
.PA	CAL	0
	JMS*	.SP	/PRINT MESSAGE.
	120		/P
	101		/A
	125		/U
	123		/S
	105		/E
	055		/-
	CAL	(6)	/SUSPEND TASK
	JMP*	.PA	/RETURN TO PROGRAM-- ASSIGNED TO INT. GLOBL PAUSE
	.ENDC
       .END
