.ENABLE SUBSTITUTION
;
; This command file will build a new extended Fortran preprocessor task (FTE).
; The task image supplied should work on most systems.
; However if your processor does not support a FPP, or if the task
; supplied does not work correctly, you will have to rebuild FTE.
; You have a choice of building it overlaid or flat.
; The VAX version is available separately.
;
.ASKS FORT Enter your Fortran compiler in upper case (FOR,F4P,F77)
.SETS FORDEF "LB:[1,1]F4POTS"
.IF FORT = "FOR" .SETS FORDEF "LB:[1,1]FOROTS"
; If OTS is in SYSLIB, enter S below.
.ASKS [::FORDEF] FOROTS Enter name of your Fortran OTS library
.ASK OVLAY Build overlaid version
.IFT OVLAY .IF FORT =  "FOR" ; The overlay descriptor assumes OTS is LB:[1,1]FOROTS.
.IFT OVLAY .IF FORT <> "FOR" ; The overlay descriptor assumes OTS is LB:[1,1]F4POTS
.IFT OVLAY ; If not, you must change it.
.IFF OVLAY .ASK FCSRES Link task to FCSRES
.SETS FORSUF ""
.IF FORT = "FOR" .SETS FORSUF "/EX/-SN"
.IFNINS 'FORT' INS $'FORT'
.IFNINS LBR INS $LBR
.IFNINS PIP INS $PIP
.IFNINS TKB INS $TKB
'FORT' FTEV5=FTEV5.FTN'FORSUF'
'FORT' STRING=STRING.FTN'FORSUF'
LBR STRINGLIB/CR:20.
LBR STRINGLIB=STRING
LBR FTE/CR:50.
LBR FTE=FTEV5
.IFF OVLAY .GOTO NOOVER
.IF FORT =  "FOR" TKB @FTEV5BLD
.IF FORT <> "FOR" TKB @FTEV5BLD7
.EXIT

.NOOVER:
.OPEN FTEBLD.CMD
		.DATA FTE/FP=FTEV5,STRINGLIB/LB
.IF FOROTS <> "S" .DATA 'FOROTS'/LB
		.DATA /
.IFT FCSRES	.DATA LIBR=FCSRES:RO
		.DATA TASK=...FTE
		.DATA ACTFIL=6
		.DATA //
.CLOSE
TKB @FTEBLD
PIP FTEBLD.CMD;*/DE
PIP FTE.OLB;*/DE,STRINGLIB.OLB;*,*.OBJ;*
