
/
/   OSCILLOSCOPE DISPLAY SUBROUTINE.
DISPLY 0
       LAC NDISP   /CHECK IF END OF DISPLAY POINTS
       CMA!IAC
       TAD NDISP2
       SMA
       JMP DISP1   /NO, CONTINUE
       LAC (400000   /RESET DISPLAY
       DAC XAXIS
       LAC NDISP0
       DAC NDISP
       TAD BUFADD
       DAC XADD
DISP1  LAC DMODE   /WHICH DISPLAY MODE?
       SZA
       JMP DISP2
       LAC* XADD   /2'S COMPLEMENT MODE
       701524      /2'S COMPLEMENT DACY
       LAC XAXIS  
       701544      /2'S COMPLEMENT DACX
DISP3  TAD XINC
       DAC XAXIS
       ISZ XADD
       ISZ NDISP
       JMP* DISPLY
DISP2  LAC* XADD    /UNSIGNED DAYX MODE
       TAD (400000
       AND (777000
       DAC SAVE17
       LAC XAXIS
       TAD (400000
       AND (777000
       SWHA
       TAD SAVE17
       701564      /UNSIGNED DAYX
       LAC XAXIS
       JMP DISP3
DMODE  0           /0 - 2'S COMPLEMENT, 1 - UNSIGNED DAYX
SAVE17 0
XAXIS  0
XINC   0
XADD   BUFFER
BUFADD BUFFER
B4000  4000
NDISP  0
