
/
/OCTAL NUMBER PRINT
/ENTER WITH AC = NUMBER
/           JMS OCTAL
/           NUMBER OF DIGITS
/EXTERNAL:  TYPE
OCTAL	0
	DAC OCT0	/SAVE NUMBER
	LAC* OCTAL	/GET NUMBER OF DIGITS
	CMA!IAC
	DAC OCT1
	ISZ OCTAL	/UPDATE RETURN LOCATION
	LAW 40
	JMS TYPE
	LAC (6
	TAD OCT1
	CMA
	DAC OCT2
OCT4	ISZ OCT2
	SKP
	JMP OCT3
	LAC OCT0
	RTL		/SHIFT 3 BITS
	RAL
	DAC OCT0
	JMP OCT4
OCT3	LAC OCT0	/PRINT 1 DIGIT
	RTL
	RAL
	DAC OCT0
	RAL
	AND (7
	TAD (60
	JMS TYPE
	ISZ OCT1
	JMP OCT3
	CLA
	JMP* OCTAL
OCT0	0
OCT1	0
OCT2	0
