	.TITLE ADJ3
/COPYRIGHT 1970, DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/
/SUBROUTINE TO PERFORM DIMENSION ADJUSTMENT
/	ON A THREE DIMENSIONAL ARRAY
/
/CALLING SEQUENCE:
/	.GLOBL	ADJ3
/	JMS*	ADJ3		/SIZE 33 (DECIMAL)
/	JMP	.+5
/	.DSA	A		/ADDRESS OF ARRAY DESCRIPTOR BLOCK
/	.DSA	B		/ADDRESS OF 1ST ELEMENT IN NEW ARRAY
/	.DSA	M		/ADDRESS OF # OF ROWS IN NEW ARRAY
/	.DSA	N		/ADDRESS OF # OF COLUMNS IN NEW ARRAY
/
	.GLOBL	ADJ3,.DA,.AD
ADJ3	0
	JMS*	.DA		/GET ARGUMENT
	JMP	.+5
ARYDIS	0			/ARRAY DESCRIPTOR
ARYSTR	0			/ARRAY START
ROWS	0			/#OF ROWS
COLS	0			/#OF COLUMNS
	LAC	ARYSTR
	DAC*	ARYDIS		/SET NEW STARTING ADDRESS
	LAW	-3
	TAD	ARYDIS
	DAC	ARYDIS
	LAC*	ARYDIS		/ARRAY TYPE IN BITS 3-4
	RTL
	RTL
	RTL
	TAD	(1		/ADD 1 TO ALL FOR # OF WORDS
	AND	(3		/CONVERT TO # OF WORDS PER ELEMENT
	SNA			/IS ARRAY LOGICAL
	LAC	(1		/YES-ONLY ONE WORD
	ISZ	ARYDIS
	JMS*	.AD		/MULTIPLY # ROWS BY SIZE
	LAC*	ROWS
	DAC*	ARYDIS		/STORE IN 1ST DIM WD
	ISZ	ARYDIS
	JMS*	.AD		/MULTIPLY BY # COLS
	LAC*	COLS
	DAC*	ARYDIS		/STORE IN 2ND DIM WD
	JMP*	ADJ3		/RETURN
	.END
