                            
ts ddt part 4

pra,	spi	/P
pr1,	law 0
	cma
	dac ch
	jsp lcc
gop,	lac bix
	and (opr
	sad (jsp
	jmp psj
	sad (cal
	jmp adj
	sad (jdp
	jmp pdj
	sad (xct
	jmp tcq
go,	cks
	ril 2s
	spi i
	jmp .-3
	lac sbi
	iot 56
	sza
	esm
pr3,	lac fl1
	sza i
	clf 1
	lio i bk1
	dio bki
	lio i bk1 1
	dio bki 1
	lio i bk1 2
	dio bki 2
	lio i bk1 3
	dio bki 3
	lio (jda tr
	dio i bk1
	dio i bk1 1
	dio i bk1 2
	dio i bk1 3
	clo
	lac ovf
	ral 1s
	spa
	eem
	rar 1s
	add c4
	tsn
	lio pf
	lpf
	lio be
	lbe
	lio io

pr2,	lac ac
bix,	xx
prc,	jmp .
prd,	jmp .

xec,	dac xe1	/X
	law xe1

bgn,	spi	/G
	jmp err
	dap bix
	lac prc
	dip bix
	jmp pr1

nws,	lac sk2	/N
	dac wea

wds,	law ws1	/W
ws,	spi
	jmp err
	dap ws2
	jsp lcc
	dzm t2
	lac ll
	dac t
                
                                
ws4,	dzm sym
	dap t2
	lac i t2
ws2,	jmp .		/ea1 or ws1

pbx,	dac lwt	/~
	jsp lct
	jda tys
	jmp pn2
                
                                
ub,	spi	/.
	cla
	dip tas
	spi i
	law 600
	dap jmc
	jmp lse

vfy,	jsp lcc	/V
	lac rb2
	jmp .+2
rd,	lac bs1	/Y
	dip vf4
	jsp soi

vf1,	law 7777
	and t
	sub ll
	spa
	jmp vf2
	add ll
	sub ul
	szm
	jmp vf2
	lac i la
vf4,	t		/dac i or sad i
	jmp vf2

vf3,	jsp pac
	jsp lct
	lac i la
	jda lwt
	jsp lcc

vf2,	idx t
	idx la
	sad rb1
	jsp rbk
	jmp vf1

kil,	law low	/K
	dac est
	jmp lse
                
                                
tbl,	jsp soi	/T

tb1,	jsp tbi
	dzm sym
	law 1
	mul i la
	div . 1
	50
	dio . 3
	mul one
	div .-3
	0
	jda cv1
 	jda cv1
	lac .-3
	jda cv1
	lac sym
	cli
	rcl 6s
	sza
	jmp .-2
	dio sym
	jsp tbi
	lac i la
	dac df1
	jsp de
	law tb1
tbi,	dap . 4
	idx la
	sad rb1
	jsp rbk
	jmp .

cv1,	0
	dap cvx
	lac cv1
	swp
	sni
	jmp cvx
	swp
	add (7
	dac df1
	sar 7
	cma
	add df1
	sar 7
	add (cvo
	dap . 1
	lac .
	add df1
	rar 6s
	ior sym
	ral 6s
	dac sym
	swp
cvx,	jmp .

cvo,	10	-10	37	6	-22
                
                                pul,	dap fa
	jmp lss

zro,	law 7777	/Z
	spi
	dac wrd
	and fa
	spi
	cla
	dac t

zr1,	sub est
	sma
	jmp lse
	add est
	sub wrd
	szm
	jmp lse
	dzm i t
	idx t
	jmp zr1

/end of dispatched routines
                
                                
adj,	lac bix
	dap . 2
	lac ac
	dac .
	idx bix
psj,	lac ovf
	dac ac
	lac prc
	dap ac
	jmp bgn 4

tcq,	lac i bix
	dac bix
	jmp gop

pdj,	lac prc
	dac i bix
	lac ovf
	dip i bix
	idx bix
	jmp bgn 3

ea1,	and ci
	sza
	jmp ea2
	law 7777
	and i t2

ws1,	xor wrd
can,	and msk		/used as and
wea,	xx		/sza or sza i
	jmp ws3

ws6,	law lcc

pac,	dap pax
	lac t
	jda pad
	law 2136
	jda tys
	lac i t
	jda lwt
pax,	jsp .

ws3,	idx t		/index and skip over pgm
	sub ul
	szm
	jmp lse
	add ul
	sub est
	sma
	jmp lse
	lac t
	jmp ws4

ea2,	idx sym
	sad c77
	jmp ws3
	lac i t2
	jmp ws4+1

spd,	lac lwt
	sad (ac
	jmp pna
	sad (io
	jmp pni
	sad (pf
	jmp pnf
	sad (be
	jmp pne
	sub (msk
	spa
	jmp err
	sub (3
	spa
	jmp pnm
	sub (4
	sma
	jmp err
	add (4
	dap pnp 5
 	sza
	jmp bnp
	law 7462
	jda tys
	jmp rpd
bnp,	law 7462
	jmp pnp 2

pob,	lio tpi
	spi i
	jmp okp
	jsp lct
	lac i tas
	sas (ch
	jmp rkp
	law 56
	jda tys
	jmp bax 1
pna,	law 7461
	jda tys
	jmp rpd
pni,	law 7471
	jmp pna 1
pnf,	law 7466
	jmp pna 1
pne,	law 7465
	jmp pna 1
pnm,	add (3
	sza
	jmp pnp
	law 7444
	jda tys
	jmp rpd
pnp,	dap . 5
	law 7444
	jda tys
	law 5472
	jda tys
	law .
	jda opt
	jmp rpd
                
                                
tbn,	jsp lct
	lac est
	jda opt

tbm,	jsp rbk
	jmp tbm

lwt,	0
	dap pnx
	lac lwt
pns,	jda pi		/pi or opt
pnx,	jmp .

tr,	0	/breaks to here
	dap prc
	dap prd
	idx prd
	sub (2	/find it
	dap . 1
get,	lac .
	sad (jda tr
	jmp got
	dap get
	jmp get
got,	law bk1
	dap sb3
	law 7777
	and get
sb3,	sad .
	jmp gtq
	index sb3,(sad bk1 4,sb3-2
	jmp err
gtq,	lac (bki-bk1
	add sb3
	dap . 1
	lac .	/get inst.
	dac bix
	lac tr
	dac ac
	jsp tr1
	isp ch
	jmp gop

tr2,	law i 1
	add prc
	jda pad	/print trap addr
	law 55
	jda tys
	lac pad
	jmp ta5

tr1,	dac ovf
	dap fvo
	dio io
	rpf
	dio pf
	rbe
	dio be
	tsf
	lem
	dac sbi
	cks
	ril 6s
	spi i
	dzm sbi
	lsm
	dzm fl1
	szf 1
	dac fl1
	lio bki
	dio i bk1
	lio bki 1
	dio i bk1 1
	lio bki 2
	dio i bk1 2
	lio bki 3
	dio i bk1 3
	lac bk1
fvo,	jmp .

xe1,	xx
	jmp lis
	dac ac
	jsp tr1
	jsp lcc
	jmp lse

t2,	0

start
                
                                                                                      
