	.TITLE IDZERO
/COPYRIGHT 1970, DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
	/EDIT 1    7--2--70
	/LOGICAL OR INTEGER FUNCTION WITH INTEGER ARGUMENT
	/IDZERO(N)
	/IF N=0, DON'T CHECK
	/IF N IS NOT EQUAL 0, CHECK
	/IF N=0, A ZERO RESULT RETURNED (FALSE)
	/IF N IS NOT EQUAL 0, TRUE (777777) RETURNED IF TEST IS POSITIVE
	/IF N IS NOT EQUAL TO 0, FALSE(0) RETURNED IF TEST IS NEGATIVE
	.GLOBL IDZERO,.DZERO,.DA
IDZERO	0
	JMS* .DA
	JMP .+2
IDZ1	0			/ADDRESS OF INTEGER ARGUMENT
	LAC* IDZ1		/GET ARGUMENT
	SNA			/TEST ARG.
	JMP* IDZERO		/EXIT WITH ZERO AC
	LAC* .DZERO		/TEST FLAG FOR DIVISION BY ZERO
	SZA!CMA			/YES OR NO?
	JMP* IDZERO		/NO. EXIT WITH ZERO AC
	DAC* .DZERO		/YES. REINIT FLAG TO 777777
	JMP* IDZERO		/EXIT WITH 777777 AC
	.END
