	.TITLE	RSCL
/
/  7 MAR 72 - MOD BY P. HENDERSON
/
/RESET SINGLE CONTROL LINE SUBROUTINE
/EXECUTION TIME: 52 TO 60 MICROSECONDS
/CALLING SEQUENCE: CALL RSCL(LINE,ERROR)
/     LINE: 0-15 ADDRESS OF CONTROL LINE 
/           TO BE RESET
/     ERROR=0: NO ERROR
/          =1: ILL. CONTROL LINE REQUESTED
/
	.GLOBL RSCL
/
RSCL	XX
	.ARG	RSCL
	DAC LINE    /LINE LOCATION
	.ARG
	DAC ERROR
	DZM* ERROR	/ERROR=0
	LAC* LINE
	AND (777760
	SZA!CLL
	JMP ERROR1   /LINE<0 OR LINE >15
	LAC* LINE   /STEP COUNTER
	TAD (LRS    /LONG RIGHT SHIFT
	DAC .+2     /FIX VARIABLE SHIFT
	LAC (400000
	XX          /LOAD DATA WORD
	IOT5
	JMP .-1
	ROCL        /RESET OUTPUT
	            /CONTROL LINE
	JMP* RSCL   
ERROR1	ISZ* ERROR      /ILL. CONTROL 
	            /LINE REQUESTED
	JMP* RSCL
ERROR
LINE
IOT5=703005
ROCL=705306
	.END
