/BETTER SYMBOL TABLE DUMP FOR U/W-FOCAL  -JVZ-

/THIS PATCH MODIFIES THE 'TYPE $' COMMAND TO PERMIT DUMPS
/WITH MORE THAN ONE ITEM PER LINE. THE NUMBER OF ITEMS MAY
/NOW BE SPECIFIED FOLLOWING THE '$'.  THUS 'TYPE $5' WILL
/DUMP FIVE VARIABLES PER LINE.  THE FORMAT SHOULD BE CHOSEN
/SO THAT ALL ITEMS FIT WITHIN THE WIDTH OF THE PAPER.  THE
/DEFAULT VALUE (IF NONE IS SPECIFIED) IS 3.  THIS PATCH RE-
/MOVES 9 (UNUSED) FUNCTION ENTRY POINTS FROM THE TABLES.

/SYMBOLS FROM THE LISTING:

	FIELD 1

	AXOUT=17
	XCT=20
	ATSW=23
	LASTLN=25
	PT1=30
	LASTV=31
	T3=33
	GINC=65
	LINENO=67
	CCR=77
	DMPSW=100
	P177=106
	C200=123
	FOUTPUT=130
	END=134
	PROC=611
	EVAL=1613

	FENT=JMS I 7
FIXMRI	FGET=0000
	FEXT=0000
	FIXIT=4453
	PUSHJ=4540
	GETC=4545
	PRINTC=4551
	POPJ=5541

	*1574
	HUMPTY		/BRANCH POINT

	*2202
HUMPTY,	PUSHJ		/READ THE ITEM COUNT
	    EVAL-1
	FIXIT
	CIA
	SNA
	CMA CLL RTL	/DEFAULT VALUE = 3
	DCA LINENO	/= 'NO. PER LINE'
	JMP I .+1
	DUMPTY
	*402
DUMPTY,	TAD DMPSW	/INITIALIZATION
	DCA ATSW
	TAD END
	DCA PT1		/START AT THE BEGINNING
	DCA XCT
	DCA I LASTV	/CLEAR THE FINAL NAME
	TAD LINENO
	DCA LASTLN
	JMP I 501
	*420
	TAD DOEXIT
	*433
DOEXIT,	PROC		/MOVED TO GAIN A WORD
	*501
	TDUMP+2
	*3052
TDUMP,	TAD SPACE	/BETWEEN MULTIPLE ITEMS
	PRINTC
	TAD I PT1	/HERE WE GO
	SNA		/END?
	POPJ		/INTO THE WILD BLUE YONDER
	CDF
	DCA I C200	/STICK NAME AHEAD OF THE PROGRAM
	TAD P177
	DCA AXOUT	/SET OUTPUT POINTERS
	DCA DMPSW	/TURN ON THE TRACE
	GETC
	GETC		/    'AB('
	GETC
	ISZ PT1
	TAD I PT1	/GET THE SUBSCRIPT
	DCA T3
	JMS I SDUMP	/WRITE IT OUT
	GETC		/        ')'
	TAD ATSW
	DCA DMPSW	/REMOVE THE TRACE
	ISZ PT1
	FENT
	FGET I PT1	/BRING IN THE VALUE
	FEXT
	JMS I FOUTPUT	/PRINT IT
	CMA CLL RAL	/=-2
	TAD GINC
	TAD PT1		/SET UP THE NEXT ONE
	DCA PT1
	ISZ LASTLN	/INCREMENT ITEM COUNT
	TAD I PT1	/LOOK-AHEAD CHECK
SPACE,	SZA CLA		/END OF LINE OR TABLE
	JMP TDUMP	/KEEP GOING
	TAD LINENO
	DCA LASTLN	/RESET COUNTER
	TAD CCR
	JMP TDUMP+1	/DO A CR/LF
SDUMP=.;$
