/READ CURRENT (ACTIVE) API LEVEL FUNCTION
/EXECUTION TIME:  16(0),26(1),36(2),46(3),
/                 56(4),66(5),76(6),86(7),
/                 OR 89 (-1) MICROSECONDS
/CALLING SEQUENCE:  LEVL(DUMMY)
/   DUMMY: ANY DUMMY ARGUMENT
/EXIT:  LEVL=0-7 CURRENT API LEVEL
/           =-1 IF NO API LEVEL IS ACTIVE
	.TITLE LEVL
	.GLOBL LEVL
LEVL	0
	DZM LEVEL	/LEVEL=0
	LAW+17770
	DAC COUNT	/8 LEVELS
	LAC (000200	/LEVEL BIT
LOOP	SPI
	JMP EXIT	/THIS LEVEL IS ACTIVE
	ISZ LEVEL	/INACTIVE - LEVEL=+1
	CLL!RAR	/SHIFT LEVEL BIT
	ISZ COUNT
	JMP LOOP
	CLC	/NO API LEVEL ACTIVE
	JMP* LEVL	/AC=-1
EXIT	LAC LEVEL	/AC=ACTIVE API LEVEL
	JMP* LEVL
COUNT
LEVEL
	.END
