	.TITLE	CISL
/
/  7 MAR 72 - MOD BY P. HENDERSON
/
/CONTINUE IF SENSE LINE HIGH SUBROUTINE
/EXECUTION TIME:  PROGRAM DEPENDENT
/                 (>59 MICROSECONDS)
/CALLING SEQUENCE:  CALL CISL(SENSE,ERROR)
/   SENSE:  0-7 ADDRESS OF SENSE LINE
/   ERROR=0:  NO ERROR
/        =1:  ILLEGAL SENSE LINE REQUESTED
/CISL DOES NOT RESET THE SENSE LINE
/   WHEN IT GOES HIGH
/
	.GLOBL CISL
/
CISL	XX
	.ARG	CISL
	DAC SENSE	/SENSE LOCATION
	.ARG
	DAC ERROR
	DZM* ERROR	/ERROR=0
	LAC* SENSE
	AND (777770
	SZA!CLA
	JMP ERROR1	/ILL. LINE
	LAC (10	/8 SHIFTS
	TAD* SENSE	/+(SENSE)
	TAD (ALS	/AC LEFT SHIFT
	DAC .+4	/FIX VARIABLE SHIFT
	IOT3
	JMP .-1
	RSLI	/READ SENSE LINE
		/INPUTS
	XX	/AC0=DESIRED LINE
	SMA	/SKIP ON SENSE HIGH
	JMP .-5	/STILL LOW
	JMP* CISL	/CONTINUE
ERROR1	ISZ* ERROR	/ILLEGAL
		/SENSE LINE REQUESTED
	JMP* CISL
ERROR
SENSE
IOT3=703003
RSLI=705213
	.END
