	.title	stddir
	.globl	stddir, .ascpp, .wdfui, .wdfdr
;
;	implements the following fortran subroutine call
;
;	call stddir(dsc)
;
;		where dsc is a descriptor pointing to the directory string
;
defdir:	.blkb	10.
defuic:	.blkw	1			; word to hold binary value of uic
stddir::
	mov	2(r5),r0		; address of descriptor in r0
	mov	(r0),r1			; count in r1
	mov	2(r0),r2		; address of string in r2
	mov	#defdir,r3		; destination address in r3
10$:
	movb	(r2)+,(r3)+		; copy byte into buffer
	sob	r1,10$
	mov	(r0),r1			; count in r1
	mov	#defdir,r2		; address of string in r2
	call	.wdfdr			; write default directory
	mov	2(r5),r2		; address of descriptor in r2
	mov	#defuic,r3		; address to hold binary
	call	.ascpp			; convert it to binary in r3
	mov	defuic,r1		; binary value in r1 for .wdfui
	call	.wdfui			; reset default uic value
	return
	.end
