	.TITLE DLOG-ALOG-.DE
	.GLOBL DLOG,ALOG,.SET,.DE,.DA
	.GLOBL .ER,.AO,.AG
DLOG	0
	LAC	.-1
	JMS*	.SET
ALOG	0
	JMS*	.DA
	JMP	.+2
ARG	0
	JMS*	.AG	/.AO IF 2-WD
		ARG+400000
	SNL!SMA		/0 OR -?
	JMP	.+4
	JMS*	.ER
	400014		/OTS 14
	JMP	.	/IDLE
	JMS	.DE
	JMP*	ALOG
/
/
	.GLOBL .AA,.AB,.AR,.AU
	.GLOBL .T1,.XA,.AW,.AP,.AS
	.GLOBL .DC,.AQ,.AV
.XX=.XA
.DE	0
	LAC*	.AA
	XOR	(400000
	DAC	ARG	/SAV EX
	LAC	(400000
	DAC*	.AA
	LAC*	.AB
	TAD	MR2	/-RT2/2
	SMA!CLC
	JMP	.+4
	ISZ*	.AA	/*2
	TAD	ARG	/N-1
	DAC	ARG
	JMS*	.AR	/Z-1
		ONE
	JMS*	.AP
		RES
	JMS*	.AQ	/Z-1+2
		TWO
	JMS*	.AV	/ Z-1/Z+1
		RES
	JMS*	.DC	/FORM POLY
		LTERM
	JMS*	.AV	/ &*&/POLY
		.T1+400000
	JMS*	.AS	/*&
		.XX+400000
	JMS*	.AP
		.T1+400000
	JMS*	.AO
		RES
	JMS*	.AS	/(Z-1)*&
		.XX+400000
	JMS*	.AU
		.T1+400000
	JMS*	.AP
		.T1+400000
	JMS*	.AO	/Z-1
		RES
	DZM*	.AB	/0 TO HI
	JMS*	.AS	/NORMALIZE
		ONE
	JMS*	.AQ
		.T1+400000
	JMS*	.AP
		.T1+400000
	LAC	ARG
	JMS*	.AW
	JMS*	.AS
		HLN2
	DZM	RES+2	/0 TO LO
	JMS*	.AQ	/N*LN2+(Z-1)H
		RES
	JMS*	.AP
		RES
	LAC ARG
	JMS*	.AW
	JMS*	.AS	/N*LLN2
		LLN2
	JMS*	.AQ
		.T1+400000
	JMS*	.AQ
		RES
	JMP*	.DE
RES	0; 0; 0
MR2	512766
ONE	1; 200000; 0
TWO	2; 200000
HLN2	0; 261344; 0
LLN2	-23; 277575; 071736
LTERM	-3
/C4=
	-4; 740446; 235367
/C3=
	-3; 722434; 072205
/C2=
	0; 746314; 656001
/C1=
	1; 300000; 0
	.END
