     rem This is the Payroll Cutoff and Percentage Entry Program

%INCLUDE ALL.BAS
     dim n(2,20),k$(6,20),c(10)
     z5$="b:epc":z6$=z5$+"back"
     repeat$="--------------------------------"
     fill$="                               "
     RESTORE
540 K$(6,1)="1 - ENTER CUTOFFS":K$(6,2)="2 - EXAMINE CUTOFFS"
550 K$(6,3)="3 - MODIFY CUTOFFS"
570 K$(6,4)="4 - CREATE NEW FILE":K$(6,5)="5 - CLEAR EXISTING FILE"
590 K$(6,6)="6 - FINISHED"
     print clear$:print
1100 K$(1,1)="FICA CUTOFF":K$(1,2)="FICA PERCENT"
1105 K$(1,3)="STATE DIS INS"
1110 K$(1,4)="SDI PERCENT"
1115 K$(1,5)="FED UNEMPLOYMENT"
1120 K$(1,6)="FUTA PERCENT"
1125 K$(1,7)="STATE UNEMPLOYMENT"
1130 K$(1,8)="SUTA PERCENT"
1200 K$(2,1)="1 - FICA CUTOFF":K$(2,2)="2 - FICA PERCENT"
1205 K$(2,3)="3 - STATE DIS INS"
1210 K$(2,4)="4 - SDI PERCENT"
1215 K$(2,5)="5 - FED UNEMPLOYMENT"
1220 K$(2,6)="6 - FUTA PERCENT"
1225 K$(2,7)="7 - STATE UNEMPLOYMENT"
1230 K$(2,8)="8 - SUTA PERCENT"
1235 K$(2,9)="9 - NONE"
1300 N(1,1)=12:N(1,2)=12:N(1,3)=12:N(1,4)=12:N(1,5)=12:N(1,6)=12
1305 N(1,7)=12:N(1,8)=12
     if end #1 then 6000
1500 open z5$ as 1
     close 1
1510 Z1=1:Z2=1
1600 PRINT clear$
1605 PRINT
1650 PRINT "THIS IS A LIST OF OPERATIONS."
1655 PRINT
1660 FOR Z=1 TO 6:PRINT K$(6,Z):NEXT Z:PRINT
1665 PRINT "INDICATE WHAT YOU WOULD LIKE TO DO BY TYPING"
1670 PRINT "THE CORRESPONDING NUMBER."
1675 PRINT
1680 INPUT Z
	IF Z<1 OR Z>6 then 1600
1685 ON Z GOSUB 2000,3000,4000,6000,7000,10000
1690 FOR Z=1 TO 10:C(Z)=0:NEXT Z:N$=""
1705 GOTO 1600
2000 PRINT clear$:PRINT
2005 PRINT "PAYROLL CUTOFF FIGURES ARE USED IN CALCULATING VARIOUS"
2010 PRINT "PAYROLL DEDUCTIONS. BE SURE THE SUTA PERCENTAGE FIGURE"
2015 PRINT "IS SET FOR THE CURRENT FIGURE ON YOUR STATE FORMS."
2025 PRINT
2040 FOR Z=1 TO 8
	PRINT CUR$
2045 PRINT TAB(30);left$(repeat$,n(1,z))
	PRINT UP$;
2050 PRINT K$(1,Z);TAB(28);
2055 INPUT C(Z):PRINT chr$(13)
	PRINT CLEAR$
2060 NEXT Z
2105 PRINT clear$:PRINT
2115 FOR Z=1 TO 9
2120 PRINT K$(2,Z);TAB(30);C(Z)
2125 NEXT Z
2145 PRINT
2150 PRINT "IF AN ITEM IS TO BE CHANGED, TYPE THE APPROPRIATE NUMBER."
2155 PRINT:INPUT Z
2160 PRINT
2165 IF Z>8 THEN 2225
2170 IF Z<1 THEN 2105
2180 PRINT TAB(30);left$(repeat$,n(1,z))
	PRINT UP$;
2185 PRINT K$(1,Z);TAB(28);
2190 INPUT C(Z)
2225 INPUT "ANY MORE CHANGES";line temp$
2230 IF left$(temp$,1)="y" OR left$(temp$,1)="Y" THEN 2105
2235 PRINT
2240 INPUT "IS RECORD TO BE ENTERED";line temp$
2245 PRINT
2250 IF left$(temp$,1)="y" OR left$(temp$,1)="Y" THEN 2280
2255 IF left$(temp$,1)<>"n" AND left$(temp$,1)<>"N" THEN 2235
2260 PRINT clear$:PRINT
2270 PRINT "*** RECORD NOT ENTERED ***":PRINT:PRINT
2275 FOR Z=1 TO 200:NEXT Z:RETURN
2276 Z1=1
2280 open z5$ as 1
     print #1;c(1),c(2),c(3),c(4),c(5),c(6),c(7),c(8)
     close 1
2300 RETURN
3000 PRINT clear$:PRINT
3010 open z5$ as 1
     read #1;c(1),c(2),c(3),c(4),c(5),c(6),c(7),c(8)
     close 1
3030 PRINT
	PRINT "Should this be a 'hard-copy' listing (Y or N)?"
	INPUT LINE LIST$
	IF LIST$="y" OR LIST$="Y" THEN LPRINTER
3035 FOR Z=1 TO 8
3040 PRINT K$(1,Z);TAB(30);C(Z)
3045 NEXT Z
	PRINT CHR$(13):PRINT CHR$(12)
	CONSOLE
3070 PRINT
3080 PRINT "IF FINISHED, TYPE F - RETURN.":PRINT
3085 INPUT line temp$
3095 RETURN
4000 PRINT clear$:PRINT
4010 open z5$ as 1
     read #1;c(1),c(2),c(3),c(4),c(5),c(6),c(7),c(8)
     close 1
4070 GOTO 2105
6000 PRINT clear$:PRINT
6005 PRINT "IF YOU HAVE ARRIVED HERE, AND HAVE A CUTOFF FILE"
6010 PRINT "ALREADY ON A DISK, YOU SHOULD INSTALL THAT DISK THEN"
6015 PRINT "TYPE THE LETTER C FOLLOWED BY A RETURN TO CONTINUE."
6020 PRINT
6025 PRINT "IF YOU WISH TO CREATE A NEW FILE, TYPE THE LETTER N"
6030 PRINT "FOLLOWED BY RETURN.":PRINT
6035 INPUT line temp$
6040 IF temp$="c" OR temp$="C" THEN INITIALIZE:GOTO 1500
6045 PRINT clear$:PRINT
6055 create z5$ as 1
     print #1;c(1),c(2),c(3),c(4),c(5),c(6),c(7),c(8)
     close 1
6095 PRINT clear$:PRINT
6100 PRINT "CUTOFF FILE CREATED AND CLEARED.":PRINT
6110 PRINT "TO CONTINUE, TYPE RETURN.":INPUT line temp$
6115 GOTO 1600
7000 INPUT "ARE YOU SURE !!! (YES OR NO)";line temp$
7007 IF temp$<>"YES" THEN RETURN
7010 open z5$ as 1
     print #1;c(1),c(2),c(3),c(4),c(5),c(6),c(7),c(8)
     close 1
7035 PRINT clear$:PRINT
7040 PRINT "CUTOFF FILE CLEARED!":PRINT
7045 PRINT "TO CONTINUE, TYPE RETURN."
7050 INPUT line temp$
7060 RETURN
10000 CHAIN "MASTER15"
