SUBROUTINE LOADIT
C
C	PURPOSE: CALLED WHEN IN "PROGRAMMING" MODE ("STATE">0).
C	 GIVEN INTERNALLY CODED COMMAND IN /COMAND/ COMMON,
C	 LOADIT EITHER EXECUTES SPECIAL "PROGRAMMING" MODE FUNCTIONS-
C	 CLPRGM,SST,BST,DEL,INS,GTO.n,SAVEfilespec-OR LOADS COMMAND
C	 INTO PROGRAM MEMORY.
C
C	NOTE: FOLLOWING COMMAND CODES ARE ASSUMED TO REPRESENT CORRESPONDING
C	 FUNCTIONS--
C		CODE#		COMMAND
C
C		-20		CLPRGM
C		-19		BST
C		-18		DEL
C		-17		INS
C		-16		RUN
C		 -5		SST
C		  0		R/S
C		 64		GTO.n
C		125		SAVEfilespec
C
C	SUBROUTINES REQUIRED:
C	 RECODE	-REGENERATES ASCII CHARACTER STRING THAT RESULTED IN CODED
C		COMMAND CURRENTLY IN /COMAND/ COMMON "CMND".
C	 DELETE	-REMOVES PROGRAM STEP AT CURRENT PROGRAM COUNTER FROM
C	 	PROGRAM MEMORY.
C	 INSERT	-INSERTS "NOP" INSTRUCTION AT CURRENT PROGRAM COUNTER, PUSHING
C		ALL OTHER PROGRAM STEPS DOWN IN MEMORY.
C	 REPLCE	-REPLACES COMMAND CURRENTLY POINTED TO BY PC WITH COMMAND
C		STORED IN /COMAND/ COMMON "CMND".
C	 STEPPC	-INCREMENTS PC TO NEXT SEQUENTIAL STEP IN PROGRAM MEMORY
C		BASED ON INTERNAL TABLE OF # BYTES EACH COMMAND REQUIRES
C		FOR STORAGE IN /MEMORY/ COMMON.
C
C
C	SORENSON 2/81
C
	COMMON/UNIT/LUNCMD,LUNOUT,LUNTI,LUNFIL
	COMMON/COMAND/LENGTH,CMND(40)
	BYTE CMND
	COMMON/MEMORY/PC,P(1000)
	BYTE P
	INTEGER PC
	COMMON/FLAGS/STATE,ERROR,STKLFT,NEST,ANGLES,DIGITS,RADIX,FLAG(4)
	BYTE STATE,ERROR,STKLFT,NEST,ANGLES,DIGITS,RADIX,FLAG
	BYTE INT(2)
	EQUIVALENCE (INT,ITEMP)
	DATA NSTEPS/1000/
C
C	FIRST OF ALL, SHOULDN'T EVEN BE HERE IF "STATE" </= 0
C
	IF(STATE.LE.0)RETURN
C
C	START BY TRYING TO INTERCEPT ANY SPECIAL FUNCTION CODES.
C
	I=0
	IF(CMND(1).EQ.125)I=8
	IF(CMND(1).EQ.64)I=7
	IF(CMND(1).EQ.-5)I=6
	IF(CMND(1).GE.-20.AND.CMND(1).LE.-16)I=CMND(1)+21
	IF(I.NE.0)GO TO 20
C
C	NO SPECIAL FUNCTION, TRY AND LOAD MEMORY BY REPLACING CURRENT
C	PROGRAM STEP.  SUBROUTINE REPLCE WILL TAKE CARE OF ERROR FLAGGING
C	IF ANYTHING GOES WRONG.
C
	CALL REPLCE
	RETURN
C
C	"PROGRAMMING" FUNCTIONS; MAKE SURE IN CORRECT "STATE"; ELSE
C	FLAG ILLEGAL COMMAND WITH ERROR -2
C
20	IF(STATE.EQ.1)GO TO 25
	ERROR=-2
	RETURN
25	GO TO (30,40,50,60,70,80,90,100),I
C
C	CLEAR PROGRAM MEMORY--PUT IN ALL "R/S" COMMANDS
C
30	DO 31 I=1,NSTEPS
31	P(I)=0
	PC=1
	RETURN
C
C	BACKSTEP PROGRAM
C
40	LASTPC=PC
	PC=1
	ITEMP=1
	DO 44 I=1,NSTEPS
	CALL STEPPC
	IF(PC.GE.LASTPC)GO TO 48
44	ITEMP=PC
48	PC=ITEMP
	RETURN
C
C	INSERT "NOP" INSTRUCTION INTO MEMORY; INSERT WILL FLAG ANY ERRORS
C
50	CALL DELETE
	RETURN
C
C	DELETE CURRENT PROGRAM STEP
C
60	CALL INSERT
	RETURN
C
C	SET TO "RUN" MODE
C
70	STATE=0
	RETURN
C
C	SINGLE STEP PROGRAM
C
80	CALL STEPPC
	RETURN
C
C	GO TO ABSOLUTE PROGRAM STEP # N; DON'T ALLOW -VE N, NOR ALLOW
C	PROGRAM COUNTER TO GO BEYOND CURRENT LIMIT TO # STEPS
C
90	PC=1
	INT(1)=CMND(2)
	INT(2)=CMND(3)
	IF(ITEMP.LE.1)GO TO 99
95	DO 97 I=1,ITEMP-1
	LASTPC=PC
	CALL STEPPC
C
C	STEPPC WILL RESET PC TO 1 WHEN OVER STEP PROGRAM BOUNDS
C
	IF(PC.EQ.1)GO TO 98
97	CONTINUE
	GO TO 99
98	PC=LASTPC
99	RETURN
C
C	SAVE CURRENT PROGRAM MEMORY CONTENTS TO FILE.  FIRST, FIND LAST
C	NON-R/S COMMAND SO WON'T SAVE A "NULL PROGRAM" OR 900+ LINES OF
C	R/S's.
C
100	PC=1
	LASTPC=1
110	DO 115 I=1,NSTEPS
	CALL STEPPC
C
C	STEPPC WILL RESET PC=1 IF OVER STEP PROGRAM BOUNDS
C
	IF(PC.EQ.1)GO TO 120
	IF(P(PC).NE.0)LASTPC=PC
115	CONTINUE
120	IF(LASTPC.GT.1)GO TO 125
	WRITE(LUNTI,122)
122	FORMAT(' No program steps to save.')
	GO TO 145
C
C	OPEN FILE ON UNIT # LUNFIL--FILE SPECIFICATION INCLUDED WITH
C	SAVE COMMAND STARTING AT CMND(3) WITH CMND(2) CHARACTERS.
C	MAKE FILENAME ASCIZ PRIOR TO TRYING TO OPEN IT.
C
125	I=CMND(2)
	CMND(I+3)=0
	OPEN(UNIT=LUNFIL,NAME=CMND(3),CARRIAGECONTROL='LIST',
	1TYPE='NEW',ERR=900)
C
C	NOW LOAD "CMND" WITH EACH CODED COMMAND.  CALL RECODE
C	TO REGENERATE ASCII COMMAND LINE, AND WRITE IT OUT.  CONTINUE
C	UNTIL PASS LAST NON-R/S, AND INCLUDE TRAILING R/S IN OUTPUT.
C
130	LASTPC=LASTPC+1
	PC=1
132	ITEMP=PC
	CALL STEPPC
	J=1
	DO 135 I=ITEMP,PC-1
	CMND(J)=P(I)
135	J=J+1
C
C	SIGNAL RECODE THAT COMMAND IN INTERNAL FORM BY NEGATING BYTE COUNT
C
	LENGTH=-(PC-ITEMP)
	CALL RECODE
	IF(LENGTH.GT.0)WRITE(LUNFIL,139,ERR=900)(CMND(I),I=1,LENGTH)
139	FORMAT(40A1)
D	IF(LENGTH.GT.0)WRITE(LUNTI,1000)LENGTH,(CMND(I),I=1,LENGTH)
D1000	FORMAT(' LENGTH = ',I5/' RECODED COMMAND = ',40A1)
	IF(PC.LE.LASTPC)GO TO 132
	CLOSE(UNIT=LUNFIL)
145	PC=1
	RETURN
C
C	ERROR ON SAVING PROGRAM
C
900	PC=1
	WRITE(LUNTI,902)
902	FORMAT(' Unexpected error saving program.')
	RETURN
	END