	.TITLE	RSX SYSTEM DEQUE LISTER
/
/ COPYRIGHT (C) 1976
/ DIGITAL EQUIPMENT CORPORATION, MAYNARD, MASS.
/
/ THIS SOFTWARE IS FURNISHED UNDER A LICENSE FOR USE ONLY
/ ON A SINGLE COMPUTER SYSTEM AND MAY BE COPIED ONLY WITH
/ THE INCLUSION OF THE ABOVE COPYRIGHT NOTICE.  THIS
/ SOFTWARE, OR ANY OTHER COPIES THEREOF, MAY NOT BE PRO-
/ VIDED OR OTHERWISE MADE AVAILABLE TO ANY OTHER PERSON
/ EXCEPT FOR USE ON SUCH SYSTEM AND TO ONE WHO AGREES TO
/ THESE LICENSE TERMS.  TITLE TO AND OWNERSHIP OF THE
/ SOFTWARE SHALL AT ALL TIMES REMAIN IN DEC.
/
/ THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE
/ WITHOUT NOTICE AND SHOULD NOT BE CONSTRUED AS A COM-
/ MITMENT BY DIGITAL EQUIPMENT CORPORATION.
/
/ DEC ASSUMES NO RESPONSIBILITY FOR THE USE OR RELIABILITY
/ OF ITS SOFTWARE ON EQUIPMENT WHICH IS NOT SUPPLIED BY
/ DEC.
/
	.EJECT
/
/	EDIT #6		JUN 10 1975	M. HEBENSTREIT
/ 007	21-APR-76 (RCHM)	LUN OFFSET AND USER NUMBER PATCH/(007)
/ 008	24 JAN 78 (PDH)		I/O COUNT (WORD 57) FOR PBDL	/(008)
/				IN PBDL LISTING LOGIC.		/(007)
/
/
/	THIS PROGRAM IS AN MCR FUNCTION USED TO LIST DEQUES IN THE RSX
/	SYSTEM.	THE COMMAND FORMAT SHOULD BE:	MCR>DEQ XT	WHERE
/	X IS A,C,D,B,S, OR P TO DENOTE THE ATL, CKQ, PDVL, SCDL, STL, OR THE
/	PBDL RESPECTIVELY.	T IS EITHER A CARRIAGE RETURN OR AN ALTMODE.
/
FAC=174
MCRRI=171
FPHDWE=236
OUT1=20	 /LINE PRINTER
OUT2=3	/TTY
IN=2	/TTY
.INH=705522
.ENB=705521
START	LAC	(START	/CALC THE XR ADJUSTMENT
	AND	(70000
	TCA
	DAC	XRADJ
	CAL	WRT
	LAC	(BUFFER
	DAC	WRT+4
	JMS	WAIT
	JMS*	(FAC	/GET PARAMETER AND TERMINATOR, TEST FOR VALIDITY AND
	SAD	(40	/JUMP TO APPROPRIATE ROUTINE.
	JMP	.-2
	SAD	(15
	JMP	.+11
	SAD	(175
	JMP	.+7
	DAC	TEMP
	LAC	PARAM
	SPA
	LAC	TEMP
	DAC	PARAM
	JMP	.-14
	DAC	TERM	/CHAR. IS A TERMINATOR SO STORE IT
	LAC	PARAM	/TEST TO SEE IF A PARAETER WAS GIVEN
	SPA
	JMP	ERR
	SAD	(101	/A
	JMP	ATL
	SAD	(104	/D
	JMP	PDVL
	SAD	(102	/B
	JMP	SCDL
	SAD	(123	/S
	JMP	STL
	SAD	(120	/P
	JMP	PBDL
	SAD	(103	/C
	JMP	CKQ
ERR	LAC	(OUT2 /PARAMETER WAS INCORRECT
	DAC	WRT+2
	LAC	(MSG1
	DAC	WRT+4
	CAL	WRT
	JMS	WAIT
	JMP	EXIT
	.EJECT
ATL	LAC	(MSGA
	JMS	NAMEH
	LAC	(-5
	DAC	LINECT
	.INH
	LAC	(244
	JMS	SETXR
	LAC	0,X
	.ENB
        SAD     (244
        JMP     NOLIST
NEWNA	JMS	SR3 /WORDS 0-3
	LAW	3	 /WORD 4
	JMS	SR1
	LAW	10	/WORD 5
	JMS	SR1
	LAW	20	/WORD 6
	JMS	SR1
	LAW	21	/WORD 7
	JMS	SR1
	JMS	NEXTWD	/WORD 10
	LAW	22
	JMS	OUTPUT
	SMA	/BIT 0
	JMP	.+3
	LAW	23
	JMS	OUTPUT
	LAC	TEMP	/BIT 1
	AND	(200000
	SNA
	JMP	.+3
	LAW	16
	JMS	OUTPUT
	LAC	TEMP	/BIT 2
	AND	(100000
	SZA
	JMP	.+3
	LAW	17
	JMS	OUTPUT
	JMS	SR2
	LAW	24	/WORD 11
	JMS	SR1
	.INH
	LAC	ADDR
	JMS	SETXR
	LAC	0,X
	DAC	ADDR
	.ENB
I1	SAD	 (244
	JMP	EXIT
	JMS	FORMCT
	JMP	NEWNA
	.EJECT
PDVL	LAC	(MSGD
	JMS	NAMEH
	LAC	(-5
	DAC	LINECT
	.INH
	LAC	(252
	JMS	SETXR
	LAC	0,X
	.ENB
        SAD     (252
        JMP     NOLIST
NEWND	JMS	SR3 /WORDS 0-3
	LAW	35	/WORD 4
	JMS	SR1
	LAW	36	/WORD 5
	JMS	SR1
	JMS	PTRS	/WORDS 6 AND 7
	LAW	37	/WORD 10
	JMS	SR1
	JMS	NEXTWD	/WORD 11
	SMA	/BIT 0
	JMP	.+3
	LAW	40
	JMS	OUTPUT
	LAC	TEMP	/BIT 1
	AND	(200000
	SNA
	JMP	.+3
	LAW	41
	JMS	OUTPUT
	JMS	SR2
	.INH
	LAC	ADDR
	JMS	SETXR
	LAC	0,X
	DAC	ADDR
	.ENB
	SAD	(252
	JMP	EXIT
	JMS	FORMCT
	JMP	NEWND
	.EJECT
SCDL	LAC	(MSGB
	JMS	NAMEH
	LAC	(-5
	DAC	LINECT
	.INH
	LAC	(254
	JMS	SETXR
	LAC	0,X
	.ENB
        SAD     (254
        JMP     NOLIST
NEWNB	JMS	SR3 /WORDS 0-3
	JMS	UNUSED	/WORD 4
	LAW	42	/WORD 5
	JMS	SR1
	LAW	43	/WORD 6
	JMS	SR1
	JMS	UNUSED	/WORDS 7
	JMS	NEXTWD	/WORD 10 (FLAGS)
	SZA
	JMP	SCDL1
	LAW	103	/NOS
	JMP	SCDL2
SCDL1	SAD	(1
	JMP	SCDL3
	LAW	101	/RW
	SKP
SCDL3	LAW	102	/RO
SCDL2	JMS	OUTPUT
	JMS	SR2
	LAW	106	/WORD 11
	JMS	SR1
	.INH
	LAC	ADDR
	JMS	SETXR
	LAC	0,X
	DAC	ADDR
	.ENB
	SAD	(254
	JMP	EXIT
	JMS	FORMCT
	JMP	NEWNB
	.EJECT
CKQ	LAC	(MSGC
	JMS	NAMEH
	LAC	(-5
	DAC	LINECT
	.INH
	LAC	(246
	JMS	SETXR
	LAC	0,X
	.ENB
	SAD	(246
	JMP	NOLIST
NEWNC	JMS	BLANKS
	JMS	PTRS	/WORDS 0-1
	JMS	NEXTWD	/WORD 2
	SAD	(6
	JMP	CQ6
	SAD	(5
	JMP	CQ5
	SAD	(1
	JMP	CQ1
	LAW	25
	SKP
CQ1	LAW	26
	SKP
CQ5	LAW	27
	SKP
CQ6	LAW	30
	JMS	OUTPUT
	JMS	SR2
	JMS	NEXTWD	/WORD 3
	SZA
	JMP	.+3
	LAW	17
	JMS	OUTPUT
	JMS	SR2
	LAW	3	/WORD 4
	JMS	SR1
	LAW	20	/WORD 5
	JMS	SR1
	LAW	31	/WORD 6
	JMS	SR1
	LAW	32	/WORD 7
	JMS	SR1
	LAW	33	/WORD 10
	JMS	SR1
	LAW	34	/WORD 11
	JMS	SR1
	.INH
	LAC	ADDR
	JMS	SETXR
	LAC	0,X
	DAC	ADDR
	.ENB
	SAD	(246
	JMP	EXIT
	JMS	FORMCT
	JMP	NEWNC
	.EJECT
STL	LAC	(MSGS
	JMS	NAMEH
	LAC	(-5
	DAC	LINECT
	.INH
	LAC	(242
	JMS	SETXR
	LAC	0,X
	.ENB
        SAD     (242
        JMP     NOLIST
NEWNS	JMS	SR3 /WORDS 0-3
	JMS	NEXTWD	/WORD 4
	LAW	3
	JMS	OUTPUT
	SMA	/BIT 0
	JMP	.+3
	LAW	4
	JMS	OUTPUT
	LAC	TEMP	/BIT 1
	AND	(200000
	SNA
	JMP	.+3
	LAW	5
	JMS	OUTPUT
	LAC	TEMP	/BIT 2
	AND	(100000
	SNA
	JMP	.+3
	LAW	6
	JMS	OUTPUT
	LAC	TEMP	/BIT 3
	AND	(040000
	SNA
	JMP	.+3
	LAW	7
	JMS	OUTPUT
	JMS	SR2
	LAW	10	/WORD 5
	JMS	SR1
	LAW	11	/WORD 6
	JMS	SR1
	LAW	12	/WORD 7
	JMS	SR1
	JMS	NEXTWD	/WORD 10
	LAW	13
	JMS	OUTPUT
	LAC	ADDR
	JMS	SETXR
	LAC	11,X	/IS TASK NORMAL MODE?
	AND	(100000
	SNA
	JMP	STL11	/NO
	LAC	TEMP	/YES -- CHECK THE XVM BITS
	AND	(000140
	SNA
	JMP	STL10
	LAW	104
	JMS	OUTPUT
STL10	LAC	TEMP
	AND	(000020
	SNA
	JMP	STL11
	LAW	105
	JMS	OUTPUT
STL11	JMS	SR2
	JMS	NEXTWD	/WORD 11
	LAW	14
	JMS	OUTPUT
	SMA	/BIT 0
	JMP	.+3
	LAW	15
	JMS	OUTPUT
	LAC	TEMP	/BIT 1
	AND	(200000
	SNA
	JMP	.+3
	LAW	16
	JMS	OUTPUT
	LAC	TEMP	/BIT 2
	AND	(100000
	SZA
	JMP	.+3
	LAW	17
	JMS	OUTPUT
	JMS	SR2
	.INH
	LAC	ADDR
	JMS	SETXR
	LAC	0,X
	DAC	ADDR
	.ENB
	SAD	(242
	JMP	EXIT
	JMS	FORMCT
	JMP	NEWNS
	.EJECT
PBDL	LAC	(MSGP
	JMS	NAMEH
	.INH
	LAC	(250
	JMS	SETXR
	LAC	0,X
	.ENB
        SAD     (250
        JMP     NOLIST
NEWNP	JMS	SR3 /WORDS 0-3
	LAW	10	/WORD 4
	JMS	SR1
	LAW	54	/WORD 5
	JMS	SR1
	LAW	13	/WORD 6
	JMS	SR1
	LAW	55	/WORD 7
	JMS	SR1
	JMS	NEXTWD	/WORD 10
	DAC SAVWD	/ SAVE RESULT FOR LATER.		/(007)
	AND (7)		/ EXTRACT FLAG BITS.			/(007)
	SZA
	JMP	PBDL1
	LAW	103
	JMP	PBDL2
PBDL1	SAD	(1
	JMP	PBDL3
	LAW	101
	SKP
PBDL3	LAW	102
PBDL2	JMS	OUTPUT
	LAC SAVWD	/ FETCH SAVED WORD.			/(007)
	AND (760)	/ USER NUMBER IN WORD?			/(007)
	SNA		/ 					/(007)
	JMP PBDL4	/ NO.					/(007)
	LAW 113		/ FETCH MODIFIER NUMBER.		/(007)
	JMS OUTPUT	/ ADD MODIFIER TO OUTPUT LINE.		/(007)
PBDL4	LAC SAVWD	/ FETCH SAVED WORD.			/(007)
	AND (777000)	/ LUN OFFSET IN WORD?			/(007)
	SNA							/(007)
	JMP PBDL5	/ NO.					/(007)
	LAW 114		/ FETCH MODIFIER NUMBER.		/(007)
	JMS OUTPUT	/ ADD MODIFIER TO OUTPUT LINE.		/(007)
PBDL5	JMS SR2		/ TERMINATE AND PRINT LINE.		/(007)
	LAW	57	/WORD 11
	JMS	SR1
	LAW	60	/WORD 12
	JMS	SR1
	LAW	61	/WORD 13
	JMS	SR1
	LAW	62	/WORD 14
	JMS	SR1
	LAW	63	/WORD 15
	JMS	SR1
	LAW	64	/WORD 16
	JMS	SR1
	LAW	51	/WORD 17
	JMS	SR1
	LAW	52	/WORD 20
	JMS	SR1
	LAW	65	/WORD 21
	JMS	SR1
	LAW	66	/WORD 22
	JMS	SR1
	LAW	67	/WORD 23
	JMS	SR1
	LAW	70	/WORD 24
	JMS	SR1
	LAW	-6	/WORDS 25-31
	JMS	SR6
	LAW	71	/WORD 32
	JMS	SR1
	LAW	-10	/WORDS 33-41
	JMS	SR6
	LAW	72	/WORD 42
	JMS	SR1
	JMS	NEXTWD	/WORD 43
	JMS	SR2
	LAW	110	/WORD 44
	JMS	SR1
	LAW	111	/WORD 45
	JMS	SR1
	LAW	112	/WORD 46
	JMS	SR1
	LAW	106	/WORD 47
	JMS	SR1
	LAW	107	/WORD 50
	JMS	SR1
	XCT*	(FPHDWE	/IS THERE FLOATING POINT HARDWARE?
	JMP	PBDLNF	/NO -- FORGET THE NEXT 6 WORDS
			/YES -- PRINT REMAINDER OF NODE
	LAW	73	/WORD 51
	JMS	SR1
	LAW	74	/WORD 52
	JMS	SR1
	LAW	75	/WORD 53
	JMS	SR1
	LAW	76	/WORD 54
	JMS	SR1
	LAW	77	/WORD 55
	JMS	SR1
	LAW	100	/WORD 56
	JMS	SR1
PBDLNF	LAW	115	/ WORD 57 (OR 51) - I/O COUNT		/(008)
	JMS	SR1						/(008)
	.INH
	LAC	ADDR
	JMS	SETXR
	LAC	0,X
	DAC	ADDR
	.ENB
	SAD	(250
	JMP	EXIT
	LAC	(MSG2
	DAC	WRT+4
	CAL	WRT
	JMS	WAIT
	LAC	(BUFFER
	DAC	WRT+4
	LAC*	(MCRRI	/HAS A CTRL/C BEEN TYPED?
	SMA
	JMP	.+3
	CAL	REQMCR	/YES -- EXIT
	CAL	(10
	LAC	ADDR	/NO -- CONTINUE
	JMP	NEWNP
SAVWD	0		/ TEMPORARY FOR WORD 10.		/(007)
	.EJECT
K10	10 /CONSTANTS AND VARIABLES
XRADJ	0
ADDR	NOP
TEMP	NOP
TEMP1	NOP
TEMP2	NOP
TEMP3	NOP
IOVAR	NOP
PCNT	NOP
A	NOP
B	NOP
AD1	FLAGS
BUFFAD	BUFFER+1
PARAM	777777
TERM	15
EXIT	LAC	TERM	 /TEST TERMINATOR AND EXIT ACCORDINGLY
	SAD	(15
	CAL	REQMCR
	SAD	(175
	DZM*	(MCRRI
	CAL	(10
WRT	2700	/WRITE CAL
	IOVAR
	20
	2
	MSG2
REQMCR	1	/REQUEST MCR CAL
	0
	.SIXBT "..."
	.SIXBT "MCR"
	0
SETXR	0
	TAD	XRADJ
	PAX
	JMP*	SETXR
FORMCT	0
	PAL		/SAVE THE AC IN THE LR
	LAC*	(MCRRI	/HAS A CTRL/C BEEN TYPED?
	SMA
	JMP	.+3
	CAL	REQMCR	/YES -- EXIT
	CAL	(10
	PLA		/NO -- RESTORE THE AC AND CONTINUE
	ISZ	LINECT
	JMP*	FORMCT
	LAC	(MSG2
	DAC	WRT+4
	CAL	WRT
	JMS	WAIT
	LAC	(BUFFER
	DAC	WRT+4
	LAC	(-5
	DAC	LINECT
	LAC	ADDR	/NO -- CONTINUE
	JMP*	FORMCT
LINECT	0
NAMEH	0
	DAC	WRT+4
	CAL	WRT
	JMS	WAIT
	LAC	(BUFFER
	DAC	 WRT+4
	JMP*	NAMEH
BLANKS	NOP	/S.R. TO PRINT 2 BLANKS LINES AND INIT. WORD PTR.
	DAC	ADDR	/DEPOSIT POINTER IN ADDR
	LAC	(MSG3	/PRINT 2 BLANK LINES
	DAC	WRT+4
	CAL	WRT
	JMS	WAIT
	CAL	WRT
	LAC	(BUFFER
	DAC	WRT+4
	JMS	WAIT
	CLC	/INIT WORD IN NODE POINTER
	TAD	ADDR
	DAC	A
	JMP*	BLANKS
WAIT	NOP
	CAL	WAITFR
	LAC	IOVAR
	SMA
	JMP*	WAIT
	LAC	(2
	DAC	WRT+2
	LAC	(MSGE
	DAC	WRT+4
	CAL	WRT
	CAL	WAITFR
	JMP	EXIT
WAITFR	20
	IOVAR
NOLIST  LAC     (MSG3
	DAC	WRT+4
	CAL	WRT
	JMS	WAIT
	LAC	(MSGNO
        DAC     WRT+4
        CAL     WRT
        JMS     WAIT
        JMP     EXIT
LCNT	NOP	/S.R. TO INCREMENT PAIR COUNT AND LOAD AC WITH TEMP
	DAC*	10	/PUT WORD IN AC INTO BUFFER
	LAC	PCNT	/INCREMENT PAIR COUNT
	IAC
	DAC	PCNT
	LAC	TEMP
	JMP*	LCNT
PTRS	NOP	/S.R. TO PRINT NEXT 2 WORDS WITH FP AND BP DESC.
	LAW	1
	JMS	SR1
	LAW	2
	JMS	SR1
	JMP*	PTRS
UNUSED	NOP	/S.R. TO PRINT WORD WITH 'UNUSED' DESCRIPTOR
	LAW	53
	JMS	SR1
	JMP*	UNUSED
SR1	NOP	 / S.R. TO PRINT A WORD AND DESCRIPTOR
	DAC	TEMP2
	JMS	NEXTWD
	LAC	TEMP2
	JMS	SR7
	JMP*	SR1
SR7	NOP	 /S.R. TO PRINT DESC. AND TERMINATE LINE
	JMS	OUTPUT
	JMS	SR2
	JMP*	SR7
SR2	NOP	 /S.R. TO END BUFFER WITH CR AND PRINT
	LAC	MSG3+2	/PUT CR INTO BUFFER
	JMS	LCNT	/INCREMENT PCNT
	CLL
	LAC	PCNT	/SET UP BUFFER HEADER
	ALS	11
	AAC	2
	DAC	BUFFER
	DZM	BUFFER+1
	CAL	WRT	/PRINT BUFFER
	JMS	WAIT
	JMP*	SR2
SR3	NOP	 /S.R. TO PRINT 1ST 2 WDS AS PTRS AND NEXT 2 AS A NAME
	JMS	BLANKS
	JMS	PTRS
	JMS	NAME
	JMP*	SR3
OUTPUT	NOP	/S.R. TO ADD THE DESCRIPTOR INDICATED BY AC TO BUFFER
	AND	(777	/FIND ADDRESS OF INDICATED DESC.
	DAC	B
	CLC
	TAD	B
	RCL
	TAD	AD1
	DAC	B
	LAC*	B	/PUT DESC. INTO BUFFER
	DAC*	10
	LAC	B
	IAC
	DAC	B
	LAC*	B
	JMS	LCNT	/PUT WD. INTO BUFFER AND INCREMENT PCNT
	JMP*	OUTPUT
NEXTWD	NOP	/PRINT OCTAL CONTENS OF NEXT WD. AND INIT. PCNT
	LAC	BUFFAD	/INITIALIZE BUFFER POINTER
	DAC*	K10
	LAC	A	 /INCREMENT WORD IN NODE POINTER
	IAC
	DAC	A
	LAC*	A	/GET NEXT NODE WD. INTO AC AND PUT ASCII INTO BUFFER
	DAC	TEMP
	LMQ
	JMS	SR4
	ALS	13
	DAC	TEMP3
	JMS	SR4
	ALS	4
	TAD	TEMP3
	AAC	6
	DAC*	10	/DEPOSIT 1ST WD. INTO BUFFER
	CLA!CLL
	LLS	3
	ALS	17
	DAC	TEMP3
	JMS	SR4
	ALS	10
	TAD	TEMP3
	DAC	TEMP3
	JMS	SR4
	RAL
	TAD	TEMP3
	DZM	PCNT	/INIT PCNT
	JMS	LCNT	/DEPOSIT 2ND WD. INTO BUFFER AND INCREMENT PCNT (5 CHAR. IN BUFF )
	JMS	SR4
	ALS	13
	TAD	(1004	/ADD SPACES AFTER LAST ASCII CHAR. NEEDED FOR NODE WD. CONTENTS
	DAC*	10	/DEPOSIT 3RD WD. INTO BUFFER
	LAC	(20100
	JMS	LCNT	/DEPOSIT 4TH WD. INTO BUFFER AND INCREMENT PCNT
	JMP*	NEXTWD
SR4	NOP	 /S.R. USED IN NEXTWD
	CLA!CLL
	LLS	3
	AAC	60
	JMP*	SR4
SR6	NOP	 /S.R. TO PRINT SOME WDS. WITHOUT DESC
	DAC	TEMP1
	ISZ	TEMP1
	SKP
	JMP*	SR6
	JMS	NEXTWD
	JMS	SR2
	JMP	.-5
SR5	NOP	 /S.R. USED IN 'NAME'
	CLA!CLL
	LLS	6
	DAC	TEMP3
	LAW	-40
	TAD	TEMP3
	SPA
	JMP	.+3
	LAC	TEMP3
	JMP	.+3
	LAC	TEMP3
	AAC	100
	CLL
	JMP*	SR5
NAME	NOP	/PRINT NEXT 2 WDS. AND ASCII NAME GIVEN IN THOSE WDS.
	JMS	NEXTWD	/PRINT 1ST 'NAME' WD AND UNPACK 1ST 3 CHAR.
	LMQ
	JMS	SR5
	ALS	13
	DAC	TEMP2
	JMS	SR5
	ALS	4
	TAD	TEMP2
	DAC	TEMP2
	JMS	SR5
	CLQ
	CLL
	LRS	3
	TAD	TEMP2
	DAC*	10	/DEPOSIT 1ST WD. NEEDED FOR NAME INTO BUFFER
	LACQ
	DAC	TEMP2
	LAC	A	 /GET NEXT NODE WD
	IAC
	DAC	A
	LAC*	A
	LMQ	/UNPACK 2ND 3 CHAR. AND PUT 5 CHAR. INTO BUFFER
	JMS	SR5
	ALS	10
	TAD	TEMP2
	DAC	TEMP2
	JMS	SR5
	ALS	1
	TAD	TEMP2
	JMS	LCNT	/DEPOSIT 2ND WD NEEDED FOR NAME INTO BUFFER AND INCREMENT PCNT
	JMS	SR5
	ALS	13
	TAD	(1004	/FILL OUT UNUSED WDS WITH SPACES
	DAC*	10	/DEPOSIT 3RD WD. INTO BUFFER
	LAC	(20100	/PUT FINAL WD. INTO BUFFER AND INCEMENT PCNT
	JMS	LCNT
	CLC	/RESTORE WORD IN NODE POINTER
	TAD	A
	DAC	A
	JMS	SR2	/PRINT 2ND 'NAME' WORD
	JMS	NEXTWD
	JMS	SR2
	JMP*	NAME
/DESCRIPTORS FOR NODE WORDS
FLAGS   .ASCII "FP   "  /FORWARD POINTER (CODE 1)
        .ASCII "BP   "  /BACKWARD POINTER
	.ASCII "PRIO "	/PRIORITY OF TASK
        .ASCII "ACT  "  /TASK ACTIVE (4)
	.ASCII "REMV "	/REMOVE ON EXIT
	.ASCII "DISA "	/TASK DISABLED
        .ASCII "FIX  "  /TASK IS FIXED IN CORE
        .ASCII "PBA  "  /PARTITION BLOCK ADDRESS (10)
	.ASCII "DA+U "	/DISK ADDRESS AND UNIT
	.ASCII "RSIZ "	/RESIDENT SIZE
	.ASCII "TSIZ "	/TASK SIZE
	.ASCII "ENTR "	/TASK ENTRY POINT (14)
        .ASCII "FFP  "  /FLOATINT POINT PROCESSOR REQUIRED
	.ASCII "BANK "	/BANK MODE
	.ASCII "EXEC "	/EXEC MODE
	.ASCII "STLA "	/STL NODE ADDRESS (20)
	.ASCII "STAT "	/STATUS OF TASK
	.ASCII "RADD "	/START OR RESUMPTION ADDRESS
        .ASCII "LS   "  /LINK SET
	.ASCII "EVAD "	/ADDRESS OF EVENT VARIABLE (24)
	.ASCII "TSNR "	/TASK SCHEDULING, NO RESCHEDULING
	.ASCII "TSPR "	/TASK SCHEDULING, PERIODIC RESCHEDULING
	.ASCII "MARK "	/MARK TIME REQUEST
	.ASCII "NULL "	/CANCEL OR UNMARK (30)
	.ASCII "SSEC "	/SCH INTERVAL IN SECONDS
	.ASCII "STIK "	/SCH INTERVAL IN TICKS
	.ASCII "RSEC "	/RESCH INTERVAL IN SECONDS
	.ASCII "RTIK "	/RESCH INTERVAL IN TICKS (34)
	.ASCII "AFLG "	/ATTACH FLAG
	.ASCII "DEVU "	/DEVICE UNIT
	.ASCII "TEVA "	/TRIGGER EVENT VARIABLE ADDRESS
        .ASCII "REA  "  /REASSIGN (40)
	.ASCII "HWOF "	/HANDLER WITH OPEN FIILES
	.ASCII "CBBA "	/COMMON BLOCK BASE ADDRESS
        .ASCII "CBS  "  /COMMON BLOCK SIZE
        .ASCII "MPV  "  /MEMORY PROTECT. VIOL. (44)
	.ASCII "NEWV "	/NON-EXIST MEM. REF.
	.ASCII "BCAL "	/BAD CAL
        .ASCII "NZT  "  /NON-ZERO TRANSFER
        .ASCII "PC   "  /PC (50)
        .ASCII "AC   "  /AC
        .ASCII "XR   "  /XR
	.ASCII "UNUS "	/UNUSED
	.ASCII "PSIZ "	/PARTITION SIZE (54)
        .ASCII "CPT  "  /COUNT OF PENDING TRANSFERS
	.ASCII "POCC "	/PARTITION OCCUPIED
	.ASCII "VPSIZ"	/VIRTUAL PARTITION SIZE
	.ASCII "BUFP "	/BUFFER POINTER (60)
	.ASCII "RSRA "	/REGISTER SAVE ROUTINE ENTRY
        .ASCII "ICL  "  /INTERUPT CONNECT LOCATION
        .ASCII "DBA  "  /DBA
        .ASCII "JMS* "  /JMS* (64)
        .ASCII "LR   "  /LR
        .ASCII "MQ   "  /MQ
        .ASCII "SC   "  /SC
	.ASCII "R1-R6"	/REGISTERS 1 TO 6 (70)
        .ASCII "AIR  "  /AUTO INCREMENT REGISTERS
        .ASCII "L20  "  /L 20
        .ASCII "EPA  "  /EPA BUFFER
	.ASCII "FMA1 " / (74)
	.ASCII "FMA2 "
	.ASCII "FMQ1 "
	.ASCII "FMQ2 "
        .ASCII "JEA  "  /JEA AND GUARD BIT BUFFER (100)
	.ASCII "RW   "	/READ AND WRITE
	.ASCII "RO   "	/READ ONLY
	.ASCII "NOS  "	/NO SHARING
	.ASCII "XVM  "	/XVM MODE (104)
	.ASCII "IOT  "	/IOT PERMISSION
	.ASCII "TCNT "	/TASK USE COUNT
	.ASCII "SHRPT"	/SHARE POINTER
	.ASCII "MM   "	/MM REGISTER BUFFER (110)
	.ASCII "CLK1 "	/XM CLOCK OVERFLOW COUNT (111)
	.ASCII "CLK2 "	/XM CLOCK TICKS (112)
	.ASCII "USR  "	/ USER NUMBER IN FLAG WORD (113)	/(007)
	.ASCII "MAP  "	/ LUN OFFSET IN FLAG WORD (114)		/(007)
	.ASCII	'IOCNT'	/ I/O COUNT (115)			/(008)
MSG1    MSG2-MSG1/2*1000
	0
	.ASCII "ILL PARAM"<15>
MSG2	MSG3-MSG2/2*1000
	0
	.ASCII <14><15>
MSG3	MSGE-MSG3/2*1000
	0
	.ASCII " "<15>
MSGE	MSGA-MSGE/2*1000
	0
	.ASCII "OUTPUT ERROR"<15>
MSGA	MSGD-MSGA/2*1000
	0
	.ASCII "ACTIVE TASK LIST"<15>
MSGD	MSGB-MSGD/2*1000
	0
        .ASCII "PHYSICAL DEVICE LIST"<15>
MSGB	MSGS-MSGB/2*1000
	0
	.ASCII "SYSTEM COMMON BLOCK LIST"<15>
MSGS	MSGP-MSGS/2*1000
	0
	.ASCII "SYSTEM TASK LIST"<15>
MSGP	MSGNO-MSGP/2*1000
	0
	.ASCII "PARTITION BLOCK LIST"<15>
MSGNO   MSGC-MSGNO/2*1000
        0
        .ASCII "*** NO NODES IN LIST ***"<15>
MSGC	BUFFER-MSGC/2*1000
	0
	.ASCII "CLOCK QUEUE"<15>
BUFFER	.BLOCK 22	/OUTPUT BUFFER	MAX. NO. CHR./LINE IS 37 (10)
	.END
