;
;
;  M M 0 : B A C K U P . C M D	WEEKLY VERIFY & BACKUP PROCEDURE
;					VARIABLE DISK DRIVES
;
.ENABLE SUBSTITUTION
TER /WIDTH:72
INS [350,1]VOLID
;
;  INPUT FOR THE DISK DRIVE AND PACK TO BE COPIED FROM
;
.50:
.ASKS DBF  DISK DRIVE TO COPY FROM (DB0,DB1,DB2)
.ASKS F    FROM PACK ID ('DBF':)
.ASK  FOK  (FROM) DISK DRIVE AND PACK ID CORRECTLY ENTERED
.IFF  FOK .GOTO 50
;
;  INPUT FOR THE DISK DRIVE AND PACK TO BE COPIED TO
;
.60:
.ASKS DBT  DISK DRIVE TO COPY TO (DB0,DB1,DB2)
.ASKS T    TO PACK ID ('DBT':)
.ASK  TOK  (TO) DISK DRIVE AND PACK ID CORRECTLY ENTERED
.IFF  TOK .GOTO 60
.ASKS TBKUP DSC OR PRE BACKUP PROCEDURE
;
;  A 'TBKUP' WILL BE DONE FROM 'F' ON 'DBF':  TO 'T' ON 'DBT':
;
.ASK TOK IS THIS CORRECT
.IFF TOK .GOTO 50
DMO 'DBT':
DMO 'DBF':
.WAIT DMO
;
;  VERIFY PACK ON 'DBF':
;
TIME
MOU 'DBF':'F'
.WAIT MOU
VFY TI:,'DBF':='DBF':
.WAIT VFY
VFY TI:,'DBF':='DBF':/LO
.WAIT VFY
;
DMO 'DBF':
.WAIT DMO
;
;  MOUNT AND DO COPY FROM 'DBF': TO 'DBT':
;
MOU 'DBF':'F'/PRO=[R,R,R,R]/CHA=[DCF]
MOU 'DBT':'T'/CHA=[DCF]/ACP=DB1ACP
.WAIT MOU
TIM
;
;  IF A PRESERVE IS TO BE DONE, AFTER THE PROMPT PRE> 
;  TYPE 'DBT':='DBF':
'TBKUP' 'DBT':='DBF':
.WAIT 'TBKUP'
;
TIME
DMO 'DBT':
.WAIT DMO
;
;  CHANGE PACK-ID ON NEW DISK ('DBT':)
;
MOU 'DBT':'F'/UNL
.WAIT MOU
VOL 'DBT': 'F'/'T'
.WAIT VOL
DMO 'DBT':
.WAIT DMO
;
;  CHECK THAT VOL ID IS OK AFTER CHANGE
;
MOU 'DBT':'T'
.WAIT MOU
;
;  DIR/FR ON 'DBF':, 'DBT':
;
PIP 'DBF':/FR
PIP 'DBT':/FR
.WAIT PIP
DMO 'DBF':
.WAIT DMO
;
;  CLEAR LOST FILES FROM 'DBT':[1,3]
;
PIP 'DBT':[1,3]*.*;*/DE
.WAIT PIP
PIP 'DBT':[1,3]*.*;*/RM
.SETS DRS1 "DRS1"
.SETS DRS2 "DRS2"
.SETS DRS3 "DRS3"
.SETS DRS4 "DRS4"
.IF DRS1 EQ T .GOTO 100
.IF DRS2 EQ T .GOTO 100
.IF DRS3 EQ T .GOTO 100
.IF DRS4 EQ T .GOTO 100
.GOTO 200
.100:
;
;  CREATE NEW MOUNT COMMAND FOR DRS PACK WHICH WILL BE ON DB1:
;
MOU DB0:/OVR
.WAIT MOU
PIP 'DBT':[1,1]MDRSXDB1.CMD;*/DE
.WAIT PIP
.OPEN DB0:[1,1]X.TMP
.DATA MOU DB1: 'T'
.CLOSE
PIP 'DBT':[1,1]MDRSXDB1.CMD=DB0:[1,1]X.TMP
.WAIT PIP
PIP DB0:[1,1]X.TMP;*/DE
.WAIT PIP
DMO DB0:
.200:
.WAIT PIP
DMO 'DBF':
DMO 'DBT':
;
;    ASK IF YOU WISH TO DO FURTHER BACKUPS
;
.ASK BKUP DO YOU WANT TO DO ANY FURTHER BACKUPS
.IFT BKUP .GOTO 50
REM ...VOL
;
;  END OF BACKUP PROCEDURE, CHANGE PACKS AND RE-BOOT
;
