	.TITLE	SSCL
/
/  7 MAR 72 - MOD BY P. HENDERSON
/
/SET SINGLE CONTROL LINE SUBROUTINE
/EXECUTION TIME: 52 TO 60 MICROSECONDS
/CALLING SEQUENCE: CALL SSCL(LINE,ERROR)
/     LINE: 0-15 ADDRESS OF CONTROL LINE 
/           TO BE SET
/     ERROR=0: NO ERROR
/           1: ILL. CONTROL LINE REQUESTED
/
	.GLOBL SSCL
/
SSCL	XX
	.ARG	SSCL
	DAC LINE    /LINE LOCATION
	.ARG
	DAC ERROR
	DZM* ERROR	/ERROR=0
	LAC* LINE
	AND (777760
	SZA!CLL
	JMP ERROR1   /LINE<0 OR LINE>15
	LAC* LINE   /STEP COUNTER
	TAD (LRS    /LONG RIGHT SHIFT
	DAC .+2     /FIX VARIABLE SHIFT
	LAC (400000
	XX         /LOAD DATA WORD
	IOT5
	JMP .-1
	SOCL        /SET OUTPUT CONTROL
	            /LINE
	JMP* SSCL
ERROR1	ISZ* ERROR      /ILL. CONTROL 
		/LINE REQUESTED
	JMP* SSCL
ERROR
LINE
IOT5=703005
SOCL=705106
	.END
