.ENABLE QUIET
.IFINS SETPRV RUN SETPRV
.ASK QMG Do you want to change a SPOOLing parameter
.IFT QMG .CHAIN QMG.CMD
.;
.;
.100:
.ASK OFF Do you need to log a terminal off
.IFF OFF .GOTO 200
.IFINS WHO WHO
.ASKS TERM Which one (TTnn)
BRO TT0:OPERATOR IS MANUALLY LOGGING OFF TERMINAL 'TERM'
RMC 'TERM':BYE
.DISABLE QUIET
; Let's abort all of his tasks.
.ABORT:
ACT /TERM='TERM':
.ASKS TNAM Give me a task to abort.
.IF TNAM = "" /
ABO 'TNAM'
.GOTO ABORT
/
.200:
.ASK X Do you want to abort "BRU"
.IFT X ABO ...BRU
.IFT X /
.;
.ASK CLEAN Clean up files from the system disks
.IFT CLEAN BRO ALL:CLEANUP IN PROGRESS, FILES BEING DELETED OFF DISKS
.IFT CLEAN BRO ALL:YOU CAN USE IT, BUT .LST ETC. FILES ARE GOING AWAY
.IFT CLEAN PIP @CLEANUP
.IFT CLEAN TRU DR0:[*,*]*.*;*
.IFT CLEAN TRU DR1:[*,*]*.*;*
.IFT CLEAN PIP DR0:/FR
.IFT CLEAN PIP DR1:/FR
.IFT CLEAN BRO ALL:CLEANUP FINISHED
.IFT CLEAN /
.;
.;
.ASK SHUT Do you want to shut the system down?
.IFF SHUT .GOTO 210
.IFACT SHUTUP ABO SHUTUP
DLY 30T
.IFINS SHUTUP REM SHUTUP
.XQT INS $SHUTUP/TASK=SHUTUP/RUN=REM
DLY 30S
SET /NOSLAVE=TI:
.XQT BYE
/
.;
.;
.210:
.ASK BACK Do you want to back-up a system disk
.IFT BACK @INCBKP.CMD
.IFT BACK .GOTO 210
.;
.;
.ASK XX Do you want to load the paper-tape handlers
.IFT XX LOA PP:
.IFT XX LOA PR:
.;
.ASK XX Do you want to un-load the paper tape handlers
.IFT XX UNL PP:
.IFT XX UNL PR:
.;
.ASK XX Do you want to install Fortran
.IFT XX INS $FOR/TASK=...FOR/INC=30000
.IFT XX .DISABLE QUIET
.IFT XX ; DON''T FORGET TO REMOVE IT WHEN YOU ARE ALL DONE!!!!!
.IFT XX .ENABLE QUIET
.;
.ASK XX Do you want to remove Fortran
.IFT XX REM FOR
.;
.;
.ASK XX Do you want to install VMR for 3.1
.IFT XX INS [2,54]VMR31/TASK=VMR3.1
.;
.ASK XX Do you want to find all the "lost" files on the public disks
.IFT XX .CHAIN LB:[2,7]VFYLOST
.;
.ASK XX Do you want to install the common area for MULTI-TREK
.IFT XX .CHAIN LB:[2,7]MTRSETUP.CMD
; MORE QUESTIONS
