	.TITLE	DCT
/
/  16 JUN 77 (006; PDH) CHANGE TO WC=22
/  10 JUN 77 (004; PDH) CONVERT TO EXEC MODE RSX TASK
/  10 JUN 77 (003; PDH) DISPLAY 'R' IN AC REGISTER
/  21 JUN 73 - ADD DIAGNOSTIC R/W IOTS
/  15 JUL 71 - PAUL HENDERSON
/
/  TEST ROUTINE FOR UOW DATA CHANNEL DEVICE.
/  IT IS NECESSARY TO JUMPER PIN C12S TO PIN D24K SO THAT
/  THE 'JOG' INSTRUCTION CAN FUNCTION.
/
DCSF=702701		/SKIP ON DATA CHANNEL DEVICE FLAG
DCCF=702721		/CLEAR FLAG
DCRD=702741		/SELECT READ (INPUT)
DCWT=702761		/SELECT WRITE (OUTPUT)
DIRD=702712		/DIAGNOSTIC READ DATA CHANNEL BUFFER
DIWT=702704		/DIAGNOSTIC WRITE (LOAD) DATA CHANNEL BUFFER
DCINT=552	/ INSTALLATION DEPENDENT LOCATION OF INTERRUPT SERVICE
API=76			/API TRAP ADDRESS
WC=22			/WORD COUND REGISTER
CA=WC+1			/CURRENT ADDRESS REGISTER
JOG=702504		/SIMULATE EXTERNAL DEVICE
/
START	LAC	(W-1
	DAC*	(CA
	LAW	-1
	DAC*	(WC
	DZM*	(DCINT	/USE AS I/O DONE FLAG
	DCWT
	JOG
	LAC*	(DCINT	/WAIT FOR INTERRUPT
	SNA
	JMP	.-2
B2	LAC	(R-1
	DAC*	(CA
	LAW	-1
	DAC*	(WC
	DZM*	(DCINT	/CLEAR 'I/O DONE FLAG'
	DCRD
	JOG
	LAC*	(DCINT	/WAIT
	SNA
	JMP	.-2
D	LAW	-200
	DAC	DELAY
	LAS
	DAC	W		/ CHANGE VALUE TO BE WRITTEN
	LAC	R		/ GET VALUE READ BACK
	ISZ	DELAY
	JMP	.-1
B1	JMP	START
	.REPT	10,1
W	525252
R	.BLOCK	10
DELAY
/
	.END	START
