/TEST AND RESET SENSE LINE TWICE FUNCTION
/EXECUTION TIME:  40 (FIRST TEST FALSE),
/                 51 (SECOND TEST FALSE),
/                 OR 52 (BOTH TESTS TRUE)
/                 MICROSECONDS
/CALLING SEQUENCE:  TRST(SENSE)
/   SENSE:  0-7 ADDRESS OF SENSE LINE
/EXIT:  AC=777777 IF SENSE LINE IS HIGH
/          (IF INPUT TO SENSE LINE IS A
/           HIGH LEVEL)
/       AC=000000 IF SENSE LINE IS LOW
/          OR IF SENSE LINE ADDRESS IS ILL.
	.TITLE TRST
	.GLOBL TRST
TRST	0
	ISZ TRST
	LAC* TRST
	DAC SENSE
	SPA
	LAC* SENSE	/INDIRECT
	DAC SENSE
	ISZ TRST	/BUMP TO EXIT
	LAC* SENSE
	AND (777770
	SZA!CLA
	JMP* TRST	/ILL. SENSE LINE ADD.
	LAC* SENSE	/X
	TAD (XCT TABLE	/XCT TABLE+X
	DAC .+4	/DEPOSIT FIRST
	DAC SECOND	/DEPOSIT 2ND
	IOT5
	JMP .-1
	XX	/TEST AND RESET
		/SENSE LINE
	SMA!CLA
	JMP* TRST	/FIRST TEST LOW
	IOT5	/FIRST TEST HIGH
	JMP .-1
SECOND	XX	/TEST AND RESET
		/SENSE LINE
	SPA!CLA
	CMA	/SECOND TEST HIGH
	JMP* TRST	/SECOND TEST LOW
SENSE
TABLE	TSL0
	TSL1
	TSL2
	TSL3
	TSL4
	TSL5
	TSL6
	TSL7
IOT5=703005
TSL0=705013
TSL1=705113
TSL2=705213
TSL3=705313
TSL4=703413
TSL5=703513
TSL6=703613
TSL7=703713
	.END
