.ENABLE SUBSTITUTION
.ENABLE QUIET
.DISABLE DISPLAY
.SETS CLI <CLI>
.IF CLI EQ "MCR" .GOTO GOMCR
SET /MCR=TI:
.GOMCR:
.; SEE IF BYE ACTIVE
.SETF BYE
.IFACT BYE .SETT BYE
.; GET LOGIN DEVICE
.SETS DEV <LOGDEV>
.TEST DEV
.SETN NDEV <STRLEN>
.SETS XDEV DEV[1:2]
.IF NDEV EQ 3 .SETS XDEV XDEV+"0"
.SETS XDEV XDEV+DEV['NDEV':'NDEV']+":"
.; GET TERMINAL NUMBER
.TESTFILE TI:
.SETS X <FILSPC>
.SETN NT 4
.SETS X1 X[4:4]
.IF X1 EQ ":" .SETN NT 3
.SETS TT X[3:'NT']
.; GET UIC
.SETS INUIC <LOGUIC>
.PARSE INUIC "[,]" NULL GRP MEM
; 'GRP' 'MEM'
; CHECK ACCOUNT BLOCK SIZES AND LOG IN
.SETN GROUP 'GRP'
.SETN MEMBER 'MEM'
.SETN MAX 3000.
.IF GROUP EQ 5 .SETN MAX 10000.
.IF INUIC EQ "[350,47]" .SETN MAX 9000. 
.IF INUIC EQ "[5,5]" .SETN MAX 32000.
.SETS LOG "/BY"
.IFF BYE .SETS LOG "/LO"
.IFNINS KBL .GOTO NOKBL
 .XQT KBL 'XDEV',2,'<UIC>','MAX','TT''LOG'
.WAIT KBL
.NOKBL:
.; CLEAN UP
.IFINS ...MSG MSG ME
