/339 DISPLAY - FORTRAN-CALLABLE SUBPROGRAM PACKAGE.
/ROUTINES TO TURN OFF OR TURN ON SUBPICTURE FILES. H.SPENCER 9/68
/@COPYRIGHT 1968 DIGITAL EQUIPMENT CORP.
/
/CALLING SEQUENCES:
/	1)TO TURN OFF A SUBPICTURE:
/		JMS	BLANK
/		JMP	.+2
/		.DSA	PNAME	/SUBPICTURE TO BE TURNED OFF
/
/	2)TO RESTORE A SUBPICTURE TO THE SCREEN:
/		JMS	UNBLNK
/		JMP	.+2
/		.DSA	PNAME	/SUBPICTURE TO BE TURNED BACK ON.
/
	.GLOBL	BLANK
	.GLOBL	UNBLNK
/BLANK ENTRY POINT
BLANK	0
	LAC	(SAD POP		/SET UP PROPER CONTROL FLOW FOR BLANK.
	DAC	BLNK20
	LAC	BLANK		/SET  UP POINTER TO ARGUMENT.
BLNK10	TAD	(1
	DAC	TEMP1
	LAC*	TEMP1		/GET THE ARGUMENT.
	SMA			/IS IT INDIRECT? (BIT0=1 IF YES)
	JMP	BLNK15		/NO.
	DAC	TEMP1		/YES, GET THE REAL ARGUMENT.
	LAC*	TEMP1
BLNK15	TAD	(1		/POINTS TO PNAME+1.
	DAC	TEMP1
	TAD	(1		/PONTS TO PNAME+2.
	DAC	TEMP2
	LAC*	TEMP2		/GET CONTENTS OF PNAME+2.
BLNK20	SAD	POP		/IF ENTRY WAS UNBLNK, THIS IS JMP BLNK30
	JMP*	BLANK		/ALREADY CONTAINS A POP, SO EXIT.
	DAC*	TEMP1		/SAVE C(PNAME+2) IN PNAME+1
	LAC	POP		/INSERT A DISPLAY POP
	DAC*	TEMP2		/IN PNAME+1,
	JMP*	BLANK		/AND RETURN.
/UNBLNK ENTRY POINT
UNBLNK	0
	LAC	(JMP BLNK30	/SET UP PROPER CONTROL FLOW FOR UNBLNK.
	DAC	BLNK20
	LAC	UNBLNK		/SET UP POINTER TO ARGUMENT.
	JMP	BLNK10		/GO TO COMMON PROCESSING.
/RETURN FROM COMMON PROCESSING.
BLNK30	SAD	POP
	SKP			/PNAME+2 SHOULD CONTAIN DISPLAY POP.
	JMP*	UNBLNK		/EXIT IF IT DOESN'T.
	LAC*	TEMP1		/MOVE C(PNAME+1) TO PNAME+2
	DAC*	TEMP2
	JMP*	UNBLNK		/AND RETURN.
/CONSTANTS
TEMP1		/TEMP STORAGE.
TEMP2		/ALSO.
POP	3000		/DISPLAY POP.
 
	.END
