/SET SINGLE RELAY PLUS SUBROUTINE
/EXECUTION TIME: 52 TO 60 MICROSECONDS
/CALLING SEQUENCE: CALL SSRP(RELAY,ERROR)
/RELAY:0=004,1=009,2=014,3=019,
/      4=034,5=039,6=044,7=049,
/      8=064,9=069,10=074,11=079
/      12=094,13=099,14=104,15=109
/ERROR=0: NO ERROR
/     =1: ILLEGAL RELAY REQUESTED
	.TITLE SSRP
	.GLOBL SSRP
SSRP	0
	ISZ SSRP
	LAC* SSRP
	DAC RELAY
	SPA
	LAC* RELAY  /INDIRECT
	DAC RELAY   /RELAY LOCATION
	ISZ SSRP    /BUMP TO ERROR
	LAC* SSRP 
	DAC ERROR
	SPA
	LAC* ERROR  /INDIRECT
	DAC ERROR   /ERROR LOCATION
	ISZ SSRP    /BUMP TO EXIT
	LAC* RELAY  
	AND (777760
	SZA!CLL
	JMP ERROR1  /RELAY<0 OR RELAY>15
	LAC* RELAY  /STEP COUNTER
	TAD (LRS   /LONG RIGHT SHIFT
	DAC .+2     /FIX VARIABLE SHIFT
	LAC (400000
	XX          /LOAD DATA WORD
	IOT5
	JMP .-1
	SRP        /SET RELAY(S) PLUS
	DZM* ERROR  /ZERO ERROR CODE
	JMP* SSRP
ERROR1	LAC (1      /ILL. RELAY REQUEST
	DAC* ERROR
	JMP* SSRP
ERROR
RELAY
IOT5=703005
SRP=703406
	.END
