	/ARCTAN X
	.GLOBL DATAN,ATAN,.DA,.SET
	.GLOBL .AO,.AG,.BA,.AP,.ED
	.GLOBL .AA,.AU,.XA,.T1,.AB
	.GLOBL .DC,.AS,.AV,.AQ,.AR
.XX=.XA
DATAN	CAL	0
	LAC	.-1
	JMS*	.SET
ATAN	CAL	0
	JMS*	.DA
	JMP	.+2
ARG	0
	JMS*	.AG	/.AO IF 2-WD
		ARG+400000
.ED	DAC	ARG	/SAVE SIGN
	SPA
	JMS*	.BA	/ABS VALUE
	LAW	-2
	DAC	FLG1
	DAC	FLG2
	LAC*	.AA
	TAD	C37S
	SMA!CLL		/X<1.0?
	SAD	C37S	/EX.EQ.0?
	JMP	DD02	/YES, X<1
	JMS*	.AV	/ 1/X
		ONE
	ISZ	FLG1	/SET TO ADD PI/2
DD02	LAC*	.AB
	TAD	MT15	/L=1 IF>7/16
	LAC*	.AA
	SAD	C37S	/EX=-1?
	SZL!CMA		/YES,C(A)
	SMA
	JMP	DD03	/< 7/16
	ISZ	FLG2	/SET TO ADD PI/6
	JMS*	.AP	/REDUCE ARG
		.XX+400000
	JMS*	.AR	/X-TAN30
		TAN30
	JMS*	.AP
		.T1+400000
	JMS*	.AO
		.XX+400000
	JMS*	.AS
		TAN30
	JMS*	.AQ	/1+X*TAN30
		ONE
	JMS*	.AV
		.T1+400000
DD03	JMS*	.DC	/FORM POLY
		ATERM
	JMS*	.AV	/X**2/F
		.T1+400000
	JMS*	.AS	/*X
		.XX+400000
	JMS*	.AU	/X-
		.XX+400000
	ISZ	FLG2
	JMP	DD04
	JMS*	.AQ	/+PI/6
		PI6R
	JMS*	.AQ
		PI6
DD04	ISZ	FLG1
	JMP	DD05
	JMS*	.AU	/PI2-
		PI2
DD05	LAC	ARG
	SPA
	JMS*	.BA	/NEG ANS
	JMP*	ATAN
FLG1	0
PI6	0; 206025
TAN30	0; 223632; 350544
PI6R	-23; 216026
C37S	377777
MT15	440000
PI2	1; 311037; 552421
ONE	1; 200000; 0
FLG2=PI6
ATERM	-5
/C6=
	-5; 363061; 252367
/C5=
	-3; 600402; 075325
/C4=
	-3; 326227; 555140
/C3=
	-2; 722475; 006302
/C2=
	1; 346314; 573074
/C1= .30000 00008D1
	2; 300000; 000113
	.END
