/CONTINUE WHEN SENSE LINE HIGH (LEVEL)
/   SUBROUTINE
/EXECUTION TIME:  PROGRAM DEPENDENT
/                 (62,74,86,...MICROSECONDS)
/CALLING SEQUENCE:  CALL CLVL(SENSE,ERROR)
/   SENSE:  0-7 ADDRESS OF SENSE LINE
/   ERROR=0:  NO ERROR
/        =1:  ILLEGAL SENSE LINE
/             REQUESTED
/CLVL RETAINS CONTROL UNTIL SENSE LINE
/   INPUT SENSE IS A HIGH LEVEL
	.TITLE CLVL
	.GLOBL CLVL
CLVL	0
	ISZ CLVL
	LAC* CLVL
	DAC SENSE
	SPA
	LAC* SENSE	/INDIRECT
	DAC SENSE	/SENSE LOCATION
	ISZ CLVL
	LAC* CLVL
	DAC ERROR
	SPA
	LAC* ERROR	/INDIRECT
	DAC ERROR
	DZM* ERROR	/ERROR=0
	ISZ CLVL	/BUMP TO EXIT
	LAC* SENSE
	AND (777770
	SZA!CLA
	JMP ERROR1	/ILL. LINE
	LAC* SENSE	/X
	TAD (XCT TABLE	/XCT TABLE+X
	DAC .+4	/DEPOSIT TSL(SENSE)
	DAC SECOND	/DEPOSIT IT AGAIN
LOOP	IOT5
	JMP .-1
	XX	/TEST AND RESET SENSE LINE
	SMA	/SKIP ON SENSE HIGH
	JMP .-4	/STILL LOW
	IOT5
	JMP .-1
SECOND	XX	/TEST AND RESET AGAIN
	SMA	/SKIP ON HIGH LEVEL
	JMP LOOP	/NOT A LEVEL
	JMP* CLVL	/CONTINUE
ERROR1	ISZ* ERROR	/ILL. SENSE
	JMP* CLVL	/   LINE REQUESTED
ERROR
SENSE
TABLE	TSL0
	TSL1
	TSL2
	TSL3
	TSL4
	TSL5
	TSL6
	TSL7
IOT5=703005
TSL0=705013
TSL1=705113
TSL2=705213
TSL3=705313
TSL4=703413
TSL5=703513
TSL6=703613
TSL7=703713
	.END
