!
! SLMPRODEF.CMD -SOURCE LIBRARY PROCEDURES DEFINITION FILE
!
! EDIT NUMBER = 0001
! EDITED BY: D.B.CURTIS  9 APR 80  10:55
!
!
SET DICTIONARY SLIB
DELETE REPORT-1;
DEFINE PROCEDURE REPORT-1
READY MODS
REPORT MODS SORTED BY SUB-PROJECT,PROCESS,MODULE-TITLE ON *.FILE
	SET REPORT-NAME = "SOURCES BY PROJECT, PROCESS, AND TITLE"
	AT TOP OF SUB-PROJECT PRINT NEW-PAGE,SUB-PROJECT(-)
	AT TOP OF PROCESS PRINT SKIP 2, COL 1,
		PROCESS(-),
		COL 25,"SOURCE LIBRARY IS ",SPACE,
		"[",SPACE,SLGROUP(-),SPACE,",",SPACE,SLMEMBER(-),
		SPACE,"]",SPACE,SLFILE(-),
		SPACE,".",SPACE,SLEXT(-),
		SPACE 15, "**** BACKUP VOLUME IDENT ****",SPACE,VOLID(-),SKIP 1,
		COL 25,"OBJECT LIBRARY IS ",SPACE,
		"[",SPACE,OLGROUP(-),SPACE,",",SPACE,OLMEMBER(-),SPACE,"]",
		SPACE,OLFILE(-),SPACE,".",SPACE,OLEXT(-),
		SKIP 1
	PRINT COL 10,
		 MODULE-TITLE,MODULE-IDENT,
		"[",SPACE,MGROUP(-),SPACE,",",SPACE,MMEMBER(-),SPACE,"]",SPACE,
		MFILE(-),SPACE,".",SPACE,MEXT(-),
		STATUS,CREATION-DATE,LAST-INSERTION-DATE,ACCESS-NUMBER
REPORT END
END-PROCEDURE
DEFINEP REPORT-1 2,UIC,[*,*],R
!
DELETE REPORT-2;
DEFINE PROCEDURE REPORT-2
READY MODS
REPORT MODS SORTED BY SUB-PROJECT, MODULE-TITLE ON *.FILE
	SET REPORT-NAME="SOURCES BY TITLE"
	AT TOP OF SUB-PROJECT PRINT NEW-PAGE,
		COL 1,"*************************************",
		COL 4,"SUB-PROJECT =",SPACE,SUB-PROJECT(-),
		SPACE,"GROUP CODE =",SPACE,SLGROUP(-), SKIP 1,
		COL 1, "**************************************",SKIP 2
	PRINT MODULE-TITLE,MODULE-IDENT,PROCESS ,
		STATUS,SLFILE,COMMENT USING X(40)
REPORT END
END-PROCEDURE;
DEFINEP REPORT-2 2,UIC,[*,*],R
!
DELETE INIT-HIST;
DEFINE PROCEDURE INIT-HIST
READY MODS READ
READY MODHIST WRITE
FOR MODS WITH STATUS = "NEW ENTRY" BEGIN
	MODIFY USING STATUS = "INITAL"
	STORE MODHIST USING BEGIN
		SUB-PROJECT=SUB-PROJECT
		PROCESS=PROCESS
		MODULE-TITLE=MODULE-TITLE
		TRACE="   000"
		MODULE-IDENT-EXTRACTED="      "
		DATE-EXTRACTED="000000"
		MODULE-IDENT-RETURNED = MODULE-IDENT
		DATE-RETURNED = LAST-INSERTION-DATE
		EXTRACTORS-NAME="INIT-HIST"
		STATUS = "INIT"
		ACCESID = 0
	END;
END;
END-PROCEDURE;
!
