/
/ Handshake.
/

	.globl	fhands

h72:	.byte	33		/<esc>.I80;1;13:
	.ascii	".I80;1;13:"
h72l	=	.-h72
	.even

/
/ fhandshake(type, fp);
/ type = 7221 or 2649
/ fp = the file pointer
/
/ The call to fhandshake forces the
/ `set handshake mode' command down the
/ line on the 7221. The call must, therefore,
/ happen at a time when this is ok.
/

fhands:	jsr	r0,__csav	/Get a frame

	mov	12(r5),r0	/Type
	mov	14(r5),r4	/File pointer

	bic	$VF_H72,(r4)	/Clear old handshake bits
	bic	$VF_H26,(r4)

	cmp	r0,$7221.	/Plotter?
	bne	0f		/No
	bis	$VF_H72,(r4)	/Set plotter handshake.
	clr	-(sp)		/Send set handshake mode.
	clr	-(sp)
	clr	-(sp)
	clr	-(sp)
	mov	$h72l,-(sp)
	mov	$h72,-(sp)
	mov	$IO.WAL,r0
	call	__qiow
	br	1f

0:	cmp	r0,$2649.	/Terminal?
	bne	1f		/No
	bis	$VF_H26,(r4)	/Set terminal handshake.

1:	jmp	__cret		/Done.
