       .TITLE SNGL   CONVERT DOUBLE ARGUMENT TO REAL
/COPYRIGHT 1970, DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
       .GLOBL SNGL,.DA,.AO,.CE,.CH
       .GLOBL .AB
/             CALLING SEQUENCE
/      JMS*   (SNGL)          SUBR CALL
/      JMP    .+2             SUBR RETURN
/      CAL/XCTADDR            ADDR OF ARGUMENT (XCT IF INDIRECT)
/
SNGL   CAL    0              /ENTRY-EXIT
       JMS*   .DA            /GET ARGUMENT (.DA)
       JMP    SNGL02
SNGL01 CAL    0              /ARGUMENT
SNGL02 JMS*   .AO            /LOAD DOUBLE (.AO)
       .DSA   SNGL01+400000  / (ARG1)
       LAC*   .AB            /GET SIGN WORD
       AND    SNGL03         /SAVE SIGN ONLY
       DAC*   .CE
       LAC*   .AB            /GET SIGN WORD AGAIN
       AND    SNGL04         /SAVE MAGNITUDE ONLY
       DAC*   .AB            /RESTORE
       JMS*   .CH            /ROUND AND SIGN
              400
              777000
       JMP*   SNGL           /EXIT
SNGL03        400000         /MASK FOR SIGN
SNGL04        377777         /MASK FOR MAGNITUDE
       .END
