       .TITLE ISIGN  TRANSFER OF SIGN FOR INTEGER ARGUMENTS
/COPYRIGHT 1970, DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
       .GLOBL ISIGN,.DA
/             CALLING SEQUENCE
/      JMS*   (ISIGN)         SUBR CALL
/      JMP    .+3             SUBR RETURN
/      CAL/XCTADDR            ADDR OF ARG1
/      CAL/XCTADDR            ADDR OF ARG2 (XCT IF INDIRECT)
/
ISIGN  CAL    0              /ENTRY-EXIT
       JMS*   .DA            /GET ARGUMENTS (.DA)
       JMP    ISIG03
ISIG01 CAL    0              /ARG1
ISIG02 CAL    0              /ARG2
ISIG03 LAC*   ISIG01         /SET LINK BIT IF SIGNS DIFFER
       XOR*   ISIG02
       RAL
       LAC*   ISIG01         /GET ARG1 READY FOR -SIGNS EQUAL- EXIT
       SNL                   /SKIP IF SIGNS DIFFER
       JMP*   ISIGN          /EXIT
       CMA                   /GET TWO@S COMP OF ARG1
       TAD    ISIG05
       JMP*   ISIGN          /EXIT
ISIG05        1
       .END
