/READ TIME CONSTANT SUBROUTINE
/EXECUTION TIME: 36(N,SEC),38(N,MS),
/                39(F,SEC),OR 41(F,MS)
/                MICROSECONDS
/CALLING SEQUENCE: CALL RTCO(TIME)
/     TIME=0: N,SEC (X1)
/         =1: F,SEC (X10)
/         =2: N,MS (X1000)
/         =3: F,MS (X10000)
	.TITLE RTCO
	.GLOBL RTCO
RTCO	0
	ISZ RTCO
	LAC* RTCO
	DAC TIME
	SPA
	LAC* TIME   /INDIRECT
	DAC TIME    /TIME LOCATION
	ISZ RTCO    /BUMP TO EXIT
	IOT3
	JMP .-1
	RSW         /READ STATUS WORD
	LMQ         /SAVE STATUS
	AND (400    /MASK OFF N-F BIT
	SNA!CLL
	STL         /FAST-LINK=1
	LACQ
	AND (200    /MASK OFF SEC-MS BIT
	SNA!CLA
	LAC (2      /MS-AC=2
	SZL
	TAD (1      /FAST-AC=AC+1
	DAC* TIME   /TIME CONSTANT
	JMP* RTCO
TIME
IOT3=703003
RSW=703613
	.END
