	.TITLE DRA.
/	9-23-68
/COPYRIGHT 1968, DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/DRUM ADAPTATION 6-25-68 (IOPS 22 6-4-68)
/M. SIFNAS 4-17-68 (IOPS 23 5-9-68)(56 FILES,EOF 5-22-68)
/CLEAR FIX (5-15-68)
/DRA.=IOPS DRUM/DECTAPE HANDLER ALL MODES, 3 FILES
/ALL FUNCTIONS
/3-256 WD. BUF.
/3 FILE BIT MAPS, 3 DIRECTORY BIT MAPS (32 WDS EACH)
/3 FILES ACTIVE AT ANY GIVEN TIME
/CALLING SEQUENCE
/CAL+.DAT SLOT(9-17)+I(7-8)/.INIT
/UNIT (0-2)+1
/RESTART ADDR. (MEANINGFUL FOR TTY HANDLER ONLY)
/BUF SIZE (255)
/
/UNIT (0-2)+2 CAL+X(6-8)+.DAT SLOT (9-17) /.OPER (X=1=.DLETE)
/DIR TYPE (0-2)=1+CORE ADDR. (3-17)
/CAL+.DAT SLOT (9-17)  /.SEEK
/UNIT (0-2)+3
/USER DIRECTORY ENTRY POINTER
/SAME AS .SEEK(FUNCTION=4) /.ENTER
/CAL+.DAT SLOT (9-17)  /.CLEAR
/UNIT(0-2)+5
/CAL+.DAT SLOT(9-17)  /.CLOSE
/UNIT(0-2)+6
/.MTAPE - ILLEGAL
/CAL+D.M.(6-8)+.DATSLOT(9-17)  /.READ
/UNIT (0-2)+10
/LINE BUF ADDR
/-WC OF L.B. (2'S COMP)
/SAME AS .READ(FUNCTION=11)  /.WRITE
/CAL+.DAT SLOT(9-17)	/.WAIT
/UNIT(0-2)+12
/CAL+X(8)+.DAT SLOT (9-17)  /.TRAN (X=0=READ)
/UNIT (0-2)+13		(X=1=WRITE)
/BLOCK#
/CORE ADDRESS
/-WC
/
	.EJECT
	.GLOBL	DRA.
.SCOM=100
.MED=3
/IOT ASSIGNMENTS
DRSF=706101	/SKIP ON DONE FLAG
DRNEF=706201	/SKIP ON NOT ERROR
DRCE=706202	/CLEAR DATA ERROR
DRCF=706102	/CLEAR DONE, ERROR FLAGS AND TRACK ADDR.
DRLD=706106	/DRCF+LOAD DRUM ADDR AND BEGIN TRANSFER
DRRD=706006	/LOAD CORE ADDR. ANF SET TO READ
DRWR=706046	/LOAD CORE ADDR. AND SET TO WRITE
DRCONT=706204	/CLEAR FLAGS AND TRANSFER NEXT SECTOR
DASIZE=BLAND-BLAB				/FILE BLOCK A SIZE
DABSIZ=BLBND-BLAB				/FILE BLOCK A+B SIZE
DBSIZE=DABSIZ-DASIZE
DABSZ2=DABSIZ*2
DELTA=5
DRA.	DAC	DTCALP		/CAL POINTER
	DAC	DTARGP		/ARG. POINTER
	ISZ	DTARGP		/INDEX TO FUNCTION (AND UNIT#)
	LAC*	DTARGP
	AND	DTUMSK
	DAC	DTCT1		/T SAVE UNIT#
/EXTRACT DATA MODE OR SUBFUNCTION
	LAW 7000
	AND* DTCALP
	RAR!CLL
	RTR
	RTR
	RTR
	RTR
	DAC DTCT2	/T STORE DATA MODE OR SUBFUNCTION
/FILE STORAGE BLOCK SWAP ROUTINE
	LAC*	DTCALP		/GET DAT SLOT (9-17)
	AND	L777
DTSLOT=DTTABL			/TEMP. STOR. FOR .DAT SLOT OF CURRENT CALL
SWAPSW=DTNTRZ
	DAC	DTSLOT		/T. SAVE
	DZM SWAPSW		/CLEAR SWAP SW
	SAD	DTFLS2	/FILE 2 SLOT #
	JMP	DTSW2	/CURRENT CALL FOR FILE 2-SET UP SWAP
	SAD	DTFLS3	/FILE 3 SLOT #
	JMP	DTSW3	/CURR. CALL FOR FILE 3- SETUP SWAP
	SAD	DTFLS1	/FILE 1 SLOT #
	JMP	DTSLOK		/CURRENT CALL FOR FILE 1
	LAC DTFLS1		/FILE 1 SLOT #
	SNA
	JMP	DTSLOK		/EMPTY
	LAC DTFLS2
	SNA
	JMP	DTSW2	/EMPTY - SWAP.
	LAC DTFLS3
	SZA!CLA		/EMPTY - SWAP
	JMP	DTER17		/EXCESSIVE # OF FILES REFERENCED
	.EJECT
/ROUTINE TO SET UP FOR FILE 3 SWAP
DTSW3	LAC DTFLS1		/SLOT 1 INTO SLOT 3
	DAC DTFLS3
	LAC LDBSZ2
	JMP	DTSW4
/ROUTINE TO SET UP FOR FILE 2 SWAP
DTSW2	LAC DTFLS1		/FILE 1 SLOT INTO FILE 2 SLOT
	DAC	DTFLS2
	LAC LDBSZ	/(DABSIZ
DTSW4	DAC	DADSIZ	/FILE BLOCK RELAT. POSITION
/SWAP STORAGE BLOCKS
DTSWAP	LAW	-DABSIZ		/SAVE FULL BLOCK (A & B)
	DAC SWAPSW		/SET SWAP SW
DTSWP1	DAC	DTCT		/COUNT TO MOVE
	LAC	(DLTDIR	/1ST ADDR. OF FILE BLOCK 1
DTFB1P=DTMPS		/FILE BLOCK 1 POINTER
DTFB2P=DTMPP		/FILE BLOCK 2 POINTER
	DAC	DTFB1P		/FILE BLOCK 1 POINTER
	TAD	DADSIZ
	DAC	DTFB2P		/FILE BLOCK 2 POINTER
DTSWP2	LAC*	DTFB1P		/SAVE BLOCK 1 CELL
DTBLSV=DTWCS
	DAC	DTBLSV
	LAC*	DTFB2P		/BLOCK 2 CELL INTO BLOCK 1
	DAC*	DTFB1P
	LAC	DTBLSV		/BLOCK 1 CELL INTO BLOCK 2
	DAC*	DTFB2P
	ISZ	DTFB1P
	ISZ	DTFB2P
	ISZ	DTCT
	JMP	DTSWP2		/CONT.
	.EJECT
DTSLOK	LAC	DTCT1		/CURR. UNIT
	DAC	DTUNIT		/INTO FILE BLOCK 1
	LAC	DTSLOT		/STORE CURRENT DAT SLOT #
	DAC	DTFLS1		/IN FILE BLOCK 1
	LAC* DTARGP		/IS THIS CALL AN INIT?
	AND DLIT77
	XOR DLIT1
	SZA!CLC			/YES, USE NEW I/O BIT
	JMP DTSWMD
	DAC SWAPSW		/SET SWAP SW
	LAC DTCT2
	SKP
DTSWMD	LAC DTIOSW
	DAC DTIOSW		/T STORE
	SNA			/OUTPUT?
	JMP DTONW		/NO
	SAD DTIOSW+DABSIZ		/IS FILE 2 OUTPUT?
	JMP D2SAME		/YES, SWAP MORE MAYBE
DTSWME	SAD DTIOSW+DABSZ2		/IS FILE 3 OUTPUT?
	JMP D3SAME		/YES, SWAP MORE MAYBE
	JMP DTONW
D2SAME	LAC SWAPSW		/SWAP SW SET?
	SZA
	LAC DTSKNT+DABSIZ		/ENTER EXECUTED?
	SNA			/YES
	JMP D2SAM1
	LAC DTUNIT		/OUTOUT ON SAME UNIT?
	XOR DTUNIT+DABSIZ
	DZM DTSAM2
	SNA!CLC
	JMP DTER23		/IOPS 22: 2OUTPUT FILES ON 1 UNIT
D2SAM1	LAC DTIOSW		/CHECK FILE 3
	JMP DTSWME
D3SAME	LAC SWAPSW		/SWAP SW SET?
	SZA
	LAC DTSKNT+DABSZ2		/ENTER EXECUTED?
	SNA			/YES
	JMP DTONW
	LAC DTUNIT		/SAME UNIT
	XOR DTUNIT+DABSZ2
	DZM DTSAM3
	SNA!CLC
	JMP DTER23		/IOPS 22: 2 OUTPUT FILES ON 1 UNIT
/
	.EJECT
DTONW	LAC*	DTARGP		/FUNCTION (3-17)=1-13
	ISZ	DTARGP		/INDEX TO ARG.3
	AND	DLIT77
	TAD	(JMP DTTABL
	DAC	DTTABL
	LAC DFULSW	/FULL SWITCH SET?
	SZA!CLL
	JMP DTCLOS	/YES - CONT. CLOSING PARTIAL FILE
DTTABL	XX
	JMP	DTIN		/1=.INIT
	JMP	DTOPER		/2=.OPER
	JMP	DTSEEK		/3=.SEEK
	JMP	DTENTR		/4=.ENTER
	JMP	DTCLER		/5=.CLEAR
	JMP	DTCLOS		/6=.CLOSE
	JMP	DTER6		/7=.MTAPE(ILL)
	JMP	DTREAD		/10=.READ
	JMP	DTWRIT		/11=.WRITE
	JMP	DTWAIT		/12=.WAIT,.WAITR
	JMP	DTRAN		/13=.TRAN
DTBUSY	LAC	DTCALP		/BUSY-DTA I/O GOING ON
	DAC	DTARGP		/RETURN TO USER CAL
	JMP	DTDBK
/I/O UNDERWAY CHECK SUBR.
DTIOU	0
	LAC	DTUND		/I/O UNDERWAY
	SZA			/NO
DTBUSB	JMP	DTBUSY		/WAIT
	LAC	DTWRWT		/CONTINUE MORE I/O
	SZA!CMA
	JMP*	DTWRWT		/YES
	JMP*	DTIOU		/OK-EXIT
/DTA-DISK-INTERRUPT SERVICE
DTPIC	DAC DTAC		/SAVE AC
	LAC* DLIT0
	DAC DOUT		/SAVE PC, LINK, EXT. MODE, MEM. PTCT.
	LAC (ION
	JMP DTSTON
DTINT	JMP DTPIC	/PIC ENTRY
	DAC DTAC		/API ENTRY, SAVE AC
	LAC DTINT	/SAVE PC, ETC.
	DAC DOUT
	IORS		/CHECK PIC STATUS
	SMA!CLA		/FOR RESTORATION AT DISMISSAL
	LAW 17740	/PIC OFF, BUILD IOF
	TAD (ION	/PIC ON, BUILD ION
	.EJECT
DTSTON	DAC DTDVSW
	DRNEF		/SKIP ON NOT ERROR
	JMP DRER
/DONE FLAG MUST HAVE COME UP
	LAC DRDWAT	/IS THIS A DONE FLAG WAIT COND.?
	SZA
	JMP DRPREV	/YES, RESOLVE EARLIER ERROR STATE
DRERET	LAC DWORD	/FULL TRANSFER COMPLETED?
	TAD (400
	SZA		/YES
	JMP DRMORE	/NO, TRANSFER MORE
	DRCF		/CLEAR FLAGS
	DZM DTUND	/CLEAR I/O UNDERWAY SW.
	LAC DTSAFE	/BLK 100(DIRECTORY) IN?
	AND L777
	XOR DLT100
	XOR DTDRGT	/DIR. REQ. SW.
	SZA!CLC
	JMP DTDISM
	DAC DTDRGT	/CLEAR (ALL 1'S) DTDRGT
	LAC DTUNIT
	DAC DTNCOR	/SET DIR IN CORE SW.
	JMP DTDISM
/MORE SECTORS TO BE TRANSFERRED
DRMORE	DAC DWORD	/UPDATE WORD COUNT
	RAL	/L=1=MORE FULL SECTORS;0=PARTIAL
	ISZ DTSAFE	/INDEX SECTOR ADDR
	LAC DTCCA	/UPDATE CORE ADDR
	TAD (400
	DAC DTCCA
	SNL		/FULL SECTOR
	JMP DRMOR1	/PARTIAL
	DRCONT
	JMP DTDISM
DRMOR1	LAW -400
	TAD DWORD
	DAC DWORD	/RESTORE TO NEG
	JMS TRANLS	/INITIATE PARTIAL TRANSFER
	JMP DTDISM
/ERROR FLAG ROUTINE
DRER	DRCE		/CLEAR DATA ERROR
			/CLEARS ONLY IF TIMING OR WRITE LOCK
	LAC DRIOT
	SAD (DRRD
	LAC (JMP DPARIT	/PARITY OR TIMING
	DRNEF		/IF SKIP, TIMING OR WRITE LOCK
	SKP		/DEFINATELY PARITY
	LAC DLCLA
	DAC DRDWAT	/SET DONE WAIT FLAG
	.EJECT
/COME HERE ON DONE TO CHECK FOR EARLIER ERROR STATE
DRPREV	DAC DRXCT		/CLA(EFFECTIVE NOP) OR JMP DPARIT
	DRSF		/SKIP ON DONE
	JMP DTDISM	/DISMIS TO WAIT FOR DONE
	DZM DRDWAT
DRXCT	XX		/CLA OR JMP DPARIT
	LAC (DRETRY
	DAC* DLIT3
	LAC DLIT4	/IOPS 4 FOR TIMING OR WRITE LOCK ERRORS
	JMP* DLIT4
DPARIT	ISZ DTERCT	/ERROR RETRY COUNT
DRETRY	JMS DKSET		/REISSUE DRUM TRANSFER
DNRET	LAC DTERCT	/0 IF RETRY COUNT OVERFLOWS
	DAC DTUND	/I/O UNDERWAY SW
	SNA
	JMP DRERET	/DATA ACCEPTED, SEE IF MORE
DTDISM	LAC	(JMP DTPIC	/RESTORE PIC INTERR. ENTRY
	DAC	DTINT
	LAC	DTAC		/RESTORE AC
DTDVSW	XX			/ION IF PIC, LAC  DTAC IF API
	DBR
	XCT .+1
	JMP*	DOUT		/INTERR. EXIT
/
	.EJECT
/INIT DTA ROUTINE - MAINSTREAM
DTIN	ISZ	DTARGP		/INDEX TO BUF. SIZE ARG.
	LAC	L377		/RETURN 255 AS BUF. SIZE
	DAC*	DTARGP
	LAC	DTCT2		/I OR O
	DAC	DTIOSW		/OUTPUT=1, INPUT=0
	ISZ	DTARGP		/INDEX TO NORM. EXIT
	LAC	DLMBIT		/DTMBIT)=FILE BITMAP POINTER
	JMS	DTBFC2		/CLEAR FILE BIT MAP (L=0)
	LAC	DTSAM2	/SAME UNIT-2 0R MORE FILES
	TAD	DTSAM3
	SNA		/YES-CHECK DAT SLOT
	JMP	DTIN1	/NO
	LAC	DTFLS1	/IS CURR. DAT SLOT SAME AS
	SAD	DTCSLT	/THAT FOR I/O UNDERWAY
DJSTOP	JMP	DTSTOP	/YES
	JMP	DTIN2	/NO-WAIT
DTIN1	LAC	DTUND	/IS I/O UNDERWAY FOR
	AND	(700000	/A UNIT OTHER THAN
	XOR	DTUNIT	/CURRENT UNIT
	SZA		/NO
DTIN2	JMS	DTIOU	/YES-WAIT
DTONCE	CAL	46		/API CORE ADDR.-MODIFIED
/
/DTONCE+1 UP TO DTSTOP USED FOR TEMP. STORE. AFTER 1ST .INIT
/DTAC=AC STORAGE CELL DURING INTERRUPT
/DOUT=INTERRUPTED RETURN ADDRESS
/DTERCT=PARITY COUNTER (INIT. TO-10)
/DTCSLT=DAT SLOT FOR I/O UNDERWAY
DTAC	16			/.SETUP
DOUT	DRSF			/DRUM DONE  FLAG
TRANT1	DTINT		/DRUM INTERRUPT SERV. ADDR.
TRANT2	CAL 46		/API CHANNEL REG.
DTERCT	16
DTCCA	DRNEF		/SKIP ON NOT ERROR
DTSAFE	DTINT
DTTR	LAC* (.SCOM+4	/BITS 15-17=DRUM SIZE (1-5)
DTWPC	AND (7
DTDATC	SNA
DCLTMP	JMP DTER35	/IOPS 35: DRUM SIZE NOT IN .SCOM+4
DTDMOD	DAC DCLTMP	/TEMP STORE
DTHPTS	TAD DRLIM	/LAC DRSTAB 1ST TIME THRU
DTUCKP	DAC DRLIM
DRLIM	LAC DRSTAB	/LAC DRSTAB,LAC DRSTAB+1-5, OR -(DRUM SIZE)
DTUDP	CMA
DTUHP	DAC DRLIM
DTCLR3	LAC DCLTMP	/SET UP CONSTANTS FOR DIRECTORY CLEAR
DTWC	TAD DTCLR4	/LAC DCLRTA 1ST TIME THRU
DTCKSM	DAC DTCLR4
	.EJECT
DTCLR4	LAC DCLRTA	/LAC DCLRTA,LACDCLRTA+1-5, OR BIT MAP POINTER
	DAC DALL1
	LAC DCLTMP
	TAD DTCLR5	/LAC DCLRTB
	DAC DTCLR5	/LAC DCLRTB+1-5 (# OF ALL 1 CELLS ON END
			/OF DIRECTORY BIT MAP
	LAC DJSTOP
DTCSLT	DAC	DTONCE
	JMP DTSTOP
DRDWAT=.		/DONE FLAG WAIT SWITCH (NON 0=WAIT)
DTER35	LAW 35
	JMP* DLIT4
DRSTAB=.
/DRSTAB= TABLE OF SECTORS (MAX) ACCORDING TO DRUM SIZE
	JMP DTSTOP
	177		/32K=1/4 DECTAPE=128 BLKS (.SCOM+4,15-17=1)
L377	377		/65K 1/2         256                     2
L777	777		/131K 1          512                     3
	1777		/262K 2          1024                    4
DCLRTA=.
/DCLRTA=TABLE OF # OF CELLS TO SET TO ALL 1 IN DIRECTORY CLEAR
	3777		/524 4          2048                     5
	LAW -30	/32K: 24 CELLS = 1
	LAW -21		/65K: 17 CELLS = 1
	LAW -3		/131K: 3 CELLS = 1
	LAW -3		/262K
	LAW -3		/524K
DTBMIN=DTFAKE			/BIT MAP BLOCK IN SWITCH (NON0=IN)
DTBMOT=DTFAKE+1			/BIT MAP BLOCK OUT SWITCH (NON0=OUT)
/
	.EJECT
/STOP DTA ROUTINE
DTSTOP	DZM	DTUND		/CLEAR I/O UNDERWAY
	DZM DRDWAT	/CLEAR DONE FLAG WAIT STATE
	DZM	DTWRWT		/CLEAR OUTPUT WAIT SWITCH
	DZM	DTEOF		/CLEAR EOF SWITCH
	DZM	DTCLSS		/SET .CLOSE SWITCH
	DZM	DTSKNT		/CLEAR .SEEK, .ENTER SWITCH
	DZM	DTWREX		/CLEAR .WRITE EXECUTED SWITCH
	DZM	DTBMIN		/BIT MAP BLOCK IN SWITCH
	DZM	DTBMOT		/BIT MAP BLOCK OUT SWITCH
	LAC	DTMTP4		/JMP DTAPE1
	DAC	DTOUT
	DAC DTNCOR	/CLEAR DIR IN CORE SWITCH
	JMP	DTDBK-1
/WAIT DTA ROUTINE
DTWAIT	LAC	DTCT2		/0 IF .WAIT
	SNA				/1 IF .WAITR
	JMP	DTDBK-1
	LAC	(700000		/GET LINK, ETC.
	AND	DTCALP
	DAC	DTCALP
	LAC*	DTARGP		/BUSV ADDR.
	AND	L77777
	XOR	DTCALP
	ISZ	DTARGP
	DAC	DTCALP
	JMS	DTIOU		/CHECK I/O UNDERWAY
DTDBK	DBR
	XCT .+1
	JMP*	DTARGP		/NORM. EXIT
	.EJECT
/.OPER ROUTINE TO INTERPRET:
/.DLETE (SUBFUNCTION 1)
/.RENAME (SUBFUNCTION 2)
/.FSTAT (SUBFUNCTION 3)
DTDLUN=DTEOF		/DELETE, RENAME UND-WAY SWITCH
DTUDRP=DTCKSM			/USER DIR ENTRY POINTER (INDEXED)
DTOPER	LAC	DTDLUN		/DELETE OR RENAM UNDERWAY
	SZA			/NO, IF 1ST PASS THUR
	JMP	DTLET3		/YES
	LAC	DLFAKE		/SETUP FOR DELETE
	DAC	DTUDRP
	JMS	DTNTRZ		/DZM DT1SAV OR DT2SAV
	CLA
	XCT	DTNTR3		/CLEAR LAST WD OF DTNSAV
	JMS	DTCKCL		/CHECK DIRECTORY FOR THIS FILE
	DAC	DTNXBK		/SAVE FOR AC=0ON NOT FOUND
	SNA
	JMP	DTFST		/NOT FOUND-RETURN WITH AC=0
	JMS	DTCK		/CHECK FILE COMPLETE LIST
	LAC	DTCT2		/SET UP SUBFUNTION DISPATCH
	TAD	(JMP DTOPTB
	DAC	DTOPTB-1
	LAW	-4
	TAD	DTCT2		/CHECK SUBFUNCTION
	SPA!CLA			/1-3 LEGAL ONLY
	XX			/DISPATCH TO SUBFUNCTION
DTOPTB	JMP	DTER6		/ILL. HANDLER FUNCTION
	JMP	DTLET		/1=.DLETE
	JMP	DTREN		/2=.RENAM
DTFST	LAC*	DTARGP		/3=.FSTAT
	XOR	(100000		/RETURN TYPE (1 IN 0-2)
	DAC*	DTARGP		/TO USER
	LAC	DTNXBK		/PICK UP BL#, RETURN TO USER IN AC
	DZM	DTCLSS
	JMP	DTAPE1
/.RENAM ROUTINE
DTREN	JMS	DTNTRZ		/NEW NAME INTO DTESAV
	XCT	DTSK5		/GET 4TH WD OF OLD ENTRY
	XCT	DTNTR3		/SAVE IN DTESAV+3
	DAC	DTBMIN		/NO NEED TO RERECORD
	DAC	DTBMOT		/FILE BIT MAPS
/.DELETE ROUTINE
DTLET	CLC
	DAC DTNCOR	/CLEAR DIR IN CORE SWITCH
	DAC	DTDLUN		/SET DELETE UNDERWAY SWITCH
	DAC	DTIOSW		/SIMULATE WRITE
	DAC	DTWREX		/USE .CLOSE TO MODIFY
	LAC	DLTDIR		/SETUP FOR TRAN OF
	DAC	DTBMPT		/DIR BIT MAP TO DIR ENTRY SECTION
DTLET3	ISZ	DTARGP		/INDEX ENTRANCE ARG. POINTER
	JMP	DTCLOS		/FILE BIT MAP+DIRECTORY
	.EJECT
/CHECK DIRECT. IN CORE SUBR.
DTDRCK	0
	JMS	DTIOU		/I/O UNDERWAY
	LAC	DTNCOR		/D IN 
	SAD	DTUNIT		/NO
	JMP*	DTDRCK		/YES - EXIT
	LAC	(DRRD		/READ PARAM
	JMS	DTDRIN		/BRING IN DIRECTORY
	JMP	DTDRCK+1		/WAIT FOR DIRECTORY
/
/CALL IN DIRECTORY SUBR.
DTDRIN	0
	DAC	DTTR		/TRANSFER DIRECTION SWITCH
	LAC	DLT100
	DAC	DTNXBK		/BL# TO TRANSFER
	DZM	DTDRGT		/SET IND. TO SET DIR IN CORE SWITCH
	LAC	DTCLSS		/0 IF SEEK, ENTER
	SZA
	LAC	(40		/NOT 0 IF CLOSE (DTBUF-1
	TAD	DLTDIR		/(DTRDIR
DTDRN1	JMS	DTWCS		/SETUP WC,CA
	JMP*	DTDRIN
/
DTUDRR=DTDVS			/USER DIR. ENTRY POINTER (FIXED)
DTCTS=DTCCA			/ENTRY COUNT (-3)
DTCT1S=DTWC			/MATCH COUNT (-4)
DTDES=DTWCS			/DTA DIR. ENTRY SECTION POINTER (INDEXED)
/DIRECTORY SEARCH SUBR.
DTSK1	0
	DAC	DTUDRR		/USER DIR. ENTRY POINTER
DTSK2	CLC		/SYSTEM TAPE?
	XOR* DLTSYS	/WD3 OF SYS BIT MAP
	SNA!CLA		/NO,56 FILES
	LAW -30		/YES, 24 FILES
	SMA
	LAW -70
	DAC	DTFPCT		/DIR. POINTER=DTDIR+40=DTBUF
	XOR (777700
	DAC DBLKLC		/50 IF 24;10 IF 56
	LAC	DLTBUF		/DIR. POINTER=DTDIR+40=DTBUF
DTSK3	DAC	DTDES		/ENTRY SECTION POINTER
	DAC	DTCURE		/CURR. ENTRY, WD0, POINTER
/NEXT FILE NAME ENTRY
	LAC	DTUDRR		/USER DIR. ENTRY POINTER
	DAC	DTUDRP
	LAW	-4
	DAC	DTCT1S		/MATCH COUNT
	DAC	DTCTS		/COUNT OF ENTRY WDS TO CHECK
	ISZ	DTCTS
	.EJECT
/NEXT WORD OF CURRENT ENTRY
DTSK5	LAC*	DTDES		/DTA DIR. ENTRY (.E.)
	SAD*	DTUDRP		/USER D.E.
	ISZ	DTCT1S		/WD N OF ENTRY SATCHES
	ISZ	DTDES		/NEXT WD OF DTA ENTRY
	ISZ	DTUDRP		/NEXT WD OF USER ENTRY
	ISZ	DTCTS		/ENTRY WD COUNT
	JMP	DTSK5		/CONT. MATCH CHECK
DTSK6	LAC	DTCURE
	ISZ	DTCT1S		/MATCH
	SKP			/N
	JMP*	DTSK1		/YES-CURRENT ENTRY POINTER IN AC
	TAD	DLIT4		/INDEX TO NEXT ENTRY
	ISZ	DTFPCT		/INDEX FILE ENTRY CT.
	JMP	DTSK3		/NEXT ENTRY
	CLA
	JMP*	DTSK1		/YES-CAN'T FIND FILE NAME
/CLOSE FILE SUBR
DTCLOS	JMS	DTIOU		/I/O UNDERWAY WAIT
	LAC	DTIOSW		/I OR O
	SNA
	JMP	DTFND1		/INPUT-CLEAR SWITCHES EXIT
	LAC	DTWREX		/WRITE EXECUTED AFTER .ENTER
	SZA
	JMP	DTCLS2		/YES
	JMS	DTCBIT		/NO-CLEAR BIT MAP
	JMP	DTFND1
DTCLS2	LAC	DTEOF		/EOF BUF IS OUT
	SPA!CLC
	JMP	DTCLS3
	DAC	DTEOF		/SET EOF SWITCH
	DZM DTCT2	/FAKE DATA MODE = IOPS BIN
	LAC	(DRWR		/OUTPUT
	JMS	DTMCK
	LAC	DLEOFH		/EOF HEADER POINTER (DTEOFH
/FAKE ARG FOLLOWS - USED AS VARIABLE
DTDRGT	LAW -1		/GET DIR IND. (0=GET)
	JMP	DTWRT1
	.EJECT
DTCLS3	LAC	DTBMIN		/FILE BIT MAP BLOCK IN
	SZA!CLC
	JMP	DTCLS4
	DAC	DTBMIN		/SET BIT MAP IN SWITCH
	LAW -50
	TAD DBLKLC
	SNA!CLA		/NON 0 IF 56 ENTRIES
	LAW -4
	TAD DLIT77
DTCLT	DAC	DTNXBK		/BIT MAP BLOCK #
	LAC	DTFPCT		/FILE COUNT
	TAD	(10
	DAC	DTFPCT
	SMA!CLC
	JMP	DTCLQ		/IN THIS BLOCK
	TAD	DTNXBK		/DECR. BIT MAP BL# BY 1
	JMP	DTCLT
DTCLQ	LAC	DTBUSB
	DAC	DTOUT
	JMP	DTSEK1		/READ BIT MAP BLOCK INTO DIR. BIT MAP
DTCLS4	LAC	DTBMOT		/FILE BIT MAP BLOCK OUT
	SZA!CLC
	JMP	DTCLS6
	DAC	DTBMOT		/SET BIT MAP OUT SWITCH
	LAC	DTFPCT		/REL. BIT MAP POINTER
	CLL!RAL			/X 40
	RTL
	RTL
	TAD	DLTBUF		/(DTBUF
DTOLBM=DTOBCK		/RELATIVE FILE BIT MAP ADDRESS
DTXROL=DTMPS		/OLD FILE BIT MAP ADDRESS
	DAC	DTOLBM
	DAC	DTXROL		/OLD BIT MAP ADDR.
	LAC	DLTDIR		/DIR. BIT MAP ADDR.
	JMS	DTXOR		/XOR OLD FILE BIT MAP INTO DIR. BIT MAP
	LAC	DLMBIT		/NEW FILE BIT MAP ADDR
	DAC	DTXROL
	LAC	DTOLBM		/OLD BIT MAP ADDR
	JMS	DTXOR		/XOR NEW INTO OLD BIT MAP
	LAC	(DRWR
	JMP	DTSEK2		/OUTPUT BIT MAP BLOCK
/
	.EJECT
/SUBROUTINE TO XOR BIT MAP 1 INTO BIT MAP 2
/ALSO CLEARS BIT MAP 1 IF LINK = 0
DTXOR	0
DTXRNW=DTMPP		/NEW BIT MAP ADDRESS
	DAC	DTXRNW		/BIT MAP 2 ADDR
	LAW	-40
	DAC	DTCTS
DTXOR1	LAC*	DTXROL		/BIT MAP 1 POINTER
	XOR*	DTXRNW		/BIT MAP 2 POINTER
	DAC*	DTXRNW
	SNL!CLC			/DO NOT CLEAR BIT MAP 1, CLC FOR SETTING DTNCOR
	DZM*	DTXROL		/CLEAR BIT MAP 1
	ISZ	DTXROL
	ISZ	DTXRNW
	ISZ	DTCTS
	JMP	DTXOR1
	JMP*	DTXOR
DTCLS6	LAC	DTCLSS		/FILE CLOSED
	SNA!CLC
	JMP	DTFEND		/YES-CLEAR SWITCHES, EXIT
	JMS	DTDRCK		/LOAD DIRECTORY INTO DTBUF
	LAC	DTBMPT		/DT. BIT MAP POINTER
DTCLRP=DTMPS		/COUNTER
	DAC	DTCLRP		/NIT. DIR ENTRY SECT. POINTER
	LAW	-40		/DIR. ENTRY SECTION COUNT
	DAC	DTCT
	LAC	DLTBUF		/(DTBUF)
	DAC	DTCT1
DTCLS5	LAC*	DTCLRP		/TRANSFER DIR. BIT MAP
	DAC*	DTCT1		/TO FRONT OF DIR. ENTRY SECTION
	ISZ	DTCLRP
	ISZ	DTCT1
	ISZ	DTCT
	JMP	DTCLS5
	LAC	DLSAV		/(DTESAV
	.EJECT
DTFIN=DTBFC2			/DTESAV POINTER
	DAC	DTFIN
	LAC	DTCURE		/ADD 40 TO ACCOUNT FOR BLOCK MOVE
	TAD	(40
	DAC	DTCURE
	LAW	-4
	DAC	DTCT
DTCLS7	LAC*	DTFIN		/NEW FILE NAME (4 WDS)
	DAC*	DTCURE		/INTO DIRECTORY ENTRY SECTION
	ISZ	DTFIN
	ISZ	DTCURE
	ISZ	DTCT
	JMP	DTCLS7
	LAC	(DRWR		/REWRITE DIRECTORY
	JMS	DTDRIN
	DZM	DTCLSS		/CLEAR CLOSE IND.
	JMP	DTCLOS
DTFEND	DAC	DTNCOR		/CLEAR DIR IN CORE SWITCH
DTFND1	DZM DTFLS1		/CLEAR FILE 1 SLOT #
	LAC DFULSW	/FULL SWITCH SET?
	DZM DFULSW	/CLEAR
	SZA!CLC
	JMP DTER16	/YES - OUTPUT MSG 15
	JMP	DTSTOP		/CLEAR OTHER SWITCHES+EXIT
/.TRAN ROUTINE
DTRAN	JMS	DTIOU		/I/O UNDERWAY
	LAC*	DTARGP		/BL#
	JMS	DTSET		/SETUP BL#, ETC
	ISZ	DTARGP
	LAC*	DTARGP 		/CORE ADDR.
	ISZ	DTARGP
	DAC DTCCA
	LAC*	DTARGP		/WC
	SZL		/READ
	AND DTUMSK	/WRITE: MUST BE MULTIPLE OF 256
	DAC DWORD	/SAFE WORD COUNT
	TAD L377
	SMA
	JMP TRAN2	/LESS THAN 1 SECTOR
	LAC	DTCCA		/CA
	JMS	DTWCS		/SETUP CA AND START TRAN.
	JMP	DTAPE1		/NORM USER EXIT
/PARTIAL SECTOR CODE
TRAN2	JMS TRANLS	/START TRANSFER OF PARTIAL SECTOR
	JMP DTAPE1
	.EJECT
/SUBR. TO TRANSFER LESS THAN 256 WORDS
TRANLS	0
	LAC (TRAN1	/SET COMPLETION RETURN
	DAC DTWRWT
	LAC DTCCA
	DAC TRANT1
	LAC DWORD	/SAVE RESIDUAL WORD COUNT
	DAC TRANT2
DTUMSK	LAW -400
	DAC DWORD
	LAC DLTBUF	/(DTBUF
	JMS DTWCS
	JMP* TRANLS
/RETURN HERE WHEN PARTIAL SECTOR LOADED INTO DTBUF
TRAN1	LAC* DTCCA	/MOVE "N" WORDS FROM DTBUF
	DAC* TRANT1	/TO END OF USER AREA
	ISZ DTCCA
	ISZ TRANT1
	ISZ TRANT2
	JMP TRAN1
	DZM DTWRWT
	JMP* DTIOU
/SUBR. TO SET UP BLK # , TRANSFER DIRECTION
DTSET	0
	DAC	DTNXBK
	LAC	DTCT2		/TRANSFER DIRECTION
	RAR
	SZL!CLA
	LAC	(40		/OUTPUT
	XOR (DRRD	/INPUT
	DAC	DTTR		/WRITE (DRWR) OR READ (DRRD)
	JMP*	DTSET
	.EJECT
/
/
/SUBR. TO SET UP CA, WC AND TRANSFER
DTWCS	0
	DAC	DTCCA		/ADDR.-1
	LAW	-10
	DAC	DTERCT		/SET PARITY RETRY COUNT
	DAC	DTUND		/SET I/O UNDERWAY SWITCH
	LAC	DTFLS1
	DAC	DTCSLT		/SAVE CURR. SLOT POINTER
	LAC DTUNIT	/UNIT # MUST BE:
			/0 IF 32,65 OR 131K DRUM
			/1 OR LESS IF 262K
			/3 0R LESS IF 524K
	CLL!RAR
	RAR
	RTR
	RTR		/UNIT # IN BITS 7,8
	DAC DTSAFE
	TAD DRLIM
	SMA		/UNIT # OK
	JMP DTER26	/IOPS 26: ILL. UNIT #
	LAC DTSAFE
	SNA
	JMP DRUN0	/IF UNIT 0, ALLOW SECTORS 0-3777 IN .TRAN
	LAW -1000	/SECTOR ADDR. = 777 OR LESS
	TAD DTNXBK	/BLK #
	SMA!CLC
	JMP DTER25	/ILL SECTOR ADDR.: IOPS 25
DRUN0	LAC DTNXBK	/OK SECTOR
	TAD DTSAFE	/ADD UNIT #
	DAC DTSAFE	/DRUM ADDR.
	TAD DRLIM	/-(MAX. DRUM SIZE)
	SMA!CLC
	JMP DTER25	/ILL SECTOR ADDR.: IOPS 25
	LAC DTTR
	DAC DRIOT	/DRRD OR DRWR
	JMS	DKSET		/SET UP DISK I/O + EXECUTE IOT'S
	JMP*	DTWCS		/EXIT SUBR
	.EJECT
/SUBR TO SET UP DRUM I/O AND EXECUTE IOT'S
DKSET	0
	LAC DTCCA	/CORE ADDR.
DRIOT	XX		/DRRD(706006) OR DRWR(706046)
	LAC DTSAFE	/DRUM ADDR
	DRLD		/LOAD DRUM ADDR.,START TRANSFER
	JMP* DKSET
/.READ, .WRITE COMMON SETUP SUBR.
DTUWC=DTXOR			/USER 2'S COMP. WC FOR ARG. LIST
DTMCK	0
	DAC	DTTR		/READ (DRRD) OR WRITE (DRWR)
	LAC	DTSKNT		/.SEEK, .ENTER SWITCH
	SNA!CLC
	JMP	DTER12		/.SEEK, .ENTER NOT EXECUTED (DTER11)
	XCT*	DTMCK		/L.B. OR DTA BUF. L.B. ADDR.
	DAC	DTUHP		/HEADER POINTER
	DAC	DTUDP		/DATA POINTER
	ISZ	DTARGP
	LAC*	DTARGP		/USER WC
	DAC	DTUWC
	LAC	DTCT2		/DATA MODE
	DAC	DTDMOD
	ISZ	DTMCK		/INDEX TO DUMP EXIT
	SAD DLIT4
	JMP	DTMCK2		/DUMP MODE
	LAC*	DTUHP		/COMPUTE W.C. FROM L.B.H. W.P.C
	JMS	DTGWPC
	ISZ	DTMCK		/IOPS, IMAGE EXIT
	JMP*	DTMCK		/EXIT,
/DUMP MODE
DTMCK2	LAC	DTUWC		/SAVE USER WC
DTWCSV=DTGWPC
	DAC	DTWCSV
	DZM	DTWPC
	XCT*	DTMCK		/JMP DTRDUM OR JUMP DTWDUM
	.EJECT
/SUBR. TO TRANSF. WPC FROM HEADER TO DTWPC
DTGWPC	0
	RTR
	RTR
	RTR
	RTR
	AND	(776
	DAC	DTWPC		/T. STORE L.B.W.P.C.
	SNA
	JMP DTER23
	AND (400
	SNA!CLA
	JMP*	DTGWPC		/L.B.W.C. INAC
DTER23	LAC DTNXBK	/DISPLAY BAD BLK# WITH IOPS ERROR
	DAC* DLIT3
	LAC	DLIT4		/IOPS 23-ILL. WPC.(0 OR GREATER THAN 177)
	JMP	DTER17
/SUBR. TO ADD TO CHKSUM AND INDEX COUNTS
DTUPTR	0
	TAD	DTCKSM		/ADD DATA WD TO CKSM.
	DAC	DTCKSM
	ISZ	DTUDP
	ISZ	DTRHPT
	ISZ	DTBFCT		/INCR DTA BUF COUNT
	ISZ	DTWPC
	JMP*	DTUPTR
	JMP	DTRDE		/END LINE
/
	.EJECT
/SUBR. TO CHECK ACTIVE FILE
DTCKCL	0
	LAC	DTCLSS		/PREVIOUS FILE CLOSED
	SZA!CLA
	JMP	DTER10		/NO-FILE STILL ACTIVE
	JMS	DTDRCK		/CHECK FOR DIRECTORY IN CORE
	LAC*	DTARGP		/USER D.E. POINTER
	JMS	DTSK1		/DIR. SEARCH FOR FILE
	DAC	DTCLSS		/CLEAR OR SET CLOSE SWITCH
	JMP*	DTCKCL
/SUBR. TO CHECK FILE COMPLETE BIT
DTCK	0
	XCT	DTSK5	/LAC* DTDES(GET 1ST BL.#)
	SMA		/O.K.
	JMP	DTSK6	/FILE INCOMPLETE, TRY AGAIN
	AND	(377777
	DAC	DTNXBK	/BL. TO READ
	JMP*	DTCK
/DTA SEEK FILE SUBR
DTSEEK	LAC	DTIOSW
	SZA!CLC
	JMP	DTER10		/ILL. DATA MODE (.SEEK ON OUTPUT FILE) (DTER7)
	JMS	DTCKCL		/CHECK DIRECTORY FOR THIS FILE
	SNA!CLC			/DTA DIR. ENTRY POINTER IN AC
	JMP	DTER14		/FILE NOT FOUND (DTER13)
	JMS	DTCK	/CHECK FILE COMPLETE BIT
	DAC	DTSKNT		/SET .SEEK, .ENTER EXECUTED SWITCH
DTSEK1	LAC	(DRRD
DTSEK2	DAC	DTTR		/INPUT
	DAC	DTNCOR		/CLEAR DIR. IN CORE SWITCH
	XOR	(DRRD
	SZA
	JMP	DTCOUB		/OUT
	DZM	DTDMOD		/CLEAR DATA MODE TO BYPASS DUMP CHECK
	JMP	DTRNX1
/L.B. TO DTA BUF (.WRITE) OR DTABUF TO L.B. (.READ)
DTRWT	0
DTWT2	LAC*	DTUDP		/USER L.B.
	DAC*	DTHPT		/TO DTA BUF
	JMS	DTUPTR		/ADD TO CKSUM, INDEX CTS, ETC
	ISZ	DTDATC		/DATA WORD COUNT
	ISZ	DTHPT
	ISZ	DTUWC		/DONE
	JMP	DTWT2
	JMP*	DTRWT
/
	.EJECT
/.WRITE ROUTINE
DTWRIT	JMS	DTIOU		/I/O UNDERWAY
	LAC	DTMTP4
	DAC	DTOUT
	DAC	DTWREX		/SET .WRITE EXECUTED SWITCH
	LAC	(DRWR
	JMS	DTMCK		/READ/WRITE COMMON SETUP
	LAC*	DTARGP
	JMP DTWDUM	/DUMP MODE WRITE ROUT.
/RETURN HERE FOR IMAGE OR IOPS MODES
DTWRT1	CLC
	TAD	DTWPC		/REMAINING BUF. AREA SIZE
	TAD	DTBFCT		/REMAINING BUF. AREA SIZE
	SMA!CLA
	JMP	DTCOUT		/NO ROOM FOR THIS LINE
DTWRT2	DAC	DTWRWT		/OUTPUT WAIT SWITCH-CLEAR
	LAC*	DTUHP
	AND	(7
	SAD	(5
	JMP	DTWRT4
	LAC*	DTUHP		/USER LBH., WD0
	AND	(377000
	XOR	DTDMOD		/DATA MODE
DTWRT3	DAC*	DTUHP
DTWRT4	ISZ	DTUHP		/CLEAR USER CKSM
	DZM*	DTUHP
	DZM	DTCKSM		/INIT CHECKSUM
	LAW	-377
	JMS	DTOBCK		/OUTPUT BUF. SIZE CHECK
	CLC			/EXCLUDE L.B.H.; WD0
DTWTM1	TAD	DTWPC		/FROM COUNT
DTWT	CMA
DTWT1	DAC	DTUWC		/ACTUAL WC (2'S COMP)
	LAC	DTHPT		/SET UP CKSM POINTER
	DAC	DTUCKP		/FOR .WRITE
	ISZ	DTUCKP
	JMS	DTRWT
	LAC	DTDMOD
	SAD	DLIT4
	JMP	DTDUMK		/DUMP MODE, CHECK FULL BOFF
DTWT4	CLC
	TAD	DTCKSM
	CMA
	DAC*	DTUCKP		/STORE 2'S COMP CKSUM IN DTABUF
DTWT5	LAC	DTEOF
	SZA			/NO EOF
	JMP	DTCOUY		/TRANSFER EOF
DTMTP4	JMP	DTAPE1		/IOPS WRITE COMPLETE
DTWRCL	JMS	DTBUFC		/CLEAR DTA BUF
	ISZ	DTARGP		/INDEX TO WC ARG
	JMP	DTWRT1		/PUT LINE IN DTA BUF
/
	.EJECT
/OUTPUT BUFFER SIZE CHECK
DTOBCK	0
	TAD	DTWPC		/L.B. W.C.
	SPA!CLC			/OUTPUT BUF. OVERFLOW (DTER16)
	JMP*	DTOBCK
DTER17	TAD	DLIT1		/TOO MANY (4 OR MORE) FILES REFERENCED
DTER16	TAD	DLIT2		/OUTPUT BUFFER OVERFLOW
				/DECTAPE FULL (DTER15)
DTER14	TAD	DLIT2		/DTA DIRECTORY FULL
DTER12	TAD	DLIT2		/IRREC. DTA ERR. MK. TK., EOT DURING TRANSFER
				/.SEEK, .ENTER NOT EXECUTED (DTER11)
DTER10	TAD	DLIT2		/FILE STILL ACTIVE
DTER6	TAD	(6		/ILL HANDLER FUNCTION
	JMP*	DLIT4		/KM-9 ERR. LOC (.MED+1=4)
DLCLA=.
DTER26	CLA
DTER25	TAD (7		/IOPS 26: ILL. DRUM UNIT
	JMP DTER17	/IOPS25: ILL. SECTOR ADDR.
/CLEAR OUTPUT BUF. SUBR.
/ALSO NEEDED FOR INPUT BECAUSE OF POINTER INITIALIZATION
DTBUFC	0
	LAC	L377		/INIT DUMP MODE
	DAC	DTROOM		/BUFF SIZE
	LAC	DTIOSW
	RAR
	LAC	DLTBUF		/BUF. (WD0) POINTER (DTBUF
	SZL!STL			/DO NOT MODIFY DTHPT ON INPUT
	DAC	DTHPT		/DTA BUF HEADER POINTER
	DAC	DTRHPT		/FOR READ
	JMS	DTBFC2	/CLEAR BUF, LINK=1
	JMP*	DTBUFC
/CLEAR SPECIFIED AREA SUBR.
DTBFC2	0
	DAC	DTBFC3
	LAW	-40		/CLEAR 40
	SZL
	AND	DTUMSK	/CLEAR 400, DTUMSK=777400
DTCLCT=DTMPP
	DAC	DTCLCT		/DTCLCT=DTMPP
	DAC	DTBFCT		/INIT BUF SIZE CT.
	ISZ	DTBFCT
DTBFC1	DZM*	DTBFC3
	ISZ	DTBFC3
	ISZ	DTCLCT
	JMP	DTBFC1
	JMP*	DTBFC2
DTBFC3	0			/CLEAR POINTER
/
	.EJECT
/OUTPUT CURR. IOPS BUFFER
DTCOUT	LAC	(DTWRCL		/SET RETURN FROM INT.
	DAC	DTWRWT		/SET OUTPUT WAIT SWITCH
DTCOUY	LAC	DTBUSB
	DAC	DTOUT
DTCOUZ	LAC	DTCNBK		/CURR. BL# TO WRITE
	DAC	DTNXBK
	SPA!CLC
	JMP	DFULL		/DECTAPE FULL (DTER15)
	LAC DTWRWT
	SNA!CLA		/IF DTWRWT IS NON 0,ALWAYS GET NEXT BLK #
	LAC	DTEOF		/EOF SWITCH SET?
	JMS	DTMAP		/FIND NEXT FREE BLOCK
	DAC*	DTLINK		/DATA LINK POINTER
DTCOUB	LAC	DLTBUF		/(DTBUF
	JMS	DTWCS		/SETUP WC,CA AND BEGIN TRAN.
DTOUT	XX		/JMP DTAPE1 OR JMP DTBUSY
/DECTAPE FULL - CLOSE FILE AND OUTPUT MSG 15
DFULL	DAC DTEOF		/SET EOF SWITCH
	DAC DFULSW	/SET DECTAPE FULL SWITCH
	DZM DTWRWT	/CLEAR WAIT
	LAC DLSAV	/(DTESAV
	TAD DLIT2
	DAC DTFIN	/EXT POINTER
	LAW	10000
	AND*	DTFIN		/CHANGE LAST TWO CHAR'S TO XX
	XOR (3030
	DAC* DTFIN
	JMP DTCLS3
/
	.EJECT
/
/DUMP MODE OUPUT
DTWDUM	JMS	DTDUMB
DTDUMX	XCT DTXXX				/JMS DTBUFC OR NOP
	JMP	DTWT1
/
DTDUMB	0
	XCT*	DTDUMB		/JMS DTBUFC (WRITE) OR NOP (READ)
	ISZ	DTDUMB
	LAC	DTWRCL		/SET SWITCH TO CLEAR
	DAC	DTXXX		/OUTPUT BUFF (JMS DTBUFC)
	LAC	DTROOM
	TAD	DTWCSV
	SMA			/MORE THAN 3 7 TO TRANSFER
	JMP	DTDUMZ	/LAST ELEMENT OF TRANSFER
	DAC	DTWCSV		/SAVE REMAINDER
	LAW	-2
	TAD	DTDUMB		/RET. ADDR. FOR TRANS. COMP
	DAC	DTWRWT		/=I/O WAIT SWITCH
	LAC	DTBUSB		/JMP DTBUSY
	DAC	DTOUT
	CLC
	TAD	DTROOM		/FILL IN BUFF
	CMA
DTDUMY	XCT*	DTDUMB		/JMP DTWT1(WRITE) OR JMP DTNSH1
DTDUMZ	DZM	DTWRWT		/CLEAR I/O WAIT SWITCH
	DAC	DTROOM		/SPACE LEFT FOR NEXT DUMP
	SNA
	JMP	.+3		/FULL BUFF, DO NOT NOP CLEAR BUFF
	LAC	DTLNOP		/SET SWITCH NOT TO CLEAR OUTPUT BUFF
	DAC	DTXXX
	LAC	DTMTP4
	DAC	DTOUT
	LAC	DTWCSV	/REMAINDER
	JMP DTDUMY
DTDUMK	LAC	DTROOM		/IF DTROOM=0, BUFF FULL
	SZA!CMA
	LAC	DTWRWT		/IF DTWRWT=0, BUFF NOT FULL
	SZA			/NO
	JMP	DTCOUZ	/YES-OUTPUT
	JMP	DTWT5		/CHECK EOF
/
	.EJECT
/DTA .READ ROUTINE
DTREAD	LAC	DTEOF		/EOF SWITCH SET?
	SZA
	JMP	DTEFX		/YES - IGNORE CALL
	JMS	DTIOU		/I/O UNDERWAY CHECK
	LAC*	DTARGP		/USER L.B. POINTER
	DAC	DTHPT
	DAC	DTHPTS
	LAC	DTMTP4		/JMP DTAPE1
	DAC	DTOUT
DTRD1	LAC	(DRRD
	JMS	DTMCK		/READ/WRITE COMMON SETUP, RETURN TO .+2
	LAC	DTRHPT		/DTA BUF HEADER POINTER
	JMP DTRDUM	/DUMP MODE INPUT
/RETURN HERE FOR IOPS OR IMAGE MODES
	CLC
	TAD	DTWPC		/IOPS ASCII OR BIN (AC=777777 ON RETURN)
	TAD	DTUWC
	DZM	DTDVS		/CLEAR SHORT LINE FLAG
	SMA!CLC
	DAC	DTDVS		/SET SHORT LINE FLAG
	TAD	DTWPC
	CMA
	DAC	DTWPC		/2'S COMP HEADER W.C.
DTRD2	DZM	DTDATC		/DATA COUNT
	DZM	DTCKSM		/CLEAR CHECKSUM
	JMS	DTRWT		/TRANSFER LINE TO USER L.B.
	LAC	DTDMOD
	SAD	DLIT4
	JMP	DTRDM1	/DUMP
	LAC*	DTUDP		/BYPASS
	JMS	DTUPTR		/EXCESS DATA
	JMP	.-2
DTRDM1	LAC	DTROOM		/DUMP MODE BUFF SIZE
	SZA!CMA			/IF DTROOM=0 OR
	LAC	DTWRWT		/DTWRWT=NON 0,
	SZA!CLC
	JMP	DTRNEX		/GET NEXT DUMP BLOCK
	JMP	DTAPE1
/
	.EJECT
/END INPUT LINE ROUTINE
DTRDE	LAC*	DTHPTS		/HEADER WD 0-IOPS
	AND	(7
	SAD	(5		/EOF?
	JMP	DTREOF		/YES
	ISZ	DTDVS		/SHORT LINE FLAG SET
	JMP	DTRDE1		/NO
	LAC	(60
	JMS	DTDVS		/SET D.V. BITS FOR SHORT LINE
DTRDE1	LAC	DTERCT		/PARITY RETRY COUNT
	SMA!CLA
	JMP	DTRDP		/SET D.V. BITS=PARITY
	LAC*	DTHPTS		/HEADER, WD 0
	SPA
	JMP	DTRDN		/IGNORE CKSUM ALREADY SET
	LAC	DTCKSM
	SNA			/SET D.V. BITS=CKSUM ERROR
	JMP	DTRDN
DTRDC	LAC	(20		/CHECKSUM ERR. IN LINE, 12,13=10
DTRDP	TAD	(20		/PARITY ERROR IN DTA BLOCK 12,13=01
	JMS	DTDVS		/SET DATA VALIDITY BITS
DTRDN	LAC*	DTUDP
DTRDN1	SNA!CLC
	JMP	DTRNEX		/NO MORE DATA-GET NEXT BL.
	ISZ	DTBFCT		/DATA BUF. CT = GET NEXT BL.
	JMP	DTRNOR		/NORM EXIT
DTRNEX	SAD*	DTLINK		/DATA LINK=-0
	JMP	DTREOF		/LAST BLOCK -SET EOF SWITCH
	LAC*	DTLINK
	DAC	DTNXBK		/DATA LINK INTO NEXT BLOCK
DTRNX1	JMS	DTBUFC		/INIT. BUFFER
	LAC	DTDMOD		/DUMP MODE?
	XOR	DLIT4
	SZA			/YES
	JMP	DTCOUB		/NO
	LAC	DTRHPT		/RESET BUFF POINTER
	DAC	DTUDP
	JMP	DTCOUB		/TRANSFER
/
	.EJECT
/SUBR. TO SET DATA VALIDITY BITS
DTDVSM=DTTABL			/DATA VALIDITY BIT MASK
DTDVS	0
	DAC	DTDVSM		/SAVE MASK
	LAC*	DTHPTS		/MASK ALL BUT BITS 0, 12,13
	AND	(777717
	XOR	DTDVSM
	DAC*	DTHPTS		/HEADER, WD0
	JMP*	DTDVS
DTEFX	ISZ	DTARGP
DTREOF	DAC	DTEOF		/SET EOF SWITCH+DROP THRU TO EXIT
DTRNOR	TAD	DTBFCT		/DECR. (BY 1) DTFCT
	DAC	DTBFCT		/BUF COUNT
DTAPE1	ISZ	DTARGP
	JMP	DTDBK
DTNSH1	DAC	DTUWC
	JMP	DTRD2		/TRANSFER LINE
/DUMP MODE INPUT
DTRDUM	JMS	DTDUMB		/SET UP FOR DUMP INPUT
DTLNOP	NOP
	JMP	DTNSH1
/
/DTA ENTER FILE ROUTINE
DTENTR	LAC	DTIOSW		/I/O SWITCH
	SNA!CLC
	JMP	DTER10		/ILL. DATA MODE (.ENTER ON INPUT FILE)(DTER7)
	JMS	DTCKCL		/CHECK DIRECTORY FOR THIS FILE
	SZA
	JMP	DTNTR6		/FOUND-WILL BE MODIFIED ON .CLOSE
	LAC	DLFAKE		/INIT GOR EMPTY SLOT SEARCH (DTFAKE
	JMS	DTSK1		/D SEARCH FOR EMPTY FILE ENTRY
	DAC	DTCLSS		/CLEAR OR SET CLOSE SWITCH
	SNA
	JMP	DTER14		/DIRECTORY FULL
DTNTR6	LAC*	DTARGP		/SAVE USER D.E. POINTER
	DAC	DTUDRP
	JMS	DTNTRZ		/SAVE USER D.E. IN DT1SAVOR DT2SAV
/
	.EJECT
	LAW	-40		/INIT BIT MAP SEARCH
	DAC	DTWMCT		/BIT MAP WORD COUNT
	LAC	DLMBIT		/FILE BIT MAP POINTER (DT1BIT) OR (DT2BIT)
	DAC	DTPONT		/CURR. FILE BIT MAP WD. POINTER
	LAC	DLTDIR		/BIT MAP ADDR. POINTER (DTDIR
	DAC	DTMTRX
	DAC	DTBMPT		/SET BIT MAP POINTER
	DZM	DTRELB		/BL. #
DL1100	LAW -1100	/INIT DT BLOCK COUNT
	DAC DTBLOK
	LAW	-1		/INIT BIT MAP
	DAC	DTREM		/SEARCH TO
	DAC	DTSKNT		/PICK UP
	DAC	DTNCOR		/1ST BLOCK FREE
	LAC	DLIT1		/(1
	DAC	DTDIRA		/SET BIT MAP DIRECTION SWITCH
	DAC	DTDIRL		/TO FORWARD (+1)
	JMS	DTMPS		/SETUP TO EXAM. MAP, WD0
DTNTR4	JMS	DTMAP		/GET NEXT FREE BL#
	XOR	(400000
	XCT	DTNTR3		/STORE BL#+COMPLETION BIT IN DTESAV+3
	SMA!CLC
	JMP	DTER16		/DECTAPE FULL (DTER15)
	JMS	DTBUFC
	LAC DTLNOP
	DAC DTXXX	/SET OUTPUT DUMP SWITCH
	JMP	DTAPE1	/NORM EXIT
/SUBR. TO SAVE USER D.E.
DTNTRZ	0
	LAC	DLSAV		/(DT1SAV) OR (DT2SAV)
	DAC	DTFIN
	LAW	-3		/SET DTA D.E.
	DAC	DTCLCT		/TRANSFER COUNTER
DTNTR2	LAC*	DTUDRP		/SAVE USER D.E.
DTNTR3	DAC*	DTFIN
	ISZ	DTFIN
	ISZ	DTUDRP
	ISZ	DTCLCT
	JMP	DTNTR2
	JMP*	DTNTRZ
	.EJECT
DT1SAV	0			/1ST NEW FILE ENTRY SAVED HERE
	0
	0
	0
DT2SAV	0			/2ND NEW FILE ENTRY SAVED HERE
	0
	0
	0
DT3SAV	0		/3RD NEW FILE ENTRY SAVED HERE
	0
	0
	0
DTFAKE	0			/EMPTY SLOT FOR ENTER SEARCH (LAST WD. UNUSED)
	0
	0
DTEOFH	1005			/EOF HEADER FOR CLOSE
/SUBR TO SET UP FOR EXAM OF NEXT BIT MAP WORD
DTMPS	0
	LAW	-22
	DAC	DTRBIT		/18 BIT COUNT
	LAC*	DTMTRX		/NEXT BIT MAP WD
	CMA!STL
	DAC	DTSBIT
	LAC	DTDIRA		/BIT MAP DIRECTION SWITCH
	SMA!CLA!RAL			/REVERSE-SEARCH BIT 18-0
	RTR			/FORWARD-SEARCH BIT 0-18
	DAC	DTTBIT		/FORWARD(0=1); REVERSE (18=1)
	JMP*	DTMPS
	.EJECT
/END OF CURRENT BIT MAP WORD SUBR.
DTMPP	0
DTMPP1	LAC	DTDIRA		/INCR. (IF FORWARD) OR
	TAD	DTMTRX		/DECR. (IF REV) BY 1
	DAC	DTMTRX		/DT. BIT MAP POINTER
	LAC	DTDIRA
	TAD	DTPONT		/FILE BIT MAP POINTER
	DAC	DTPONT
DTMPP2	JMS	DTMPS		/SET FOR NEXT WD
	ISZ	DTWMCT		/BIT MAP WORD CT
	JMP*	DTMPP		/EXIT
	LAW	-1100
	DAC	DTBLOK		/RESET BLK COUNT
	DZM	DTBMCT		/CLEAR BIT MAP SEARCH COUNT
	CLA
	ISZ	DTDIRA		/TURN AROUND
	LAW	-2		/REV.
	TAD	DLIT1		/FORWARD
	DAC	DTDIRA		/SET FOR REV. SEARCH
	TAD	DTRELB		/REINIT
	DAC	DTRELB
/ROUTINE TO SET DTREM FOR TURN AROUND CASE
	LAC DTDIRA
	RAL		/L=1=REV.,L=0=FORW.
	LAC DTNXBK	/LAST BL # RECORDED FOR THIS FILE
	CMA
	SNL		/REV
	JMP .+3
	TAD (1100
	CMA
	DAC DTREM	/LAW TO CHECK ENOUGH SPACE BETW BL
	LAW	-41
	DAC	DTWMCT		/MATRIX COUNT
	JMP	DTMPP1		/START REV. SEARCH
DTBMCT=DTOBCK			/BIT MAP SEARCH COUNT (MUST BE 5 OR MOR TO EXIT)
/
	.EJECT
/BLOCK AVAILABILITY BIT MAP SEARCH
DTMAP	0
	DAC DTCLR2	/SAVE AC, IF -1, IT WILL BE BLK# ON EXIT
	DZM	DTBMCT		/BIT MAP SEARCH COUNT
DTMAP1	LAC	DTTBIT		/TEST BIT
DTMAP2	AND	DTSBIT		/MATRIX WORX
	SZA!CLC
DTMAP3	JMP	DTREM		/BLOCK AVAILABLE
	ISZ	DTBLOK		/INCR. DT BLOCK COUNT
	JMP DTMAP4
	DAC DTBLOK
	JMP DTREM5
DTMAP4	ISZ	DTBMCT
	LAC	DTDIRA		/IF FORW, INCR. BL#
	TAD	DTRELB		/IF REV., DECR. BL.# BY1
	DAC	DTRELB
	LAC	DTDIRA
	RAL			/L=0=FORW; L=1=REV.
	LAC	DTTBIT		/SHIFT TEST BIT RIGHT IF FORW,
	SNL!CLL!RAL			/LEFT IF REV.
	RTR
	DAC	DTTBIT
	ISZ	DTRBIT		/INDEX-18 BIT COUNT
	JMP	DTMAP2		/NEXT BIT
	JMS	DTMPP		/END OF MATRIX WD. SUBR.
	JMP	DTMAP1		/NEXT WORD
DTREM	XX		/DELTA BLOCKS IN BETWEEN
	TAD	DTBMCT
DTREM3	SPA!CLC			/OK-4 BLOCKS IN BETWEEN
	JMP	DTMAP4		/CHECK BIT MAP AGAIN
	SAD DTCLR2	/IF ENTRY AC = -1, NO DTCBIT
	JMP DTREM6
	JMS	DTCBIT		/SET BIT IN MAPS
	CMA
	DAC	DTSBIT
DTREM6	LAW	-DELTA		/RESET BLOCK
	DAC	DTREM		/DISTANCE CHECK TO -DELTA
	LAC	DTDIRA		/UPDATE DTDIRL
	DAC	DTDIRL
DTREM4	LAC	DTRELB		/T. STORE BL# TO BE  USED
DTREM5	DAC	DTCNBK		/EXIT
	LAW -1		/WAS AC ON ENTRY = -1?
	SAD DTCLR2
	SKP		/YES, EXIT WITHH AC= -1
	LAC DTCNBK	/NEW BLK #
	JMP*	DTMAP		/EXIT -BL ! FOUND(777777=DTA FULL)
	.EJECT
/CHANGE BIT IN MAPS SUBR.
DTCBIT	0
	LAC	DTTBIT		/SET BIT IN FILE BIT MAP
	XOR*	DTPONT
	DAC*	DTPONT
	LAC	DTTBIT		/SET BIT IN MAP
	XOR*	DTMTRX
	DAC*	DTMTRX
	JMP*	DTCBIT		/C(*DTMTRX) MUST BE IN AC ON EXIT
/CLEAR DIRECTORY ROUTINE
DTCLR2	XX			/LAC DTBLBT=BLOCK TABLE
	DZM	DTCT2
	ISZ	DTCT2		/WRITE FORWARD
	JMS	DTSET		/SET BL# ETC
	LAC	DLTBUF		/(DTBUF
	JMS	DTWCS		/SET UP CA, WC+BEGIN TRANSFER
	ISZ	DTCLR2		/INDEX FOR NEXT TRANSFER
DTCLER	JMS	DTIOU		/WAIT FOR I/O TO FINISH
	LAC	DTCLSS		/CLOSE SWITCH CLEAR
	SZA!CLA			/YES
	JMP	DTER10		/FILE STILL ACTIVE
	LAC	(DTCLR1		/SET RETURN AND
	DAC	DTWRWT		/I/O WAIT SWITCH
	DAC	DTNCOR		/CLEAR DIR IN CORE SWITCH
	LAC	(LAC DTBLBT
	DAC	DTCLR2		/INIT TABLE REF
	JMS	DTBUFC		/CLEAR BUFF
	LAW	-10		/COUNT FOR
	DAC	DTBFC3		/FILE BIT MAP BLOCKS
	LAW	-11
	DAC	DTCLCT		/COUNT OF BLOCKS TO CLEAR+1
DTCLR1	ISZ	DTBFC3		/FILE BIT MAP BLOCKS CLEARED?
	JMP	DTCLR6
	LAC	(77600		/INIT DIRECTORY TO 4 SYSTEM BLKS OCCUPE
	DAC*	DLB003
DALL1	XX		/LAW -30,21, OR 3
	DAC DTCLR3	/AS FUNCTION OF DRUM SIZE
	LAW -1
	TAD DTLB40
	DAC DTCLR4
DCLMOR	LAW -1
	DAC* DTCLR4	/STORE ALL 1'S
	TAD DTCLR4	/DECREMENT BIT MAP POINTER
	DAC DTCLR4
	ISZ DTCLR3	/DONE?
	JMP DCLMOR
DTCLR5	LAC DCLRTB	/MODIFIED TO PICK UP LAST CORRECT BIT MAP WORD
	DAC* DTCLR4
DTCLR6	ISZ	DTCLCT		/DONE
	JMP	DTCLR2
	DZM	DTWRWT		/YES-CLEAR I/O WAIT SWITCH
	JMP	DTDBK
	.EJECT
/DTCLER BLOCK TABLE
DTBLBT	71			/BLOCKS 71-73 CONTAIN
	72			/24 BIT MAPS ORDERED ACCORDING
DLIT73	73			/TO THE FILE NAMES IN THE DIR. ENTRY SECTION
	74
	75
	76
DLIT77	77
DLT100	100			/BLOCK 100=DIRECTORY
DT1BIT	0			/FILE 1 BIT MAP
	.LOC	DT1BIT+40
DT2BIT	0			/FILE 2 BIT MAP
	.LOC	DT2BIT+40
DT3BIT	0			/FILE 3 BIT MAP
	.LOC	DT3BIT+40
DTDIR	0			/DTA DIRECTORY (FILE1)
	.LOC	DTDIR+40
DTBUF	0			/DTA BUFFER (FILE1)
	.LOC	DTBUF+400
DTDIR2	0			/DTA DIRECTORY (FILE2)
	.LOC	DTDIR2+40
DTBUF2	0			/DTA BUFFER (FILE2)
	.LOC	DTBUF2+400
DTDIR3	0
	.LOC	DTDIR3+40		/DTA DIRECTORY (FILE 3)
DTBUF3	0
	.LOC	DTBUF3+400		/DTA BUFFER (FILE 3)
DTFLS1	0			/FILE1 DAT SLOT
DTFLS2	0			/FILE 2 DAT SLOT
DTFLS3	0			/FILE 3 DAT SLOT
/
	.EJECT
/FILE 1 BLOCK-SECTION A
BLAB=.
DLTDIR	DTDIR			/DIRECTORY POINTER
DLTSYS	DTDIR+203		/WD3 0F SYS BIT MAP
DLTBUF	DTBUF			/DTA BUF. POINTER
DLB003	DTBUF+3			/SYSTEM BLOCK BITS POINTER
DLB203	DTBUF+203		/BASIC SYSTEM BLOCK BITS POINTER
DTLB40	DTBUF+40			/DIR. ENTRY POINTER (.CLOSE)
DTLINK	DTBUF+377			/FILE1 DATA LINK POINTER
DLMBIT	DT1BIT			/FILE1 BIT MAP POINTER
DLSAV	DT1SAV			/POINTER TO 1ST CELL OF NEW DIR. ENTRY
DTROOM	377		/DUMP MODE BUFF SIZE (MODIFIED
DTXXX	XX		/DUMP MODE OUT SWITCH(JMS DTBUFC OR NOP)
DTNXBK	0			/BL.# TO BE TRANSFERRED
DTCNBK	0			/DATA LINK (NEXT BL.#)
DTCURE	0			/DIR. POINTER TTO CURR. FILE ENTRY EXAMINED
DTEOF	0			/EOF SWITCH, -0=EOF
DTHPT	0			/DTA BUF. LINE HEADER POINTER (INDEXED)
DTIOSW	0			/I/O SWITCH, 0=INPUT, 1=OUTPUT
DTRHPT	0			/DTA BUF. LINE HEADER POINTER (.READ)
DTSKNT	0			/.SEEK,.ENTER EXECUTED SWITCH (NON 0=EXECUTED)
DTPONT	0			/CURR. FILE BIT MAP WD POINTER
DTCLSS	0			/FILE OPEN, CLOSE SWITCH(NON-0=OPEN,0=CLOSED)
DTBFCT	0			/BUFFER COUNT (INIT=-377)
DTWREX	0			/WRITE EXECUTED SWITCH (0=NOT, NON 0=EXECUTED)
DTFPCT	0			/FILE ENTRY COUNT
DBLKLC	0			/24-56 FILE ENTRY SWITCH(50=24;10=70)
BLAND=.
/FILE 1 BLOCK-SECTION B
/SECTION B IS NOT SWAPPED WHEN BOTH FILES ARE ON SAME UNIT
DTFILE	0			/FILE ORIENT. SWITCH,0=FILE,-0=NON-FILE
DTUNIT	0			/(0-2)=DTA UNIT# FOR TRANSFER
DTNCOR	077777		/DIRECT. IN CORE SWITCH
DTDIRA	0			/BIT MAP DIRECTION SWITCH (CURR. BL.)+1=F,-1=R
DTDIRL	0			/BIT MAP DIRECTION SWITCH (LAST.BL.),+1=F,-1=R
DTMTRX	0			/CURRENT BIT MAP WD. POINTER
DTRBIT	0			/18  BIT (2'S COMP)COUNTER FOR BIT MAP SEARCH
DTRELB	0			/FREE BL.#AFTER BIT MAP SEARCH
DTSBIT	0			/-(MATRIX WORD)
DTTBIT	0			/TEST BIT FOR BIT MAP SEARCH
DTWMCT	0			/BIT MAP WORD COUNT
DTBMPT	0		/DIR. BIT MAP 1 POINTER
DTBLOK	0			/BLOCK EXAMINED COUNT
BLBND=.
/
	.EJECT
/FILE 2 BLOCK - SECTION A
	DTDIR2			/DIRECT 2 POINTER
	DTDIR2+203
	DTBUF2			/DTA BUF 2 POINTER
	DTBUF2+3
	DTBUF2+203
	DTBUF2+40			/DIR. ENTRY POINTER (FOR CLOSE)
	DTBUF2+377			/FILE 2 DATA LINK POINTER
	DT2BIT			/FILE 2 BIT MAP POINTER
	DT2SAV			/NEW DIR ENTRY POINTER
	377
	XX
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
/FILE 2 BLOCK - SECTION B
	0
	0
	077777
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
/
	.EJECT
/FILE 3 BLOCK - SECTION A
	DTDIR3		/DIRECTORY 3 POINTER
	DTDIR3+203
	DTBUF3		/DTA BUF 3 POINTER
	DTBUF3+3
	DTBUF3+203
	DTBUF3+40		/DIRECTORY ENTRY POINTER (FOR CLOSE)
	DTBUF3+377		/FILE 3 DATA LINK POINTER
	DT3BIT		/FILE 3 BIT MAP POINTER
	DT3SAV		/NEW DIRECTORY ENTRY POINTER
	377
	XX
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
/
/
/FILE 3 BLOCK - SECTION B
	0
	0
	077777
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
/
	.EJECT
/FOLLOWING =CELLS USED IN COMMON BY BOTH FILES
DLFAKE	DTFAKE			/POINTER TO EMPTY FILE NAME
DTARGP	0			/ENTRANCE ARG. POINTER
/DTCCA	0			/CURRENT ADDR. (C.A.) POINTER FOR TRANSFER
DTCALP	0			/USER CAL POINTER
DTCT1	0			/GEN. PURP. COUNTER AND T. STOR.
DTCT2	0		/GEN PURP COUNT AND T STOR
/DTDATC	0			/LINE DATA COUNT
/DTDMOD	0			/DATA MODE (15-17)
/DTHPTS	0			/DTA BUF. LINE HEADER POINTER
/DTTR	0			/DTA SEARCH-READ(DRRD) OR SEARCH-WRITE(DRWR)CONVERSION FACTOR
/DTUCKP	0			/USER LINE BUF. CHECKSUM POINTER
/DTUDP	0			/USER LINE BUF DATA POINTER (MODIFIED)
/DTUHP	0			/USER LINE BUF. HEADER POINTER
DTUND	0			/I/O UNDERWAY SWITCH,NOT 0=BUSY,0=NOT BUSY
/DTWC	0			/2'S COMP TRANSFER WORD COUNT
DTWRWT	0			/CONTINUED I/O SWITCH (NON 0=CONT),0=DONE)
DLEOFH	DTEOFH			/EOF HEADER POINTER (FOR .CLOSE)
/DTCKSM	0		/LINE CHECKSUM
DTCT	0		/T STORE
/DTSAFE	0		/BLOCK # SAFE STORAGE DURING TRANSFER
DTSAM2	0		/FILE1+2 ON SAME UNIT (NON 0=SAME)
DTSAM3	0		/FILE1+3 ON SAME UNIT (NON 0=SAME)
DADSIZ	0		/FILE BLOCK RELATIVE POSITION
DFULSW	0		/DECTAPE FULL SW(NON 0=FULL)
DLIT0	0
DLIT1	1
DLIT2	2
DLIT3	3
DLIT4	4
LDASZ	DASIZE		/LIT
LDBSZ	DABSIZ		/LIT
LDBSZ2	DABSZ2		/LIT
/DTWPC	0			/WORD PAIR COUNT
DCLRTB=.
/DCLRTB=TABLE OF LAST SETTIG OF BIT MAP IN DIRECTORY CLEAR
DWORD	LAW	-400		/WORD COUNT, MODIFIED BY.TRAN
	177777		/32K DRUM
	037777		/65K
	001777		/131K
	001777		/262K
	001777		/524K
L77777	77777		/LIT
	.END
