ORG 0100H
ENTRY:
 PUSH AF
 PUSH BC
 PUSH DE
 PUSH HL
 PUSH IY
 PUSH IX
 LD IY,(DATA)
 LD IX,(INST)
 PUSH IY
 POP HL
 LD B,48
CLEAR:
 LD (HL),' '
 INC HL
 DJNZ CLEAR
 PUSH IY
 POP HL
 LD BC,30
 ADD HL,BC
 PUSH HL
 CALL ADDR
 CALL BYTE
 EX (SP),IY
 LD A,(IX+0)
 AND 0C0H
 RLCA
 RLCA
 RLCA
 LD B,0
 LD C,A
 LD HL,JPTBL
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 JP (HL)
EXIT:
 INC IX
 LD (INST),IX
 POP HL
 POP IY
 POP IX
 POP HL
 POP DE
 POP BC
 POP AF
 RET
ZERO:
 LD A,(IX+0)
 AND 07H
 RLCA
 LD C,A
 LD HL,ZRTBL
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 JP (HL)
ZR000:
 LD HL,JRTBL
 LD A,(IX+0)
 AND 38H
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD C,11
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 CALL SNCPY
 LD A,(IX+0)
 AND 30H
 JR Z,EXIT
 INC IX
 PUSH IX
 POP HL
 INC HL
 LD A,(IX+0)
 AND A
 JP P,ZRPOS
 LD B,0FFH
ZRPOS:
 LD C,A
 ADD HL,BC
 LD A,H
 CALL UHEX
 LD A,L
 CALL UHEX
 EX (SP),IY
 CALL BYTE
 JR EXIT
ZR001:
 LD A,(IX+0)
 BIT 3,A
 JR Z,ZRLD16
 LD HL,ADDSTR
 JR ZR001A
ZRLD16:
 LD HL,LDSTR
ZR001A:
 LD C,8
 CALL SNCPY
 LD HL,DRTBL
 AND 30H
 RRCA
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,2
 CALL SNCPY
 LD A,(IX+0)
 BIT 3,A
 JP NZ,EXIT
 LD (IY+0),','
 INC IY
 INC IX
 CALL WORD
 EX (SP),IY
 CALL BYTE
 INC IX
 CALL BYTE
 JP EXIT
ZR010:
 LD A,(IX+0)
 LD HL,LDSTR
 LD C,5
 CALL SNCPY
 BIT 5,A
 JR NZ,ZR010A
 BIT 4,A
 JR NZ,ZR010B
 LD HL,DRBC
 JR ZR010C
ZR010B:
 LD HL,DRDE
ZR010C:
 BIT 3,A
 JR Z,ZR010D
ZR010F:
 LD (IY+0),'A'
 INC IY
 LD (IY+0),','
 INC IY
 JR Z,ZR010E
ZR010D:
 LD (IY+0),'('
 INC IY
 CALL SNCPY
 LD (IY+0),')'
 INC IY
 LD (IY+0),','
 INC IY
 JR Z,ZR010F
ZR010E:
 LD (IY-1),' '
 JP EXIT
ZR010A:
 BIT 4,A
 JR NZ,ZR010G
 LD HL,DRHL
 JR ZR010H
ZR010G:
 LD HL,SRA
ZR010H:
 BIT 3,A
 JR Z,ZR010I
ZR010K:
 CALL SNCPY
 LD (IY+0),','
 INC IY
 JR Z,ZR010J
ZR010I:
 LD (IY+0),'('
 INC IY
 INC IX
 CALL WORD
 LD (IY+0),')'
 INC IY
 LD (IY+0),','
 INC IY
 JR Z,ZR010K
ZR010J:
 LD (IY-1),' '
 DEC IY
 EX (SP),IY
 CALL BYTE
 INC IX
 CALL BYTE
 JP EXIT
ZR011:
 LD A,(IX+0)
 BIT 3,A
 JR NZ,ZR011A
 LD HL,INCSTR
 JR ZR011B
ZR011A:
 LD HL,DECSTR
ZR011B:
 LD C,5
 CALL SNCPY
 LD HL,DRTBL
 AND 30H
 RRCA
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,2
 CALL SNCPY
 JP EXIT
ZR100:
ZR101:
 LD A,(IX+0)
 BIT 0,A
 JR NZ,ZR100A
 LD HL,INCSTR
 JR ZR100B
ZR100A:
 LD HL,DECSTR
ZR100B:
 LD C,5
 CALL SNCPY
 LD HL,SRTBL
 AND 38H
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,4
 CALL SNCPY
 JP EXIT
ZR110:
 LD A,(IX+0)
 LD C,5
 LD HL,LDSTR
 CALL SNCPY
 LD HL,SRTBL
 AND 38H
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,4
 CALL SNCPY
 LD (IY+0),','
 INC IY
 INC IX
 CALL BYTE
 EX (SP),IY
 CALL BYTE
 JP EXIT
ZR111:
 LD A,(IX+0)
 LD HL,ROTBL
 AND 38H
 RRCA
 RRCA
 LD B,0
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,4
 CALL SNCPY
 JP EXIT
ONE:
 LD A,(IX+0)
 CP 76H
 JR Z,HLT
 LD C,5
 LD HL,LDSTR
 CALL SNCPY
 LD HL,SRTBL
 AND 38H
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,4
 CALL SNCPY
 LD (IY+0),','
 INC IY
 LD HL,SRTBL
 LD A,(IX+0)
 AND 07H
 RLCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,4
 CALL SNCPY
 JP EXIT
HLT:
 LD C,4
 LD HL,HLTSTR
 CALL SNCPY
 JP EXIT
TWO:
 LD HL,COTBL
 LD A,(IX+0)
 AND 38H
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,5
 CALL SNCPY
 LD HL,SRTBL
 LD A,(IX+0)
 AND 07H
 RLCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,4
 CALL SNCPY
 JP EXIT
THREE:
 LD A,(IX+0)
 AND 07H
 RLCA
 LD C,A
 LD HL,THRTBL
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 JP (HL)
TH000:
TH010:
TH100:
 LD HL,RJCTBL
 LD A,(IX+0)
 AND 06H
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,5
 CALL SNCPY
 LD HL,CCTBL
 LD A,(IX+0)
 AND 38H
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,5
 CALL SNCPY
 LD A,(IX+0)
 AND 06H
 JP Z,EXIT
 LD (IY+0),','
 INC IY
 INC IX
 CALL WORD
 EX (SP),IY
 CALL BYTE
 INC IX
 CALL BYTE
 JP EXIT
TH001:
 LD HL,TH1TBL
 LD A,(IX+0)
 AND 38H
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,10
 CALL SNCPY
 JP EXIT
TH011:
 LD A,(IX+0)
 CP 0CBH
 JP Z,SHIFT
 BIT 5,A
 JR Z,TH011A
 LD HL,TH2TBL
 AND 18H
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,12
 CALL SNCPY
 JP EXIT
TH011A:
 AND 38H
 JR NZ,TH011B
 LD HL,RJCJP
 LD C,5
 CALL SNCPY
 INC IX
 CALL WORD
 EX (SP),IY
 CALL BYTE
 INC IX
 CALL BYTE
 JP EXIT
TH011B:
 BIT 4,A
 JR NZ,TH011C
 LD HL,OUTSTR
 LD C,6
 CALL SNCPY
 INC IX
 CALL BYTE
 LD (IY-1),')'
 LD (IY+0),','
 LD (IY+1),'A'
 EX (SP),IY
 CALL BYTE
 JP EXIT
TH011C:
 LD HL,INSTR
 LD C,8
 CALL SNCPY
 INC IX
 CALL BYTE
 LD (IY+0),')'
 EX (SP),IY
 CALL BYTE
 JP EXIT
TH101:
 LD A,(IX+0)
 BIT 3,A
 JR NZ,TH101A
 LD HL,TH5TBL
 AND 38H
 RRCA
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,7
 CALL SNCPY
 JP EXIT
TH101A:
 AND 30H
 JR NZ,SHIFT
 LD HL,RJCALL
 LD C,5
 CALL SNCPY
 INC IX
 CALL WORD
 EX (SP),IY
 CALL BYTE
 INC IX
 CALL BYTE
 JP EXIT
TH110:
 LD A,(IX+0)
 LD HL,COTBL
 AND 38H
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,5
 CALL SNCPY
 INC IX
 CALL BYTE
 EX (SP),IY
 CALL BYTE
 JP EXIT
TH111:
 LD A,(IX+0)
 LD HL,RSTSTR
 LD C,5
 CALL SNCPY
 AND 38H
 CALL UHEX
 JP EXIT
SHIFT:
 INC IX
 EX (SP),IY
 CALL BYTE
 EX (SP),IY
 LD A,(IX-1)
 CP 0CBH
 JP Z,SHCB
 BIT 4,A
 JP Z,SHED
 BIT 5,A
 JR Z,SHDD
 LD HL,IYSTR
 JR SHDD1
SHDD:
 LD HL,IXSTR
SHDD1:
 PUSH IY
 LD IY,TMPSTR
 LD (IY+0),'('
 INC IY
 LD C,2
 CALL SNCPY
 LD A,(IX+1)
 CALL SHEX
 LD (IY+0),')'
 POP IY
 LD A,(IX+0)
 CP 0CBH
 JP Z,DDCB
 AND 0C0H
 JP Z,DDIFF
 CP 0C0H
 JP Z,DDIFF2
 BIT 7,A
 JP NZ,DDCO
DDLD:
 LD A,(IX+0)
 CP 76H
 JP Z,ILLEG
 EX (SP),IY
 INC IX
 CALL BYTE
 EX (SP),IY
 LD HL,LDSTR
 LD C,5
 CALL SNCPY
 AND 07H
 XOR 06H
 JR Z,DDLD1
DDLD2:
 LD HL,TMPSTR
 LD C,7
 CALL SNCPY
 LD (IY+0),','
 INC IY
 LD HL,SRTBL
 LD A,(IX-1)
 AND 07H
 RLCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,4
 CALL SNCPY
 JP EXIT
DDLD1:
 LD HL,SRTBL
 LD A,(IX-1)
 AND 38H
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,4
 CALL SNCPY
 LD (IY+0),','
 INC IY
 LD HL,TMPSTR
 LD C,7
 CALL SNCPY
 JP EXIT
DDCO:
 LD A,(IX+0)
 AND 07H
 CP 06H
 JP NZ,ILLEG
 LD HL,COTBL
 LD A,(IX+0)
 AND 38H
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,5
 CALL SNCPY
 LD HL,TMPSTR
 LD C,7
 CALL SNCPY
 EX (SP),IY
 INC IX
 CALL BYTE
 JP EXIT
DDIFF2:
 EX DE,HL
 LD A,(IX+0)
 CP 0E1H
 JR NZ,DDIF2A
 LD HL,TH1BC
 LD C,5
 CALL SNCPY
 JR DDIF2E
DDIF2A:
 CP 0E3H
 JR NZ,DDIF2B
 LD HL,TH2EX1
 LD C,10
 CALL SNCPY
 JR DDIF2E
DDIF2B:
 CP 0E5H
 JR NZ,DDIF2C
 LD HL,TH5BC
 LD C,5
 CALL SNCPY
 JR DDIF2E
DDIF2C:
 CP 0E9H
 JR NZ,DDIF2D
 LD HL,TH1JP
 LD C,9
 CALL SNCPY
 DEC IY
 DEC IY
 DEC IY
 JR DDIF2E
DDIF2D:
 CP 0F9H
 JP NZ,ILLEG
 LD HL,TH1LD
 LD C,8
 CALL SNCPY
DDIF2E:
 EX DE,HL
 LD C,2
 CALL SNCPY
 JP EXIT
DDIFF:
 LD A,(IX+0)
 AND 0FH
 CP 09H
 JR NZ,DDIFFA
 EX DE,HL
 LD HL,COADD
 LD C,5
 CALL SNCPY
 EX DE,HL
 LD C,2
 CALL SNCPY
 LD (IY+0),','
 INC IY
 LD A,(IX+0)
 LD A,(IX+0)
 CP 29H
 CALL Z,SNCPY
 JP Z,EXIT
 LD HL,DRTBL
 AND 30H
 RRCA
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,2
 CALL SNCPY
 JP EXIT
DDIFFA:
 LD A,(IX+0)
 CP 21H
 JR NZ,DDIFFB
 EX DE,HL
 LD HL,LDSTR
 LD C,5
 CALL SNCPY
 EX DE,HL
 LD C,2
 CALL SNCPY
 LD (IY+0),','
 INC IY
 INC IX
 CALL WORD
 EX (SP),IY
 CALL BYTE
 INC IX
 CALL BYTE
 JP EXIT
DDIFFB:
 CP 22H
 JR NZ,DDIFFC
 EX DE,HL
 LD HL,LDSTR
 LD C,5
 CALL SNCPY
 LD (IY+0),'('
 INC IY
 INC IX
 CALL WORD
 LD (IY+0),')'
 INC IY
 LD (IY+0),','
 INC IY
 EX DE,HL
 LD C,2
 CALL SNCPY
 EX (SP),IY
 CALL BYTE
 INC IX
 CALL BYTE
 JP EXIT
DDIFFC:
 CP 23H
 JR NZ,DDIFFD
 EX DE,HL
 LD HL,INCSTR
 LD C,5
 CALL SNCPY
 EX DE,HL
 LD C,2
 CALL SNCPY
 JP EXIT
DDIFFD:
 CP 2AH
 JR NZ,DDIFFE
 EX DE,HL
 LD HL,LDSTR
 LD C,5
 CALL SNCPY
 EX DE,HL
 LD C,2
 CALL SNCPY
 LD (IY+0),','
 INC IY
 LD (IY+0),'('
 INC IY
 INC IX
 CALL WORD
 LD (IY+0),')'
 EX (SP),IY
 CALL BYTE
 INC IX
 CALL BYTE
 JP EXIT
DDIFFE:
 CP 2BH
 JR NZ,DDIFFF
 EX DE,HL
 LD HL,DECSTR
 LD C,5
 CALL SNCPY
 EX DE,HL
 LD C,2
 CALL SNCPY
 JP EXIT
DDIFFF:
 CP 34H
 JR NZ,DDIFFG
 EX DE,HL
 LD HL,INCSTR
 LD C,5
 CALL SNCPY
 LD HL,TMPSTR
 LD C,7
 CALL SNCPY
 EX (SP),IY
 INC IX
 CALL BYTE
 JP EXIT
DDIFFG:
 CP 35H
 JR NZ,DDIFFH
 EX DE,HL
 LD HL,DECSTR
 LD C,5
 CALL SNCPY
 LD HL,TMPSTR
 LD C,7
 CALL SNCPY
 EX (SP),IY
 INC IX
 CALL BYTE
 JP EXIT
DDIFFH:
 CP 36H
 JP NZ,ILLEG
 EX DE,HL
 LD HL,LDSTR
 LD C,5
 CALL SNCPY
 LD HL,TMPSTR
 LD C,7
 CALL SNCPY
 EX (SP),IY
 INC IX
 CALL BYTE
 EX (SP),IY
 LD (IY+0),','
 INC IY
 INC IX
 CALL BYTE
 EX (SP),IY
 CALL BYTE
 JP EXIT
DDCB:
 INC IX
 INC IX
 LD A,(IX+0)
 AND 0C0H
 JR NZ,DDCB1
 LD HL,CBTBL
 LD A,(IX+0)
 AND 38H
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,5
 CALL SNCPY
 JR DDCBC
DDCB1:
 BIT 7,A
 JR NZ,DDCB2
 LD HL,BITSTR
 JR DDCB4
DDCB2:
 BIT 6,A
 JR NZ,DDCB3
 LD HL,RESSTR
 JR DDCB4
DDCB3:
 LD HL,SETSTR
DDCB4:
 LD C,5
 CALL SNCPY
 LD A,(IX+0)
 AND 38H
 RRCA
 RRCA
 RRCA
 ADD A,'0'
 LD (IY+0),A
 INC IY
 LD (IY+0),','
 INC IY
DDCBC:
 LD HL,TMPSTR
 LD C,7
 CALL SNCPY
 EX (SP),IY
 DEC IX
 CALL BYTE
 INC IX
 CALL BYTE
 JP EXIT
SHED:
 LD A,(IX+0)
 BIT 7,A
 JP NZ,BLOCK
 BIT 6,A
 JP Z,ILLEG
 AND 07H
 RLCA
 LD C,A
 LD HL,EDTBL
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 JP (HL)
ED000:
 LD HL,INSTR
 LD C,5
 CALL SNCPY
 LD HL,SRTBL
 LD A,(IX+0)
 AND 38H
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 CALL SNCPY
 LD (IY+0),','
 LD (IY+1),'('
 LD (IY+2),'C'
 LD (IY+3),')'
 JP EXIT
ED001:
 LD HL,OUTSTR
 LD C,6
 CALL SNCPY
 LD (IY+0),'C'
 LD (IY+1),')'
 LD (IY+2),','
 INC IY
 INC IY
 INC IY
 LD HL,SRTBL
 LD A,(IX+0)
 AND 38H
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 CALL SNCPY
 JP EXIT
ED010:
 LD A,(IX+0)
 BIT 3,A
 JR NZ,ED010A
 LD HL,COSBC
 JR ED010B
ED010A:
 LD HL,COADC
ED010B:
 LD C,5
 CALL SNCPY
 LD HL,DRHL
 LD C,2
 CALL SNCPY
 LD (IY+0),','
 INC IY
 LD HL,DRTBL
 AND 30H
 RRCA
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,2
 CALL SNCPY
 JP EXIT
ED011:
 LD HL,LDSTR
 LD C,5
 CALL SNCPY
 LD HL,DRTBL
 LD A,(IX+0)
 AND 30H
 RRCA
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,2
ED011H:
 BIT 3,A
 JR Z,ED011I
ED011K:
 CALL SNCPY
 LD (IY+0),','
 INC IY
 JR Z,ED011J
ED011I:
 LD (IY+0),'('
 INC IY
 INC IX
 CALL WORD
 LD (IY+0),')'
 INC IY
 LD (IY+0),','
 INC IY
 JR Z,ED011K
ED011J:
 LD (IY-1),' '
 DEC IY
 EX (SP),IY
 CALL BYTE
 INC IX
 CALL BYTE
 JP EXIT
ED100:
 LD A,(IX+0)
 CP 44H
 JP NZ,ILLEG
 LD HL,NEGSTR
 LD C,3
 CALL SNCPY
 JP EXIT
ED101:
 LD A,(IX+0)
 AND 0F0H
 CP 40H
 JP NZ,ILLEG
 LD HL,TH1RET
 LD C,3
 CALL SNCPY
 LD A,(IX+0)
 BIT 3,A
 JR NZ,ED101A
 LD (IY+0),'N'
 JP EXIT
ED101A:
 LD (IY+0),'I'
 JP EXIT
ED110:
 LD A,(IX+0)
 AND 0F0H
 CP 40H
 JR NZ,ED110B
 LD A,(IX+0)
 BIT 3,A
 JP NZ,ILLEG
 JR ED110C
ED110B:
 CP 50H
 JP NZ,ILLEG
ED110C:
 LD HL,IMSTR
 LD C,5
 CALL SNCPY
 LD A,(IX+0)
 AND 18H
 JR NZ,ED110A
 LD (IY+0),'0'
 JP EXIT
ED110A:
 BIT 3,A
 JR NZ,ED110D
 LD (IY+0),'1'
 JP EXIT
ED110D:
 LD (IY+0),'2'
 JP EXIT
ED111:
 LD HL,ED7TBL
 LD A,(IX+0)
 AND 38H
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,8
 CALL SNCPY
 JP EXIT
BLOCK:
 BIT 2,A
 JP NZ,ILLEG
 BIT 6,A
 JP NZ,ILLEG
 BIT 5,A
 JP Z,ILLEG
 LD HL,BLTBLX
 AND 18H
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD A,(IX+0)
 AND 03H
 RLCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,4
 CALL SNCPY
 JP EXIT
SHCB:
 LD A,(IX+0)
 AND 0C0H
 JR NZ,SHCB1
 LD HL,CBTBL
 LD A,(IX+0)
 AND 38H
 RRCA
 RRCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,5
 CALL SNCPY
 JR SHCBC
SHCB1:
 BIT 7,A
 JR NZ,SHCB2
 LD HL,BITSTR
 JR SHCB4
SHCB2:
 BIT 6,A
 JR NZ,SHCB3
 LD HL,RESSTR
 JR SHCB4
SHCB3:
 LD HL,SETSTR
SHCB4:
 LD C,5
 CALL SNCPY
 LD A,(IX+0)
 AND 38H
 RRCA
 RRCA
 RRCA
 ADD A,'0'
 LD (IY+0),A
 INC IY
 LD (IY+0),','
 INC IY
SHCBC:
 LD HL,SRTBL
 LD A,(IX+0)
 AND 07H
 RLCA
 LD C,A
 ADD HL,BC
 LD E,(HL)
 INC HL
 LD D,(HL)
 EX DE,HL
 LD C,4
 CALL SNCPY
 JP EXIT
ILLEG:
 LD HL,ILLSTR
 LD C,7
 CALL SNCPY
 JP EXIT
ADDR:
 PUSH AF
 PUSH BC
 PUSH IX
 POP BC
 LD A,B
 CALL UHEX
 LD A,C
 CALL UHEX
 LD (IY+0),':'
 INC IY
 INC IY
 POP BC
 POP AF
 RET
BYTE:
 PUSH AF
 LD A,(IX+0)
 CALL UHEX
 INC IY
 POP AF
 RET
WORD:
 PUSH AF
 LD A,(IX+1)
 CALL UHEX
 LD A,(IX+0)
 CALL UHEX
 POP AF
 RET
SNCPY:
 PUSH AF
 PUSH BC
 PUSH DE
 PUSH HL
 PUSH IY
 POP DE
 XOR A
LCPY:
 CP (HL)
 JR Z,ECPY
 LDI
 JP PE,LCPY
ECPY:
 PUSH DE
 POP IY
 POP HL
 POP DE
 POP BC
 POP AF
 RET
SHEX:
 PUSH AF
 AND A
 JP P,PHEX
 LD (IY+0),'-'
 NEG
 JR CHEX
PHEX:
 LD (IY+0),'+'
CHEX:
 INC IY
 CALL UHEX
 POP AF
 RET
UHEX:
 PUSH AF
 PUSH BC
 PUSH DE
 PUSH HL
 LD D,0
 LD B,A
 LD HL,HXTBL
 AND 0FH
 LD E,A
 ADD HL,DE
 LD C,(HL)
 LD (IY+1),C
 LD A,B
 LD HL,HXTBL
 RLCA
 RLCA
 RLCA
 RLCA
 AND 0FH
 LD E,A
 ADD HL,DE
 LD C,(HL)
 LD (IY+0),C
 INC IY
 INC IY
 POP HL
 POP DE
 POP BC
 POP AF
 RET
JPTBL:
 DW ZERO
 DW ONE
 DW TWO
 DW THREE
ZRTBL:
 DW ZR000
 DW ZR001
 DW ZR010
 DW ZR011
 DW ZR100
 DW ZR101
 DW ZR110
 DW ZR111
THRTBL:
 DW TH000
 DW TH001
 DW TH010
 DW TH011
 DW TH100
 DW TH101
 DW TH110
 DW TH111
EDTBL:
 DW ED000
 DW ED001
 DW ED010
 DW ED011
 DW ED100
 DW ED101
 DW ED110
 DW ED111
ED7TBL:
 DW EDLDIA
 DW EDLDRA
 DW EDLDAI
 DW EDLDAR
 DW EDRRD
 DW EDRLD
 DW ILLSTR
 DW ILLSTR
BLTBLX:
 DW BLTBL1
 DW BLTBL2
 DW BLTBL3
 DW BLTBL4
BLTBL1:
 DW BLLDI
 DW BLCPI
 DW BLINI
 DW BLOUTI
BLTBL2:
 DW BLLDD
 DW BLCPD
 DW BLIND
 DW BLOUTD
BLTBL3:
 DW BLLDIR
 DW BLCPIR
 DW BLINIR
 DW BLOTIR
BLTBL4:
 DW BLLDDR
 DW BLCPDR
 DW BLINDR
 DW BLOTDR
CBTBL:
 DW CBRLC
 DW CBRRC
 DW CBRL
 DW CBRR
 DW CBSLA
 DW CBSLR
 DW CBSLL
 DW CBSRL
TH1TBL:
 DW TH1BC
 DW TH1RET
 DW TH1DE
 DW TH1EXX
 DW TH1HL
 DW TH1JP
 DW TH1AF
 DW TH1LD
TH2TBL:
 DW TH2EX1
 DW TH2EX2
 DW TH2DI
 DW TH2EI
TH5TBL:
 DW TH5BC
 DW TH5DE
 DW TH5HL
 DW TH5AF
CCTBL:
 DW CCNZ
 DW CCZ
 DW CCNC
 DW CCC
 DW CCPO
 DW CCPE
 DW CCP
 DW CCM
RJCTBL:
 DW RJCRET
 DW RJCJP
 DW RJCALL
ROTBL:
 DW RORLCA
 DW RORRCA
 DW RORLA
 DW RORRA
 DW RODAA
 DW ROCPL
 DW ROSCF
 DW ROCCF
JRTBL:
 DW JRNOP
 DW JREX
 DW JRDJNZ
 DW JRNOCC
 DW JRNZ
 DW JRZ
 DW JRNC
 DW JRC
COTBL:
 DW COADD
 DW COADC
 DW COSUB
 DW COSBC
 DW COAND
 DW COXOR
 DW COOR
 DW COCP
DRTBL:
 DW DRBC
 DW DRDE
 DW DRHL
 DW DRSP
SRTBL:
 DW SRB
 DW SRC
 DW SRD
 DW SRE
 DW SRH
 DW SRL
 DW SRHL
 DW SRA
EDLDIA:
 DM 'LD   I,A',0
EDLDRA:
 DM 'LD   R,A',0
EDLDAI:
 DM 'LD   A,I',0
EDLDAR:
 DM 'LD   A,R',0
EDRRD:
 DM 'RRD',0
EDRLD:
 DM 'RLD',0
BLLDI:
 DM 'LDI',0
BLCPI:
 DM 'CPI',0
BLINI:
 DM 'INI',0
BLOUTI:
 DM 'OUTI',0
BLLDD:
 DM 'LDD',0
BLCPD:
 DM 'CPD',0
BLIND:
 DM 'IND',0
BLOUTD:
 DM 'OUTD',0
BLLDIR:
 DM 'LDIR',0
BLCPIR:
 DM 'CPIR',0
BLINIR:
 DM 'INIR',0
BLOTIR:
 DM 'OTIR',0
BLLDDR:
 DM 'LDDR',0
BLCPDR:
 DM 'CPDR',0
BLINDR:
 DM 'INDR',0
BLOTDR:
 DM 'OTDR',0
CBRLC:
 DM 'RLC  ',0
CBRRC:
 DM 'RRC  ',0
CBRL:
 DM 'RL   ',0
CBRR:
 DM 'RR   ',0
CBSLA:
 DM 'SLA  ',0
CBSLR:
 DM 'SLR  ',0
CBSLL:
 DM 'SLL  ',0
CBSRL:
 DM 'SRL  ',0
TH1BC:
 DM 'POP  BC',0
TH1DE:
 DM 'POP  DE',0
TH1HL:
 DM 'POP  HL',0
TH1AF:
 DM 'POP  AF',0
TH1RET:
 DM 'RET',0
TH1EXX:
 DM 'EXX',0
TH1JP:
 DM 'JP   (HL)',0
TH1LD:
 DM 'LD   SP,HL',0
TH2EX1:
 DM 'EX   (SP),HL'
TH2EX2:
 DM 'EX   DE,HL',0
TH2DI:
 DM 'DI',0
TH2EI:
 DM 'EI',0
TH5BC:
 DM 'PUSH BC',0
TH5DE:
 DM 'PUSH DE',0
TH5HL:
 DM 'PUSH HL',0
TH5AF:
 DM 'PUSH AF',0
CCNZ:
 DM 'NZ',0
CCZ:
 DM 'Z',0
CCNC:
 DM 'NC',0
CCC:
 DM 'C',0
CCPO:
 DM 'PO',0
CCPE:
 DM 'PE',0
CCP:
 DM 'P',0
CCM:
 DM 'M',0
RJCRET:
 DM 'RET  ',0
RJCJP:
 DM 'JP   ',0
RJCALL:
 DM 'CALL ',0
RORLCA:
 DM 'RLCA',0
RORRCA:
 DM 'RRCA',0
RORLA:
 DM 'RLA',0
RORRA:
 DM 'RRA',0
RODAA:
 DM 'DAA',0
ROCPL:
 DM 'CPL',0
ROSCF:
 DM 'SCF',0
ROCCF:
 DM 'CCF',0
JRNOP:
 DM 'NOP',0
JREX:
 DM 'EX   AF,AF''',0
JRDJNZ:
 DM 'DJNZ ',0
JRNOCC:
 DM 'JR   ',0
JRNZ:
 DM 'JR   NZ,',0
JRZ:
 DM 'JR   Z,',0
JRNC:
 DM 'JR   NC,',0
JRC:
 DM 'JR   C,',0
COADD:
 DM 'ADD  ',0
COADC:
 DM 'ADC  ',0
COSUB:
 DM 'SUB  ',0
COSBC:
 DM 'SBC  ',0
COAND:
 DM 'AND  ',0
COXOR:
 DM 'XOR  ',0
COOR:
 DM 'OR   ',0
COCP:
 DM 'CP   ',0
DRBC:
 DM 'BC',0
DRDE:
 DM 'DE',0
DRHL:
 DM 'HL',0
DRSP:
 DM 'SP',0
SRA:
 DM 'A',0
SRB:
 DM 'B',0
SRC:
 DM 'C',0
SRD:
 DM 'D',0
SRE:
 DM 'E',0
SRH:
 DM 'H',0
SRL:
 DM 'L',0
SRHL:
 DM '(HL)',0
ADDSTR:
 DM 'ADD  HL,',0
BITSTR:
 DM 'BIT  ',0
DECSTR:
 DM 'DEC  ',0
HLTSTR:
 DM 'HALT',0
ILLSTR:
 DM 'illegal',0
IMSTR:
 DM 'IM   ',0
INCSTR:
 DM 'INC  ',0
INSTR:
 DM 'IN   A,(',0
IXSTR:
 DM 'IX',0
IYSTR:
 DM 'IY',0
NEGSTR:
 DM 'NEG',0
LDSTR:
 DM 'LD   ',0
OUTSTR:
 DM 'OUT  (',0
RESSTR:
 DM 'RES  ',0
RSTSTR:
 DM 'RST  ',0
SETSTR:
 DM 'SET  ',0
TMPSTR:
 DM '(IX+00)',0
HXTBL:
 DM '0123456789ABCDEF'
DATA:
 DW 77D0H
INST:
 DW 0000H