8000	! ROUTINE TO TURN 4 CHAR (2 NUMBER) PROJECT CODE INTO A
	! SINGLE CODE FOR THE SAKE OF ACCUMULATING AND DISPLAYING
	! BILLING INFO FOR PROGRAMMERS.
	!
	! FILE NAME PROJNUM.BAS
	!
	! ON ENTRY:
	!	DP$ CONTAINS 4 (OR 2) CHARACTER PROJECT CODE
	!
	! ON EXIT:
	!	DP% CONTAINS SINGLE VALUE NUMBER AS FOLLOWS:
	!	-1 = BAD STRING
	!	 1 = OPHTHAMOLOGY				( 1 1)
	!	 2 = OPHTHAMOLOGY QUALITY CONTROL	   ( 1 2, 1 3)
	!	 3 = INFECTION CONTROL				( 2 1)
	!	 4 = INFECTION CONTROL		      ( 2 2, 2 3, 2 4)
	!	 5 = NUCLEAR MEDICINE 		      ( 3 1, 3 2, 3 5)
	!	 6 = NUCLEAR MEDICINE - SCAN RELATED WORK	( 3 3)
	!	 7 = NUCLEAR MEDICINE - LABORATORY RELATED WORK	( 3 4)
	!	 8 = TUMOR REGISTRY DATA BASE		   ( 4 1, 4 2)
	!	 9 = TUMOR REGISTRY QUALITY CONTROL	   ( 4 3, 4 4)
	!	10 =						( 5 1)
	!	11 =						( 5 2)
	!	12 =						( 6 1)
	!	13 =						( 6 2)
	!	14 =						( 6 3)
	!	15 = MED PHYS - PO LOGGING			( 7 1)
	!	16 = MED PHYS - BILLING				( 7 2)
	!	17 = MED PHYS - MEEG				( 7 3)
	!	18 = MED PHYS - RAD. SAFETY			( 7 4)
	!	19 = MED PHYS - DIAG. X-RAY WORK		( 7 5)
	!	20 = MED PHYS - MACHINE SHOP (BOHDAN, CHARLIE)	( 7 6)
	!	21 = MED PHYS - DEPARTMENTAL AFFAIRS		( 7 7)
	!	22 = MED PHYS - 				( 7 8)
	!	23 = MED PHYS - OTHER				( 7 9)
	!	24 = RAD ONC - DATA BASE			( 8 1)
	!	25 = RAD ONC - QUALITY CONTROL			( 8 2)
	!	26 = RAD ONC - BILLING				( 8 3)
	!	27 = RAD ONC - CELL KINETICS			( 8 4)
	!	28 = RAD ONC - RAD TECH TRAINING		( 8 5)
	!	29 = RAD ONC - TREATMENT PLANNING		( 8 6)
	!	30 = RAD ONC - PFIZER, ETC. SCANNERS		( 8 7)
	!	31 = RAD ONC - BIOMEDICAL COMPUTATION		( 8 8)
	!	32 = RAD ONC - DEPARTMENTAL AFFAIRS		( 8 9)
	!	33 = RAD ONC - THERAC-20 VERIFICATION SYSTEM	( 810)
	!	34 = RAD ONC - THERAC-20 QUALITY ASSURANCE	( 811)
	!	35 = RAD ONC -					( 812)
	!	36 = RAD ONC - OTHER				( 813)
	!	37 = OVERHEAD - WORKING HERE     ( 9 1, 9 2, 9 7, 9 8)
	!	38 = OVERHEAD - WORKING AWAY               ( 9 3, 9 9)
	!	39 = OVERHEAD - PAID BUT NOT WORKING  ( 9 4, 9 5, 9 6)
	!	40 = WEISS MEMORIAL HOSPITAL			(10 1)
	!	41 = ST. JAMES HOSPITAL				(10 2)
	!	42 = WAUKEGAN					(10 3)
	!	43 =						(10 4)
	!	44 =						(10 5)
	!	45 =						(10 6)
	!
	! OTHER VARIABLES USED:
	!	D1&, D2&
8010 ON ERROR GOTO 8350
8020 D1&=VAL(SBS$(DP$,1,2)) : IF D1& < 1 OR D1& > 12 THEN 8350
8030 IF LEN(DP$) <> 4 THEN D2&=0
	ELSE D2&=VAL(SBS$(DP$,3,2))
8040 ON D1& GOTO 8050,8080,8120,8190,8350,8350,8110,8250,8260,8340
	! OPHTHALMOLOGY
8050 IF D2& < 1 OR D2& > 3 THEN 8350
	ELSE ON D2& GOTO 8060,8070,8070
	! DATA BASE
8060 DP%=1 : GOTO 8360
	! QUALITY CONTROL
8070 DP%=2 : GOTO 8360
	! INFECTION CONTROL
8080 IF D2& < 1 OR D2& > 4 THEN 8350
	ELSE ON D2& GOTO 8090,8100,8100,8100
	! DATA BASE
8090 DP%=3 : GOTO 8360
	! QUALITY CONTROL, STATISTICAL ANALYSIS, OTHER
8100 DP%=4 : GOTO 8360
	! MEDICAL PHYSICS
8110 IF D2& < 1 OR D2& > 9 THEN 8350
	ELSE DP%=14+D2& : GOTO 8360
	! NUCLEAR MEDICINE
8120 IF D2& <1 OR D2& > 5 THEN 8350
	ELSE ON D2& GOTO 8130,8130,8140,8150,8130
	! SYSTEMS SUPPORT, IMAGE PROCESSING, OTHER
8130 DP%=5 : GOTO 8360
	! SCAN DATA BASE
8140 DP%=6 : GOTO 8360
	! LAB DATA BASE
8150 DP%=7 : GOTO 8360
	! TUMOR REGISTRY
8190 IF D2& < 1 OF D2& > 4 THEN 8350
	ELSE ON D2& GOTO 8200,8200,8210,8210
	! DATA BASE
8200 DP%=8 : GOTO 8360
	! QUALITY CONTROL
8210 DP%=9 : GOTO 8360
	! RAD ONC
8250 IF D2& < 1 OR D2& > 13 THEN 8350
	ELSE DP%=23+D2& : GOTO 8360
	! OVERHEAD
8260 IF D2& < 1 OR D2& > 9 THEN 8350
	ELSE ON D2&
	GOTO 8270,8270,8280,8290,8290,8290,8270,8270,8280
	! OVERHEAD - WORKING AT REESE
8270 DP%=37 : GOTO 8360
	! OVERHEAD - WORKING AWAY
8280 DP%=38 : GOTO 8360
	! OVERHEAD - PAID BUT NOT WORKING
8290 DP%=39 : GOTO 8360
	! SMALL USERS
8340 IF D2& < 1 OR D2& > 6 THEN 8350
	ELSE DP%=39+D2& : GOTO 8360
8350 DP%=-1
8360 ON ERROR GOTO 0 : RETURN
