	.TITLE	TRSL
/
/  7 MAR 72 - MDO BY P. HENDERSON
/
/TEST AND RESET SENSE LINE FUNCTION
/EXECUTION TIME: 39 (TRUE) OR 38 (FALSE) 
/         MICROSECONDS
/CALLING SEQUENCE: TRSL(SENSE)
/     SENSE: 0-7 ADDRESS OF SENSE LINE
/EXIT: AC=777777 IF SENSE LINE WAS HIGH
/      AC=000000 IF SENSE LINE WAS LOW
/         OR IF SENSE LINE ADDRESS IS ILL.
/
	LOGAC
/
	.GLOBL TRSL
/
TRSL	XX
	.ARG	TRSL
	DAC SENSE
	LAC* SENSE
	AND (777770
	SZA!CLA
	JMP	SET   /ILL. SENSE LINE ADD.
	LAC* SENSE   /X
	TAD (XCT TABLE /XCT TABLE+X
	DAC .+3     /DEPOSIT TSL(SENSE)
	IOT5
	JMP .-1
	XX    /TEST AND RESET SENSE LINE
	SPA!CLA     /SKIP ON SENSE LOW
	CMA   /SENSE LINE WAS HIGH
SET	DAC*	LOGICA	/SET LOGICAL SOFTWARE AC
	LAC	(600000
	DAC*	.MODEA	/SET MODE TO LOGICAL
	JMP* TRSL
SENSE
TABLE	TSL0
	TSL1
	TSL2
	TSL3
	TSL4
	TSL5
	TSL6
	TSL7
IOT5=703005
TSL0=705013
TSL1=705113
TSL2=705213
TSL3=705313
TSL4=703413
TSL5=703513
TSL6=703613
TSL7=703713
	.END
