           
ts ddt part 2


define disp lc,uc
ucx1000 lc-ev4x1001
terminate


sym=7747
wrd=7750

lr,	lar
	scn

lis,	dac ac
	jsp tr1

lse,	jsp lcc
lss,	clc
	dac tpi
	dac chi

lsp,	dzm wrd
	lac cun
ssn,	dip sgn
	dzm dnm
	dzm syl
n2,	dzm sym
	clc
	dac let

lsr,	lio sk1
	dio wea
	init bax,lwt
	lac ac
	lio io
	clf 1
	szf 1 i
	jmp .-1
	tyi
ps1,	dio ch
	law dtb
	add ch
	dap .+1
	lac .
cas,	xx	/rar 9s (uc) or dio ch (lc)
	and (777
cad,	add tls
	dap lsx
	sub ar1		/last no-eval routine
	spq
	jmp i lsx
	law syl
	lio let
	spi i
	jsp evl
tls,	jmp ev4
	lac (flex U
	jda tys
	jmp lsp

evl,	dap evx
evc,	lac est
	dap ev2
                
                                
ev2,	lac .
	sad sym
	jmp ev3		/match found
	idx ev2
	index ev2, evc, ev2
	idx evx
ev3,	idx ev2
evx,	jmp .

ev4,	dap sgn
	lac wrd
sgn,	xx		/operator and syllable addr.
	dac wrd
	lio chi
	spi
	lac lwt
lsx,	jmp .

/no-eval routines

n,	rir 5s		/number routine
	lac syl
	ral 3s
	spi i
cun,	ior ch
	dac syl
	lac dnm
	ral 2s
	add dnm
	ral 1s
	spi i
	add ch
	dac dnm
	jmp l1

l,	dzm let		/letter routine
l1,	lac sym
	ral 6s
	add ch
	dac sym
	dzm chi
	jmp lsr
                
                                
uc,	lio rc		/upper case
	jmp .+2
lc,	lio ps1		/lower case
	dio cas
	jmp lsr

dot,	lac loc	/.
	lio sym
	sni
	jmp n1

sqo,	lac dnm	/'
	jmp n1+1

quo,	lac sym	/"
	jmp n1 1

m,	law msk	/M 
	jmp n1

ovb,	lac syl	/.
	sza i
	jmp ptb
	lac syl
	sas (bk1
	jmp mo
	law ch	/B.
	dac bk1
	dac bk1 1
	dac bk1 2
	dac bk1 3
	jmp lse
mo,	sas (msk
	jmp err
	clc	/M.
	dac msk
	dzm ll
	law i 1
	add est
	dac ul
	jmp lse
ptb,	law i bk1
	add loc
	spa
	jmp err
	sub (4
	sma
	jmp err
	law ch
	jmp n1

q,	lac lwt	/Q
	jmp n1

f,	law pf	/F
n1,	dzm chi
	dac syl
	jmp n2

err,	law 7435
	jda tys
	law 2134
	jda tys
	jmp lse

daq,	law 7777	/>>04<<
	and lwt
	jmp .+2

com,	lac loc	/,
	dac df1

start
                
                                                                                                                          
