/SET SINGLE CONTROL LINE SUBROUTINE
/EXECUTION TIME: 52 TO 60 MICROSECONDS
/CALLING SEQUENCE: CALL SSCL(LINE,ERROR)
/     LINE: 0-15 ADDRESS OF CONTROL LINE 
/           TO BE SET
/     ERROR=0: NO ERROR
/           1: ILL. CONTROL LINE REQUESTED
	.TITLE SSCL
	.GLOBL SSCL
SSCL	0
	ISZ SSCL
	LAC* SSCL
	DAC LINE
	SPA
	LAC* LINE   /INDIRECT
	DAC LINE    /LINE LOCATION
	ISZ SSCL
	LAC* SSCL
	DAC ERROR
	SPA
	LAC* ERROR	/INDIRECT
	DAC ERROR
	DZM* ERROR	/ERROR=0
	ISZ SSCL	/BUMP TO EXIT
	LAC* LINE
	AND (777760
	SZA!CLL
	JMP ERROR1   /LINE<0 OR LINE>15
	LAC* LINE   /STEP COUNTER
	TAD (LRS    /LONG RIGHT SHIFT
	DAC .+2     /FIX VARIABLE SHIFT
	LAC (400000
	XX         /LOAD DATA WORD
	IOT5
	JMP .-1
	SOCL        /SET OUTPUT CONTROL
	            /LINE
	JMP* SSCL
ERROR1	ISZ* ERROR      /ILL. CONTROL 
		/LINE REQUESTED
	JMP* SSCL
ERROR
LINE
IOT5=703005
SOCL=705106
	.END
