
*7400
BEGRIM,	KCC		/RIM-LOADER
	JMS READIN
	CLL RTL
	RTL
	SPA
	JMP BEGRIM+1
	RTL
	KSF
	JMP .-1
	KRS
	SNL
	DCA I KOBUS
	DCA KOBUS
	JMP I BEGRIM
READIN,	0		/READ-ROUTINE
	KSF
	JMP .-1
	KRB
	DCA CHAR
	TAD CHAR
	JMP I READIN
BEGN,	CLA CMA		/(AL)BIN-LOADER
	DCA INDIC		/SET BIN-MODE
	DCA CHKSM
	DCA FIRST
	JMS BEGG
	JMP .-1
GO,	TAD CHAR
	DCA CKT
	TAD CHAR
	CLL RTL
	RTL
	RTL
	DCA WORD
	JMS READIN
	TAD WORD
	DCA WORD
	SZL
	CLA CMA
	DCA MEM
	TAD CHAR
	TAD CKT
	DCA CKT
	JMS BEGG
	JMP BEND
	ISZ MEM
	JMP STORE
	TAD INDIC
	SZA CLA
	JMP B1
	TAD FIRST
	SNA CLA
	JMP B2
B4,	TAD WORD

	TAD M200
	SPA
	JMP B3
	TAD KOBUS
	DCA WORD
B3,	M200,7600		/CLA
	TAD ORIGIN
	DCA I WORD
CHEX,	TAD CKT
	TAD CHKSM
	DCA CHKSM
	JMP GO
STORE,	TAD WORD
	DCA I ORIGIN
	ISZ ORIGIN
	JMP CHEX
B1,	TAD WORD
	DCA ORIGIN
	JMP CHEX
B2,	ISZ FIRST
	HLT
	CLA OSR
	DCA KOBUS
	TAD KOBUS
	DCA ORIGIN
	JMP B4
BEGG,	0
	DCA SWITCH
	JMS READIN
	TAD M377
	SZA CLA
	JMP .+4
	ISZ SWITCH
	CLA CMA
	JMP BEGG+1
	TAD SWITCH
	SZA CLA
	JMP BEGG+2
	TAD CHAR
	AND MASK
	TAD M200
	SNA
	JMP I BEGG
MASK,	SMA CLA
	JMP BEGG+2
	ISZ BEGG
	JMP I BEGG
INDIC,	0
CHKSM,	0
CHAR,	0
CKT,	0
WORD,	0

MEM,	0
FIRST,	0
KOBUS,	0
ORIGIN,	0
SWITCH,	0
M377,	-377
BEND,	TAD WORD
	CMA IAC
	TAD CHKSM
	HLT
	JMP BEGN
$
