1 REM ::::::::::       FILENAME =  MKNBRK.BAS     ::::::::::::::::::::::::
2 REM ::   THIS FILE WILL MAKE/BREAK    66 FILES   TO/FROM   1 FILE     ::
3 REM ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
10 DIM #2,R(66,150)
12 DIM L(67)
20 OPEN "BIBLE.R" AS FILE #2
25 L(1)=R(2,1)-2
26 L(66)=R(66,23)-R(66,1)+1
30 FOR I=2 TO 65
32 L(I)=R(I+1,1)-R(I,1)
39 NEXT I
40 PRINT " MAKE OR BREAK ";
41 INPUT A$
42 S$=SEG$(A$,1,1)
44 IF S$="B" THEN 100
46 IF S$="M" THEN 200
47 PRINT CHR$(7);"ONLY MAKE OR BREAK   PLEASE..."
48 GO TO 40
99 REM ......       BREAK  BIBLE.BIB  INTO   BOOK??.BIB  .....
100 F$="BIBLE.BIB"
110 OPEN F$ FOR INPUT AS FILE #1 DOUBLE BUF
112 FOR J=1 TO 66
113 O$="BOOK"+SEG$(STR$(100+J),2,3)+".BIB"
114 OPEN O$ FOR OUTPUT AS FILE #3 DOUBLE BUF
117 FOR I=1 TO L(J)
120 LINPUT #1,A$
125 PRINT #3,A$
140 NEXT I
141 CLOSE #3
142 PRINT J;
150 REM NEXT BOOK .......
160 NEXT J
170 GO TO 900
199 REM ----   MAKE BOOK??.BIB  INTO   BIBLE.BIB   ----------
200 OPEN "BIBLE.BIB" FOR OUTPUT AS FILE #3 DOUBLE BUF
201 FOR J=1 TO 66
202 F$="BOOK"+SEG$(STR$(100+J),2,3)+".BIB"
204 OPEN F$ FOR INPUT AS FILE #1 DOUBLE BUF
210 FOR I=1 TO L(J)
220 LINPUT #1,A$
230 PRINT #3,A$
250 NEXT I
252 CLOSE #1
254 PRINT J;
260 NEXT J
900 END
