/SET SINGLE RELAY MINUS SUBROUTINE
/EXECUTION TIME: 52 TO 60 MICROSECONDS
/CALLING SEQUENCE: CALL SSRM(RELAY,ERROR)
/RELAY:0=004,1=009,2=014,3=019,
/      4=034,5=039,6=044,7=049,
/      8=064,9=069,10=074,11=079
/      12=094,13=099,14=104,15=109
/ERROR=0: NO ERROR
/     =1: ILLEGAL RELAY REQUESTED
	.TITLE SSRM
	.GLOBL SSRM
SSRM	0
	ISZ SSRM
	LAC* SSRM
	DAC RELAY
	SPA
	LAC* RELAY  /INDIRECT
	DAC RELAY   /RELAY LOCATION
	ISZ SSRM    /BUMP TO ERROR
	LAC* SSRM 
	DAC ERROR
	SPA
	LAC* ERROR  /INDIRECT
	DAC ERROR   /ERROR LOCATION
	ISZ SSRM    /BUMP TO EXIT
	LAC* RELAY  
	AND (777760
	SZA!CLL
	JMP ERROR1  /RELAY<0 OR RELAY>15
	LAC* RELAY  /STEP COUNTER
	TAD (LRS   /LONG RIGHT SHIFT
	DAC .+2     /FIX VARIABLE SHIFT
	LAC (400000
	XX          /LOAD DATA WORD
	IOT5
	JMP .-1
	SRM         /SET RELAY(S) MINUS
	DZM* ERROR  /ZERO ERROR CODE
	JMP* SSRM
ERROR1	LAC (1      /ILL. RELAY REQUEST
	DAC* ERROR
	JMP* SSRM
ERROR
RELAY
IOT5=703005
SRM=703506
	.END
