.; whogotwot.cmd - prepare report of disk usage by account
	.enable substitution

	.sets home <uic>

	.ifins ...srd .goto ok10
	@[1,2]want2use $srd res fsl
	@[1,2]ballsup / Install SRD (sort directory) program
.ok10:

	.ifins ...pip .goto ok20
	@[1,2]want2use $pip res fsl
	@[1,2]ballsup / Install PIP (filing) program
.ok20:

	.ifins ...gre .goto ok30
	ins $grep/task=...gre
	@[1,2]ballsup /  Install GREP (sifting) program
.ok30:

	.ifins ...cle .goto ok40
	ins $clean/task=...cle
	@[1,2]ballsup / Install text file scrubber (CLEan)
.ok40:

	.ifins ...lum .goto ok50
	ins $lump/task=...lum
	@[1,2]ballsup / Install text file line joining program (LUMP)
.ok50:

	@[3,54]kilmtdirs keepwork

	set /uic=[1,1]
	@[1,2]ballsup / Gain file privileges

	srd [0,0]/wb
	@[1,2]ballsup / Sort the directory of directories

	pip 'home'work.=[*,*]/tb
	@[1,2]ballsup / Count the total block usage

	pip 'home'work./pr:0
	@[1,2]ballsup / Make the block usage report deletable

	set /uic='home'
	@[1,2]ballsup / remove filing privileges
	cle work work
	@[1,2]ballsup / clean up PIPs total block report

	gre <work >work ^[st]
	@[1,2]ballsup / slim down block usage report

.; we need short file names to fit a REO command in 80 cols

	lum <work >w 2
	@[1,2]ballsup / Make 1 big line from 2 pip lines of /TB info

	reo <w >x |`file` \s`l1
	@[1,2]ballsup / Normalise PIP/TB output

	reo <x >z -
	\[``[`|`,`r5 -
	`,`|`]`r5 -
	"` of`|`/`r9" -
	`./`|`.`r9 -
	"\ in`l3" -
	"` in`r14"
	@[1,2]ballsup / Humanise PIP/TB output

	.if p1 = "keepwork" .goto ok200
	delete work;0
	@[1,2]ballsup / Delete temporary files
	delete work;0
	@[1,2]ballsup / Delete temporary files
	delete work;0
	@[1,2]ballsup / Delete temporary files
.ok200:

	@killfile w.;0
	@killfile x.;0
	pip whogotwot.lst/nv=z;0
	@[1,2]ballsup / Name the disk usage report
	@killfile z.;0
	@[1,2]ballsup / Delete temporary file
