
	.ABS
PINT=0
	.LOC	1
	DAC	PIHAC#
TRAP	JMP	SKPCHN
	.LOC	100
SKPCHN	ASF
	JMP	DHAND
	SCLF
	SKP
	JMP	CLMD
	KSF
	SKP
	JMP	%CTL
	TSF
	JMP	SKPCHN
	LAC	PIHAC
	JMP*	PINT
	.LOC	200
%CTL	JMS	READ
	SAD	(201
	JMP	%AN
	SAD	(210
	JMP	%HLT
	SAD	(203
	JMP	%CRLT
	SAD	(204
	JMP	%INIT
	SAD	(221
	JMP	%QCRLT
	SAD	(205
	JMP	%ERASE
	SAD	(224
	JMP	%TYPE
	SAD	(217
	JMP	PUNCH
	SAD	(211
	JMP	READTP
	SAD	(230
	JMP	%XCORR
	SAD	(232
	JMP	INTGT
	SAD	(215
	JMP	%COPY
	JMP	%CTL
CLMD	LAC	CLFLAG
	SZA
	JMP	%CRCT
	JMP	%CLOC
%CLOC	NDRR
	TAD	LIVE
	DAC	LIVE
CLOC	ISZ	REAL
	ISZ	CLCNT
	JMP	CONTIN
	LAC	(210
	JMP	%HLT
%CRCT	NDRR
	SZA
	JMP	CLOC
CRCT	ISZ*	EVEC
	SKP
	JMP	.-7
CONTIN	LAC	PIHAC
	ION
	JMP*	PINT
%AN	JMS	CTECH
	NDAN
	DZM	CFLAG
	JMP	DPY
%HLT	NDST
	JMP	.-1
	NDST
	JMP	.-1
	JMS	CTECH
	JMP	DPY
%INIT	JMS	CTECH
	CAF
	DZM	SFLAG
%READ	JMS	READ
	SAD	(307
	JMP	%GROUP
	SAD	(316
	JMP	%SELECT
	SAD	(326
	JMP	%GAIN
	SAD	(311
	JMP	%INT
	SAD	(323
	JMP	%SLIDE
	SAD	(223
	JMP	%START
	SAD	(220
	JMP	MPR
	SAD	(324
	JMP	%TIME
	SAD	(320
	JMP	%PIME
	SAD	(315
	JMP	%EXPAND
	JMP	%READ
INTGT	JMS	CTECH
	TLS+10
	LAC	INL
	TCA
	DAC	ZMSTRT#
	TAD	INU
	DAC	ZMCT#
	DZM	ZMTOT#
ZUM	LAC*	ZMSTRT
	TAD	ZMTOT
	DAC	ZMTOT
	ISZ	ZMSTRT
	ISZ	ZMCT
	JMP	ZUM
	JMS	CARR
	LAC	(323
	JMS	WRITE
	LAC	(325
	JMS	WRITE
	LAC	(315
	JMS	WRITE
	LAC	(250
	JMS	WRITE
	LAC	INL
	TAD	XLIST
	TCA
	JMS	%DIP
	LAC	(272
	JMS	WRITE
	LAC	INU
	TAD	XLIST
	TCA
	JMS	%DIP
	LAC	(251
	JMS	WRITE
	LAC	(275
	JMS	WRITE
	LAC	ZMTOT
	JMS	%DIP
	JMP	DPY
ASF=701601
TCF=700402
NDRR=701656
NDCN=701622
SCLF=701621
NDAN=701641
KSF=700301
CAF=703302
IOF=700002
RRND=701616
NDST=701661
%EXPAND	JMS	ECHO
	DAC	MFACTOR
	CLC
	DAC	MFLAG
	JMP	%READ
%GROUP	JMS	ECHO
	CLL
	DAC	RLIM#
	DZM	RAMP
	RTL
	RAL
	RTL
	RAL
	DAC	XINC
	LAC	XLIST
	DAC	XLIM#
ROTATE	LAC	RLIM
	RAR
	SZL
	JMP	GREXIT
	DAC	RLIM
	LAC	XLIM
	RCR
	DAC	XLIM
	ISZ	RAMP
	JMP	ROTATE
GREXIT	LAC	RAMP
	TCA
	DAC	RAMP
	JMP	%READ
LNSET	0
	ISZ	LINE
	JMP*	LNSET
	TLS+10
	JMS	CARR
	LAW	-12
	DAC	LINE
	JMP*	LNSET
XLIST	10000
SFLAG	0
CFLAG	0
CLFLAG	0
TFLAG	1
TYFLAG	1
MFLAG	0
OFLAG	0
EFLAG	0
XLOW	10000
ILOW	0
IHIGH	0
LINE	-12
RAMP	0
XINC	100
VGAIN	0
%SELECT	JMS	ECHO
	JMS	STACAL
	DAC	XLOWS
	CLC
	DAC	OFLAG
	LAC	HAC
	SZA
	JMP	OLAP
	DZM	OFLAG
	LAC	XLOWS
	DAC	SLOW#
	SKP
OLAP	JMS	STACAL
	DAC	XLOW
	JMP	%READ
STACAL	0
	TAD	(-1
	JMS	MULT
	LAC	XLIM
	TAD	XLIST
	JMP*	STACAL
%GAIN	DZM	VGAIN
	CLL
	JMS	ECHO
PST	RAR
	SZL
	JMP	GEXIT
	ISZ	VGAIN
	JMP	PST
GEXIT	LAC	VGAIN
	TCA
	DAC	VGAIN
	JMP	%READ
%ERASE	JMS	CTECH
	CLC
	DAC	EFLAG
	JMP	DPY
%INT	JMS	ECHO
	DAC	INHLD
	LAC	HAC
	TCA
	DAC	ILOW
	TAD	INHLD#
	TCA
	DAC	IHIGH
	JMP	%READ
%SLIDE	TLS+10
	LAC	(314
	JMS	WRITE
	CLC
	DAC	SFLAG
	JMS	%OPSP
	JMP	%READ
%TYPE	JMS	CTECH
	TLS+10
	JMS	CARR
	LAC	INL
	TAD	XLIST
	TCA
	JMS	%DIP
	LAC	LIVE
	JMS	%DIP
	LAC	REAL
	JMS	%DIP
	JMS	CARR
	DZM	TFLAG
	LAW	-12
	DAC	LINE
	LAC	PIHAC
	JMP	DPY
%PIME	CLC
	DAC	CLFLAG
	JMP	%COMM
%TIME	DZM	CLFLAG
%COMM	JMS	ECHO
	DAC	TIME#
	LAW	-7
	DAC	TMCNT#
	CLL
	LAC	TIME
	RCL
	ISZ	TMCNT
	JMP	.-2
	TCA
	DAC	CLCNT#
	DZM	LIVE#
	DZM	REAL#
	NDCN
	JMP	%READ
%START	JMS	CTECH
	JMP	DPY
MPR	TLS+10
	LAW	336
	JMS	WRITE
	LAW	320
	JMS	WRITE
	JMS	ECHO
	DAC	PAD#
	JMP*	PAD
CTECH	0
	TAD	(100
	DAC	RHLD#
	TLS+10
	LAW	336
	JMS	WRITE
	LAC	RHLD
	JMS	WRITE
	JMS	%OPSP
	JMS	LNSET
	TSF
	JMP	.-1
	TCF
	JMP*	CTECH
ECHO	0
	DZM	WDCNT#
	DZM	HAC#
	TLS+10
	LAW	275
	JMS	WRITE
REED	JMS	READ
	SAD	(257
	JMP	REXIT
	SAD	(240
	JMP	RESET
	AND	(17
	DAC	HOLD#
	LAC	RBUFF
	TAD	WDCNT
	DAC	RVEC#
	LAC	HOLD
	DAC*	RVEC
	ISZ	WDCNT
	JMP	REED
RESET	JMS	DBC
	DAC	HAC
	DZM	WDCNT
	JMP	REED
REXIT	JMS	%OPSP
	JMS	LNSET
	JMS	DBC
	JMP*	ECHO
DBC	0
	DZM	BIN#
	LAC	WDCNT
	TAD	(-1
	DAC	PCNT#
	CMA
	DAC	ACNT#
	LAC	RBUFF
	DAC	RVEC#
	LAC	CONBUFF
	TAD	PCNT
	DAC	CONVEC#
CONV	LAC*	RVEC
	JMS	MULT
	LAC*	CONVEC
	TAD	BIN
	DAC	BIN
	ISZ	RVEC
	LAC	CONVEC
	TAD	(-1
	DAC	CONVEC
	ISZ	ACNT
	JMP	CONV
	LAC	BIN
	JMP*	DBC
READBF	.BLOCK	4
CVBF	1
	12
	144
	1750
RBUFF	READBF
CONBUFF	CVBF
WRITE	0
	TSF
	JMP	.-1
	TLS
	JMP*	WRITE
READ	0
	KSF
	JMP	.-1
	KRB
	JMP*	READ
CARR	0
	LAW	212
	JMS	WRITE
	LAW	215
	JMS	WRITE
	JMP*	CARR
KSF=700301
TSF=700401
KRB=700312
TLS=700406
XFRA=701524
XFRB=701544
DPY	LAC	XLOW
IRET	DAC	STAD#
ORET	TCA
	TAD	ILOW
	DAC	INL#
	TAD	IHIGH
	DAC	INU#
	ION
SRET	DZM	XCOOR#
DGO	LAC	VGAIN
	SZA
	JMS	AUG
	LAC*	STAD
	DAC	OUT#
	LAC	EFLAG
	SZA
	DZM*	STAD
	CLL
TRANS	LAC	CFLAG
	RAR
	LAC	OUT
	SZL
	TAD	(400000
	XFRA
	LAC	XCOOR
	XFRB
	LAC	STAD
	TAD	INL
	SPA
	JMP	INC
	LAC	STAD
	TAD	INU
	SMA
	JMP	INC
	ISZ	ICNT#
	JMP	TRANS
	LAW	-10
	DAC	ICNT
	LAC	TYFLAG
	SZA
	JMP	INC
	LAC*	STAD
	JMS	%DIP
	JMS	LNSET
INC	LAC	MFLAG
	SZA
	JMP	WORSE
URET	ISZ	STAD
	LAC	XCOOR
	TAD	XINC
	DAC	XCOOR
	SNA
	JMP	DFIN
	JMP	DGO
DFIN	DZM	EFLAG
	DZM	MFLAG
	LAC	TFLAG
	SZA
	JMP	WINDY
	LAC	TYFLAG
	SZA
	JMP	TYSET
	JMS	CARR
	TCF
	LAW	-12
	DAC	TFLAG
	DAC	TYFLAG
	DAC	LINE
	SKP
TYSET	DZM	TYFLAG
WINDY	LAC	SFLAG
	SNA
	JMP	DRET
	LAS
	JMP	IRET
WORSE	LAC	MFACTOR#
	JMS	MULT
	LAC*	STAD
	DAC*	STAD
	JMP	URET
DRET	LAC	OFLAG
	SNA
	JMP	DPY
	ISZ	CYCLE#
	LAC	CYCLE
	AND	(1
	SNA
	JMP	DPY
	LAC	XLOWS#
	DAC	STAD
	JMP	ORET
AUG	0
	DAC	RCNT#
	XCT*	AUG
AUGST	RCL
	ISZ	RCNT
	JMP	AUGST
	ISZ	AUG
	JMP*	AUG
DHAND	RRND
	RAL
	SZL
	JMP	CONTIN
	RAR
	AND	(377777
	DAC	TEMP#
	LAC	RAMP
	DAC	RMPCNT#
	SZA
	JMS	DWNCNT
	LAC	TEMP
	TAD	XLOW
	DAC	EVEC#
	ISZ*	EVEC
	SKP
	JMP	%HLT
	JMP	CONTIN
DWNCNT	0
	XCT*	DWNCNT
	RCR
	ISZ	RMPCNT
	JMP	.-2
	ISZ	DWNCNT
	JMP*	DWNCNT
SQRT	0
	DAC	ARG
	SNA
	JMP*	SQRT
	DZM	SHIFT
	CLL
%POWER	RAL
	ISZ	SHIFT
	SNL
	JMP	%POWER
	LAC	SHIFT
	AND	(1
	ADD	SHIFT
	TCA
	DAC	SHIFT
	ADD	(21
	DAC	POWER
	CLA
FACTOR	RAR
	ISZ	SHIFT
	JMP	FACTOR
	TCA
	TAD	ARG
	DAC	REM
	CLL
	LAC	POWER
	RAR
	ADD	(1
	PAL
	CLL!CLA
	CLX
	CML
FIRST	RAL
	AXS	1
	JMP	FIRST
	DAC	ANS
	CLX
	LAC	REM
FIRST1	CLL!RAR
	AXS	1
	JMP	FIRST1
	ADD	ANS
	DAC	ANS
	LAW	-3
	DAC	ITER
	LAC	ANS
%ITER	JMS	MULT
	LAC	ANS
	TCA
	TAD	ARG
	DAC	REM
	LAC	ANS
	CLL
	RAL
	DAC	ANS2
	CLL
	LAC	REM
	AND	(400000
	RAL
	SZL
	CMA
	JMS	DIV
	LAC	REM
	LAC	ANS2
	TAD	ANS
	DAC	ANS
	ISZ	ITER
	JMP	%ITER
	JMP*	SQRT
ARG	0
SHIFT	0
ANS	0
POWER	0
REM	0
ANS2	0
ITER	0
%DIP	0
	DAC	%DIP1
	SPA
	JMP	%DIPA
	CMA
	TAD	(1
%DIPA	DAC	%DIP3
	LAW	-5
	DAC	%DIP2
%DIPB	JMS	%DIPG
	LAC	%DIP4
	SZA
	JMP	%DIPE
	JMS	%OPSP
	ISZ	%DIP2
	JMP	%DIPB
%DIPC	JMS	%DIPF
%DIPD	LAC	%DIP3
	CMA
	TAD	(261
	JMS	WRITE
	LAC	(TAD %DIPTB
	DAC	%DIPG2
	LAC	%DIP1
	JMP*	%DIP
%DIPE	JMS	%DIPF
	LAC	%DIP4
	TAD	(260
	JMS	WRITE
	ISZ	%DIP2
	SKP
	JMP	%DIPD
	JMS	%DIPG
	JMP	%DIPE+1
%DIPF	0
	LAC	%DIP1
	RAL
	LAW	240
	SZL
	LAW	255
	JMS	WRITE
	JMP*	%DIPF
%DIPG	0
	DZM	%DIP4
	LAC	%DIP3
	JMP	%DIPG2
%DIPG1	DAC	%DIP3
	ISZ	%DIP4
%DIPG2	TAD	%DIPTB
	SPA!SNA
	JMP	%DIPG1
	ISZ	%DIPG2
	JMP*	%DIPG
%DIP1	0
%DIP2	0
%DIP3	0
%DIP4	0
%DIPTB	303240
	023420
	001750
	000144
	000012
	000001
%OPSP	0
	LAW	240
	JMS	WRITE
	JMP*	%OPSP
DIV	0
	SPA!CLL
	CMA!CML
	DAC	%REM
	JMS	%SDV5
%SDV5	0
	XCT*	DIV
	SZL
	JMS	%SDNEG
	DAC	%SQUO
	SPL!CLL
	ISZ	%REM
	NOP
	ISZ	DIV
	XCT*	DIV
	DAC	%SDVS
	XOR	%SDV5
	DAC	%SDV4
	LAC	%SDVS
	SMA
	JMS	%SDNEG
	DAC	%SDVS
	LAC	%REM
	RCL
	TAD	%SDVS
	ISZ	DIV
	SMA!CLA!STL
	JMP	%SDV0
	LAW	-23
	DAC	%SDV1
	CLL
	JMP	%SDV2
%SDV3	LAC	%REM
	RAL
	DAC	%REM
	TAD	%SDVS
	SZL
	DAC	%REM
%SDV2	LAC	%SQUO
	RAL
	DAC	%SQUO
	ISZ	%SDV1
	JMP	%SDV3
	LAC	%SDV5
	RAL
	LAC	%REM
	SZL
	JMS	%SDNEG
	DAC	%REM
	LAC	%SDV4
	RAL
	LAC	%SQUO
	SZL
	JMS	%SDNEG
	SKP!CLL
%SDV0	DZM	%REM
	JMP*	DIV
%SDVS	0
%REM	0
%SQUO	0
%SDV4	0
%SDV1	0
%SDNEG	0
	CMA!CLL
	TAD	(1
	JMP*	%SDNEG
PUNCH	JMS	CTECH
	LAC	XLOW
	DAC	%STAD#
	LAC	XLIM
	DAC	#CHN#
	LAC	%TAG#
	JMS	ROT
	PSB
	JMS	ROTT
	PSB	
	JMS	ROTT
	PSB
	LAC	%STAD
	DAC	%PAD#
	LAC	#CHN
	TCA
	DAC	CHNCT#
EAST	DZM	RNTOT#
	LAW	-100
	DAC	CKCT#
SOUTH	LAC*	%PAD
	JMS	PNCH
	LAC*	%PAD
	TAD	RNTOT
	DAC	RNTOT
	ISZ	CHNCT
	SKP
	JMP	END
	ISZ	%PAD
	ISZ	CKCT
	JMP	SOUTH
END	LAC	RNTOT
	JMS	PNCH
	LAC	CHNCT
	SZA
	JMP	EAST
	PSF
	JMP	.-1
	PCF
	JMP	DPY
PNCH	NOP
	JMS	ROT
	PSF
	JMP	.-1
	PSB
	JMS	ROTT
	PSB
	JMS	ROTT
	PSB
	JMP*	PNCH
ROT	NOP
	RTL
	RTL
	RTL
	RAL
	JMP*	ROT
ROTT	NOP
	RTL
	RTL
	RTL
	PSF
	JMP	.-1
	JMP*	ROTT
RCF=700102
PSB=700244
PSF=700201
PCF=700202
RSB=700144
RRB=700112
RSF=700101
READTP	JMS	CTECH
	LAC	XLOW
	DAC	%STAD
	LAC	XLIM
	DAC	#CHN
	RSB
	RSF
	JMP	.-1
	RRB
	DAC	%TAG
	LAC	%STAD
	DAC	%PAD
	LAC	#CHN
	TCA
	DAC	CHNCT
MIN	DZM	RNTOT
	LAW	-100
	DAC	CKCT
MAX	RSB
	RSF
	JMP	.-1
	RRB
	DAC*	%PAD
	TAD	RNTOT
	DAC	RNTOT
	ISZ	CHNCT
	SKP
	JMP	STOP
	ISZ	%PAD
	ISZ	CKCT
	JMP	MAX
STOP	RSB
	RSF
	JMP	.-1
	RRB
	TCA
	TAD	RNTOT
	SZA
	JMP	PRBLM
	LAC	CHNCT
	SZA
	JMP	MIN
	CLA
	JMP	DPY
PRBLM	CLC	
	JMP	DPY
MULT	0
	DZM	%MHIGH
	SNA
	JMP	%SMPZ
	DAC	%SMP1
	XCT*	MULT
	DAC	%SMP2
	XOR	%SMP1
	DAC	%MPSIN
	LAC	%SMP1
	SPA
	JMS	%SMNEG
	DAC	%SMP1
	LAC	%SMP2
	SPA
	JMS	%SMNEG
	DAC	%SMP2
	LAW	-22
	DAC	%SMP3
	CLL
%SMP4	LAC	%SMP1
	RAR
	DAC	%SMP1
	LAC	%MHIGH
	SZL!CLL
	TAD	%SMP2
	RAR
	DAC	%MHIGH
	ISZ	%SMP3
	JMP	%SMP4
	LAC	%SMP1
	RAR
	DAC	%SMP1
	LAC	%MPSIN
	SMA
	JMP	%SMPZ-1
	LAC	%SMP1
	JMS	%SMNEG
	DAC	%SMP1
	LAC	%MHIGH
	SPL!CLL!CMA
	TAD	(1
	DAC	%MHIGH
	LAC	%SMP1
%SMPZ	ISZ	MULT
	JMP*	MULT
%SMP1	0
%MHIGH	0
%MPSIN	0
%SMP2	0
%SMP3	0
%SMNEG	0
	CMA!CLL
	TAD	(1
	JMP*	%SMNEG
%COPY	JMS	CTECH
	TLS+10
	JMS	CARR
	LAC	XLOW
	DAC	LAG
	LAC	XLOWS
	DAC	LAGSIG
	LAC	XLIM
	TCA
	DAC	SIG
LOOP	JMS	READ
	SAD	(323
	JMP	SUB
	SAD	(324
	JMP	TRS
	SAD	(301
	SKP
	JMP	LOOP
	LAC*	LAG
	TAD*	LAGSIG
	JMS	DECISIO
	JMP	.-3
SUB	LAC*	LAG
	TCA
	TAD*	LAGSIG
	JMS	DECISIO
	JMP	SUB
TRS	LAC*	LAG
	JMS	DECISIO
	JMP	TRS
DECISIO	0
	DAC*	LAGSIG
	ISZ	LAG
	ISZ	LAGSIG
	ISZ	SIG
	JMP*	DECISIO
	TLS+10
	JMS	%OPSP
	JMS	LNSET
	JMP	DPY
	.EOT
