	.TITLE	RACO
/
/  7 MAR 72 - RESURRECTED BY P. HENDERSON
/
/READ ANALOG COMPONENT ADDRESS
/     SUBROUTINE
/EXECUTION TIME: ABT. 150 USEC
/CALLING SEQUENCE:
/     CALL RACO(TYPE,ADDRESS)
/     TYPE: 0=AMPLIFIER, 1=DERIVATIVE
/           2=FUNCTION GENERATOR,3=TRUNK
/           4=POTENTIOMETER
/           5=PATCH PANEL,6=DERIVATIVE/10
/           7=HAND-SET POTENTIOMETER
/     ADDRESS: 0-119 INTEGER PATCHBOARD
/                 ADDRESS
	.GLOBL	RACO,%BCDB
/
RACO	XX
	.ARG	RACO
	DAC	TYPE    /TYPE LOCATION
	.ARG
	DAC	ADDRES
	IOT3
	JMP	.-1
	RAA
	DAC	TEMP
	RTL; RTL; RAL
	AND	(7
	DAC*	TYPE
	LAC	TEMP
	RTR
	AND	(777
	JMS*	%BCDB
	TAD	(-170
	SMA
	TAD	(-144
	TAD	(170
	DAC*	ADDRES
	JMP*	RACO
/
TYPE;ADDRES;TEMP
/
IOT3=703003
RAA=703413
	.END
