100 PRINT; "THIS PROGRAM WILL PLOT YOUR BIO-RHYTHM CURVES!"
110 PRINT "REQUIRED INPUT WILL BE:"
120 PRINT " ","YOUR NAME"
130 PRINT " ","YOUR BIRTHDATE"
140 PRINT " ","DATE YOU WANT PLOT TO BEGIN"
150 PRINT " ","NUMBER OF MONTHS YOU WANT PLOTTED";CHR$(10);CHR$(10)
160 DIM A$[63],Y$[2]V,C$[8],Z5$[6],N$[24],L$[51],D$[8],L1$[1]
170 DATA 23,28,33
180 DIM A(2,12),Z(3)
185 P2=2*3.14159265
190 READ Z(1),Z(2),Z(3)
210 A$=" 01020304050607080910111213141516171819202122232425262728293031"
240 FOR I=1 TO 12
245 A(1,I)=31
250 A(2,I)=31
255 NEXT I
260 A(1,2)=28:A(2,2)=29
261 A(1,4)=30:A(2,4)=30
262 A(1,6)=30:A(2,6)=30
263 A(1,9)=30:A(2,9)=30
264 A(1,11)=30:A(2,11)=30
270 PRINT "YOUR NAME ";
280 INPUT N$
290 PRINT "YOUR BIRTHDATE MM,DD,YY ";
300 INPUT B,C,D
320 B=INT(B):C=INT(C):D=INT(D)
370 PRINT "START DATE MM,DD,YY ";
380 INPUT E,F,G
390 E=INT(E):F=INT(F):G=INT(G)
440 PRINT "NUMBER OF MONTHS TO BE PLOTTED ";
450 INPUT Q
510 PRINT " "
520 PRINT " BIORHYTHM CURVES FOR   *** ";N$;" ***"
530 PRINT "   NOTE  1= PHYSICAL CYCLE"
540 PRINT "         2= EMOTIONAL CYCLE"
550 PRINT "         3= INTELLECTUAL CYCLE"
555 PRINT " "
560 PRINT "   DATE                   DOWN           0           UP"
570 PRINT " --------       -------------------------+";
571 PRINT "-------------------------"
580 H=G-D
590 I=0
600 FOR J=D TO G
610 IF J/4<>INT(J/4) THEN 630
620 I=I+1
630 NEXT J
640 K=365*H+I
650 M=1
660 IF D/4 <> INT(D/4) THEN 690
670 M=2
690 IF B=1 THEN 730
700 FOR N=1 TO B-1
710 K=K-A(M,N)
720 NEXT N
730 IF M=1 THEN 750
740 K=K-1
750 K=K-C
760 M=1
770 IF G/4 <> INT(G/4) THEN 800
780 M=2
800 IF E=1 THEN 840
810 FOR N=1 TO E-1
820 K=K+A(M,N)
830 NEXT N
840 K=K+F
850 V=F-1
860 Q=Q*31
870 FOR P=K TO K+Q
880 L$=RJS$(":",26)
890 V=V+1
900 FOR R=1 TO 3
910 P1=P/Z(R)
920 O=(SIN((P1-INT(P1))*P2)+1)*25+1.5
930 O1=INT(O-1)
940 O2=INT(O+1)
950 L1$=STR$(R)
960 L$=SEG$(L$,1,O1)+L1$+SEG$(L$,O2,LEN(L$))
970 NEXT R
1000 IF V<=A(M,E) THEN 1110
1010 V=1
1020 IF E=12 THEN 1050
1030 E=E+1
1040 GOTO 1110
1050 G=G+1
1060 E=1
1070 M=1
1080 IF G/4 <> INT(G/4) THEN 1110
1090 M=2
1110 Y$=STR$(G)
1120 IF LEN(Y$)=1 THEN Y$="0"+Y$
1130 D$=SBS$(A$,E*2,2)+"/"+SBS$(A$,V*2,2)+"/"+Y$
1200 PRINT " ";D$;TAB(17);TRM$(L$)
1220 NEXT P
1230 PRINT
1240 PRINT " --------       -------------------------";
1241 PRINT;"+-------------------------"
1250 PRINT "   DATE                   DOWN           0          UP"
1260 PRINT
1270 PRINT TAB(7);
1290 FOR Z9=1 TO 20
1300 PRINT "--";
1310 NEXT Z9
1320 PRINT
1330 PRINT
1340 PRINT "                 BIO-CURVE INFORMATION"
1350 PRINT;CHR$(10);"   THE BIO-CURVE IS BASED ON PATTERNS OF THE BIOLOG-"
1360 PRINT "ICAL    CYCLES"
1370 PRINT CHR$(10);CHR$(10);"   PHYSICAL;  A 23-DAY CYCLE"
1380 PRINT; "   EMOTIONAL; A 28-DAY CYCLE"
1390 PRINT; "   INTELLECTUAL; A 33-DAY CYCLE"
1400 PRINT; CHR$(10);CHR$(10);
1410 PRINT; "  PHYSICAL CYCLE  HAS AN 11 & 1/2 DAY UP PHASE  WHEN"
1420 PRINT; " THE PERSON  IS STRONGER  AND HAS  MORE  RESISTANCE,"
1430 PRINT; " FOLLOWED  BY  A DOWNWARD  CYCLE  OF  11 & 1/2  DAYS"
1440 PRINT; CHR$(10);CHR$(10);
1450 PRINT; "  EMOTIONAL CYCLE FEATURES 14 DAY  PERIODS OF AFFEC-"
1460 PRINT; " TION AND AFFABILITY, FOLLOWED  BY 14 DAYS OF GLOOM-"
1470 PRINT; " INESS, SELF-DOUBT AND IRRATABILITY."
1480 PRINT; CHR$(10);CHR$(10)
1490 PRINT; "  MENTAL  CYCLE  HAS A 16 & 1/2 DAY PERIOD IN  WHICH"
1500 PRINT; " CREATIVITY AND  LOGICAL THINKING ARE AT HIGH POINTS"
1510 PRINT; " AFTER  WHICH  THERE  IS A SIMILIAR  PERIOD  OF POOR"
1520 PRINT; " CONCENTRATION AND ABILITY."
1525 PRINT; CHR$(10);CHR$(10)
1530 PRINT; "  IT IS THE INTERTWINING OF THESE CYCLES THAT IS IM-"
1540 PRINT; " PORTANT."
1550 PRINT; CHR$(10);
1560 PRINT; "  WHEN ALL CURVES PEAK, ALL IS WELL; WHEN THE CURVES"
1570 PRINT; " DIP LOW, THE INDIVIDUAL'S PERFORMANCE WILL LIKEWISE"
1580 PRINT; " DROOP. WHEN SOME CYCLES ARE MOVING UP WHILE  OTHERS"
1590 PRINT; " ARE MOVING  DOWN, IT WILL BE A MIXED PERIOD OF ADE-"
1600 PRINT; " QUACY, WITHOUT BRILLIANCE."
1610 PRINT; CHR$(10);
1620 PRINT; "  THE MOST  DIFFICULT PERIODS COME WHEN  CURVES PASS"
1630 PRINT; " THE  ZERO POINT, GOING  NEITHER ABOVE  OR BELOW THE"
1640 PRINT; " CENTER  LINE. IT IS  DURING  THIS  ZERO PERIOD THAT"
1650 PRINT; " ACCIDENTS  MAY OCCUR, VULNURABILITY  TO DISEASE IN-"
1660 PRINT; " CREASES, AND  BAD DECISIONS ARE  LIKELY TO BE MADE."
1670 PRINT TAB(7);
1680 FOR Z9=1 TO 20
1690 PRINT; "--";
1700 NEXT Z9
1710 PRINT
1800 END
