.TITLE	ENDPLT - END PLOT ROUTINE
	.IDENT	/18NOV7/	;16:30, MK
;	.ENTRY	ENDPLT - END PLOT ROUTINE
;+
; E N D P L T
;
; PURPOSE:	END PLOT ROUTINE - PART OF TEKTRONIX PLOTTING
;		PACKAGE. HOMES CURSOR AND ENTERS ALPHANUMERIC
;		MODE. THIS ROUTINE SHOULD BE CALLED TO TERMINATE
;		GRAPHICS OUTPUT TO ALLOW THE TERMINAL TO "REST"
;		AND PREVENT SCREEN BURN-IN.
;
; INTERFACE:	CALLING SEQUENCE:    (FORTRAN-CALLABLE SUBROUTINE)
;			CALL ENDPLT
;
; LANGUAGE:	MACRO-11
;-
;
; REVISIONS:
;		MM/MK	WRITTEN
; 26-JAN-77	NS	ADD HEADER RECORD
; 06-MAY-77	LV	UPDATED TO CONFORM TO STANDARDS
; 18-NOV-77	MK	ADD CALL TO IHAR$S MACRO
;
	.MCALL	PUSH,POP,IHAR$S
ENDPLT::PUSH	<R0,R1,R2>
	MOV	#ARG1,R5	;SETUP TPLOT CALLING SEQUENCE
	JSR	PC,TPLOT	;HOME CURSOR - DARK VECTOR TO 0,767
	IHAR$S			;INHIBIT AST'S
	MOV	CH.IN,R0	;GET ADDRESS IN BUFFER
	MOVB	#US,(R0)+	;ENTER ALPHA TERMINAL MODE
	CLR	CH.MOD
	JSR	PC,CHO
	POP	<R2,R1,R0>
	RTS	PC
;
ARG1:	.BYTE	3,0		;CALLING SEQUENCE FOR TPLOT
	.WORD	1$
	.WORD	2$
	.WORD	3$
;
1$:	.WORD	0		;MODE = DARK VECTOR
2$:	.WORD	0		;IX = 0
3$:	.WORD	^D767		;IY = 767.
	.END