	.; Rev. c 3-Mar-82 lmf
	!
	! This command stream provides a guided tour through the FILES 11
	! ODS-1 data structures as they are created and modified by file
	! system activity.
	avd vd7:=test/cr:494.
	mou vd7:/for
	init vd7:test
	dmo vd7:
	mou vd7:test/vi
	set /uic=[200,200]
	asn vd7:=sy:
	ufd sy:[200,200]
	dir [0,0]
	!
	! dump boot block
	dmp ti:=[0,0]indexf.sys/bl:1:1
	dmp ti:=[0,0]indexf.sys/bl:1:1/as
	!
	! dump Home Block
	dmp ti:=[0,0]indexf.sys/bl:2:2
	dmp ti:=[0,0]indexf.sys/bl:2:2/as
	!
	! dump index file bitmap - for this volume it's only 1 block
	!  but watch out bit = 1 means used
	dmp ti:=[0,0]indexf.sys/bl:3:3
	dmp ti:=[0,0]indexf.sys/bl:3:3/as
	!
	! dump header for FID 1,1,0 - indexf.sys
	dmp ti:=[0,0]indexf.sys/bl:4:4
	dmp ti:=[0,0]indexf.sys/bl:4:4/as
	dmp ti:=[0,0]indexf.sys/bl:4:4/hf
	!
	! dump bitmap.sys FID 2,2,0
	dmp ti:=[0,0]bitmap.sys
	dmp ti:=[0,0]bitmap.sys/as
	!
	! open a file "test.fil" and put some data in it
	.OPEN test.fil
	.DATA This is a test file for the DECUS class.
	.CLOSE
	!
	! dump directory file
	dmp ti:=[0,0]200200.dir
	dmp ti:=[0,0]200200.dir/r5
	!
	! and check on file allocation
	dmp ti:=[0,0]indexf.sys/bl:3:3
	dmp ti:=[0,0]bitmap.sys/bl:2:2
	dmp ti:=[0,0]indexf.sys/bl:12:12/hf
	dmp ti:=test.fil/hd/bl:0:0
	!
	! insert a file to take some space
	pip filler.fil=test.fil


	!
	! now write 5 more blocks of data into "test.fil" to force an extend
	! ( 40 records of 64 bytes should do it)
	.SETS FILL "01234567012345670123456701234567012345670123456701234567012345"
	.OPENA TEST.FIL
	.SETN N 40.
	.LOOP:
	.DATA 'FILL'
	.DEC N
	.IF N NE 0 .GOTO LOOP
	.CLOSE
	!
	! now check mapping again
	dmp ti:=test.fil/hd/bl:0:0
	dmp ti:=[0,0]bitmap.sys/bl:2:2
	!
	! delete the bugger
	pip test.fil;*/de
	!
	! and check how deletes are handled
	dmp ti:=[0,0]indexf.sys/bl:3:3
	dmp ti:=[0,0]bitmap.sys/bl:2:2
	dmp ti:=[0,0]indexf.sys/bl:12:12
	dmp ti:=[0,0]indexf.sys/bl:12:12/hf
	!
	! All done
	asn =
	dmo vd7:
	dvd vd7:
	!
	! bye now ...

