/CONTINUE WHEN SENSE LINE HIGH SUBROUTINE
/EXECUTION TIME:  PROGRAM DEPENDENT
/                 (51,63,75,... MICROSECONDS)
/CALLING SEQUENCE:  CALL CWSL(SENSE,ERROR)
/   SENSE:  0-7 ADDRESS OF SENSE LINE
/   ERROR=0:  NO ERROR
/        =1:  ILLEGAL SENSE LINE REQUESTED
/CWSL RESETS THE SENSE LINE WHEN IT GOES HIGH
	.TITLE CWSL
	.GLOBL CWSL
CWSL	0
	ISZ CWSL
	LAC* CWSL
	DAC SENSE
	SPA
	LAC* SENSE	/INDIRECT
	DAC SENSE	/SENSE LOCATION
	ISZ CWSL
	LAC* CWSL
	DAC ERROR
	SPA
	LAC* ERROR	/INDIRECT
	DAC ERROR
	DZM* ERROR	/ERROR=0
	ISZ CWSL	/BUMP TO EXIT
	LAC* SENSE
	AND (777770
	SZA!CLA
	JMP ERROR1	/ILL. SENSE LINE
	LAC* SENSE	/X
	TAD (XCT TABLE	/XCT TABLE+X
	DAC .+3	/DEPOSIT TSL(SENSE)
	IOT5
	JMP .-1
	XX	/TEST AND RESET SENSE LINE
	SMA	/SKIP ON SENSE HIGH
	JMP .-4	/STILL LOW
	JMP* CWSL	/CONTINUE
ERROR1	ISZ* ERROR	/ILL. SENSE LINE
	JMP* CWSL
ERROR
SENSE
TABLE	TSL0
	TSL1
	TSL2
	TSL3
	TSL4
	TSL5
	TSL6
	TSL7
IOT5=703005
TSL0=705013
TSL1=705113
TSL2=705213
TSL3=705313
TSL4=703413
TSL5=703513
TSL6=703613
TSL7=703713
	.END
