        title MACRO2
;FORTRAN CALLABLE ROUTINES NEEDED BY FROFF ON THE DECSYSTEM20
;These make the use of FROFF easier, but are not necessary.
;
        search monsym,macsym
;
;------------------------------------------------------------------
;
;CALL EXPUNG(NO ARGUMENTS)
;
;Expunges deleted files from a directory on the DECsystem-20.
;This is called by FROFF after each temporary scratch file is
;closed and deleted.
;
;kim peck 1/79
;
expung::
        seto    1,              ;set up info to get current dir num
        move    2,[-1,,dirnum#] ;ask for 1 word of info
        movei   3,.jidno        ;offset  for dir number in gettab
        getji                   ;get actual info
        jump                    ;noop
        move    2,dirnum        ;load directory number
        hrlzi   1,(dd%dtf+dd%dnf)       ;flag options for deldf
        deldf                   ;do expunge of temp and deleted files
        popj    17,             ;return

;------------------------------------------------------------------
;
;CALL LEAVE(NO ARGUMENTS)
;
;Exits without the time statistics produced by FORTRAN STOP statement
;
LEAVE::
        HALTF                   ;stop this fork
        jrst 0,leave              ;repeat if user continues program
;
;FOLLOWING IS THE DECSYSTEM10 CODE TO DO SAME
;
;        EXIT 0,
;        EXIT 0,
;        EXIT 0,
;
;------------------------------------------------------------------
;
;CALL TTYSET(NO ARGUMENTS)
;
;Judy Martel  Nov 81
;
;Sets terminal characteristics of controlling terminal to following:
;
;Refuse Links
;Refuse Advice
;Refuse System-Messages
;Pause Command
;No Pause End-Of-Page
;Length 0
;Width 0
;Lowercase
;No Raise
;No Flag
;No Indicate
;Formfeed
;No Tabs
;No Immediate.
;

ttyset::

; Do mode word
        movx    1,.priou                ;TT%PGM == enables pause command
        movx    2,TT%PGM+TT%MFF+TT%LCA  ;TT%MFF == formfeed
        stpar                           ;TT%LCA == lowercase

; Do "system messages" bit.
        movx    1,.priou
        movx    2,.mosnt                ;Refuse system messages
        movx    3,.mosmn
        mtopr

; Do CCOC words.
        movx    1,.priou
        rfcoc                           ;Get current CCOC words
        movx    1,2                     ;"send actual code"
        dpb     1,[point 2,2,25]        ;For ^L

; Do links/advice
        movx    1,.cttrm                ;refuse links and advice
        txo     1,tl%sab!tl%sta         ;don't ask!
        tlink
        jump                            ;failure return
        ret                             ;normal return

        end
