1 	SUB SCREEN(Text$,    INTEGER Terminal_Type,	&
			     INTEGER X_Pos,		&
			     INTEGER Y_Pos,		&
			     INTEGER Control)
	!
	! This subroutine will display the text for Vax Professional
	! workstation tasks.  Input is the text (passed as a literal
	! string), the terminal type found from $GETDVI, the 
	! (x,y) screen position, and a control function
	!
	!		Control = 0	No screen control
	!			= 1	Erase cursor to end of screen
	!			= 2	Erase top of screen to cursor
	!			= 3	Erase entire screen
	!			= 4	Erase cursor to end of line
	!			= 5	Erase start of line  to cursor
	!			= 6	Erase entire line

	IF Terminal_Type  >= 96  THEN		! If a VT100 type terminal
	  Text_Length=LEN(Text$)		!
	  ESC$=CHR$(27)				!
	  Control$="" 		IF Control=0	! No screen control
	  Control$=Esc$+"[0J"   IF Control=1	! Erase from cursor->screen end
	  Control$=Esc$+"[1J"	IF Control=2	! Erase top of screen to cursor
	  Control$=Esc$+"[2J"	IF Control=3	! Erase screen first
	  Control$=Esc$+"[0K"   IF Control=4	! Erase cursor to end of line
	  Control$=Esc$+"[1K"   IF Control=5	! Erase start of line->cursor
	  Control$=Esc$+"[2K"   IF Control=6	! Erase entire line
	  Position$=Esc$+"["+NUM$(X_pos)+";"+NUM$(Y_pos)+"H"
	  Position$=EDIT$(Position$,2%)		!
	  Outline$=Position$+Control$+Text$	!
	  PRINT Outline$;			!
	ELSE					!
	  PRINT Text$;				!
	END IF					!
	END SUB					!
