         SYSTEM   SIG7FDP
D        RES      0
S        CSECT    1
         CAL1,2   PK
         USECT    D
PK       DATA     X'4000000',X'F0000000',P,P,3,P
P        TEXTC    'DEVICE ADDRESS (NDD)='
         USECT    S
         LB,3     P
         CI,3     3
         BNE      X
         LW,2     P
         CAL1,6   SYS
         USECT    D
SYS      DATA     X'8000000'
         USECT    S
         REF      DCT16
         REF      MASKS,AVRTBLSIZ,AVRTBLNE
         LW,3     MASKS+24
         LI,1     DCTSIZ+DCTSIZ+1
         REF      DCTSIZ
         CS,2     DCT16,1
         BE       %+3
         BDR,1    %-2
         B        X
         SLS,1    -1
         CI,1     BATAPE+AVRTBLSIZ
         BL       X
         CI,1     BATAPE+AVRTBLNE
         BGE      X
         REF      AVRTBL,BATAPE
         LD,2     AVRTBL-BATAPE-BATAPE,1
         LC       3
         BCS,10   X
         AI,2     0
         BNEZ     X
         STS,1    R
         CAL1,2   CY
         USECT    D
CY       DATA     X'4000000',X'F0000000',CM,CM,3,CM
CM       TEXTC    'CYLINDER SIZE ='
         USECT    S
         REF      HGP,DCT22,DISCLIMS
         INT,7    3                 GET HGP DISP
         AI,7     HGP
         LI,2     X'80001'
         LI,3     0                 START AT ZERO
         LB,4     CM,2
         AI,4     -'0'
         BLZ      %+4
         MI,3     10
         AW,3     4
         BIR,2    %-5
         CI,3     255
         BG       X
         BANZ     %+3
         LI,2     7                 GET DEFAULT CYL SIZ
         LB,3     *7,2
         LB,4     DCT22,1           FIGURE # CYLS
         LW,5     DISCLIMS,4        # SECTORS
         SLS,5    -1
         DW,5     3                 ROUND DOWN
         AI,5     31
         SLD,4    27                #WORDS BIT MAP
         STB,5    4                 ZAP GARBAGE
         CW,4     4,7               WILL IT FIT
         BLE      %+2
         CAL1,2   BV
         USECT    D
BV       DATA     X'2000000',X'80000000',BM
BM       TEXTC    'WARNING: BAD VTOC'
         USECT    S
         STW,4    VTOC+4
         STH,3    VTOC+4
         AWM,4    VTOC+3
         SLS,5    -27               FIGURE WHAT LAST WORD IS
         LCW,5    5
         LI,4     -1
         SLS,4    31,5
         LW,5     VTOC+3
         CI,5     511
         BGE      X
         STW,4    VTOC-1,5
         MTW,1    VTOC,5
         LI,4     -3                NOW SET FIRST WORD AND NGAVAL
         LI,5     -1
         SLS,5    -1
         AH,4     VTOC+4
         CI,4     27
         BL       %-3               MUST HAVE AT LEAST 30 GRANS
         STW,5    VTOC+7
         STB,4    NGV
         CAL1,2   SK
         USECT    D
SK       DATA     X'4000000',X'F0000000',SN,SN,4,SN
SN       TEXTC    'SERIAL NUMBER ='
         USECT    S
         LB,3     SN
         LM,4     SN
         SLD,4    8
         LI,2     5
         LI,5     64
         AI,3     -1
         BEZ      X
         CB,5     4,3
         BLE      %+2
         STB,5    4,3
         AI,3     1
         BDR,2    %-2
         STW,4    VTOC+1
         CAL1,2   AK
         USECT    D
AK       DATA     X'4000000',X'F0000000',A,A,8,A
A        TEXTC    'ACCOUNT ='
         USECT    S
         LB,3     A
         BDR,3    %+2
         B        S1
         LM,4     A
         SLD,4    8
         LB,6     A+2
         AW,5     6
         LI,2     9
         LI,6     64
         CB,6     4,3
         BLE      %+2
         STB,6    4,3
         AI,3     1
         BDR,2    %-2
         STD,4    ACND+4
         USECT    D
R        DATA     X'1FF0A00',BA(VTOC),2048*3,0,0,0
         USECT    S
S1       LCI      6
         LM,12    R
         REF      NEWQ
         BAL,11   NEWQ
         B        X
         CAL1,9   1
X        CAL1,2   X2
         CAL1,9   1
X2       DATA     X'2000000',X'80000000',X1
X1       TEXTC    'INITVOL ABORTED'
         USECT    D
         BOUND    8
VTOC     TEXT     ':LBL        '
         DATA     7,13,X'7FFFFFFC',X'70000'
         DATA     X'7FFFFFFF'
         DO1      504
         DATA     -1
ACND     DATA     0,0,X'21000C',X'B404040',0,0,X'10004',X'600',0
         ORG      ACND+256
         DATA     0,0,X'740000',X'1000000'
         RES      7
         DATA     X'A000202','1111','  74'
         DATA     X'D000101',0
         DATA     X'C000707',0,0,0,0,0,0,0
         DATA     X'9010303',0,0,0
         ORG      ACND+512
         DATA     0,0,X'354020',X'1000000'
         RES      7
         DATA     X'10003',X'600',0
         ORG      ACND+512+512-3
NGV      DATA     X'1B010006',0,0
         END      S
