
/      PROGRAM TO DELETE COMMENTS FROM SYMBOLIC TAPES.
/      THIS IS A SELF STARTING BINARY TAPE.
/      HOWEVER, THE PROGRAM HALTS TO ALLOW THE SOURCE TAPE
/      TO BE PLACED IN THE READER. DEPRESS CONT TO PROCEED.
       .ABS
       .LOC 100
RSF=700101
RSA=700104
RRB=700112
PSF=700201
PSA=700204
TSF=700401
TLS=700406
START  HLT
       CLA
       PSA
       TLS
       RSA
START3 DZM NEWL
START1 JMS IN
       SAD SLASH
       JMP START2
       ISZ NEWL
       SAD LF
       DZM NEWL
       JMS OUT
       JMP START1
START2 JMS IN
       SAD LF
       SKP
       JMP START2
       LAC NEWL
       SNA
       JMP START3
       LAC CR
       JMS OUT
       LAC LF
       JMS OUT
       JMP START3
SLASH  257
LF     012
CR     215
NEWL   0
IN     0
       RSF
       JMP .-1
       RRB
       RSA
       JMP* IN
OUT    0
       PSF
       JMP .-1
       PSA
       TSF
       JMP .-1
       TLS
       JMP* OUT
       .END START
