/RESET SINGLE CONTROL LINE SUBROUTINE
/EXECUTION TIME: 52 TO 60 MICROSECONDS
/CALLING SEQUENCE: CALL RSCL(LINE,ERROR)
/     LINE: 0-15 ADDRESS OF CONTROL LINE 
/           TO BE RESET
/     ERROR=0: NO ERROR
/          =1: ILL. CONTROL LINE REQUESTED
	.TITLE RSCL
	.GLOBL RSCL
RSCL	0
	ISZ RSCL
	LAC* RSCL
	DAC LINE
	SPA
	LAC* LINE   /INDIRECT
	DAC LINE    /LINE LOCATION
	ISZ RSCL
	LAC* RSCL
	DAC ERROR
	SPA
	LAC* ERROR	/INDIRECT
	DAC ERROR
	DZM* ERROR	/ERROR=0
	ISZ RSCL	/BUMP TO EXIT
	LAC* LINE
	AND (777760
	SZA!CLL
	JMP ERROR1   /LINE<0 OR LINE >15
	LAC* LINE   /STEP COUNTER
	TAD (LRS    /LONG RIGHT SHIFT
	DAC .+2     /FIX VARIABLE SHIFT
	LAC (400000
	XX          /LOAD DATA WORD
	IOT5
	JMP .-1
	ROCL        /RESET OUTPUT
	            /CONTROL LINE
	JMP* RSCL   
ERROR1	ISZ* ERROR      /ILL. CONTROL 
	            /LINE REQUESTED
	JMP* RSCL
ERROR
LINE
IOT5=703005
ROCL=705306
	.END
