	REMARK	********************************************\
		*  P/R030.BAS FEDERAL TAX FILE MAINTENANCE *\
		*     3/9/79                   10:00 AM    *\
		********************************************

%INCLUDE CURSOR

	DIM F1(36)
	MASK1$="##.##    ######"
	MASK2$="######"
	MASK3$="##.##    ######    ##.##    ######"

	GOTO 6000

%INCLUDE SUBS1

6000	 OPEN "P/R0F060.DAT"  RECL 350 AS 5, "CRT" RECL 1100 AS 19	REMARK  OPEN FILES
	READ #5,1;F1(1),F1(2),F1(3),F1(4),F1(5),F1(6),F1(7),\		REMARK  READ FEDERAL TAX FILE FROM DISK
	F1(8),F1(9),F1(10),F1(11),F1(12),F1(13),F1(14),F1(15),\
	F1(16),F1(17),F1(18),F1(19),F1(20),F1(21),F1(22),F1(23),\
	F1(24),F1(25),F1(26),F1(27),F1(28),F1(29),F1(30),F1(31),\
	F1(32),F1(33),F1(34),F1(35),F1(36)
	X0=2
	GOSUB 260							REMARK  GET SCREEN #2 FROM CRT MASK FILE AND DISPLAY IT
6005	 X1=256
	GOSUB 210
	FOR I%=1TO 6 STEP 2
	X1=23
	GOSUB 215
	PRINT USING MASK1$;F1(I%)/100;F1(I%+1)				REMARK  DISPLAY INSURANCE FIELDS ON CRT
	NEXT I%
	PRINT 
	X1=32
	GOSUB 215
	PRINT USING  MASK2$;F1(7);					REMARK  DISPLAY ANNUAL SINGLE EXEMPTION
	X1=14
	GOSUB 215
	PRINT USING  MASK2$;F1(22);					REMARK  DISPLAY ANNUAL MARRIED EXEMPTION
6007	FOR I%=8 TO 20 STEP 2
	PRINT 
	X1=23
	GOSUB 215
	PRINT USING  MASK3$;F1(I%)/100;F1(I%+1);F1(I%+15)/100;F1(I%+16);
	NEXT I%

6010	X2=2
	X3=0
	X4=11
	X2$="ENTER FIELD TO CHANGE"
	GOSUB 665							REMARK  PROMPT OPERATOR TO CHANGE FIELD
	IF X0=0 THEN GOTO 7000						REMARK  END PROGRAM IF NO MORE CHANGES
6100	F%=X0
	I1%=214+(F%*64)
	IF F%>3 THEN 6200
	X1=I1%
	X2=5
	X3=0
	X4=99.99
	GOSUB 345							REMARK  ENTER FEDERAL TAX PERCENTAGE FIELD
	F1(2*F%-1)=X0*100
	GOSUB 210
	PRINT USING "##.##";X0;
	X1=I1%+9
	X2=6
	X3=0
	X4=999999
	GOSUB 345							REMARK  ENTER FUT, EMPLOYER OR EMPLOYEE FICA RATE & CUTOFF
	F1(2*F%)=X0
	GOSUB 210
	PRINT USING MASK2$;X0;
	GOTO 6010
6200	I1%=I1%+64
	IF F%>4 THEN 6250
	FOR I%=0 TO 1
	X1=I1%+9+I%*19
	X2=6
	X3=0
	X4=999999
	GOSUB 345							REMARK  ENTER SINGLE AND MARRIED ANNUAL EXEMPTION AMOUNTS
	F1(F%+3+I%*15)=X0
	GOSUB 210
	PRINT USING MASK2$;X0;						REMARK  DISPLAY AMOUNT ENTERED
	NEXT I%
	GOTO 6010
6250	FOR I%=0 TO 1
	X1=I1%+I%*19
	X2=5
	X3=0
	X4=99.99
	GOSUB 345							REMARK  DEPENDING ON LEVEL, ENTER ANNUAL RATES & CUTOFFS\
									        FOR SINGLE AND MARRIED EMPLOYEES
	F1(2*F%-2+I%*15)=X0*100
	X1=I1%+9+I%*19
	X2=6
	X3=0
	X4=999999							REMARK  ENTER CUTOFF HERE
	GOSUB 345
	F1(2*F%-1+I%*15)=X0
	NEXT I%
	GOTO 6010

    									REMARK  EXIT FROM PROGRAM HERE
7000	PRINT #5,1;F1(1),F1(2),F1(3),F1(4),F1(5),F1(6),F1(7),\		REMARK  RE-WRITE THE FEDERAL TAX FILE WITH NEW DATA
	F1(8),F1(9),F1(10),F1(11),F1(12),F1(13),F1(14),F1(15),\
	F1(16),F1(17),F1(18),F1(19),F1(20),F1(21),F1(22),F1(23),\
	F1(24),F1(25),F1(26),F1(27),F1(28),F1(29),F1(30),F1(31),\
	F1(32),F1(33),F1(34),F1(35),F1(36)
	PRINT CLEAR.SCREEN$;"FEDERAL TAX F/M ENDED"
	CHAIN "P/R000"							REMARK  AFTER RE-WRITING FEDERAL TAX FILE,\
									        RETURN TO THE MENU.
