	.TITLE	INTRINISIC FUNCTION IDENTIFIER
	.GLOBL	INTRSC
/ THIS SUBROUTINE IS ENTERED WITH THE ADDRESS OF THE FIRST WORD OF
/ A TWO WORD FUNCTION NAME IN THE AC.
/
INTRSC	XX
	DAC	LOOK+1	/ MOVE FUNCTION NAME
	LAC*	LOOK+1	/ TO TWO WORD AREA LOOK
	DAC	LOOK
	ISZ	LOOK+1
	LAC*	LOOK+1
	DAC	LOOK+1
/
	LAC	(TABLE-1	/ POINT AT TABLE
	DAC*	(AUTOX	/ OF INTRINSIC FUNCTIONS
/
LOOPA	LAC	LOOK	/ FIRST WORD OF NAME
LOOPB	SAD*	AUTOX	/ COMPARE WITH TABLE
	JMP	SECOND	/ SAME- TRY SECOND WORD
	ISZ*	(AUTOX	/ SKIP SECOND WORD
SKPMOD	ISZ*	(AUTOX	/ SKIP OVER THE MODE
	JMP	LOOPA	/ TRY AGAIN
SECOND	LAC	LOOK+1	/ CHECK IF SECOND WORD MATCHES
	SAD*	AUTOX
	SKP
	JMP	SKPMOD	/ IT DOESN'T, TRY NEXT
/
/ SINCE LOOK IS AT END OF TABLE A MATCH WILL BE FOUND. MUST NOW
/ DETERMINE IF TRUE MATCH OR END OF TABLE.
/
	LAC*	AUTOX	/ NON-ZERO INDICATES
	CLA
	JMP*	INTRSC
/
/ TABLE DEFINITION MACRO
/
	.DEFIN	NAMES,A,B,C,D,E,F
	.DSA	A*100+B*100+C
	.DSA	D*100+E*100+F
	.ENDM
/
/ ABSOLUTE VALUE
TABLE	NAMES	II,AA,BB,SS,0,0	/ IABS
	.DSA	DINTGM
	NAMES	AA,BB,SS,0,0,0	/ ABS
	.DSA	REALM
	NAMES	DD,AA,BB,SS,0,0	/ DABS
	.DSA	DBLEM
	NAMES	CC,AA,BB,SS,0,0	/ CABS
	.DSA	REALM
	NAMES	CC,DD,AA,BB,SS,0	/CDABS
	.DSA	DBLEM
/ TYPE CONVERSION
	NAMES	FF,LL,OO,AA,TT,0	/ FLOAT
	.DSA	REALM
	NAMES	DD,FF,LL,OO,AA,TT	/ DFLOAT
	.DSA	DBLEM
	NAMES	II,FF,II,XXX,0,0	/ IFIX
	.DSA	SINTGM
	NAMES	HH,FF,II,XXX,0,0	/ HFIX
	.DSA	SINTGM
	NAMES	SS,NN,GG,LL,0,0	/ SNGL
	.DSA	REALM
	NAMES	DD,BB,LL,EE,0,0	/ DBLE
	.DSA	DBLEM
	NAMES	CC,MM,PP,LL,XXX,0	/ CMPLX
	.DSA	CMPLXM
	NAMES	DD,CC,MM,PP,LL,XXX	/ DCMPLXM
	.DSA	DCMPXM
	NAMES	RR,EE,AA,LL,0,0	/ REAL
	.DSA	REALM
	NAMES	AA,II,MM,AA,GG,0	/ AIMAG
	.DSA	REALM
/ COMPLEX CONJUGATE
	NAMES	CC,OO,NN,JJ,GG,0	/ CONJG
	.DSA	CMPLXM
	NAMES	DD,CC,OO,NN,JJ,GG	/ DCONJG
	.DSA	DCMPXM
/ LARGEST VALUE
	NAMES	AA,MM,AA,XXX,ZERO,0	/ AMAX0
	.DSA	REALM
	NAMES	AA,MM,AA,XXX,ONE,0	/ AMAX1
	.DSA	REALM
	NAMES	MM,AA,XXX,ZERO,0,0	/ MAX0
	.DSA	SINTGM
	NAMES	MM,AA,XXX,ONE,0,0	/ MAX1	
	.DSA	SINTGM
	NAMES	DD,MM,AA,XXX,1,0	/ DMAX1
	.DSA	DBLEM
/ SMALLEST VALUE
	NAMES	AA,MM,II,NN,ZERO,0	/ AMIN0
	.DSA	REALM
	NAMES	AA,MM,II,NN,ONE,0	/ AMIN1
	.DSA	REALM
	NAMES	MM,II,NN,ZERO,0,0	/ MIN0
	.DSA	SINTGM
	NAMES	MM,II,NN,ONE,0,0	/ MIN1
	.DSA	SINTGM
	NAMES	DD,MM,II,NN,ONE,0	/ DMIN1
	.DSA	DBLEM
/
/ INSERT ANY ADDITIONAL NAMES HERE
/
LOOK	.BLOCK	2
	.DSA	0	/ END OF TABLE MARKER
	.END
