	.GLOBL MSQRT,.ER,.AA,.AB,.AO,.AP
	.GLOBL .DA,MP,.BA,ST,DIV,RDIV
	.GLOBL ADD,ZRA,NEG,.MA,.AW
XCT=400000
	.DEFIN	CALL,OP,X,SIZE
	JMS*	MP
	JMP	.+4
		OP+XCT
		X
		SIZE
	.ENDM
MSQRT	XX
	JMS*	.DA
	JMP	.+5
IN	0
N1	0
OUT	0
N2	0
	JMS*	ZRA	/0 TO ACC
	JMS*	.AO	/LD ARG
	XCT	IN
	SZL
	JMP	LOOP-3	/EXIT IF 0
	SPA		/ERROR IF -
	JMS*	.ER
	741006		/IOPS 6 OR SKP
	JMS*	.BA
	LAC*	.AA
	RCR
	TAD	TWO+1
	DAC*	.AA
	SZL
	ISZ*	.AA
	LAC*	.AB
	TAD	TWO+1
	SNL!RCR
	TAD	(100000
	DAC*	.AB
	LAC*	.MA
	DAC	.+2
	JMS*	.AP
		0	/APPROX ROOT
	LAC*	N2
	JMS*	.AW
	LAC*	.AA
	XOR	(400000
	TAD	TWO
	CMA		/-(EN2+3)
	DAC	T1	/NO. OF ITERATIONS
	JMP	STOR
LOOP	CALL  RDIV,XCT+IN,XCT+N1
	SPA
	JMS*	NEG
	CALL  ADD,XCT+OUT,XCT+N2
	CALL  DIV,TWO,(1
STOR	CALL  ST,XCT+OUT,XCT+N2
	ISZ	T1
	JMP	LOOP
	JMP*	MSQRT
TWO	2; 200000; 0
T1	0
	.END
