/INITIALIZE FAULT INTERRUPT HANDLERS
/EXECUTION TIME: 62 MICROSECONDS
/CALLING SEQUENCE:
/   CALL IFLT(OVLD,RANGE,NULL)
/   OVLD:  PARAMETERLESS FORTRAN IV
/          SUBROUTINE NAME
/          (OVERLOAD FAULT HANDLER)
/   RANGE:  PARAMETERLESS FORTRAN IV
/           SUBROUTINE NAME
/           (OVERRANGE FAULT HANDLER)
/   NULL: PARAMETERLESS FORTRAN IV
/         SUBROUTINE NAME
/         (POT NULL FAULT HANDLER)
	.TITLE IFLT
	.GLOBL IFLT,%OVLD,%RANGE,%NULL
IFLT	0
	ISZ IFLT
	LAC* IFLT
	SMA
	JMP .+3
	DAC TEMP    /INDIRECT
	LAC* TEMP
	DAC* %OVLD /OVLD LOC.
	ISZ IFLT
	LAC* IFLT
	SMA
	JMP .+3
	DAC TEMP	/INDIRECT
	LAC* TEMP
	DAC* %RANGE	/RANGE LOC.
	ISZ IFLT
	LAC* IFLT
	SMA
	JMP .+3
	DAC TEMP	/INDIRECT
	LAC* TEMP
	DAC* %NULL	/NULL LOC.
	ISZ IFLT	/BUMP TO EXIT
	LAC (JMS* 36
	DAC* (76     /API TRANSFER
	LAC (100
	IOT3
	JMP .-1
	RIMB        /RESTORE INTERRUPT
	            /MASK BITS
	JMP* IFLT
TEMP
IOT3=703003
RIMB=703606
	.END
