	REMARK	*********************************************\
		*   P/R040.BAS  STATE TAX FILE MAINTENANCE  *\
		*     3/9/79			10:45 AM    *\
		*********************************************
	DIM S1(8)							REMARK  S1() IS THE STATE TAX FILE ARRAY
%INCLUDE CURSOR
%INCLUDE PRNMASK
GOTO 6000
%INCLUDE SUBS1.BAS
6000	OPEN "P/R0F070.DAT" AS 1					REMARK  OPEN STATE TAX FILE
	OPEN "CRT" RECL 1100 AS 19
	X0=18:GOSUB 260							REMARK  OPEN FILES AND LOAD CRT MASK FOR ENTRY
6005	X1=264:GOSUB 210
	READ #1;S1$,S1(1),S1(2),S1(3),S1(4),S1(5),S1(6),\		REMARK  READ STATE TAX FILE
	S1(7),S1(8)
	PRINT S1$							REMARK  DISPLAY NAME OF STATE
	X1=284:GOSUB 210
	PRINT S1(1);							REMARK  DISPLAY STATE CODE
	X1=293:GOSUB 210
	PRINT S1(2)							REMARK  DISPLAY TYPE
	FOR I%=3 TO 8 STEP 2
	X1=25:GOSUB 215
	PRINT USING MASK2.2$;S1(I%)/100;
	X1=14:GOSUB 215
	PRINT USING MASK6$;S1(I%+1)
	NEXT I%
6010	X2=1:X3=0:X4=4:X2$="ENTER FIELD TO CHANGE":GOSUB 665		REMARK  PROMPT OPERATOR TO CHANGE FIELDS
	IF X0=0 THEN 7000						REMARK  END PROGRAM IF NO MORE CHANGES
6100	IF X0 = 1 THEN X1=264:X2=12:X3=0:X4=0:GOSUB 345:\	  	REMARK  ENTER STATE NAME
	S1$=X0$:\
	X1=284:X2=2:X3=0:X4=99:GOSUB 345:\				REMARK  ENTER STATE CODE
	S1(1)=X0:\
	X1=293:X2=2:X3=0:X4=99:GOSUB 345:\				REMARK  ENTER TYPE CODE
	S1(2)=X0:\
	GOTO 6010
6200	F%=X0
	I1%=216+F%*64
	X1=I1%:X2=5:X3=0:X4=99.99:GOSUB 345				REMARK  ENTER SDI OR SUI RATE
	S1(F%*2-1)=X0*100
	X1=I1%+18:X2=6:X3=0:X4=999999:GOSUB 345				REMARK  ENTER CUTOFF FIGURE
	S1(F%*2)=X0
	GOTO 6010
									REMARK  END PROGRAM, RE-WRITE FILE AND LOAD MENU
7000	CLOSE 1								REMARK  CLOSE FILE TO ALLOW RE-WRITING
	OPEN "P/R0F070.DAT" AS 1
	PRINT #1;S1$,S1(1),S1(2),S1(3),S1(4),S1(5),S1(6),S1(7),S1(8)
	CLOSE 1
	PRINT CLEAR.SCREEN$;"STATE TAX F/M ENDED"

	CHAIN "P/R000"
