	.GLOBL	POINTS,.DA,FILE
POINTS	XX
	JMS*	.DA	/  FIND ARGUMENTS
	JMP	.+5
I	.DSA	0	/  ADDRESSES OF ARGUMENTS
A	.DSA	0
B	.DSA	0
N	.DSA	0
	LAC*	A	/  GET THE STARTING ADDRESS OF THE
	DAC	INT#	/  DIMENSIONED AREA INT
	LAC*	B	/  GET THE STARTING ADDRESS OF THE
	DAC	ISCALE#	/  DIMENSIONED AREA ISCALE
	LAC	FILE
	ADD*	I
	TAD	(-1
	DAC	PLACE#	/  ADDR. OF LOC IN FILE COMMON
	LAC*	PLACE
	LMQ
	CLA
	LLS+3
	SAD	(3
	JMP	PLANE
	SAD	(1	/  POINT MODE
	JMP	OTHER
	SAD	(2	/  CURVE & LINE MODE
	JMP	OTHER
	.IODEV 4
	.INIT 4,1,POINTS
	.WRITE 4,2,ERR,10
	.CLOSE 4
	JMP*	POINTS
PLANE	LAW	17775	/  DATA IS STILL IN THE MQ
	DAC	COUNT#
	CLA
	LLS+3
	DAC*	INT
	ISZ	INT	/  POINTS AT NEXT LOC. IN INT
	CLA
	LLS+2
	DAC*	ISCALE
	ISZ	ISCALE	/  POINTS AT NEXT LOC. IN ISCALE
	ISZ	COUNT
	JMP	PLANE+2	/  GET NEXT SET OF VALUES
	LAC	(3
	DAC*	N
	JMP*	POINTS
OTHER	CLA
	LLS+3
	DAC*	INT
	CLA
	LLS+2
	DAC*	ISCALE
	LAC*	PLACE
	AND	(1777
	DAC*	N
	JMP*	POINTS
ERR	.ASCII	'     BAD MODE/POINTS'<015><012>
	.END
