/SELECT ANALOG COMPONENT ADDRESS
/     SUBROUTINE
/EXECUTION TIME: DEVICE LIMITED
/CALLING SEQUENCE:
/     CALL SACO(TYPE,ADDRESS,ERROR)
/     TYPE: 0=AMPLIFIER, 1=DERIVATIVE
/           2=FUNCTION GENERATOR,3=TRUNK
/           4=POTENTIOMETER
/           5=PATCH PANEL,6=DERIVATIVE/10
/           7=HAND-SET POTENTIOMETER
/     ADDRESS: 0-119 INTEGER PATCHBOARD
/                 ADDRESS
/     ERROR=0: NO ERROR
/          =1: ILL. TYPE OR ADDRESS REQ.
/          =2: TYPE AND/OR ADDRESS
/              FAILED TO SET PROPERLY
/          =4: HARDWARE MALFUNCTION
/          =7: KEYBOARD INTERFERENCE
/              SACO CANNOT PROCEED
	.TITLE SACO
	.GLOBL SACO,%SACO
SACO	0
	ISZ SACO
	LAC* SACO
	DAC TYPE
	SPA
	LAC* TYPE   /INDIRECT
	DAC TYPE    /TYPE LOCATION
	ISZ SACO
	LAC* SACO
	DAC ERROR
	SPA
	LAC* ERROR  /INDIRECT
	DAC ERROR
	LAC* ERROR
	LMQ         /ADDRESS IN MQ
	ISZ SACO
	LAC* SACO
	DAC ERROR
	SPA
	LAC* ERROR  /INDIRECT
	DAC ERROR   /ERROR LOCATION
	ISZ SACO    /BUMP TO EXIT
	LAC* TYPE   /TYPE IN AC
	JMS* %SACO
	DAC* ERROR  /ERROR CODE
	JMP* SACO
ERROR
TYPE
	.END
