.TITLE	HISTCA - CLEAR ALL HISTOGRAMS ROUTINE
	.IDENT	/04MAY7/	;14:10:00, EM
;	.ENTRY	HISTCA - CLEAR ALL HISTOGRAMS ROUTINE
;+
;
; H I S T C A
;
; PURPOSE:	THIS ROUTINE CLEARS ALL HISTOGRAMS BELONGING TO A
;		GIVEN OWNER TO ZERO.
;
; INTERFACE:	CALLING SEQUENCE: (FORTRAN-CALLABLE SUBROUTINE)
;			CALL HISTCA(IOWNER)
;
;		INPUT:	IOWNER (INTEGER): HISTOGRAM OWNER
;
;		EVENT FLAG 23. IS USED BY THIS SUBROUTINE.
;
; LANGUAGE:	MACRO-11
;
; REFERENCES:	"HISTOGRAMMING AND HISTOGRAM PLOTTING"
;		SEE SUBROUTINE HISTSU FOR DESCRIPTION OF
;		HISTOGRAM OWNER FORMAT.
;-
; REVISIONS:	
; 03-JUN-75	MK	WRITTEN
; 02-FEB-77	NS	CHANGE NAMES OF GLOBALS IN HCOM1 TO AVOID
;			USER CONFLICTS
;			ENABL=H.ENBL, HDBCHN=H.DBCH
; 04-MAY-77	EM	UPDATED TO CONFORM TO STANDARDS
;
HISTCA::
	TST	H.ENBL		;PACKAGE ENABLED?
	BEQ	4$		;NO
	CALL	HST$LK		;LOCK HDBS
	MOV	H.DBCH,R3	;GET FIRST HDB IN CHAIN
	BEQ	3$		;NO CHAIN
1$:	CMP	@2(R5),HDB.OW(R3) ;DOES IT BELONG TO THIS OWNER?
	BNE	2$		;NO
	CALL	HST$CL		;CLEAR HISTOGRAM
2$:	MOV	(R3),R3		;GET NEXT HDB IN CHAIN
	BNE	1$
3$:	CALL	HST$UN		;UNLOCK HDBS
4$:	RETURN
	.END