         SYSTEM   SIG7P
         DEF      PTRP,PTRPCU
         REF      DCT3,NB31TO0,M16
         REF      COMLIST,RE:ENT,IOSERCK,IOSCU
:DOT     COM,8,8,8,8 BA(AF(1))-BA(DOT),AF(2),AF(3),AF(4)
:CLST    COM,8    DA(AF(1))-DA(DOT)
:CDW     COM,8,24,8,1,15,8 AF(1),AF(2),AF(3),1,AF(4),AF(5)
XEF      EQU      NB31TO0+5
LD       EQU      2                 LOST DATA TYC
PTRP     BAL,10   COMLIST           BUILD CLIST AND GO TO IOSST
DOT      SET      %
         :DOT     RDS,4,0,0         0 => READ BIN
         :DOT     PU,4,1,1          1 => WRITE BCD
         DATA     0                 2 DOESNT EXIST
         :DOT     PU,4,3,3          3 => WRITE BIN
         :DOT     RDI,4,4,4         4 => READ DRC (BIN OR BCD)
         :DOT     PU,4,5,5          5 => WRITE DRC (BIN OR BCD)
         DATA     0                 6 DOESNT EXIST
         DATA     0                 7 DOESNT EXIST
         :DOT     RDS,4,8,8         8 => READ BCD
PU       :CLST    PUCDW
RDI      :CLST    RDICDW
RDS      :CLST    RDSCDW
         BOUND    8
PUCDW    :CDW     X'01',0,X'1E',2,0
RDICDW   :CDW     X'82',0,X'1E',2,0
RDSCDW   :CDW     X'02',0,X'1E',2,0
PTRPCU   BAL,0    RE:ENT            RE-ENTRANCE TEST
         LB,6     DCT3,1            RESET TIMEOUT
         AND,6    XEF               TO KILL MESSAGE TO OC
         STB,6    DCT3,1            FROM IOSERCK
         WD,0     X'27'             ****ENABLE****
         BAL,9    IOSERCK           GENERAL ERROR CHECK
         B        IOSCU             ERROR, HANDLE IN GENERAL WAY
         AND,11   M16               TEST THE REMAINING BYTE COUNT
         BE       IOSCU             NORMAL TYC
         LI,12    LD                RBC NON-ZERO => TIMEOUT AT REEL END
         B        IOSCU             WHICH WE WILL CALL LOST DATA
PTRPSZ   EQU      %-PTRP
         END
