/DOUBLE PRECISION DIVIDE
/CALL: TAD ADDRESS OF HI-ORDER DIVIDEND
/      JMS DDVD
/      ADDRESS OF HI-ORDER DIVISOR
/      RETURN: HI-ORDER QUOTIENT IN AC, LOW IN QUOL, REMAINDER
/      IN HORD, LORD, SIGN OF REMAINDER POSITIVE
/ ABSOLUTE VALUE OF DIVISOR MUST BE GREATER THAN ABSOLUTE VALUE
/ OF 2 HI-ORDER WORDS OF DIVIDEND FOR CORRECT RESULTS.
*200
DDVD, 0
DCA DIVA
TAD SET
DCA L2
TAD I DIVA
DCA HORD
ISZ DIVA
TAD I DIVA
DCA LORD
ISZ DIVA
TAD I DIVA
DCA QUOH
ISZ DIVA
TAD I DIVA
DCA QUOL
TAD HORD
SMA
JMP GO
ISZ L2
CMA CLL
DCA HORD
TAD QUOL
CIA
DCA QUOL
TAD QUOH
CMA
SNL
JMP ARND
IAC CLL
DCA QUOH
SNL
JMP ARND+1
TAD LORD
CMA IAC CLL
DCA LORD
SZL
ISZ HORD
GO, CLL CLA
TAD I DDVD
DCA DIVA
TAD I DIVA
DCA AC1H
ISZ DIVA
TAD I DIVA
DCA AC1L
TAD AC1H
SMA CLA
JMP XX10
ISZ L2
NOP
JMP XX11
XX10, TAD AC1L
CMA IAC
DCA AC1L
TAD AC1H
CMA
SZL
IAC
DCA AC1H
XX11, TAD MIF
DCA DV1
CLL
JMP DV2
DV3, TAD LORD
RAL
DCA LORD
TAD HORD
RAL
DCA HORD
TAD LORD
TAD AC1L
DCA SAV
RAL
TAD HORD
TAD AC1H
SZL
JMP OK
CLA
DV2, TAD QUOL
RAL
DCA QUOL
TAD QUOH
RAL
DCA QUOH
ISZ DV1
JMP DV3
TAD QUOL
ISZ L2
JMP XX8
CMA IAC
DCA QUOL
TAD QUOH
CMA
SZL
IAC
XX7, ISZ DDVD
JMP I DDVD
XX8, DCA QUOL
TAD QUOH
JMP XX7
OK, DCA HORD
TAD SAV
DCA LORD
JMP DV2
ARND, DCA QUOH
TAD LORD
CMA
DCA LORD
JMP GO
SAV, 0
DIVA, 0
HORD, 0
LORD, 0
QUOH, 0
QUOL, 0
AC1H, 0
AC1L, 0
L2, 0
SET, 7776
MIF, 7750
DV1, 0
$
