************************************************************                    
*                                                          *                    
*                                                          *                    
*        K E Y - I N   P A R T   F O U R                  *                     
*                                                          *                    
*                                                          *                    
************************************************************                    
         PCC      0                                                             
         SYSTEM   SIG5P                                                         
         SYSTEM   OPTIONS                                                       
         DEF      A:KEY4                                                        
         DEF      KEY4EXB                                                       
         DEF      KEY4A04                                                       
OLAYFLAG EQU      'KEY4'                                                        
         SYSTEM   CPRMON                                                        
*                                                                               
*                                                                               
         TITLE    '** KEY4 - CONTROL SECTION **'                                
*                                   RUNS UNDER RBM CONTROL TASK AS AN           
*                                   OVERLAY.                                    
*                                                                               
*        AT ENTRY,                                                              
*        R2=KEYIN INDEX                                                         
*        R6=SCAN RETURN CODE FROM FIRST SCAN CALL                               
*        R7=KEYIN TEXT POINTERS AS REQUIRED FOR SCAN ROUTINE                    
*                                                                               
KEY4     RES      0                                                             
A:KEY4   EQU      KEY4                                                          
*                                   ENTER HERE FOR PART 2 OF KEY-IN OLAY        
A01      RES      0                 ENTRY FOR THIS OVERLAY                      
         PUSH     R7                SAVE INDEX INTO KEYIN BUFFER                
         LI,R7    31                GET TSPACE FOR FPTS                         
         BAL,R8   GETTEMP                                                       
         B        KEY4NOTS          NO TSPACE. ERROR.                           
         ENABLE                     SPACE FOUND                                 
         LW,R3    R7                KEEP TSACE PTR IN R3                        
         PULL     R7                RESTORE INDEX INTO DEYIN BUFFER             
         PUSH     R3                SAVE TEMP SPACE POINTER FOR EXIT            
         AI,R3    2                 START AT FIRST DW OF T-SPACE                
         LW,R4    A92,R2            MOVE FPT FOR INDICATED KEYIN                
         BEZ      A01A              NO SPACE TO MOVE                            
         LI,R5   20                 NUMBER OF DW TO MOVE                        
MOVFPT   LW,R8    *R4,R5                                                        
         STW,R8   *R3,R5                                                        
         BDR,R5   MOVFPT                                                        
         LW,R8    *R4               GET LAST DW                                 
         STW,R8   *R3               PUT IN TEMP SPACE                           
A01A     LH,R8    A91,R2            GET ADDRESS TO PROCESS KEYIN                
         B        *R8               GO TO PROPER REGUON                         
KEY4NOTS PULL     R7                ERROR EXIT - NO TEMP                        
         B        KEY4A04                                                       
A04      RES      0                 ERROR ENTRY, TYPE 'KEY ERROR'               
         PULL     R7                                                            
         BAL,R8   RELTEMP                                                       
KEY4A04  B        KEY1A04                                                       
*                                                                               
KEY4EXIT RES      0                 NORMAL EXIT                                 
         PULL     R7                                                            
         BAL,R8   RELTEMP           RELEASE TSPACE                              
KEY4EXB  B        CT1               RETURN TO CONTROL TASK                      
*                                                                               
         PAGE                                                                   
A91      EQU      %                                                             
         DO1      #ECB                                                          
         DATA,2   SIGNALK                                                       
         DATA,2   DISPLAY                                                       
         DATA,2   SETNAMEK                                                      
         DO1      #TJE                                                          
         DATA,2   BREAKEY           BREAK                                       
         DATA,2   BMEMK                                                         
         DATA,2   FMEMK                                                         
         DO1      #TJE                                                          
         DATA,2   CONTROLK          CONTROL KEYIN                               
         DATA,2   PAUKEY                                                        
         DATA,2   ATTKEY                                                        
         BOUND    4                                                             
A92      EQU      %                                                             
         DO1      #ECB                                                          
         DATA     SIGFPT                                                        
         DATA     DISFPT                                                        
         DATA     SETNFPT                                                       
         DO1      #TJE                                                          
         DATA     0                 BREAK                                       
         DATA     0                 BMEM                                        
         DATA     0                 FMEM                                        
         DO1      #TJE                                                          
         DATA     0                                                             
         DATA     0                 PAU                                         
         DATA     0                 ATT                                         
#KEYINS  EQU      %-A92             NUMBER OF KEYINS IN THIS OVERLAY            
         BOUND    4                                                             
OLAYSIZ  EQU      512                                                           
*                                                                               
         PAGE                                                                   
*        SUBROUTINE  TO CONVERT BINARY TO HEX GBCDIC                            
*        CALL IS  BAL,R8  HEXBCD                                                
*        WHERE    R11=VALUE TO  CONVERT                                         
*        EXITS    R10,R11=VALUE IN BCD RT. JUST.                                
*        USES     R0,R5,R6,R10,R11                                              
*                                                                               
HEXBCD   LI,R5    -28                                                           
         LI,R6    0                                                             
         LW,R9    R11                                                           
HEXBCD1  LW,R0    R9                                                            
         SLS,R0   0,R5                                                          
         AND,R0   M4                                                            
         AI,R0    X'F0'                                                         
         CI,R0    X'FA'                                                         
         BL       %+2                                                           
         AI,R0    -X'39'                                                        
         STB,R0   R10,R6                                                        
         AI,R6    1                                                             
         AI,R5    4                                                             
         BLEZ     HEXBCD1                                                       
         B        *R8                                                           
         TITLE    '** KEY4 - GET NEXT OPTION SUBROUTINE **'                     
*        ROUTINE TO FETCH NEXT OPTION FOR A KEYIN                               
*        CALL IS                                                                
*                                                                               
*        BAL,R13  GETOPT                                                        
*        GEN,8,24 #OPT,OPTIONLIST   WHERE #OPT IS THE NUMBER OF OPTIONS         
*                                   AVAILABLE FOR THE KEYIN.                    
*                                   OPTIONLIST IS THE ADDRESS OF A              
*                                   DOUBLE WORD TABLE THAT HAS ONE              
*                                   ENTRY PER OPTION AS FOLLOWS:                
*                                                                               
*                                     FIRST WORD:  THE OPTION KEYWORD           
*                                                  IDENTIFIER  IN EBCDIC        
*                                                  LEFT   JUSTIFIED BLANK       
*                                                  FILLED                       
*                                                                               
*                                     SECOND WORD: PARAMETER CONTROL            
*                                     BITS 0-7                                  
*                                        00  NO PARAMETER ALLOWED               
*                                            ON RETURN R8 WILL HAVE             
*                                            THE CONTENTS OF THIS WORD          
*                                                                               
*                                        01  CONVERT TO EBCDIC                  
*                                        02  CONVERT  TO HEX                    
*                                        04  CONVERT  TO DECIMAL                
*                                                                               
*                                        8X  IF  NO PARAMETER - RETURN          
*                                            CONTENTS  OF THIS WORD IN          
*                                            R8.   IF PARAMETER IS PRESENT      
*                                            CONVERT  ACCORDING TO X AND        
*                                            AND  RETURN IT IN R8.  X           
*                                            IS  DESCRIBED ABOVE.               
*        RETURN IS TO CALL LOCATION +(N+2)                                      
*                 WHERE N IS 0 IF ANY ERRORS ARE DETECTED                       
*                 IF NO ERRORS N WILL BE THE INDEX                              
*                 INTO THE OPTION LIST TABLE CORRESPONDING                      
*                 TO THE OPTION BEING PROCESSED.                                
*                                                                               
*        USES REGISTERS:                                                        
*                                                                               
*        R0,R5-R11                                                              
*                                                                               
*        USES SCAN ROUTINE                                                      
*                                                                               
*                                                                               
GETOPT   EQU      %                                                             
         PUSH     4,R1              SAVE R1-R4                                  
         LI,R11   1                                                             
         BAL,R14  SCAN              NEXT CHAR SHOULD BE '('                     
         CI,R6    0                                                             
         BGE      GO02              B IF NO SCAN ERROR                          
GO01     EQU      %                                                             
         AI,R13   1                 TAKE ERROR EXIT                             
         PULL     4,R1                                                          
         B        *R13                                                          
GO02     EQU      %                                                             
         LI,R1    0                 OPTION SEARCH INDEX                         
         LW,R0    *R13              GET ADDRESS OF OPTION LIST                  
GO03     EQU      %                                                             
         LD,R2    *R0,R1            GET OPTION DESCRIPTOR                       
         CW,R8    R2                IS IT THIS OPTION                           
         BE       GO04              B IF YES                                    
         AI,R1    1                 MOVE TO NEXT OPTION                         
         CB,R1    *R13              REACHED LIMIT YET                           
         BL       GO03              B IF NO                                     
         B        GO01              YES -TAKE ERROR EXIT                        
GO04     EQU      %                                                             
         LB,R11   R3                GET CONVERT TYPE                            
         BEZ      GO09              B IF NO PARAMETER                           
         CI,R11   X'80'             IS IT NO PRAMETER OPTION                    
         BANZ     GO010             B IF YES                                    
GO05     RES      0                                                             
         AND,R11  M7                                                            
         BAL,R14  SCAN              GET PARAMETER                               
         CI,R6    0                                                             
         BL       GO01              B IF SCAN ERROR                             
GO07     AI,R13   2                 POINT TO FIRST EXIT                         
         AW,R13   R1                NOW POINT TO CORRECT OPTION EXIT            
         PULL     4,R1                                                          
         B        *R13              RETURN                                      
*                                                                               
GO09     EQU      %                                                             
         LW,R8    R3                GET RETURN PARAMETER                        
         B        GO07                                                          
GO010    EQU      %                                                             
         LW,R8    R3                GET DUMMY PARAMETER                         
         CI,R6    0                                                             
         BG       GO07              B IF END OF PAREN FIELD                     
         B        GO05              PROCESS FIRST OPTION                        
*                                                                               
         TITLE    '** KEY4 - SIGNAL KEY-IN **'                                  
SIGNALK  EQU      %                                                             
         CI,R6    2                                                             
         BE       A04               ERROR IF NO PARAMETERS                      
         LI,R11   1                 SET FOR EBCDIC                              
         BAL,R14  SCAN              GET TASK NAME                               
         LCI      2                                                             
         STM,R8   2,R3              SET TASK NAME                               
         CI,R6    0                 CHECK SCAN PROCESSING                       
         BL       A04               B IF SCAN ERROR                             
         CI,R6    2                 IS IT END OF FIELD OR END OF CARD           
         BG       A04               NO - THEN ITS AN ERROR                      
         BE       SIG03             B IF END OF ARD                             
SIG01    EQU      %                                                             
         BAL,R13  GETOPT            GET NEXT OPTION                             
         GEN,8,24 2,SIGOPT          OPTION LIST POINTER                         
         B        A04               ERROR EXIT                                  
         B        SIG04             JOB OPTION                                  
         B        SIG05             DATA                                        
SIG02    EQU      %                                                             
         CI,R6    2                 ANY MORE OPTIONE                            
         BNE      SIG01             B IF YES                                    
SIG03    EQU      %                                                             
         CAL1,7   0,R3              SIGNAL THE SPECIFIED TASK                   
         B        KEY4EXIT                                                      
SIG04    EQU      %                                                             
         LCI      2                                                             
         STM,R8   5,R3              SET JOB NAME                                
         B        SIG02             B FOR NEXT OPTION                           
*                                                                               
SIG05    EQU      %                                                             
         LCI      2                                                             
         STM,R8   8,R3              SET DATA                                    
         STW,R3   4,R3              SET ADDRSS OF FPT INTO DATA POINTER         
         MTW,7    4,R3              POINT TO DATA AREA                          
         B        SIG02             B FOR NEXT OPTION                           
*                                                                               
         BOUND    8                                                             
SIGFPT   EQU      %                                                             
         GEN,8,1,23   X'43',1,0                                                 
         DATA     P3+P4+P6+P11+P12+F8+F7                                        
         DATA     0,0,0,0,0                                                     
         GEN,8,24 3,0               DATA AREA LENGTH                            
         DATA     0,0               DATA AREA                                   
         BOUND    8                                                             
SIGOPT   EQU      %                                                             
         TEXT 'JOB'                                                             
         GEN,8,24 1,0                                                           
         TEXT     'DATA'                                                        
         GEN,8,24 1,0                                                           
*                                                                               
         TITLE    '** KEY4 - DISPLAY KEY-IN **'                                 
DISPLAY  EQU      %                                                             
         LI,R1    2                                                             
         LI,R2    20                RECL WITH CR                                
         CI,R6    2                                                             
         BE       DISP01            B IF NO PARAM (ASSUME OC OUTPUT)            
         LI,R11   1                 SET EBCDIC                                  
         BAL,R14  SCAN                                                          
         CI,R6    2                 IS IT END OF CARD                           
         BNE      A04               B IF NO                                     
         SLS,R8   -16               RT JUSTIFY                                  
         CI,R8    'LL'              IS IT LL DEVICK                             
         BNE      A04               B IF NO   ERROR                             
         LI,R1    1                 PRINT FUNC CODE                             
         LI,R2    19                RECL WITHOUT CR                             
DISP01   EQU      %                                                             
         STB,R1   *R3               SET FUNCTION CODE                           
         LI,R1    6                                                             
         LW,R0    DISMSG0-1,R1                                                  
         STW,R0   IMAGE-1,R1        MOVE MESSAGE TO IMAGE AREA                  
         BDR,R1   %-2                                                           
         STB,R2   IMAGE             SET RECL                                    
         CAL1,8   3,R3              DO DATE TIME CAL                            
         CAL1,2   0,R3              PRINT DATE AND TIME                         
         LI,R1    11                                                            
         LW,R2    DISMSG1-1,R1                                                  
         STW,R2   IMAGE-1,R1        SET FIRST LINE OF HEADER                    
         BDR,R1   %-2                                                           
         CAL1,2   0,R3              OUTPUT FIRST LINE OF HEADER                 
         LI,R1    11                                                            
         LW,R2    DISMSG2-1,R1                                                  
         STW,R2   IMAGE-1,R1        SET SECOND LINE OF HEADER                   
         BDR,R1   %-2                                                           
         CAL1,2   0,R3              OUTPUT SECOND LINE OF HEADER                
         LI,R1    1                 STI INDEX                                   
DISP02   EQU      %                                                             
         CB,R1    STILMID                                                       
         BG       KEY4EXIT          B IF DONE                                   
         LW,R0    STITCB,R1                                                     
         BEZ      DISP03            B IF NO                                     
         LI,R2    11                                                            
         LW,R4    DISMSG3-1,R2                                                  
         STW,R4   IMAGE-1,R2                                                    
         BDR,R2   %-2                                                           
         LI,R0    'P'                                                           
         LB,R11   STISTAT,R1                                                    
         CI,R11   STIPRIM           IS IS PRIMARY                               
         BANZ     %+2               B IF YES                                    
         LI,R0    'S'                                                           
         LI,R2    2                                                             
         STB,R0   IMAGE,R2                                                      
         BAL,R8   HEXBCD            CONVERT STATUS                              
         LI,R2    10                                                            
         STH,R11  IMAGE,R2          SET STATUS                                  
         LW,R11   STIPRIO,R1        GET PRIORITY                                
         BAL,R8   HEXBCD            CONVERT                                     
         LI,R2    8                                                             
         STH,R10  IMAGE,R2          SET PRIORITY                                
         AI,R2    -1                                                            
         LH,R10   R10                                                           
         STH,R10  IMAGE,R2                                                      
         LB,R2    STILMID,R1        GET LOAD MODULE ID                          
         LD,R4    LMINAME,R2        GET TASK NAME                               
         LCI      2                                                             
         STM,R4   IMAGE+1           SET TASK NAME                               
         LB,R2    STIJID,R1                                                     
         LD,R4    SJI2,R2           GET JOB NAME                                
         LCI      2                                                             
         STM,R4   IMAGE+6           SET JOB NAME                                
         LI,R13   0                 CLEAR FLAG                                  
         LB,R2    STILMID,R1        GET LMI INDEX                               
         LW,R11   LMIFWA,R2         FIRST WORD ADDRESS                          
         LB,R0    STISTAT,R1        TASK STATUS                                 
         CI,R0    STIPRIM           IS THIS TASK PRIMARY                        
         BANZ     DISP02A           B IF YES                                    
         LB,R0    R11                                                           
         CI,R0    LMIMAP            IS IT MAPPED SECONDARY                      
         BAZ      DISP02A           B IF NO - MUST BE UNMAPPED SEC.             
         LI,R13   -1                SET FLAG FOR MAPPED CASE                    
         LW,R11   STVM              START OF TASK VIRTUAL MEMORY                
DISP02A  EQU      %                                                             
         BAL,R8   HEXBCD            CONVERT TO EBCDIC                           
         LI,R4    1                                                             
         STH,R11  IMAGE+9                                                       
         LH,R11   R11                                                           
         STH,R11  IMAGE+8,R4                                                    
         STB,R10  IMAGE+8,R4                                                    
         LW,R11   LMILWA,R2                                                     
         CI,R13   0                 IS IT THE MAPPED CASE                       
         BE       DISP02B           B IF NO                                     
         LW,R11   ETVM              END OF TASK VIRTUAL MEMORY                  
DISP02B  EQU      %                                                             
         BAL,R8   HEXBCD            CONVERT TO EBCDIC                           
         STW,R11  IMAGE+10                                                      
         LI,R4    3                 INDEX OFFSET                                
         STB,R10  IMAGE+9,R4        SET IN MESSAGE BUFFER                       
         CAL1,2   0,R3                                                          
DISP03   AI,R1    1                 MOVE TO NEXT TASK                           
         B        DISP02                                                        
*                                                                               
DISFPT   EQU      %                                                             
         DATA     X'02000000'       INITIALIZE TO TYPE                          
         DATA     P1+F3                                                         
         DATA     IMAGE                                                         
TIMEFPT  GEN,8,24 X'10',IMAGE+1                                                 
DISMSG0  EQU      %                                                             
         DATA     X'13404040'                                                   
         TEXT     'TIME UNKNOWN    '                                            
DISMSG1  EQU      %                                                             
         TEXTC    'PRI  TASK    TASK TASK   JOB    TASK  TASK'                  
DISMSG2  TEXTC    'SEC  NAME    PRIO STAT   NAME   FWA   LWA'                   
DISMSG3  TEXTC    '                                           '                 
*                                                                               
         TITLE    '** KEY4 - SETNAME KEY-IN **'                                 
SETNAMEK EQU      %                                                             
         CI,R6    2                                                             
         BE       A04               ERROR IF NO PARAMETERS                      
         LI,R11   1                 SET FOR EBCDIC                              
         BAL,R14  SCAN              GET TASK NAME                               
         LCI      2                                                             
         STM,R8   3,R3              SET TASK NAME IN FPT                        
         CI,R6    0                 CHECK SCAN PROCESSING                       
         BL       A04               B IF SCAN ERROR                             
         CI,R6    2                 END OF FIELD OR END OF CARD                 
         BGE      A04               NO - THEN ITS AN ERROR                      
         LI,R11   1                 SET FOR EBCDIC                              
         BAL,R14  SCAN              GET LOAD MODULE NAME                        
         LCI      2                                                             
         STM,R8   5,R3              SET LMD NAME IN FPT                         
SETN01   EQU      %                                                             
         CI,R6    2                 ANY MORE OPTIONS                            
         BE       SETN02            B IF NO                                     
         BAL,R13  GETOPT            GET NEXT OPTION                             
         GEN,8,24 1,SETOPT                                                      
SETNERR  B        A04               ERROR                                       
         B        SETN03            JOB OPTION                                  
SETN02   EQU      %                                                             
         CAL1,7   0,R3              DO THE SETNAME                              
         B        KEY4EXIT          GOOD CAL THEN EXIT                          
*                                                                               
SETN03   EQU      %                                                             
         LCI      2                                                             
         STM,R8   7,R3              SET JOB NAME IN FPT                         
         B        SETN01            B FOR NEXT OPTION                           
*                                                                               
SETNFPT  EQU      %                                                             
         GEN,8,1,23  X'51',1,0                                                  
         DATA     P1+P3+P4+P6+P7+P11+P12+F7                                     
         DATA     SETNERR                                                       
         DATA     0,0                                                           
         DATA     0,0                                                           
         DATA     0,0                                                           
         BOUND    8                                                             
SETOPT   EQU      %                                                             
         TEXT     'JOB'                                                         
         GEN,8,24 1,0               EBCDIC CONVERSION                           
         TITLE    '** KEY4 - BREAK/CONTROL KEY-INS **'                          
         DO       #TJE                                                          
*                                                                               
*                                                                               
*        ROUTINE TO PROCESS BREAK KEYINS                                        
*                                                                               
*                                                                               
BREAKEY  EQU      %                                                             
         LI,R1    0                 SET FOR BREAK                               
         LI,R11   1                 SET FOR EBCDIC SCAN                         
         BAL,R14  SCAN              GET JOB NAME                                
         CI,R6    0                                                             
         BL       A04               B IF ERROR                                  
         CI,R6    2                 CHECK FOR END OF FIELD                      
         BNE      A04               ERROR IF NOT                                
         STD,R8   R10               SER FOR SUBROUTINE                          
         BAL,R8   TMFINDJ           FIND JOB                                    
         B        A04               ERROR NO JOB BY THAT NAME                   
         DO       #TJE                                                          
         CI,R1    0                                                             
         BGE      %+3               B IF BREAK                                  
         BAL,R8   CTLSUB            GO DO CONTROL FUNCTIONS                     
         B        %+2                                                           
         FIN      #TJE                                                          
         BAL,R8   BRKSUB            GO DO BREAK FUNCTIONS                       
BRKEX    ENABLE                                                                 
         B        KEY4EXIT                                                      
*                                                                               
*        PROCESS CONTROL KEY-IN                                                 
*                                                                               
CONTROLK LI,R1    -1                                                            
         B        BREAKEY+1                                                     
*                                                                               
         FIN      #TJE                                                          
         TITLE    '** KEY4 - BMEM/FMEM KEY-INS **'                              
*                                                                               
*                                                                               
*        ROUTINE TO PROCESS BMEM KEYIN                                          
*                                                                               
*                                                                               
BMEMK    EQU      %                                                             
         CI,R6    2                 IF END OF KEYIN                             
         BE       BMEM01              B TO USE SYSGEN VALUE                     
         LI,R11   4                 SET FOR DECIMAL INPUT                       
         BAL,R14  SCAN              GO GET # PAGES                              
         CI,R6    2                 CHECK FOR END OF CARD                       
         BNE      A04               ERROR IF NOT                                
         CI,R8    2*96              IF GREATER THAN MAX                         
         BLE      BMEM02            B IF WITHIN LIMITS                          
         B        A04               B IF ERROR                                  
BMEM01   LW,R8    K:BMEM            USE SYSGEN VALUE                            
         AND,R8   M16               MASK OUT SYSGEN VALUE                       
BMEM02   STH,R8   JCBBKG+1          PLACE VALUE IN BKG JCB                      
         STH,R8   K:BMEM            AND IN CURRENT K:BMEM HW                    
         B        KEY4EXIT                                                      
*                                                                               
*                                                                               
*        ROUTINE TO PROCESS FMEM KEYIN                                          
*                                                                               
FMEMK    RES      0                                                             
         CI,R6    2                                                             
         BE       FMEM01            B IF DEFAULT                                
         LI,R11   4                 SET FOR DEC INPUT                           
         BAL,R14  SCAN                                                          
         CI,R6    2                                                             
         BNE      A04               B IF NOT END OF CARD                        
         CI,R8    2*96                                                          
         BLE      FMEM02            B IF NOT UNREASONABLY LARGE                 
         B        A04                                                           
*                                                                               
FMEM01   LW,R8    K:FSMM            USE FMEM DEFAULT                            
         AND,R8   M16                                                           
FMEM02   STH,R8   K:FSMM            SET NEW CURRENT VALUE                       
         B        KEY4EXIT                                                      
*                                                                               
         TITLE    '** KEY4 - PAUSE/ATTEND KEY-INS **'                           
*                                                                               
*                                                                               
*                                                                               
*                                                                               
PAUKEY   RES      0                                                             
         LW,R3    Y01               RESET BITS FOR 'ON'                         
         LW,R4    Y03               SET BITS FOR 'OFF'                          
         B        PAUATT                                                        
ATTKEY   RES      0                                                             
         LW,R3    Y03               RESET BITS FOR 'ON'                         
         LW,R4    Y02               SET BITS FOR 'OFF'                          
PAUATT   RES      0                                                             
         LI,R2    0                 ASSUME 'ON'                                 
         CI,R6    2                                                             
         BE       PAUATTON          IF NO PARAMS, 'ON'                          
         BAL,R13  GETOPT                                                        
         GEN,8,24  2,PAUATTGO                                                   
         B        A04               ERROR                                       
         LI,R2    -1                'OFF'                                       
PAUATTON RES      0                 'ON'                                        
         CI,R2    0                                                             
         BE       %+2               B IF 'ON'                                   
         LW,R3    R4                GET 'OFF' MASK                              
         STS,R2   K:JCP1            SET/RESET FLAGS                             
         B        KEY4EXIT                                                      
*                                                                               
PAUATTGO RES      0                 GETOPT TABLE                                
         GEN,32,8,24  'OFF ',0,0                                                
         GEN,32,8,24  'ON  ',0,0                                                
*                                                                               
         OLAYEND                                                                
         END                                                                    
