/READ SINGLE SENSE LINE FUNCTION
/EXECUTION TIME: 47 TO 49 MICROSECONDS
/CALLING SEQUENCE: RSSL(SENSE)
/     SENSE:0-7 ADDRESS OF SENSE LINE
/EXIT: AC=777777 IF SENSE LINE IS HIGH
/      AC=000000 IF SENSE LINE IS LOW
/          OR IF SENSE LINE ADDRESS IS ILL.
	.TITLE RSSL
	.GLOBL RSSL
RSSL	0
	ISZ RSSL
	LAC* RSSL
	DAC SENSE
	SPA
	LAC* SENSE  /INDIRECT
	DAC SENSE
	ISZ RSSL    /BUMP TO EXIT
	LAC* SENSE
	AND (777770
	SZA!CLA
	JMP* RSSL    /ILL. SENSE LINE 
	LAC (10     /8 SHIFTS
	TAD* SENSE  /+ (SENSE) SHIFTS
	TAD (ALS  /AC LEFT SHIFT
	DAC .+4     /FIX VARIABLE SHIFT
	IOT3
	JMP .-1
	RSLI        /READ SENSE LINE
	            /INPUTS
	XX    /AC0=DESIRED SENSE LINE
	SPA!CLA     /SKIP ON SENSE LOW
	CMA         /SENSE LINE IS HIGH
	JMP* RSSL
SENSE
IOT3=703003
RSLI=705213
	.END
