       .TITLE SIGN   TRANSFER OF SIGN FOR REAL ARGUMENTS
/COPYRIGHT 1970, DIGITAL EQUIPMENT CORP.,MAYNARD, MASS.
/EDIT 2   10-22-70
       .GLOBL SIGN,.DA,.AG,.AB
/             CALLING SEQUENCE
/      JMS*   (SIGN)          SUBR CALL
/      JMP    .+3             SUBR RETURN
/      CAL/XCTADDR            ADDR OF ARG1
/      CAL/XCTADDR            ADDR OF ARG2  (XCT IF INDIRECT)
/
SIGN   CAL    0              /ENTRY-EXIT
       JMS*   .DA            /GET ARGUMENTS (.DA)
       JMP    SIGN03
SIGN01 CAL    0              /ARG1
SIGN02 CAL    0              /ARG2
SIGN03 JMS*   .AG            /LOAD REAL (.AG)
       .DSA   SIGN02+400000  / (ARG2)
       LAC*   .AB            /GET SIGN WORD (.AB)
       AND    SIGN07         /KEEP SIGN ONLY
       DAC    SIGN02         /HOLD SIGN
       JMS*   .AG            /LOAD REAL (.AG)
       .DSA   SIGN01+400000  / (ARG1)
       LAC*   .AB            /GET SIGN WORD (.AB)
       AND    SIGN08         /STRIP SIGN
       XOR    SIGN02         /ADD SIGN OF ARG2
	SAD SIGN07	/CHECK FOR -0.0 CASE
	CLA	/YES.  MAKE -0.0 A 0.0
       DAC*   .AB            /RESTORE IN SIGN WORD (.AB)
       JMP*   SIGN           /EXIT
SIGN07        400000
SIGN08        377777
       .END
