.TITLE	STROUT- CHARACTER STRING OUTPUT
	.IDENT	/18NOV7/	;16:45, MK
;	.ENTRY	STROUT - CHARACTER STRING OUTPUT
;+
; S T R O U T
;
; PURPOSE:	BASIC CHARACTER STRING OUTPUT - PART OF
;		TEKTRONIX 4010 PLOTTING PACKAGE
;
; INTERFACE:	CALLING SEQUENCE:
;			CALL STROUT
;			
;		INPUT:	R0	LOCATION OF NEXT CHARACTER IN OUTPUT
;				BUFFER
;
;			2(R5)	LOCATION OF STRING OF CHARACTERS TO
;				BE OUTPUT
;
;			@4(R5)	NUMBER OF CHARACTERS TO BE OUTPUT
;
;			ASTS MUST BE INHIBITED.
;
; METHOD:	THE CHARACTERS ARE MOVED INTO THE OUTPUT BUFFER, BUT
;		ARE NOT SENT TO THE TERMINAL.  A CALL TO CHO WILL
;		SEND THEM TO THE TERMINAL.  THE ASCII CODES ESC, FS,
;		GS, RS, AND US ARE SKIPPED IF ENCOUNTERED, AND NOT
;		MOVED INTO THE BUFFER.
;			
; LANGUAGE:	MACRO-11
;
; RESTRICTIONS:	NOT FORTRAN-CALLABLE.  THIS ROUTINE IS INTERNAL TO THE
;		PLOTTING PACKAGE (RS4010) AND IS NOT INTENDED FOR
;		GENERAL USE.
;-
; REVISIONS:	
; 		MM/MK	WRITTEN
; 26-JAN-77	NS	ADD HEADER INFORMATION.
; 31-MAY-77	EM	UPDATED TO CONFORM TO STANDARDS.
; 18-NOV-77	MK	CORRECT DOCUMENTATION
;	
STROUT::
	MOV	2(R5),R1	;GET LOC OF LINE
	MOV	@4(R5),R2	;GET VALUE N
1$:	MOVB	(R1)+,R3	;GET CHAR
	CMP	R3,#US		;>US
	BHI	2$		;(YES)
	CMP	R3,#ESC		;=>ESC AND =<US
	BHIS	3$		;YES - DON'T OUTPUT
2$:	MOVB	R3,(R0)+	;PUT IN STRING
3$:	DEC	R2
	BGT	1$		;LOOP BACK IF MORE
	RTS	PC
	.END