
/
/      PROCESS T..........24 HOUR PRINT OUTPUT.
COMND4 0
       SNA
       JMP .+3
        DZM CLKCNT
       JMP* COMND4
       LAC TIMID
       JMS ASPRT
       LAC HRS
       JMS DECP
       LAC COLON
       JMS TYPE
       LAC MINS
       JMS DECP
       LAC COLON
       JMS TYPE
       LAC SECS
       JMS DECP
       JMP* COMND4
COLON  272
HRS    0
MINS   0
SECS   0
TIMFLG 0
BELFLG 0
TIMID  TIMID+1
       .SIXBT "   THE TIME IS:   @"
/
/      PROCESS S..........REAL TIME SAMPLING.
COMND2 0
       SNA
       JMP CMND2
       DZM SAMFLG    /STOP PREVIOUS SAMPLING PROCESS
       DZM SCHECK    /INHIBIT FURTHER SAMPLING.
       LAC FSAM       
       CMA!IAC       /CHECK NEW SAMPLE RATE
       TAD FSMAX
       SMA
       JMP .+4
       LAC MESS3     /MAXIMUM RATE EXCEEDED
       JMS ASPRT
       JMP* COMND2
                     /CALCULATE NUMBER OF POINTS
                     /TO BE SAMPLED
       LAC FSAM
       JMS MUL
       LAC TSAM
       DAC SAVE13
       LAC %MHIGH
       JMS DIV
       LAC SAVE13
       LAC P1000
       DAC NSAM      /STORE NUMBER OF POINTS
       CMA!IAC       /CHECK IF TOO LARGE
       TAD BUFCAP
       SMA
       JMP .+4
       LAC MESS4     /MAXIMUM NUMBER OF POINTS EXCEEDED
       JMS ASPRT
       JMP* COMND2
                      /PARAMETERS IN RANGE
       CLA            /CALCULATE SAMPLE PERIOD
       JMS DIV
       LAC P1SEC
       LAC FSAM
       DAC TSAM1    /SAVE CLOCK INCREMENT
       CLA!IAC
       DAC SCHECK      /SAMPLE PROCESS READY.
       JMP* COMND2
/
/      START SAMPLING PROCESS
CMND2   DZM SAMFLG     /STOP PREVIOUS SAMPLING PROCESS
       LAC SCHECK      /IS SAMPLING PROCESS READY?
       SZA
       JMP .+4
       LAC MESS5       /NO, PRINT ERROR MESSAGE.
       JMS ASPRT
       JMP* COMND2
                      /INITIALIZE SAMPLING PROCESS
       DZM SAMCNT
       LAC BUFADD
       DAC SAMBUF
       LAC TSAM1    /GET CLOCK INCREMENT
       JMS CLKSET      /START CLOCK
       DZM ADCFLG      /CLEAR ADC S.W. FLAG
       701502          /INITIATE ADC
       CLA!IAC
       DAC SAMFLG      /SAMPLING IN PROGRESS
       JMP* COMND2
FSAM   0
TSAM   0
FSMAX  1750
BUFCAP 1000
SCHECK 0
SAVE13 0
TSAM1  0
P1000  1750
NSAM   0
P1SEC  23420
P10000 23420
MESS3  MESS3+1
       .SIXBT "   MAXIMUM SAMPLING RATE = 1000 HZ.@"
MESS4  MESS4+1
       .SIXBT "   MAXIMUM NUMBER OF POINTS = 512@"
MESS5 MESS5+1
       .SIXBT "   SAMPLING PARAMETERS NOT IN RANGE@"
y