.TITLE	ATINIT - ACTIVE TASKS INITIALIZATION
	.IDENT	/V01/
	.NLIST	BEX
;
; COPYRIGHT (C) 1979, 1980 BY
; DIGITAL EQUIPMENT CORPORATION, MAYNARD, MASS.
;
;
; THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY BE USED AND  COPIED
; ONLY  IN  ACCORDANCE  WITH  THE  TERMS  OF  SUCH  LICENSE AND WITH THE
; INCLUSION OF THE ABOVE COPYRIGHT NOTICE.  THIS SOFTWARE OR  ANY  OTHER
; COPIES  THEREOF MAY NOT BE PROVIDED OR OTHERWISE MADE AVAILABLE TO ANY
; OTHER PERSON.  NO TITLE TO AND OWNERSHIP OF  THE  SOFTWARE  IS  HEREBY
; TRANSFERRED.
;
; THE INFORMATION IN THIS SOFTWARE IS SUBJECT TO CHANGE  WITHOUT  NOTICE
; AND  SHOULD  NOT  BE  CONSTRUED  AS  A COMMITMENT BY DIGITAL EQUIPMENT
; CORPORATION.
;
; DIGITAL ASSUMES NO RESPONSIBILITY FOR THE USE OR  RELIABILITY  OF  ITS
; SOFTWARE ON EQUIPMENT WHICH IS NOT SUPPLIED BY DIGITAL.
;
;
; MODULE DESCRIPTION:
;
;	INITIAL PROCESSING FOR DISPLAYING ACTIVE TASK LIST
;
;
;
; DISTRIBUTED SYSTEMS SOFTWARE ENGINEERING
;
; IDENT HISTORY:
;
; 1.00	03-MAR-80
;

	.SBTTL	ENTRY POINT DEFINITION

                                        
	.PSECT	INIT,OVR,I,LCL

	.WORD	INIT		; ENTRY ADDRESS (FIRST WORD)


	.SBTTL	LOCAL MACROS

;
; INDICATE CHARACTER HAS CHANGED SINCE LAST DISPLAY
;
	.MACRO	FLAG,DD
	BISB	#200,DD
	.ENDM


	.SBTTL	HEADER TEXT STRINGS

	.IF 	DF,R$$MPL

HEADER:	.ASCIZ	/RSX-11M-PLUS V01 BL/

	.IFF

HEADER:	.ASCIZ	/RSX-11M V3.2 BL/

	.ENDC

IDSTRG:	.ASCIZ	/            /		; EXTRA SPACE FOR BASE LEVEL STRING

	.ENABL	LC
INITXT:	.ASCIZ	* Name  Length TI    Pri  I/O  Status flags*
	.DSABL	LC
	.EVEN

	.SBTTL	ENTRY POINT

;+
;
; INIT - SET UP HEADER TEXT FOR ACTIVE TASK LIST INFORMATION
;
; INPUTS: NONE
;
; OUTPUTS: HEADER TEXT IS DISPLAYED ON TI:
;
;-

INIT:	CALL	$CLEAR		; CLEAR THE SCREEN
	MOV	#HEADER,R1	; GET ADDRESS OF HEADER TEXT
	MOV	$ATHDR,R0	; GET ADDRESS TO STORE HEADER
10$:	MOVB	(R1)+,(R0)+	; STORE IT
	BNE	10$		; ...
	DEC	R0		; DON'T DISPLAY NULL
	MOV	#$SYSID,R1	; STORE THE SYSTEM ID
	MOVB	(R1)+,(R0)+	; ...
	MOVB	(R1)+,(R0)+	; ...
	MOVB	(R1)+,(R0)+	; ...
	MOVB	(R1)+,(R0)+	; ...
	MOV	$SYSIZ,R1	; STORE THE SYSTEM SIZE
	.REPT	5
	ASR	R1
	.ENDR
	CLR	R2		; ZERO SUPPRESSION
	CALL	$CBDMG		; CONVERT BINARY TO ASCII
	MOVB	#'K,(R0)+	; 
	MOV	#INITXT,R1	; STORE THE HEADER FOR THE ACTIVE TASK LIST
	MOV	$ATINI,R0	; GET ADDRESS TO STORE HEADER
20$:	MOVB	(R1)+,(R0)+	; STORE IT
	BNE	20$		; ...
	MOVB	#40,-(R0)	; REPLACE NULL WITH A SPACE
	CALL	$HOME		; START UPDATE AT HOME POSITION
;
; NOW FLAG ALL AS NEW CHARS
;
FLAG:	MOV	#$SCRN,R1	; BEGINNING OF SCREEN BUFFER
	MOV	#$ESCRN,R2	; END OF SCREEN BUFFER
10$:	CMP	R1,R2		; AT END
	BHIS	20$
	CMPB	#40,(R1)+	; SCREEN WAS ALL BLANKS
	BEQ	10$
	FLAG	-1(R1)		; FLAG AS CHANGED
	BR	10$

20$:	RETURN
	.END