         SYSTEM   BPM
         SYSTEM   SIG6
         DEF      ATTR
         REF      F:1,ATRHLP,SETUP
ATTR     CSECT    1
         LCI      0
         STM,0    SAVEREGS
         M:INT    DO$CAL$1
         M:GCP    1
         BCS,8    NOPAGE
         STW,9    POINTER
         STW,9    SAVEPAGE
         MTW,1    SAVEPAGE
         LCI      3
         LM,4     CLOSEFPT
         PSM,4    POINTER
ASK      M:KEYIN  (MESS,WHATATTR),(REPLY,LWJ),(SIZE,10),(ECB,ECB)
         M:CHECKECB (ECB,ECB)
         LB,1     LWJ
         CI,1     1
         BG       $+4
GETHELP  LI,14    0
         BAL,15   ATRHLP
         B        ASK
         LI,2     1
         LB,1     LWJ,2
         CI,1     C'F'
         BE       FILENAME
         CI,1     C'P'
         BE       PASSWD
         CI,1     C'W'
         BE       WRITE
         CI,1     C'R'
         BE       READ
         CI,1     C'U'
         BE       UNDER
         CI,1     C'E'
         BE       EXECUTE
         B        GETHELP
FILENAME LW,11    =X'01000008'
         PSW,11   POINTER
         LW,11    POINTER
FILENAM2 BAL,15   CLEARLWJ
         M:KEYIN  (MESS,NEWNAME),(REPLY,LWJ),(SIZE,32),(ECB,ECB)
         LI,2     2
         LI,4     BA(LWJ)
         LW,5     POINTER
         AI,5     1
         SLS,5    2
         M:CHECKECB  (ECB,ECB)
         LB,1     LWJ
         CI,1     1
         BE       FILERR
         CI,1     31
         BG       FILERR
         MTB,-1   LWJ
         STB,1    5
         MBS,4    0
         AI,1     3
         SLS,1    -2
         MSP,1    POINTER
         SLS,1    8
         AWM,1    *11
         B        DO$CAL
FILERR   M:TYPE   (MESS,FILERONG)
         B        FILENAM2
FILERONG TEXTC    '****ERROR****FILE NAME TOO LONG/SHORT
'
PASSWD   BAL,15   CLEARLWJ
         LW,11    =X'03000002'
         PSW,11   POINTER
         LW,11    POINTER
         LI,2     2
         M:KEYIN  (MESS,NEWPASS),(REPLY,LWJ),(SIZE,9),(ECB,ECB)
         LI,4     BA(LWJ)
         LI,5     14*4
         M:CHECKECB (ECB,ECB)
         LB,3     LWJ
         LI,7     C' '
         STB,7    LWJ,3
         MTW,-1   3
         BEZ      DO$CAL
         LI,3     8
         STB,3    5
         MBS,4    1
         MTB,2    *11,2
         PSW,14   POINTER
         PSW,15   POINTER
         B        DO$CAL
UNDER    LI,8     8
         LI,2     2
         LW,11    =X'15000018'
         PSW,11   POINTER
         LW,11    POINTER
UNDER1   BAL,15   CLEARLWJ
         M:KEYIN  (MESS,NEWUNDR),(REPLY,LWJ),(SIZE,11),(ECB,ECB)
         LI,4     BA(LWJ)
         LI,5     13*4
         M:CHECKECB (ECB,ECB)
         LB,3     LWJ
         LI,7     C' '
         STB,7    LWJ,3
         CI,3     1
         BE       DO$CAL
         STB,3    5
         MTW,-1   3
         STB,3    LWJ
         MBS,4    0
         MTB,3    *11,2
         PSW,13   POINTER
         PSW,14   POINTER
         PSW,15   POINTER
         BDR,8    UNDER1
         B        DO$CAL
WRITE    LW,11    =X'06000010'
         B        COMMON
READ     LW,11    =X'05000010'
         B        COMMON
COMMON   LI,2     2
         LI,8     8
         PSW,11   POINTER
         LW,11    POINTER
COMMON1  BAL,15   CLEARLWJ
         M:KEYIN  (MESS,NEWACCT),(REPLY,LWJ),(SIZE,9),(ECB,ECB)
         LI,5     14*4
         LI,4     BA(LWJ)
         M:CHECKECB (ECB,ECB)
         LB,3     LWJ
         LI,7     C' '
         STB,7    LWJ,3
         MTW,-1   3
         BEZ      DO$CAL
         LI,3     8
         STB,3    5
         MBS,4    1
         PSW,14   POINTER
         PSW,15   POINTER
         MTB,2    *11,2
         BDR,8    COMMON1
DO$CAL   EQU      $
         LI,2     2
         LB,1     *11,2
         AI,2     1
         LB,2     *11,2
         SW,2     1
         MSP,2    POINTER
         BAL,15   CLEARLWJ
         M:KEYIN  (MESS,MOREATTR),(REPLY,LWJ),(SIZE,3),(ECB,ECB)
         LI,2     1
         M:CHECKECB (ECB,ECB)
         LB,1     LWJ,2
         CI,1     C'Y'
         BE       ASK
         MTB,1    *11,2
         CAL1,1   *SAVEPAGE
DO$CAL$1 LI,2     1
         LCH,1    POINTER+1,2
         MSP,1    POINTER
         M:FCP    1
         LI,14    0
         BAL,15   SETUP
         LCI      0
         LM,0     SAVEREGS
         B        *15
NOPAGE   M:TYPE   (MESS,MESS1)
         B        $-4
CLEARLWJ LW,0     =C'    '
         LI,1     BA(LWJ)
         LI,10    24
         STB,10   1
         MBS,0    0
         B        *15
         CSECT    0
POINTER  RES      1
         DATA,2   512,0
LWJ      RES      6
CLOSEFPT EQU      $
         GEN,8,24 X'15',F:1

SAVEREGS RES      16
WHATATTR TEXTC    'ATTRIBUTE TO MODIFY: '
MOREATTR TEXTC    'MORE ATTRIBUTES TO CHANGE (Y/N)?'
NEWUNDR  TEXTC    'ENTER PROCESSOR NAME: '
NEWPASS  TEXTC    'ENTER NEW PASSWORD: '
NEWNAME  TEXTC    'ENTER NEW FILENAME: '
NEWACCT  TEXTC    'ENTER ACCOUNT: '
ECB      DATA     0
MESS1    TEXTC    'NO CORE AVAILABLE TO MODIFY ATTRIBUTES'
SAVEPAGE RES      1
         END

