MCE    JOB   TEST MCE INSTRUCTION
       ORG   500
START  CS    332
       CS
       MLCWA @TEST OF MCE INSTRUCTION@,250
       W
       CS    299
       H
       MLCWA @---------------- SIMPLE EDITS ----------------@,266
       W
       CS    299
* POSITIVE VALUE WITH - SIGN
       MLCWA F1,FMT
       MLCWA C1,VAL
       B     WRT
* NEGATIVE VALUE WITH - SIGN
       MLCWA C2,VAL
       B     WRT
* LARGE POSITIVE VALUE TO TEST COMMA INSERTION
       MLCWA C3,VAL
       B     WRT
* POSITIVE VALUE WITH CR SIGN
       MLCWA F2,FMT
       MLCWA C1,VAL
       B     WRT
* NEGATIVE VALUE WITH CR SIGN
       MLCWA C2,VAL
       B     WRT
*
       MLCWA @---------------- FLOATING $ EDITS ----------------@,266
       W
       CS    299
* FLOATING $
       MLCWA F3,FMT
       MLCWA C1,VAL
       B     WRT
       MLCWA C3,VAL
       B     WRT
*
       MLCWA @---------------- * FILL EDITS ----------------@,266
       W
       CS    299
* ASTERISK FILL
       MLCWA F4,FMT
       MLCWA C1,VAL
       B     WRT
       MLCWA C2,VAL
       B     WRT
       MLCWA C3,VAL
       B     WRT
*
       MLCWA @---------------- DECIMAL CONTROL EDITS ----------------@,266
       W
       CS    299
* DECIMAL FILL
       MLCWA F5,FMT
       MLCWA C1,VAL
       B     WRT
       MLCWA C4,VAL
       B     WRT
       MLCWA C5,VAL
       B     WRT
       H     *-3
*
* SUBROUTINE TO EDIT AND PRINT
*
WRT    SBR   WRTR+3
       MLCWA @'@,270
       MLCWA FMT
       MLCWA @' GIVES: '@
       MLCWA FMT
       MLCWA @ UNDER '@
       MLCWA VAL
       MCE   VAL,269
       W
       WM                                    WRITE WORD MARK INFO
       CS    299
WRTR   B     0
*
VAL    DCW   #20
FMT    DCW   #20
F1     DCW   @   ,   ,  0.  -@
F2     DCW   @   ,   ,  0.  CR@
F3     DCW   @   ,   , $0.  -@
F4     DCW   @   ,   , *0.  CR@
F5     DCW   @   ,   . 0&&CR@
C1     DCW   +123
C2     DCW   -457
C3     DCW   9876543
C4     DCW   00
C5     DCW   01
       END   START
