/READ SINGLE COMPARATOR STATUS FUNCTION
/EXECUTION TIME:  38 TO 47 MICROSECONDS
/CALLING SEQUENCE:  RSCS(COMPARE)
/   COMPARE:  0=004,1=009,2=014,3=019
/             4=034,5=039,6=044,7=049
/             8=064,9=069,10=074,11=079
/             12=094,13=099,14=104,15=109
/EXIT:  AC=777777 IF THE COMP. IS HIGH
/       AC=000000 IF THE COMP. IS LOW
/                 OR IF AN ILLEGAL
/                 COMPARATOR IS REQUESTED
	.TITLE RSCS
	.GLOBL RSCS
RSCS	0
	ISZ RSCS
	LAC* RSCS
	DAC COMPARE
	SPA
	LAC* COMPARE	/INDIRECT
	DAC COMPARE	/COMPARATOR
		/NUMBER
	ISZ RSCS	/BUMP TO EXIT
	LAC* COMPARE
	AND (777760
	SZA!CLA
	JMP* RSCS	/ILL. COMPARATOR REQ.
	LAC* COMPARE	/STEP COUNT
	TAD (ALS	/AC LEFT SHIFT
	DAC .+4	/FIX VARIABLE SHIFT
	IOT3
	JMP .-1
	RCS	/READ COMPARATOR STATE
	XX	/AC0=DESIRED COMP.
	SPA!CLA	/SKIP ON COMP. LOW
	CMA	/COMPARATOR IS HIGH
	JMP* RSCS
COMPARE
IOT3=703003
RCS=703513
	.END
