                                                 /MACRO COMPILER
                     /
                     /PAGE 3000
                     *3000
          PUNONE,    0
                     NOP                   /OR JMP OPASS
                     DCA UNPUN
                     TAD Z EVAL
                     RTR
                     RTR
                     RTR
                     AND C77
                     TAD UNPUN
                     JMS PUN
                     TAD Z EVAL
                     AND C77
                     JMS PUN
                     CLA
                     JMP I PUNONE
                     /
          PUNORG,    0
                     TAD C100
                     JMS PUNONE
                     JMP I PUNORG
                     /
          PUN,       0
                     NOP                   /JMP I PUN IF UNPUN
                     IOF
                     PLS
                     PSF
                     JMP .-1
                     ION
                     TAD Z CKSUM
                     DCA Z CKSUM
                     JMP I PUN
                     /
          UNPUN,     0
                     TAD .-2
                     DCA PUN+1
                     JMP I UNPUN
                     /
          PUNCHK,    0
                     TAD Z CKSUM
                     RTR
                     RTR
                     RTR
                     AND C77
                     JMS I Z BINOUT
                     TAD Z CKSUM
                     AND C77
                     JMS I Z BINOUT
                     JMP I PUNCHK
                     /
          PUNCON,    0                     /PUNCH OUT CONSTANTS
                     TAD Z CBUFE
                     CIA
                     TAD Z PCON
                     SMA
                     JMP I PUNCON
                     /
                     DCA NUCON
                     TAD Z STUP
                     JMS I Z FIND2
                     DCA Z EVAL 
                     TAD I Z EVAL
                     TAD Z APAGE
                     DCA Z EVAL
                     JMS PUNORG
                     CLA CMA
                     TAD Z PCON
                     DCA Z AUT17
                     TAD I Z AUT17
                     DCA Z EVAL
                     JMS PUNONE
                     ISZ NUCON
                     JMP .-4
                     /
                     JMP I PUNCON
                     /
          ZUNCON,    0
                     TAD Z ZCON
                     DCA Z PCON
                     DCA Z APAGE
                     TAD Z C200
                     JMS PUNCON
                     CLA
                     TAD Z PASS
                     SMA CLA
                     JMP I ZUNCON
                     /
                     TAD Z NOW3
                     SZA CLA
                     JMP I ZUNCON
                     /
                     JMS PUNCHK
                     JMS LT
                     JMP I ZUNCON
                     /
          NUCON,     0
                     0
                     /
          LT,        0
                     TAD Z C7600
                     DCA NUCON+1
                     TAD Z PASS
                     SMA CLA
                     JMP I LT
                     /
                     TAD Z C200
                     JMS I Z BINOUT
                     ISZ NUCON+1
                     JMP .-3
                     /
                     JMP I LT
                     /
                     OPS
                     /
          OPASS,     SNA CLA
                     JMP .+4
                     /
                     TAD Z EVAL
                     DCA Z CURADD
                     JMP I PUNONE
                     /
                     TAD Z CURADD
                     JMS I OPASS-1
                     ISZ Z CURADD
                     NOP
                     TAD Z M2
                     JMS I Z SKIP
                     TAD Z EVAL
                     JMS I OPASS-1
                     TAD Z M2
                     JMS I Z SKIP
                     JMS I .+2
                     JMP I PUNONE
                     /
                     EMPTY
                     *3176
          C100,      100
          C77,       77
                     PAUSE
                                                                                