/SET LOGIC MODE SUBROUTINE
/EXECUTION TIME: 91 (RUN), 92 (CLEAR),
/                 OR 93 (STOP) MICROSECONDS
/CALLING SEQUENCE: CALL SLMO(MODE,ERROR)
/     MODE: 1=RUN,2=STOP,3=CLEAR
/     ERROR=0: NO ERROR
/          =1: ILLEGAL MODE REQUESTED
/          =2: MODE FAILED TO SET PROPERLY
	.TITLE SLMO
	.GLOBL RLMO,SLMO
SLMO	0
	ISZ SLMO
	LAC* SLMO
	DAC MODE
	SPA
	LAC* MODE   /INDIRECT
	DAC MODE    /MODE LOCATION
	ISZ SLMO
	LAC* SLMO
	DAC ERROR
	SPA
	LAC* ERROR  /INDIRECT
	DAC ERROR   /ERROR LOCATION
	ISZ SLMO    /BUMP TO EXIT
	DZM* ERROR  /ZERO ERROR CODE
	LAC* MODE
	SNA
	JMP ERROR1  /MODE=0
	AND (777774
	SZA
	JMP ERROR1  /MODE<0 OR MODE>3
	LAC* MODE
	CLL!RAR
	RTR
	RTR
	RTR
	RTR
	IOT3
	JMP .-1
	SLM         /SET LOGIC MODE
	JMS* RLMO   /READ LOGIC MODE
	JMP .+2
	RMODE
	LAC RMODE
	SAD* MODE
	JMP* SLMO   /LOGIC MODE OK
	LAC (2      /FAILED TO SET 
	DAC* ERROR
	JMP* SLMO
ERROR1	ISZ* ERROR  /ILL. MODE REQUESTED
	JMP* SLMO
ERROR
MODE
RMODE
IOT3=703003
SLM=705226
	.END
