	.TITLE ADJ2
/COPYRIGHT 1970, DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/
/SUBROUTINE TO PERFORM DIMENSION ADJUSTMENT
/	ON A TWO DIMENSIONAL ARRAY
/
/CALLING SEQUENCE:
/	.GLOBL	ADJ2
/	JMS*	ADJ2		/SIZE 30 (DECIMAL)
/	JMP	.+4
/	.DSA	A		/ADDRESS OF ARRAY DESCRIPTOR BLOCK
/	.DSA	B		/ADDRESS OF 1ST ELEMENT IN NEW ARRAY
/	.DSA	M		/ADSESS OF # OF ROWS IN NEW ARRAY
/
	.GLOBL	ADJ2,.DA,.AD
ADJ2	0
	JMS*	.DA		/GET ARGUMENT
	JMP	.+4
ARYDIS	0			/ARRAY DISCRIPTOR
ARYSTR	0			/ARRAY START
ROWS	0			/# OF ROWS
	LAC	ARYSTR
	DAC*	ARYDIS		/SET NEW STARTING ADDRESS
	LAW	-3
	TAD	ARYDIS
	DAC	ARYDIS
	LAC*	ARYDIS		/ARRAY TYPE IN BITS 3-4
	RTL
	RTL
	RTL
	TAD	(1		/ADD 1 TO ALL FOR # OF WORDS
	AND	(3		/CONVERT TO # OF WORDS PER ELEMENT
	SNA			/WAS IT LOGICAL ARRAY
	LAC	(1		/YES-ONLY ONE WORD
	ISZ	ARYDIS
	JMS*	.AD		/MULTIPLY # ROWS BY SIZE
	LAC*	ROWS
	DAC*	ARYDIS		/STORE IN 1ST DIM INFO WD
	ISZ	ARYDIS
	DZM*	ARYDIS		/ZERO 2ND WORD
	JMP*	ADJ2		/RETURN
	.END
