/TWO'S COMPLEMENT SINGLE PRECISION MULTIPLY ROUTINE
/RETURN HIGH ORDER PRODUCT IN AC, LOW IN MP1

MULT,     0
          CLL
          SPA
          CMA CML IAC
          DCA MP1
          DCA MP5
          TAD I MULT
          SNA
          JMP MPSN+2
          SPA
          CMA CML IAC
          DCA MP2
          TAD THIR
          DCA MP3
MP4,      TAD MP1
          RAR
          DCA MP1
          TAD MP5
          SNL
          JMP .+3
          CLL
          TAD MP2
          RAR
          DCA MP5
          ISZ MP3
          JMP MP4
          TAD MP1
          RAR
MPSN,     SZL
          JMP COMP
          DCA MP1
          TAD MP5
MPZ,      ISZ MULT
          JMP I MULT
COMP,     CMA CLL IAC
          DCA MP1
          TAD MP5
          CMA
          SZL
          IAC
          JMP MPZ
THIR,     7764
MP1,      0
MP5,      0
MP2,      0
MP3,      0
          $
