/RAISE PRIORITY LEVEL FUNCTION
/EXECUTION TIME:  22 TO 146 MICROSECONDS
/CALLING SEQUENCE:  RPRI(LEVEL)
/   LEVEL:  0-7 PRIORITY LEVEL DESIRED
/EXIT:  AC=777777 AND PRIORITY=LEVEL
/          IF LEVEL<LEVL(DUMMY)
/          OR IF THE API IS DISABLED
/       AC=000000 AND PRIORITY UNCHANGED
/          IF LEVEL NOT< LEVL(DUMMY)
/          OR IF THE API IS DISABLED
/          OR IF LEVEL<0 OR IF LEVEL>7
	.TITLE RPRI
	.GLOBL LEVL,RPRI
RPRI	0
	ISZ RPRI
	LAC* RPRI
	DAC LEVEL
	SPA
	LAC* LEVEL  /INDIRECT
	DAC LEVEL	/DESIRED LEVEL
	ISZ RPRI	/BUMP TO EXIT
	LAC (400000
	SPI
	JMP EXIT	/API IS DISABLED
	LAC* LEVEL
	AND (777770
	SZA!CLA
	JMP* RPRI	/ILL. LEVEL REQUESTED
	JMS* LEVL	/LOAD ACTIVE API LEVEL
	SPA!CLL	/NO 'DUMMY' REQUIRED
	JMP PAST	/NO API LEVEL ACTIVE
	CMA
	TAD (1
	TAD* LEVEL
	SMA!CLA!CLL
	JMP* RPRI	/LEVEL NOT<LEVL(DUMMY)
PAST	LAC* LEVEL	/STEP COUNT
	TAD (LRS	/LONG RIGHT SHIFT
	DAC .+2	/FIX VARIABLE SHIFT
	LAC (000200
	XX	/PRIORITY REQUEST BIT
	TAD (400000	/ENABLE BIT
	ISA	/REQUEST API RAISE
	CLC	/RPRI=TRUE
	JMP* RPRI
EXIT	CLA	/API IS DISABLED
	JMP* RPRI
LEVEL
	.END
