.; INDIRECT COMMAND FILE TO MOVE FILES FOUND BY "FILES"
.;
.ENABLE SUBSTITUTION
.SETS SEMI ";"
.SETS COLON ":"
.;
.; What device are we talking about?
;
.5:
.ASKS DEV ENTER DEVICE (DD:)
.SETN DLEN <STRLEN>
.SETS COL DEV[DLEN:DLEN]
.IF COL EQ COLON .GOTO 10
;
; Device must include the ":"
;
.GOTO 5
.;
.10:
;
.ASKS OUIC ENTER OWNER''S UIC (OMIT [])
.SETN ULEN <STRLEN>
.IF ULEN EQ 0 .SETN SAME 1
.IF ULEN EQ 0 .GOTO 20
.SETS UIC OUIC
.SETN SAME 0
.20:
;
.ASKS FSPEC ENTER FILENAME.TYP;VER
.SETN LEN <STRLEN>
.;
.; NOW STRIP OFF THE VERSION NUMBER
.;
.25:
.SETS TWO FSPEC[LEN:LEN]
.IF TWO EQ SEMI .GOTO 30
.DEC LEN
.IF LEN GT 0 .GOTO 25
;
; Filespec must contain a specific version
.GOTO 20
.;
.30:
.SETS NAME FSPEC[1:LEN-1]
.;
.;
.; NOW WE CAN MOVE THE FILE
;
.IF SAME EQ 0 SET /UIC=['UIC']
PIP 'DEV'/NV/CD='DEV''FSPEC'
PIP 'DEV''FSPEC'/DE
PIP 'DEV''FSPEC'/RE='DEV''NAME'
.GOTO 10
/
