                                                /MACRO COMPILER
                     /
                     /PAGE 4000
                     *4000
          PUSH2,     0
                     DCA PACK
                     TAD Z PCON
                     CIA
                     TAD Z POINT
                     SMA CLA
                     JMS I Z MKROOM        /TEST FOR SPACE
                     TAD PACK              /ROOM NOW
                     DCA I Z POINT
                     ISZ Z POINT
                     JMP I PUSH2           /EXIT
                     /
          PACK,      0
                     NOP                   /NOP OR JMP RIGHT2
                     /
                     CLL RTL
                     RTL
                     RTL
                     DCA I Z MACEND
                     TAD .+2
                     JMP XPACK
                     /
                     JMP RIGHT2
                     /
          RIGHT2,    DCA PUSH2
                     TAD I Z MACEND
                     AND CT7700
                     TAD PUSH2
                     DCA I Z MACEND
                     ISZ Z MACEND
                     TAD Z MACEND
                     CIA
                     TAD Z SEND
                     SPA CLA
                     JMP I .+4
                     /
                     TAD Z M1000
          XPACK,     DCA PACK+1
                     JMP I PACK
                     /
                     SYMEX
                     /
          MACROD,    JMS I Z IDX1
                     TAD Z PASS
                     SPA CLA
                     JMP IGNORE
                     /
                     TAD Z M1000
                     DCA PACK+1
                     SKP
                     /
                     JMS I Z IDX1
                     DCA Z TRUBL
                     JMS I Z GETSY1
                     /
                     .-3-4000+SPACE        /SPACE=5600
                     .+2-4000+USYMB        /USYMB=2000
                     MACERR-4000+ALL       /ALL=7600
                     /
                     JMS COUDBE
                     TAD Z MACEND
                     DCA I Z VADR
                     JMS I Z TYPAD1
                     /
                     0
                     /
                     DCA PACK
                     TAD Z SEND
                     DCA SENTEM
                     SKP
                     /
          MAC3,      JMS I Z IDX1
                     DCA Z TRUBL
                     JMS I Z GETSY1
                     /
                     MAC3-4000+SPACE       /SPACE=5600
                     MAC4-4000+USYMB       /USYMB=2000
                     MAC3-4000+SCOLON      /SCOLON=0200
                     MAC5-4000+LANG        /LANG=1200
                     MACERR-4000+ALL       /ALL=7600
                     /
          MAC4,      JMS COUDBE
                     JMS I Z TYPAD1
                     5000
                     TAD PACK
                     DCA I Z VADR
                     ISZ PACK
                     JMP MAC3+1
                     /
                     SWITCH
                     /
          MAC5,      TAD CJMPHE
                     DCA I .-2
                     TAD PACK+1
                     DCA CJMPHE-1
                     TAD Z MACEND
                     DCA COUDBE
                     JMS I Z IDX1
                     TAD Z CHARX
                     TAD Z M33
                     SMA CLA
                     JMP BCKMAC
                     /
                     JMS I Z GETAS1
                     TAD Z TYPE
                     TAD M5000
                     SZA CLA
                     JMP BCKMAC
                     /
                     TAD CJMPHE-1
                     DCA PACK+1
                     TAD COUDBE
                     DCA Z MACEND
                     TAD CS77
                     JMS PACK
                     TAD I Z VADR
                     JMS PACK
                     TAD Z CHARX2
                      JMS PACK
          BCKMAC,    TAD Z ITEM
                     TAD M276
                     SZA CLA
                     JMP MAC5+2
                     /
                     ISZ Z MACEND
                     TAD SENTEM
                     DCA Z SEND
                     TAD Z M1000
                     DCA I MAC5-1
                     JMP I Z MAIN1
                     /
                     0
          CJMPHE,    JMS I MSTOR1+2000
          SENTEM,    0
                     /
          COUDBE,    0
                     ISZ Z TRUBL
                     JMP I COUDBE
                     /
          MACERR,    TAD C13
                     JMS I Z ERR1
          IGNORE,    JMS I .+5
                     TAD M276
                     SZA CLA
                     JMP IGNORE
                     /
                     JMP I Z MAIN1
                     /
                     GETIN
          C13,       13
          M276,      0-276
          CS77,      77
          M5000,     0-5000
          CT7700,    7700
                     PAUSE
                                                                                                                    