
/REAL TIME CLOCK TEST
/
/CLOCK STARTS COUNTING DOWN FROM 777777
/UNTIL A GIVEN TIME DETERMINED BY THE SWITCHES
/APPROXIMATELY = N*4 MICRO SECS.
/THE NUMBER LEFT IN THE CLOCK IS TYPED AND
/THE EXACT PROCESS IS REPEATED.
       .ABS
       .LOC 1000
START  CAF
       TLS
       705322      /STOP CLOCK
       NOP
AGAIN  LAS
       CMA!IAC
       DAC TIME
       LAC (777777      /SET CLOCK
       705222      /LOAD SR
       705324      /LOAD CLOCK
       .REPT 20
       DZM WAIT    /WAIT FOR TRANSFER
       705321      /START CLOCK
       NOP         / 0.8 MICRO SECS
       ISZ TIME    / 2.4 MICRO SECS
       JMP .-2     / 0.8 MICRO SECS
       705322      /STOP CLOCK
       705324      /READ CLOCK
       .REPT 20
       DZM WAIT    /WAIT FOR TRANSFER
       705212      /READ SR
       JMS OCT6
       LAC CR
       JMS TYPE
       LAC LF
       JMS TYPE
       JMP AGAIN
CR     215
LF     212
WAIT   0
TIME   0
TYPE   0
       TSF
       JMP .-1
       TLS
       JMP* TYPE
TSF=700401
TLS=700406
/SIX OCTAL DIGIT PRINT SUBROUTINE
OCT6    0
        DAC OCTS   /SAVE DATA
        LAC (240
        JMS TYPE
       LAC (240
       JMS TYPE
      LAC OCTS       /GET DATA
       AND (700000
       CLL!RTL
       RTL
       TAD (260
       JMS TYPE
       LAC OCTS     /GET 2ND DIGIT
       SWHA
       AND (70
       CLL!RAR
       RTR
       TAD (260
       JMS TYPE
       LAC OCTS     /GET 3RD DIGIT
       SWHA
       AND (7
       TAD (260
       JMS TYPE
       LAC OCTS           /GET 4TH DIGIT
       SWHA
       AND (700000
       CLL!RTL
       RTL
       TAD (260
       JMS TYPE
       LAC OCTS          /GET 5TH DIGIT
       AND (70
       CLL!RAR
       RTR
       TAD (260
       JMS TYPE
       LAC OCTS          /GET 6TH DIGIT
       AND (7
       TAD (260
       JMS TYPE
       JMP* OCT6
OCTS   0
       .END START
