/PROGRAM TO PRINT MAXIMUM AND MINIMUM MEMORY
/ADDRESSES LOADED FROM A BIN FORMAT PAPER TAPE.
/BY JOHN WILSON 05-MAY-84.
*0
	JMP I .+1
	200		/SKIP TO PAGE 1
MAX,	0
MIN,	7777
ADDR,	0
CHAR,	0
	PAGE
	RFC		/CLR BUF AND READ A CHAR
	JMP LEAD+2	/JUMP INTO LOOP
LEAD,	CLA
	RRB		/GET CHAR INTO AC
	DCA CHAR	/SAVE
	TAD CHAR	/RESTORE
	AND (200	/TRAILER?
	SZA		/NO, SKIP
	JMP LEAD	/YES, LOOP
	JMP LOOP+2	/JUMP INTO LOOP
LOOP,	RRB		/GET CHAR
	DCA CHAR	/SAVE
	TAD CHAR
	AND (200	/TRAILER?
	SZA
	JMP EXIT	/YES, PRINT RESULTS AND EXIT
	TAD CHAR
	AND (100	/ORIGIN?
	SNA
	JMP DATA	/NO, MUST BE DATA
	CLA
	TAD CHAR
	RTL		/MOVE TO HIGH BYTE
	RTL
	RTL
	AND (7700	/MASK OUT BOTTOM BYTE
	DCA CHAR	/SAVE
	RRB		/READ LOW BYTE
	TAD CHAR	/ADD IN HIGH BYTE
	DCA ADDR	/RESET CURRENT ADDRESS
	JMP LOOP	/DO NEXT CHAR
DATA,	RRB		/IGNORE NEXT CHAR
	RRB		/SEE IF THIS WAS CHECKSUM
	DCA CHAR
	TAD CHAR
	AND (200	/NEXT CHAR TRAILER?
	SZA		/SKIP IF NOT
	JMP EXIT	/YES, EXIT
	TAD ADDR
	CIA		/AC=-(ADDR)
	TAD MIN		/LINK SET IF (ADDR)<(MIN)
	SNL		/ADDR IS A NEW MIN
	JMP DATA1	/ADDR>=MIN
	CLA
	TAD ADDR	/REPLACE MIN WITH ADDR
	DCA MIN
DATA1,	CLA
	TAD ADDR
	CIA		/AC=-(ADDR)
	TAD MAX		/LINK CLEAR IF (ADDR)>(MAX)
	SZL		/ADDR IS A NEW MAX
	JMP DATA2	/ADDR<=MAX
	CLA
	TAD ADDR	/REPLACE MAX WITH ADDR
	DCA MAX
DATA2,	ISZ ADDR	/UPDATE ADDR
	NOP		/SKIPS ARE OKAY
	CLA
	JMP LOOP+2	/JUMP BACK INTO LOOP
EXIT,	HLT		/FOR NOW, MAX,MIN,ADDR IN 2,3,4
/
$