.TITLE	LOGMSG - OUTPUT A MSG TO DAYFILE IN SPECIFIED COLOR
	.IDENT	/04MAY7/	;10:20:00, EM
;	.ENTRY	LOGMSG - OUTPUT A MESSAGE TO DAYFILE
;+
; L O G M S G
;
; PURPOSE:	OUTPUT A MESSAGE TO DAYFILE IN SPECIFIED COLOR
;
; INTERFACE:	CALLING SEQUENCE  (FORTRAN-CALLABLE SUBROUTINE)
;			CALL LOGMSG(LUN,NCHAR,MSG,COLOR,DST)
;
;		INPUT:	LUN=LOGICAL UNIT NMBER ALREADY ASSIGNED TO LO 		
;				(INTEGER)
;			NCHAR=NUMBER OF CHARACTERS IN MESSAGE (INTEGER)
;			MSG=TEXT OF MESSAGE (BYTES)
;			COLOR=COLOR CODE (INTEGER)--
;				0=WHITE, 1=TURQUOISE, 2=PINK, 3=DARK BLUE,
;				4=YELLOW, 5=GREEN, 6=RED
;			DST=DESTINATION CODE (INTEGER)
;				1=DISK, 2=SCOPE, 3=BOTH
;
;		THIS SUBROUTINE USES EVENT FLAG 24. TO DETECT I/O
;		COMPLETION.
;
; LANGUAGE:	MACRO-11
;
; RESTRICTIONS:	THIS ROUTINE IS USABLE ONLY ON THOSE SYSTEMS
;		WHICH HAVE A KINETICS SYSTEMS COLOR CHARACTER
;		SCOPE AND THE RSX HANDLERS LO.... AND KS....
;-
; REVISIONS:
; 02-SEP-76	SS	WRITTEN
; 04-MAY-77	EM	UPDATED TO CONFORM TO STANDARDS
;
	.MCALL QIO$,DIR$,WTSE$C
;
LOGMSG::
	MOV	@2(R5),QIO+Q.IOLU
	MOV	@4(R5),QIO+Q.IOPL+2
	MOV	6(R5),QIO+Q.IOPL
	MOV	@10(R5),QIO+Q.IOPL+6
	MOV	@12(R5),QIO+Q.IOPL+4
	DIR$	#QIO		;OUTPUT MESSAGE
	TST	$DSW		;DID DIRECTIVE GO?
	BPL	20$		;BRANCH IF YES
	RETURN
20$:	WTSE$C	24.
	RETURN
;DPB FOR QIO
QIO:	QIO$	IO.WLB,0,24.,,,,<0,0,0,0,0,0>
.END