         TITLE    'PHASE 6.2'
         SYSTEM   BPM
         SYSTEM   SIG7FDP
         PAGE
         REF      PH62E,M:LO,PDBT,RDOLF,RDOLFS
         REF      TMDATE
         REF      PDBZ
         DEF      STLIST
         REF      RANGE
         DEF      COB62
B1       EQU      1
B2       EQU      2
B3       EQU      3
B4       EQU      4
B5       EQU      5
B6       EQU      6
B7       EQU      7
B8       EQU      8
B9       EQU      9
B10      EQU      10
B11      EQU      11
STLIST   RES      33
STLIST2  RES      33
HEADR    TEXTC    'COBOL OBJECT CODE LISTING                         ',;
                  '                                      PAGE'
ROOT1    TEXT     '*****  ROOT SEGMENT  *****  '
OVLY1    TEXT     '*****  OVERLAY SEGMENT      *****   '
ERRMSG   TEXT     '*** CONTROL BYTE ERROR  '
ERRMSG2  TEXT     '*** DYNAMIC MEMORY OVERFLOW ***'
         BOUND    8
NAMENO   GEN,32   0                 SAVE NAME NUMBER
         GEN,32   0
TEMPNU   GEN,32   0                 TEMPORARY NUMBER STORAGE
DENNCT   GEN,32   0                 DECLARED NAME COUNTER
SUBLIN   GEN,32   0                 SAVE SUB-LINE NUMBER
STB1     GEN,32   0                 SAVE REGISTER 1
DEFLG    GEN,32   0                 DEF PROCESSING FLAG
SVINST   GEN,32   0                 SAVE INSTRUCTION PART
DISPLC   GEN,32   0                 SAVE DISPLACEMENT NUMBER
SVXPRT   GEN,32   0                 SAVE X PART OF INSTRUCTION
SUBLOC   GEN,32   0                 BYTE NUMBER OF LOCATION
ENDNAM   GEN,32   0                 SAVE FOR START
ENDADN   GEN,32   0
STARTF   GEN,32   0                 START CLUSTER FLAG
STCONN   GEN,32   0                 CSECT DECLARE NUMBER
ENDF     GEN,32   0                 FLAG FOR NEXT TO END
OVRCNT   GEN,32   0                 OVERLAY SEGMENT COUNT
RELOF    GEN,32   0                 RELOCATABLE INSTRUCTION FLAG
RRFLG    GEN,32   0                 RR FLAG
LOCCNTR  GEN,32   -1                LOCATION COUNTER
DSCT     DATA     0
DSCT1    DATA     0
CSCT     DATA     0                 CSECT FLAG
STRORG   DATA     0
SVLIN    GEN,8,24 120,BA(STLIST+3)                                      COBOL62
PRINTFLG DATA     1
BASECMNT TEXT     'PROGRAM BASE'
ZEROWORD TEXT     '*ZERO WORDS NOT PRINTED*'
BCRTX    TEXT     'B   '            BCR,0
         TEXT     'BGE '                1
         TEXT     'BLE '                2
         TEXT     'BE  '                3
         TEXT     'BAZ '                4
BCSTX    TEXT     'BL  '            BCS,1
         TEXT     'BG  '            BCS,2
         TEXT     'BNE '            BCS,3
         TEXT     'BANZ'            BCS,4
CURCNTPL TEXT     '%+  '
CURCNTMI TEXT     '%-  '
SAVB2    DATA     0
SAVB3    DATA     0
SAVB5    DATA     0
         BOUND    8
POTSF    DATA,4   X'7F235FAD'       10**75
         DATA,4   X'D81C2813'
POTMU    DATA,4   X'59C9F2C9'       10**30
         DATA,4   X'CD046740'
         DATA,4   X'45186A00'       10**5
         DATA,4   X'00000000'
         DATA,4   X'41A00000'       10
         DATA,4   X'00000000'
POTSB    DATA,4   X'662CD76F'       10**45
         DATA,4   X'E086B935'
         DATA,4   X'7B172EBA'       10**70
         DATA,4   X'D6DDC733'
POTSN    DATA,4   X'7E389916'       10**74
         DATA,4   X'26937352'
         DATA,4   X'7E71322C'       2X10**74
         DATA,4   X'4D26E6A4'
         DATA,4   X'7EE26458'       4X10**74
         DATA,4   X'9A4DCD48'
         DATA,4   X'7F1C4C8B'       8X10**74
         DATA,4   X'1349B9A9'
MAXTST   DATA,4   X'7F199999'       FOR OVERFLOW TEST
         DATA,4   X'99999998'
CVRTBL   GEN,32   8000000           CONVERSION TABLE
         GEN,32   4000000
         GEN,32   2000000
         GEN,32   1000000
         GEN,32   800000
         GEN,32   400000
         GEN,32   200000
         GEN,32   100000
         GEN,32   80000
         GEN,32   40000
         GEN,32   20000
         GEN,32   10000
         GEN,32   8000
         GEN,32   4000
         GEN,32   2000
         GEN,32   1000
         GEN,32   800
         GEN,32   400
         GEN,32   200
         GEN,32   100
         GEN,32   80
         GEN,32   40
         GEN,32   20
TEN      GEN,32   10                TEN
         GEN,32   8
         GEN,32   4
         GEN,32   2
         GEN,32   1
         GEN,32   0
         GEN,32   0
         GEN,32   0
         GEN,32   0
BITWD    DATA,4   X'E0000000'
BLANK    DATA,4   X'40404040'       FOR BLANK
CONBYTE  GEN,32   X'03040506'       CONTROL BYTE
         GEN,32   X'090A0BCA'
         GEN,32   X'0D0EC1C2'
         GEN,32   X'C3C4C5C6'
         GEN,32   X'C7C8C900'
DBCNTRL  B        EXTRNL            BRANCH TABLE-DEF EXT REF NAME
         B        ORIGIN            ORIGIN
         B        DPERNM            DEC PRI EXT REF NAME
         B        SEXDEF            DEF EXT REF FOR STANDARD
         B        DDUMYS            DEC DUMMY SECTION
         B        DEXTDF            DEF EXT DEFINITION
         B        NXCLUS            DEC STANDARD CONTROL
         B        SOURLC            SOURCE LINE COUNT
         B        DSTART            DEFINE START
         B        MODEND            MODULE END
         B        LDABSI            LOAD ABSOLUTE-INSTRUCTION
         B        LDABSB            LOAD ABSOLUTE-BINARY
         B        LDABSB            LOAD ABSOLUTE-ADDRESS CONST
         B        LDABSO            LOAD ABSOLUTE-FLOAT POINT S
         B        LDABST            LOAD ABSOLUTE-FLOAT POINT L
         B        LDABSD            LOAD ABSOLUTE-DECIMAL
         B        LDABNA            LOAD ABSOLUTE-ALPHA DISPLAY
         B        LDABNA            LOAD ABSOLUTE-NUMER DISPLAY
         B        LDRELO            LOAD RELOCATABLE-ADDRS CONST
MNEMTB1  TEXT     'SFS,'            SFS
         TEXT     'SFL,'            SFL
MNEMTB2  TEXT     'SLS,'            SLS
         TEXT     'SLD,'            SLD
         TEXT     'SCS,'
         TEXT     'SCD,'
         TEXT     'SAS,'            SAS
         TEXT     'SAD,'            SAD
MNEMTB3  TEXT     'LF  '            LF
         TEXT     'LC  '            LC
         TEXT     'LCF '            LCF
MNEMTB4  TEXT     'LFI '            LFI
         TEXT     'LCI '            LCI
         TEXT     'LCFI'            LCFI
DEFTEX   TEXT     'DEF '
REFTEX   TEXT     'REF '
ORGTEX   TEXT     'ORG '
ENDTEX   TEXT     'END '
FLOTEX   TEXT     'FS'' '
FLTTEX   TEXT     'FL'' '
EQUTEX   TEXT     'EQU '
DEFNOC   TEXT     'BASE'
         BOUND    8
CSECTX   TEXT     'CSECT   '
DSECTX   TEXT     'DSECT   '
SIZETX   TEXT     'SIZE IS '
DATATX   TEXT     'DATA,4  '
         TEXT     ',8  '
SUBOPF   GEN,32   0                 SUBROUTINE OPCODE FLAG
MNEMTB   TEXT     '**  '            MNEMONIC OPCODE TABLE
         TEXT     '**  '
         TEXT     '**  '            *LCFI
         TEXT     '**  '
         TEXT     'CAL1'            CAL1
         TEXT     'CAL2'            CAL2
         TEXT     'CAL3'            CAL3
         TEXT     'CAL4'            CAL4
         TEXT     '**  '            PLW
         TEXT     '**  '            PSW
         TEXT     '**  '            PLM
         TEXT     '**  '            PSM
         TEXT     '**  '
         TEXT     '**  '
         TEXT     '**  '            LPSD
         TEXT     '**  '            XPSD
         TEXT     'AD  '            AD
         TEXT     'CD  '            CD
         TEXT     'LD  '            LD
         TEXT     '**  '            MSP
         TEXT     '**  '
         TEXT     'STD '            STD
         TEXT     '**  '
         TEXT     '**  '
         TEXT     'SD  '            SD
         TEXT     'CLM '            CLM
         TEXT     'LCD '            LCD
         TEXT     'LAD '            LAD
         TEXT     'FSL '            FSL
         TEXT     'FAL '            FAL
         TEXT     'FDL '            FDL
         TEXT     'FML '            FML
         TEXT     'AI  '            AI
         TEXT     'CI  '            CI
         TEXT     'LI  '            LI
         TEXT     'MI  '            MI
         TEXT     '**  '            *SF
         TEXT     '**  '            *S
         TEXT     '**  '
         TEXT     '**  '
         TEXT     'CVS '            CVS
         TEXT     'CVA '            CVA
         TEXT     'LM  '            LM
         TEXT     'STM '            STM
         TEXT     '**  '
         TEXT     '**  '
         TEXT     '**  '            WAIT
         TEXT     '**  '            LRP
         TEXT     'AW  '            AW
         TEXT     'CW  '            CW
         TEXT     'LW  '            LW
         TEXT     'MTW '            MTW
         TEXT     '**  '
         TEXT     'STW '            STW
         TEXT     'DW  '            DW
         TEXT     'MW  '            MW
         TEXT     'SW  '            SW
         TEXT     'CLR '            CLR
         TEXT     'LCW '            LCW
         TEXT     'LAW '            LAW
         TEXT     'FSS '            FSS
         TEXT     'FAS '            FAS
         TEXT     'FDS '            FDS
         TEXT     'FMS '            FMS
         TEXT     'TTBS'            TTBS
         TEXT     'TBS '            TBS
         TEXT     '**  '
         TEXT     '**  '
         TEXT     '**  '            ANLZ
         TEXT     'CS  '            CS
         TEXT     'XW  '            XW
         TEXT     'STS '            STS
         TEXT     'EOR '            EOR
         TEXT     'OR  '            OR
         TEXT     'LS  '            LS
         TEXT     'AND '            AND
         TEXT     '**  '            SIO
         TEXT     '**  '            TIO
         TEXT     '**  '            TDV
         TEXT     '**  '            HIO
         TEXT     'AH  '            AH
         TEXT     'CH  '            CH
         TEXT     'LH  '            LH
         TEXT     'MTH '            MTH
         TEXT     '**  '
         TEXT     'STH '            STH
         TEXT     'DH  '            DH
         TEXT     'MH  '            MH
         TEXT     'SH  '            SH
         TEXT     '**  '
         TEXT     'LCH '            LCH
         TEXT     'LAH '            LAH
         TEXT     '**  '
         TEXT     '**  '
         TEXT     '**  '
         TEXT     '**  '
         TEXT     'CBS '            CBS
         TEXT     'MBS '            MBS
         TEXT     '**  '
         TEXT     'EBS '            EBS
         TEXT     'BDR '            BDR
         TEXT     'BIR '            BIR
         TEXT     'AWM '            AWM
         TEXT     'EXU '            EXU
         TEXT     'BCR '            BCR
         TEXT     'BCS '            BCS
         TEXT     'BAL '            BAL
         TEXT     'INT '            INT
         TEXT     '**  '            RD
         TEXT     '**  '            WD
         TEXT     '**  '            AIO
         TEXT     '**  '            MMC
         TEXT     '**  '            *LCF
         TEXT     'CB  '            CB
         TEXT     'LB  '            LB
         TEXT     'MTB '            MTB
         TEXT     'STCF'            STCF
         TEXT     'STB '            STB
         TEXT     'PACK'            PACK
         TEXT     'UNPK'            UNPK
         TEXT     'DS  '            DS
         TEXT     'DA  '            DA
         TEXT     'DD  '            DD
         TEXT     'DM  '            DM
         TEXT     'DSA '            DSA
         TEXT     'DC  '            DC
         TEXT     'DL  '            DL
         TEXT     'DST '            DST
OPBRCH   B        BRMTB             BRANCH TABLE
         B        BRMTB
         B        BRMTB5
         B        BRMTB
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB
         B        BRMTB
         B        BRMTB
         B        BRMTB
         B        BRMTB
         B        BRMTB
         B        BRMTB
         B        BRMTB
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB
         B        BRMTB
         B        BRMTB1
         B        BRMTB
         B        BRMTB
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB3
         B        BRMTB3
         B        BRMTB3
         B        BRMTB3
         B        BRMTB6
         B        BRMTB7
         B        BRMTB
         B        BRMTB
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB
         B        BRMTB
         B        BRMTB
         B        BRMTB
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB2
         B        BRMTB
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB3
         B        BRMTB3
         B        BRMTB
         B        BRMTB
         B        BRMTB
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB
         B        BRMTB
         B        BRMTB
         B        BRMTB
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB2
         B        BRMTB
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB
         B        BRMTB1
         B        BRMTB1
         B        BRMTB
         B        BRMTB
         B        BRMTB
         B        BRMTB
         B        BRMTB3
         B        BRMTB3
         B        BRMTB
         B        BRMTB3
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB41
         B        BCR
         B        BCS
         B        BRMTB1
         B        BRMTB1
         B        BRMTB
         B        BRMTB
         B        BRMTB
         B        BRMTB
         B        BRMTB4
         B        BRMTB1
         B        BRMTB1
         B        BRMTB2
         B        BRMTB41
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
         B        BRMTB9
         B        BRMTB1
         B        BRMTB1
         B        BRMTB1
ALBLN    DATA,4   X'07C2C14D'
         DATA,4   X'C2C1E2C5'
         DATA,4   X'07C8C14D'
         DATA,4   X'C2C1E2C5'
         DATA,4   X'04C2C1E2'
         DATA,4   X'C5404040'
         DATA,4   X'07C4C14D'
         DATA,4   X'C2C1E2C5'
ALBLN2   DATA     X'03C2C14D'       'BA('
         DATA     X'03C8C14D'       'HA('
         DATA     X'00404040'
         DATA     X'03C4C14D'       'DA('
PLIST    GEN,8,24 X'11',M:LO        PRINT PLIST
         GEN,32   X'30000010'
         GEN,32   STLIST
         GEN,32   132
SUBPOT   CD,B4    POTSB,B3          FOR HEXTEN
MULPOT   FML,B4   POTMU,B3
SUBEXP   AI,B9    -1                EXPONENT DECREMENT
         AI,B9    -5
         AI,B9    -30
TEXCOM1  LW,B4    NAMENO            FOR ORIGIN OR START
         LW,B4    ENDNAM
TEXCOM2  LW,B4    TEMPNU
         LW,B4    ENDADN
COB62    LI,5     BA(HEADR+16)
         LI,4     18
         STB,4    5
         LI,4     BA(TMDATE+1)      MOVE TIME-DATE
         MBS,4    0
         M:DEVICE M:LO,(HEADER,10,HEADR)
         M:DEVICE M:LO,(COUNT,105)
         M:DEVICE M:LO,(PAGE)
         BAL,B1   STBLNK
         CAL1,1   PLIST
         LCI      7
         LM,B3    ROOT1
         STM,B3   STLIST+10
         CAL1,1   PLIST
         BAL,B1   STBLNK
         CAL1,1   PLIST
COBOLF   BAL,11   RDOLF             READ OLF CLUSTER
         CI,B2    0
         BCS,1    COBOLF1
         BAL,B1   FORML
         B        COBOLF
COBOLF1  LI,3     1
         LH,B2    PDBT,B3
         BCR,3    PH62E             RETURN TO PHASE 6.0
COB620   BAL,11   RDOLFS            FETCH OVERLAY CLUSTER
         CI,B2    0
         BCS,1    PH62E
         LW,B3    ENDF
         BCR,3    COB621
         CAL1,1   PLIST
         LCI      9
         LM,B3    OVLY1
         STM,B3   STLIST+9          HEADER-OVERLAY
         MTW,-1   ENDF
         LW,B5    OVRCNT            OVERLAY COUNT
         LI,B4    0
         STW,B4   CSCT              CLEAR
         STW,B4   DSCT
         STW,B4   DSCT1
         STW,B4   FIRSTREF
         DW,B4    TEN
         OR,B4    L(X'F0')
         OR,B5    L(X'F0')
         STB,B5   STLIST+15
         LI,B1    1
         STB,B4   STLIST+15,B1
         CAL1,1   PLIST
         BAL,B1   STBLNK
         CAL1,1   PLIST
COB621   BAL,B1   FORML
         B        COB620
STBLNK   LW,14    BLANK             FILL BLANK IN STLIST
         LI,B3    33
         STW,14   STLIST-1,B3
         BDR,B3   %-1
         B        *B1
PRINT    LW,B1    PRINTFLG          CHECK PRINT FLAG
         BEZ      %+2               SKIP PRINT
         CAL1,1   PLIST             PRINT
         BAL,B1   STBLNK
NXCLUS   LW,B1    STB1              RETURN TO FETCH CLUSTER
         B        *B1
FINSRT   CI,B4    9                 CONVERT TO EBCDIC
         BG       %+3
         OR,B4    L(X'F0')
         B        *B8
         AI,B4    -9
         OR,B4    L(X'C0')
         B        *B8
STNUM1   LI,B4    0                 BLANK FILLING NUMERIC
         SLD,B4   4
         CI,B4    0
         BCS,3    STNUM10
         BDR,B7   %-3
         B        *B3
STNUM10  BAL,B8   FINSRT
         STB,B4   STLIST,B1
         AI,B1    1
         BDR,B7   %+2
         B        *B3
STNUM11  LI,B4    0                 NO BLANK FILLING
         SLD,B4   4
         B        %-7
FORML    STW,B1   STB1              START FORM LISTING LINE
         AI,B2    1
         LB,B6    0,B2
         CI,B6    X'40'
         BCR,3    SUBROT
         SLD,B6   -6
         CI,B6    2
         BCR,3    LRSHRT            GO TO LOAD REL-SHORT INST
         CI,B6    1
         BCR,3    LRLONG
         LB,B3    0,B2
         LI,B1    19
         LI,B5    18
         CB,B3    CONBYTE,B5        FIND CONTROL BYTE
         BCS,3    %+2
         B        DBCNTRL-1,B1
         AI,B5    -1
         BDR,B1   %-4
         LI,B7    BA(STLIST)
         LI,B6    24
         STB,B6   B7
         LI,B6    BA(ERRMSG)
         MBS,B6   0
         B        PRINT
SUBROT   AI,B2    1                 SUBROUTINE OPCODE
         MTW,1    SUBOPF            SET SUBROUTINE OPCODE FLAG
         LB,B6    0,B2
         SLD,B6   -6
         CI,B6    1
         BCR,3    LRLONG            RELOC LONG
         B        LRSHRT            RELOC SHORT
SOURLC   AI,B2    -1                SOURCE LINE NUMBER
         LW,B3    CSCT
         BNEZ     %+2
         STW,B2   CSCT              SET CSECT FLAG
         BAL,B3   GETCLUB
         SLD,B4   -16
         SLS,B5   -16
         STW,B5   SUBLIN
*
*        LO OPTION RANGES HANDLER
*
         LW,B1    RANGE-1
         BEZ      NOTHING           NO RANGE OPTION
         LH,B1    *RANGE-1          GET RANGE
         CI,B1    0
         BL       %+3               END OF RANGE OPTION
         CW,B4    B1
         BGE      PRINTOUT          IN RANGE
         LI,B1    0
         STW,B1   PRINTFLG          NO PRINT
         B        NOTHING
PRINTOUT LI,B1    0
         STH,B1   *RANGE-1          CLEAR 1ST HALF OF CURRE(T RANGE
         LW,B1    *RANGE-1
         CW,B4    B1                CHECK 2ND HALF
         BG       RESTPINT          RESET PRINT FLAG
         STW,B4   PRINTFLG          SET PRINT FLAG
         B        NOTHING
RESTPINT MTW,1    RANGE-1           NEXT RANGE
         LI,B1    0
         STW,B1   PRINTFLG          RESET FLAG
         BAL,B1   STBLNK
         CAL1,1   PLIST
         CAL1,1   PLIST
NOTHING  RES      0
         CVS,B4   CVRTBL
         LI,B1    1
         SLS,B5   8
         LI,B7    5
         BAL,B3   STNUM11           PROCESS SERIAL NUMBER
         LW,B4    SUBLIN
         BCR,3    NXCLUS
         LI,B5    X'4B'
         STB,B5   STLIST,B1
         AI,B1    1
         CVS,B4   CVRTBL
         SLS,B5   8
         LI,B7    5
         BAL,B3   STNUM11           PROCESS SUB NUMBER
         B        NXCLUS
CKNNUM   AI,B2    1                 CHECK NAME NUMBER
         LB,B4    0,B2
         LW,B5    DENNCT
         CI,B5    256
         BCS,1    *B3
         AI,B2    1
         LB,B5    0,B2
         SLS,B5   24
         SLD,B4   8
         B        *B3
ACCODE   AI,B2    1                 ACCESS CODE
         LI,B4    0
         LB,B4    0,B2
         SLD,B4   -6
         STW,B4   DSCT1             SET DSECT 1 FLAG
         BAL,B8   FINSRT+2
         STB,B4   STLIST+13
         B        *B3
SUBLCIN  SLD,B4   -4                SUB-LOCATION
         LI,B4    X'40F'
         SLD,B4   4
         STH,B4   STLIST+5
         B        *B9
LOCATN   LI,B4    0
         STW,B4   SUBLOC            0 IN SUBLOC
LOCATNV  LI,B1    15                LOCATION
         LW,B5    LOCCNTR
         SLS,B5   12
         LI,B7    5
         BAL,B3   STNUM11
         B        *B9
DDUMYS   MTW,1    DENNCT            DECLARE DUMMY SECTION
         LI,B5    1
         STW,B5   DEFLG
         STW,B5   DSCT              SET DSCT FLAG
         LI,B5    0
         STW,B5   LOCCNTR
         BAL,B3   CKNNUM
         STW,B4   NAMENO+1
         LW,B5    LOCCNTR
         LW,B7    NAMENO+1
*     SEE IF DYNAMIC WILL OVERFLOW
         LW,B4    PDBZ
         AW,B4    B7
         CW,B4    PDBZ+5
         BGE      DYNOVL
         STW,B5   *PDBZ,B7
         LD,B4    DSECTX
         STW,B4   STLIST+11
         STW,B5   STLIST+12
         BAL,B3   ACCODE
         LI,B4    0
         SLD,B4   6                 COMMENT-SIZE
         LI,B7    4*B5
         LI,B6    2
         STB,B6   B7
         LW,B6    B2
         MBS,B6   1
         SLD,B4   16
         LI,B1    88
         BAL,B10  LDRELO4
         LD,B4    SIZETX
         STD,B4   STLIST+20
         BAL,B9   LOCATN
         B        PRINT
EXTRNL   MTW,1    DENNCT            DECLARE DEF REFERENCE
         LW,B3    DENNCT            NAME NUMBER
         LW,B4    DEFTEX
         STW,B4   STLIST+11
         BAL,B1   MVCOMD
         CAL1,1   PLIST
         BAL,B1   STBLNK
         B        NXCLUS
MVCOMD   AI,B2    1                 MOVE NAME IN AUGMENT FIELD
         LB,B4    0,B2
         LI,B5    BA(STLIST+13)
         STB,B4   B5
         LW,B4    B2
         MBS,B4   1
         LB,B4    0,B2
         LW,B5    AVAIL
         STB,B4   B5
         STW,B5   REFINDX,B3        SET DEF INDEX
         LW,B4    B2
         MBS,B4   1
         STW,B5   AVAIL
         LCW,B5   REFINDX,B3
         STW,B5   REFINDX,B3        STORE DEF INDEX IN COMPLEMENT FORM
         LI,B4    0
         AI,B3    1                 POINT TO NEXT REFINDX
         STW,B4   REFINDX,B3        CLEAR NEXT REFINDX WORD
         B        *B1
*
*        BUILD-UP REF TABLE
*
DPERNM   LI,B4    0                 CLEAR B4
         LW,B3    DENNCT
         AI,B3    1                 INCREASE DECLARED NAME
         STW,B3   DENNCT               NUMBER COUNTER
         LW,B5    FIRSTREF          CHECK FIRST REF FLAG
         BNEZ     %+2               YES, SKIP
         STW,B3   FIRSTREF          SET FIRST REF FLAG
         AI,B2    1                 UPDATE OUTPUT POINTER
         LB,B4    0,B2              GET BYTE COUNT
         LW,B5    AVAIL             GET DEST ADDR
         STB,B4   B5                SET BYTE COUNT
         STW,B5   REFINDX,B3        STORE REF INDX WORD
         LW,B4    B2                GET SOURCE BA
         MBS,B4   1                 MOVE EXTERNAL DEF NAME TO REFTBLE
         STW,B5   AVAIL             STORE NEW AVAIL
         AI,B3    1
         LI,B4    0
         STW,B4   REFINDX,B3        CLEAR NEXT REF INDEX
         LW,B4    DENNCT
         LI,B3    -1
*     SEE IF DYNAMIC WILL OVERFLOW
         LW,B1    PDBZ
         AW,B1    B4
         CW,B1    PDBZ+5
         BGE      DYNOVL
         STW,B3   *PDBZ,B4
         B        NXCLUS            GET NEXT CLUSTER
SEXDEF   MTW,1    DENNCT            DECLARE STANDARD DEF
         LI,B5    0
         STW,B5   LOCCNTR
         LW,B5    DENNCT
         STW,B5   STCONN
         AI,B2    1
         B        EXTRNL+1
ORIGIN   AI,B2    1                 ORIGIN
         LB,B3    0,B2
         CI,B3    1
         BCS,3    ORIGN1
         AI,B2    -1
         BAL,B3   GETCLUB
         SLD,B4   -2
         SLS,B5   -30
         STW,B5   SUBLOC
         AI,B2    6
         B        ORIGN2
ORIGN1   LI,B4    0
         STW,B4   SUBLOC
ORIGN2   STW,B4   TEMPNU
         BAL,B3   CKNNUM
         STW,B4   NAMENO
         BAL,B9   LDRELO2
         STW,B5   LOCCNTR
         BAL,B9   LOCATNV
         LW,B4    SUBLOC
         BCR,3    %+2
         BAL,B9   SUBLCIN
         LW,B4    ORGTEX
         LW,B9    CSCT              CSECT ?
         BEZ      DCTORG            NO
         LI,B1    0
         STW,B1   RRFLG
         LI,B1    1
         STW,B1   DEFLG
         STW,B4   STLIST+18         OUTPUT 'ORG'
         BAL,B9   ORGOPND           GET OPERAND FIELD OF ORG            COBOL62
         B        %+2               BASE ITEM                           COBOL62
         B        %+3               NAME ITEM                           COBOL62
         LW,B4    DEFNOC
         STW,B4   STLIST+20         OUTPUT 'BASE'
         LI,B1    84                OUTPUT DISPLESMENT
         LI,B4    0
         STW,B4   RRFLG
         BAL,B9   SETSGN
         LI,B4    1
         STW,B4   DEFLG
         LI,B7    BA(STLIST2)
         LI,B6    132
         STB,B6   B7                FORM ORG IN STLIST2
         LI,B6    BA(STLIST)
         MBS,B6   0
         STW,B6   STRORG            SET STORE ORG FLAG
         LW,B1    SVLIN                                                 COBOL62
         MBS,0    BA(BLANK)                                             COBOL62
         B        NXCLUS
ORGOPND  LW,B3    NAMENO            BASE ITEM ?                         COBOL62
         BEZ      *B9               YES                                 COBOL62
         AI,B9    1                 UPDATE RETURN ADDR                  COBOL62
         LI,B5    BA(STLIST)                                            COBOL62
         AI,B1    32                                                    COBOL62
         AW,B5    B1                SET OUTPUT POINTER                  COBOL62
         LW,B4    REFINDX,B3        GET REF NAME BA                     COBOL62
         BGEZ     %+2                                                   COBOL62
         LCW,B4   B4                COMPLEMENT DEF INDEX                COBOL62
         LI,B3    0                                                     COBOL62
         LB,B3    B4                GET NAME BYTE COUNT                 COBOL62
         STB,B3   B5                STORE BYTE TO RU1                   COBOL62
         AW,B1    B3                                                    COBOL62
         LI,B3    0                                                     COBOL62
         STB,B3   B4                CLEAR BYTE COUNT IN SOURCE WORD     COBOL62
         MBS,B4   0                                                     COBOL62
         B        *B9                                                   COBOL62
DCTORG   STW,B4   STLIST+11
         BAL,B9   ORGOPND           GET OPERAND FEILE OF ORG            COBOL62
         B        %+2               BASE ITEM                           COBOL62
         B        %+5               NOT A BASE ITEM                     COBOL62
         LW,B4    DEFNOC
         STW,B4   STLIST+13
         LI,B1    56
         B        OUTORG-6
         LW,B4    DSCT                                                  COBOL62
         BEZ      %-2                                                   COBOL62
         LI,B4    0
         STW,B4   DSCT
         LW,B4    DSCT1
         CI,B4    2                 CHECK IF DCB (DSECT 2)              COBOL62
         BNE      OUTORG-6
         LI,B5    BA(STLIST)        OUTPUT
         AI,B5    72                   *ZERO WORDS NOT PRINTED*
         LI,B4    24
         STB,B4   B5
         LI,B4    BA(ZEROWORD)
         MBS,B4   0
         LI,B4    0
         STW,B4   RRFLG
         BAL,B9   SETSGN
         LI,B4    1
         STW,B4   DEFLG
         B        PRINT
OUTORG   LCI      3
         STM,B1   SAVB2
         LW,B1    STRORG            ORG NOT YET PRINTED OUT
         BEZ      OUT               OUT
         LW,B1    PRINTFLG          PERFORM PRINTING ?
         BEZ      OUT               NO
         LI,B3    BA(STLIST)        NOT YET
         LI,B2    132
         STB,B2   B3
         LI,B2    BA(STLIST2)
         MBS,B2   0                 MOVE STLIST2 TO STLIST
         CAL1,1   PLIST             OUTPUT ORG
         BAL,B1   STBLNK            CLEAR OUTPUT BUF
         STW,B3   STRORG            CLEAR STORE ORG FLAG
OUT      LCI      3
         LM,B1    SAVB2             RESTORE REGISTER
         B        *11
DSTART   BAL,B3   GETCLUB           START
         SLS,B4   -2
         STW,B4   ENDADN
         AI,B2    6
         BAL,B3   CKNNUM
         STW,B4   ENDNAM
         MTW,1    STARTF
         B        NXCLUS
MODEND   LW,B3    FIRSTREF          LOAD 1ST REF NUMBER
         LW,B4    REFTEX
         STW,B4   STLIST+11
         CW,B3    STCONN            CSECT NAME NUMBER ?
         BNE      %+2               NO
         AI,B3    1
         LW,B4    REFINDX,B3        GET TABLE INDX
         BLEZ     %-2               SKIP UNUSED LABEL NUMBER AND DEF
         CW,B3    DENNCT            MAX ?
         BG       FINISH            TO PRINT END
         SCS,B4   8                 MOVE BYTE COUNT TO LOWEST BYTE
         LI,B5    BA(STLIST)
         AI,B5    52
         STB,B4   B5                SET BYTE COUNT
         SLS,B4   -8                DROP BYTE COUNT
         MBS,B4   0                 OUTPUT REF NAME
         CAL1,1   PLIST             PRINT
         STW,B3   SAVB3
         BAL,B1   STBLNK
         LW,B3    SAVB3
         AI,B3    1                 NEXT NAME NUMBER
         B        MODEND+1
FINISH   LW,B4    STARTF
         BCR,3    MODEND1
         LW,B4    ENDADN
         STW,B4   TEMPNU
         LW,B7    ENDNAM
         BAL,B9   LDRELO2+1
         LI,B1    21
         BAL,B9   LOCATNV+2
         LW,B4    DEFNOC
         STW,B4   STLIST+13
         LI,B1    56
         MTW,-1   STARTF
         LW,B4    ENDADN
         BCR,3    %+2
         BAL,B9   SETSGN1
MODEND1  LW,B4    ENDTEX
         STW,B4   STLIST+11
         CAL1,1   PLIST
         BAL,B1   STBLNK
         LI,B3    0
         STW,B3   DENNCT
         STW,B3   LOCCNTR
         MTW,-1   LOCCNTR
         STW,B3   SUBLOC
         LI,B3    1
         STW,B3   ENDF
         MTW,1    OVRCNT
         CAL1,1   PLIST
         B        NXCLUS
DEXTDF   BAL,B3   CKNNUM            GET NAME NUMBER
         STW,B4   NAMENO+1          SAVE NAME NUMBER
         BAL,B3   GETCLUB
         SLS,B4   -2
         STW,B4   TEMPNU
         AI,B2    6
         BAL,B3   CKNNUM
         STW,B4   NAMENO
         BAL,B9   LDRELO2
*     SEE IF DYNAMIC WILL OVERFLOW
         LW,B1    PDBZ
         AW,B1    B7
         CW,B1    PDBZ+5
         BGE      DYNOVL
         STW,B5   *PDBZ,B7          STORE ' X' FLAG
         LW,B7    NAMENO+1
         CW,B7    STCONN
         BCS,3    NXCLUS
         LD,B6    CSECTX           STANDARD CONTROL SECTION
         STW,B6   STLIST+11
         STW,B7   STLIST+12
         LI,B6    0
         STW,B6   DSCT1             CLEAR DSECT 1 FLAG
         BAL,B9   LOCATN
         LI,B5    BA(STLIST)
         AI,B5    80                FORM COMMENT FIELD
         LI,B4    12
         STB,B4   B5
         LI,B4    BA(BASECMNT)
         MBS,B4   0
         B        PRINT
STDATX   LD,B6    DATATX
         LW,B1    CSCT              CSECT ?
         BNEZ     %+4
         STW,B6   STLIST+11
         STW,B7   STLIST+12
         B        *B9
         STD,B6   STLIST+18
         B        *B9
CKSIGN   LI,B4    0                 SIGN INSERTION
         SLD,B4   1
         CI,B4    1
         BCR,3    %+3
         SLS,B5   -1
         B        *B9
         LI,B6    X'60'             '-' SIGN
         LI,B1    44
         AW,B1    DISPLC
         STB,B6   STLIST,B1
         SLD,B4   3
         SLS,B4   28
         SAS,B4   -28
         LCW,B4   B4
         SLD,B4   -4
         MTW,1    DISPLC
         B        *B9
MRPROC   LI,B1    0                 FIND DISPLACEMENT
         LB,B6    STLIST+11,B1
         CI,B6    X'40'
         BCR,3    %+3
         AI,B1    1
         B        %-4
MRPROC1  LI,B6    X'6B'
         STB,B6   STLIST+11,B1
         AI,B1    1
         STW,B1   DISPLC
         B        *B9
RVPROC   LI,B4    0                 MOVE R OR V - COMMAND
         SLD,B4   4
         CI,B4    10
         BCS,1    RVPROC1
         AI,B4    -10
         SLD,B4   -4
         LI,B4    1
         SLD,B4   -4
         LI,B7    2
         B        %+3
RVPROC1  SLD,B4   -4
         LI,B7    1
         LI,B1    44
         AW,B1    DISPLC
         BAL,B3   STNUM11
         B        *B9
SVXINS   LI,B4    0                 SAVE X PART OF INSTRUCTION
         SLD,B4   3
         SLS,B4   28
         STW,B4   SVXPRT
         LI,B1    52
         B        *B9
CKASRX   LB,B4    STLIST+13         CHECK ASTRIX '*'
         CI,B4    X'40'
         BCR,3    %+2
         AI,B1    1
         LI,B4    0
         SLD,B4   17
         CI,B4    0
         BCS,3    %+5
         LI,B4    X'F0'
         STB,B4   STLIST,B1         FOR ZERO V VALUE
         AI,B1    1
         B        *B9
         CVS,B4   CVRTBL
         LI,B7    7
         BAL,B3   STNUM1
         B        *B9
CXPROC   LW,B5    SVXPRT            PROCESS ',X' PART
         BCR,3    MVVALU
         LI,B4    X'6B'
         STB,B4   STLIST,B1
         AI,B1    1
         LI,B7    1
         BAL,B3   STNUM11
MVVALU   LW,B5    SVINST            MOVE IN VALUE PART
         LI,B7    8
         LI,B1    24
         BAL,B3   STNUM11
         B        PRINT
GETCLUB  LI,B7    16                FETCH BYTES
         LI,B4    4
         STB,B4   B7
         LW,B6    B2
         MBS,B6   2
         B        *B3
AUGSIGN  LI,B1    52                SIGN FOR AUGMENT V FIELD
         LI,B4    0
         SLD,B4   1
         CI,B4    1
         BCR,3    %+3
         SLD,B4   19
         B        AUGSIGN2
         SLD,B4   -1
         SAS,B5   -12
AUGSIGN1 LCW,B4   B5
         LI,B5    X'60'             NEGATIVE SIGN
         STB,B5   STLIST+13
         AI,B1    1
AUGSIGN2 CVS,B4   CVRTBL
         SLS,B5   -4
         CI,B5    0
         BCS,3    %+4
         LI,B7    1
         BAL,B3   STNUM11
         B        *B9
         LI,B7    8
         BAL,B3   STNUM1
         B        *B9
SVRXS    LI,B4    0                 SAVE X OF INSTRUCTION
         SLD,B4   7
         STW,B4   SVXPRT
         LI,B4    0
         SLD,B4   9
         B        *B9
STDISP   STW,B6   STLIST+11
         LI,B4    4
         STW,B4   DISPLC
         SLS,B5   1
         SAS,B5   -13
         LW,B4    SVXPRT
         SLD,B4   -7
         B        *B9
CKDEFLG  LW,B3    DEFLG             CHECK DEFLG FOR LOCATION
         BCR,3    %+3
         MTW,-1   DEFLG
         B        %+2
         MTW,1    LOCCNTR
         BAL,B9   LOCATNV
         B        *B11
SETASX   BAL,B3   GETCLUB           CHECK AND SET *
         STW,B4   SVINST
         SLS,B4   1
         BCR,8    %+3
         LI,B3    X'5C'
         STB,B3   STLIST+13         SET *
         B        *B9
LDABSI   BAL,B11  CKDEFLG           LOAD ABSOLUTE-INSTRUCTION
         BAL,B9   SETASX
         LI,B3    0
         STW,B3   RELOF
         BAL,11   SETA
         B        LDABSI2
LDABSI1  LW,B3    SUBOPF            CHECK SUBOPF
         BCS,3    LDABSI3
LDABSI2  SLD,B4   -25
         CI,B4    X'80'
         BCS,1    %+2
         LI,B4    0
         LW,B6    MNEMTB,B4
         STW,B6   STLIST+11
         B        OPBRCH,B4
LDABSI3  LW,B6    MNEMTB            SUBROUTINE OPCODE
         STW,B6   STLIST+11
         MTW,-1   SUBOPF
         SLD,B4   -21
         B        BRMTB31
BRMTB    B        MVVALU
BRMTB1   BAL,B9   MRPROC            M,R *A,X
         BAL,B9   RVPROC            MOVE R OR V
         BAL,B9   SVXINS            SAVE X OF INSTRUCTION
         LW,B3    RELOF
         BCS,3    ASRXPL
         BAL,B9   CKASRX            CHECK ASTRIX AND MOVE IN A
         B        CXPROC            PROCESS ',X' PART
BRMTB2   BAL,B9   MRPROC            M,V *A,X
         BAL,B9   CKSIGN
         B        BRMTB1+1
BRMTB3   BAL,B9   MRPROC            M,R V OR M,R D
         BAL,B9   RVPROC
         LW,B3    RELOF
         BCS,3    BRMTB31
         BAL,B9   AUGSIGN           SIGN INSERTION-AUGMENT V
         B        MVVALU
BRMTB31  SAS,B5   -12
         STW,B5   TEMPNU
         LI,B1    52
         LW,10    NAMENO
         BEZ      %+3
         BAL,10   LDRELO31
         B        %+2
         BAL,B10  LDRELO5
         BAL,B10  LDRELO6
         LW,B4    TEMPNU
         BCR,3    MVVALU
         BCR,1    %+4
         LCW,B4   B4
         LI,B5    X'60'
         B        %+2
         LI,B5    X'4E'
         STB,B5   STLIST,B1
         BAL,B9   SETSGN1+2
         B        MVVALU
BRMTB4   LI,B4    0                 LCF
         SLD,B4   4
         LW,B6    MNEMTB3-1,B4
         B        %+2
BRMTB41  SLS,B5   4
         STW,B6   STLIST+11
         B        BRMTB1+2
BRMTB5   LI,B4    0                 LCFI
         SLD,B4   4
         LW,B6    MNEMTB4-1,B4
         STW,B6   STLIST+11
         LI,B1    52
         CI,B4    2
         BCS,1    BRMTB50           LFI
         BCR,3    %+8               LCI
         SLS,B5   12                LCFI V,V
         LI,B7    1
         BAL,B3   STNUM11
         LI,B4    X'6B'
         STB,B4   STLIST,B1         INSERT ','
         AI,B1    1
         B        %+4
         SLS,B5   12
         B        %+2
BRMTB50  SLS,B5   16
         LI,B7    1
         BAL,B3   STNUM11
         B        MVVALU
BRMTB6   LB,B4    STLIST+13         SHIFT FLOATING
         CI,B4    X'40'
         BCR,3    %+6
         LI,B2    X'E2C6'
         STH,B2   STLIST+11
         LI,B1    2
         BAL,B9   MRPROC1
         B        BRMTB1+1
         BAL,B9   SVRXS
         LW,B6    MNEMTB1,B4
         B        BRMTB8
BRMTB7   LB,B4    STLIST+13
         CI,B4    X'40'
         BCR,3    %+5
         LI,B2    X'E240'
         STH,B2   STLIST+11
         LI,B1    1
         B        BRMTB6+6
         BAL,B9   SVRXS
         LW,B6    MNEMTB2,B4
BRMTB8   BAL,B9   STDISP            S
         BAL,B9   RVPROC
         BAL,B9   SVXINS
         BAL,B9   AUGSIGN
         B        CXPROC
BRMTB9   SLS,B5   4                 DSA
         BAL,B9   SVXINS
         LW,B4    SVXPRT
         BCS,3    BRMTB1+3          M *A,X
         SAS,B5   -3
         BAL,B9   AUGSIGN           M  V
         B        MVVALU
BCR      LI,B1    0
         LB,B1    B5
         SLS,B1   -4
         LW,B6    B1
         CI,B6    4
         BG       BRMTB1
         LW,B1    BCRTX,B6
         B        BCRS
BCS      LI,B1    0
         LB,B1    B5
         SLS,B1   -4
         LW,B6    B1
         BEZ      BRMTB1
         CI,B6    4
         BG       BRMTB1
         LW,B1    BCSTX-1,B6
BCRS     STW,B1   STLIST+11
         SLD,B4   4                 SKIP V FIELD
         BAL,B9   SVXINS            SAVE X OF INSTRUCTION
         LW,B9    RELOF
         BE       SETX-2            ABSOLUTE ADD
         LB,B4    STLIST+13
         CI,B4    X'40'
         BE       %+2               SKIP NEXT
         AI,B1    1                 INCREMENT POINTER
         LW,B4    NAMENO
         BNE      ASRXPL+4          EXTERNAL REF
         AI,B1    2
         LW,B4    SVINST
         AND,B4   L(X'0001FFFF')
         SW,B4    LOCCNTR
         BGEZ     %+5
         LW,B6    CURCNTMI
         STW,B6   STLIST+13
         LCW,B4   B4
         B        %+3
         LW,B6    CURCNTPL
         STW,B6   STLIST+13
         BAL,B10  LDRELO4
         B        CXPROC
         BAL,B9   CKASRX            CHECK ASTRIX AND MOVE IN A
         B        CXPROC            PROCESS ',X'
SETX     LW,B4    *PDBZ,B6          EXTERNAL SIGN
         BCR,1    *11
         LI,B3    X'40E7'
         B        SETA+1
SETA     LI,B3    X'40C1'           ABSOLUTE SIGN
         STH,B3   STLIST+8
         B        *11
*        LOAD ABS-BIN, ADDRS CONSTANT
LDABSB   RES      0                 C2 & C3 CLUSTER
         BAL,B11  OUTORG            OUTPUT 'ORG' IF NEEDED
         BAL,B11  CKDEFLG
         BAL,B9   STDATX
         BAL,11   SETA
         LI,B4    X'E77D'
         LW,B1    CSCT
         BNEZ     CSCASDTA
         STH,B4   STLIST+13
         LI,B1    10
         STB,B4   STLIST+13,B1
         BAL,B3   GETCLUB
         STW,B4   SVINST
         LW,B5    B4
         LW,B1    DSCT1
         CI,B1    2                 CHECK IF DCB (DSECT 2)              COBOL62
         BNE      %+5
         CI,B5    0
         BNE      %+3
         BAL,B1   STBLNK
         B        NXCLUS
         LI,B1    54
         LI,B7    8
         BAL,B3   STNUM11
         B        MVVALU
CSCASDTA STH,B4   STLIST+20         OUTPUT
         LI,B1    10                 'X''
         STB,B4   STLIST+20,B1      '''
         BAL,B3   GETCLUB
         STW,B4   SVINST
         LW,B5    B4
         LI,B1    82
         B        CSCASDTA-3
SETRR    SLS,B7   4                 SET RR
         LI,B6    0
         SLD,B6   2
         STW,B6   RRFLG
         B        *11
LRLONG   BAL,11   SETRR             LOAD RELOC LONG-INSTRUCTION
         BAL,11   CKDEFLG
         BAL,11   GETNMT
LRLONG1  STW,B6   NAMENO            SAVE NAME NUMBER
         BAL,11   SETX
         LI,B3    1
         STW,B3   RELOF
         AI,B2    -1
         BAL,B9   SETASX
         B        LDABSI1
LRSHRT   BAL,11   CKDEFLG           LOAD RELOC SHORT-INSTRUCTION
         BAL,11   GETNMO
         B        LRLONG1
GETNMT   LB,B3    0,B2              GET NAME NUMBER-LONG
         AI,B2    1
         LB,B6    0,B2
         LI,B4    8
         AND,B4   B3
         BCS,3    %+5
         AI,B2    1
         LB,B7    0,B2
         SCS,B7   -8
         SLD,B6   8
         B        *11
GETNMO   LI,B3    2                 GET NAME NUMBER-SHORT
         STW,B3   RRFLG
         LB,B6    0,B2
         SLD,B6   -6
         LI,B6    0
         SLD,B6   6
         B        *11
SETSGN   LW,B4    TEMPNU
         BCR,3    *B9
SETSGN1  LI,B5    X'4E'
         STB,B5   STLIST,B1
         AI,B1    1
         LI,B5    X'E7'             X
         STB,B5   STLIST,B1
         AI,B1    1
         LI,B5    X'7D'             '
         STB,B5   STLIST,B1
         AI,B1    1
         SLD,B4   -28
         LI,B7    7
         BAL,B3   STNUM1
         LI,B5    X'7D'             '
         STB,B5   STLIST,B1
         AI,B1    1
         B        *B9
ASRXPL   LB,B4    STLIST+13         CHECK * OR NOT
         CI,B4    X'40'
         BCR,3    %+2
         AI,B1    1
         SLS,B5   -15
         STW,B5   TEMPNU
         LW,B4    NAMENO            CHECK NAME NUMBER
         BNEZ     %+3               EXIST
         BAL,B10  LDRELO5           SET-UP BASE+X'  '
         B        ASRXPL1-2
         BAL,B10  LDRELO31          TO OUTPUT REF NAME
         BAL,B10  LDRELO6
         BAL,B9   SETSGN
ASRXPL1  LW,B5    SVXPRT            PROCESS ',X' PART
         BCR,3    ASRXPL2
         LI,B4    X'6B'
         STB,B4   STLIST,B1
         AI,B1    1
         LI,B7    1
         BAL,B3   STNUM1
ASRXPL2  BAL,B9   LDRELO2
         SLS,B5   15
         LW,B4    SVINST
         SLS,B4   -17
         SLD,B4   -15
         CW,B7    DENNCT            FORWARD REF
         BG       %+2               YES
         B        MVVALU+1
         B        MVVALU
*        LOAD RELOC-ADDRESS CONSTANT
LDRELO   RES      0                 C9 CLUSTER
         BAL,B11  OUTORG            OUTPUT 'ORG' IF NEEDED
         AI,B2    1
         LB,B6    0,B2
         SLD,B6   -6
         CI,B6    1
         BCR,3    RELLNG
         LI,B6    2
         STW,B6   RRFLG
         LI,B6    0
         SLD,B6   6
LDRELO1  STW,B6   NAMENO
         BAL,11   SETX
         AI,B2    -1
         BAL,B3   GETCLUB
         STW,B4   SVINST
         SLS,B4   15
         SLS,B4   -15
         STW,B4   TEMPNU
         BAL,11   CKDEFLG
         BAL,B9   STDATX
         LI,B1    52
         LW,B10   CSCT              CSECT ?
         BEZ      %+6
         LI,B1    80
         LW,B10   NAMENO
         BEZ      %+5
         BAL,B10  LDRELO31          REF NAME AS RELATIVE ADDRESSING
         B        %+4
         LW,B10   NAMENO            CHECK NAME NUMBER
         BNEZ     %-3
         BAL,B10  LDRELO5
         BAL,B10  LDRELO6
         LI,B4    X'4E'
         STB,B4   STLIST,B1
         AI,B1    1
         LI,B4    X'E7'
         STB,B4   STLIST,B1
         AI,B1    1
         LI,B9    X'7D'
         STB,B9   STLIST,B1
         AI,B1    1
         LI,B7    8
         LW,B5    SVINST
         BAL,B3   STNUM11
         STB,B9   STLIST,B1
         B        ASRXPL2
LDRELO2  LW,B7    NAMENO
         BCR,3    %+3
         CW,B7    STCONN
         BCS,3    %+3
         LI,B5    0
         B        %+3
         LW,B5    *PDBZ,B7
         BCS,1    %-3
         AW,B5    TEMPNU
         B        *B9
LDRELO3  LW,B4    NAMENO            FOR STANDARD CONTROL
         BCS,3    %+2
         LW,B4    STCONN
LDRELO4  CVS,B4   CVRTBL
         LI,B7    7
         BAL,B3   STNUM1
         B        *B10
LDRELO31 LW,B3    RRFLG             LOAD ADDR TYPE
         SLS,B3   2
         LI,B5    BA(STLIST)        LOAD BA OF OUTPUT AREA
         AW,B5    B1                AJST OPERAND POINTER
         LI,B4    0
         LB,B4    ALBLN2,B3         GWT STRING BYTE COUNT
         STB,B4   B5                SET RU1 FOR MBS
         AW,B1    B4                UPDATE OUTPUT POINTER
         LI,B4    BA(ALBLN2)
         AW,B4    B3                SET SOURCE BA
         MBS,B4   1                 OUTPUT OPERAND
*                 OUTPUT            EXTERNAL DEF NAME IN OPERAND FIELD
         LI,B5    BA(STLIST)
         AW,B5    B1                SET OUTPUT POINTER
         STW,B5   SAVB5
         LW,B3    NAMENO            GET NAME NUMBER
         CW,B3    DENNCT            FORWARD REFERENCE ?
         BG       UNUSUAL
         LW,B4    REFINDX,B3        GET REF NAME BA
         BGEZ     %+2
         LCW,B4   B4                COMPLEMENT DEF INDEX
         LI,B3    0
         LB,B3    B4                GET REF NAME BYTE COUNT
         STB,B3   B5                STORE BYTE TO RU1
         AW,B1    B3
         LI,B3    0
         STB,B3   B4                CLEAR BYTE COUNT IN SOURCE WORD
         MBS,B4   0                 OUTPUT REF NAME
         B        *B10
UNUSUAL  AI,B3    -2
         LW,B4    REFINDX,B3        GET INDEX
         BGEZ     %+2
         LCW,B4   B4                COMPLEMENT DEF INDEX
         LI,B3    0
         LB,B3    B4
         STB,B3   B5
         AW,B1    B3
         LI,B3    0
         STB,B3   B4
         MBS,B4   0                 MOVE DEF NAME TO OUTPUT
         LW,B5    SAVB5
         LI,B4    X'C6'             CHANGE TO 'F:'
         STB,B4   0,5
         LI,B3    X'40E7'           EXTERNAL SIGN
         STH,B3   STLIST+8
         B        *B10
LDRELO5  LW,B3    RRFLG
         SLS,B3   3
         LI,B5    BA(STLIST)
         AW,B5    B1
         LB,B4    ALBLN,B3
         STB,B4   B5
         AW,B1    B4
         LI,B4    BA(ALBLN)
         AW,B4    B3
         MBS,B4   1
         B        *B10
LDRELO6  LW,B3    RRFLG
         CI,B3    2
         BCR,3    *B10
         LI,B5    X'5D'
         STB,B5   STLIST,B1
         AI,B1    1
         B        *B10
RELLNG   BAL,11   SETRR
         LB,B3    0,B2
         AI,B2    1
         LB,B6    0,B2
         LI,B4    8
         AND,B4   B3
         BCS,3    LDRELO1
         AI,B2    1
         LB,B7    0,B2
         SCS,B7   -8
         SLD,B6   8
         B        LDRELO1
*        ALPHA, NUMERIC DISPLAY
LDABNA   RES      0                 C7 & C8 CLUSTER
         BAL,B11  OUTORG            OUTPUT 'ORG' IF NEEDED
         BAL,B10  COMAND
         BAL,11   SETA
         LI,B4    X'C37D'
         BAL,B10  COMANV
         LW,B1    CSCT
         BEZ      %+3               NOT CSECT
         LI,B1    82
         B        %+2
         LI,B1    54
         LI,B5    BA(STLIST)
         AW,B5    B1
         AW,B1    TEMPNU
         LW,B4    TEMPNU
         STB,B4   B5
         LW,B4    B2
         MBS,B4   1
         LI,B6    X'7D'
         STB,B6   STLIST,B1
         AI,B2    1
         LW,B6    TEMPNU
LOCLOP1  LI,B1    24
         LB,B4    0,B2
         SLD,B4   -8
         LI,B7    2
         BAL,B3   STNUM11           VALUE BYTE
         MTW,1    SUBLOC
         LW,B3    SUBLOC
         CI,B3    4
         BCS,1    LOCLOP2
         STW,B2   SVINST
         CAL1,1   PLIST             PRINT A LINE
         BAL,B1   STBLNK
         LI,B4    0
         STW,B4   SUBLOC
         BDR,B6   %+2
         B        NXCLUS            FOR NEXT CLUSTER
         MTW,1    LOCCNTR
         BAL,B9   LOCATNV
         LW,B2    SVINST
         AI,B2    1
         B        LOCLOP1           FOR NEXT LINE
LOCLOP2  BDR,B6   %+2
         B        PRINT             END OF CLUSTER
         AI,B2    1
         B        LOCLOP1+1         NEXT BYTE
COMAND   LW,B3    DEFLG             LOCATION
         BCR,3    %+5
         MTW,-1   DEFLG
         LW,B4    SUBLOC
         BCR,3    COMAND1
         B        %+3
         LW,B4    SUBLOC
         BCR,3    %+3
         BAL,B9   SUBLCIN
         B        %+2
         MTW,1    LOCCNTR
COMAND1  BAL,B9   LOCATNV
         AI,B2    1
         LB,B4    0,B2
         SLD,B4   -6
         SLS,B5   -2
         LB,B4    B5
         BCS,3    %+2
         LI,B4    16
         STW,B4   TEMPNU
         B        *B10
INSRTS   LI,B4    0
         SLD,B4   4
         CI,B4    X'C'
         BCR,3    %+4
         LI,B7    X'60'             '-' IN AUGMENT FIELD
         STB,B7   STLIST,B1
         AI,B1    1
         B        *B9
COMANV   LW,B1    CSCT
         BEZ      %+3               NOT CSECT
         STH,B4   STLIST+20
         B        %+2
         STH,B4   STLIST+13
         BAL,B9   STDATX
         LW,B4    TEMPNU
         CVS,B4   CVRTBL
         SLS,B5   20
         LW,B1    CSCT
         BEZ      %+3               NOT CSECT
         LI,B1    77
         B        %+2
         LI,B1    49
         LI,B7    2
         BAL,B3   STNUM1            DATA BYTE COUNT
         B        *B10
*        LOAD ABSOLUTE-DECIMAL
LDABSD   RES      0                 C6 CLUSTER
         BAL,B11  OUTORG            OUTPUT 'ORG' IF NEEDED
         BAL,B10  COMAND
         BAL,11   SETA
         LI,B5    48
         STB,B4   B5
         LW,B4    B2
         MBS,B4   1
         LI,B4    X'C47D'
         BAL,B10  COMANV
         LW,B3    TEMPNU
         AI,B3    -1
         LB,B4    12,B3
         SLD,B4   -4
         LW,B1    CSCT
         BEZ      %+3
         LI,B1    82
         B        %+2
         LI,B1    54
         BAL,B9   INSRTS
         LW,B9    TEMPNU
         SLS,B9   1
         AI,B9    -1
         LI,B2    0
         LI,B6    8
         LW,B5    12,B2
         LI,B7    1
         BAL,B3   STNUM11
         BDR,B9   %+2
         B        LDABSD1
         BDR,B6   %-4
         AI,B2    1
         B        %-8
LDABSD1  LI,B4    X'7D'             END OF AUGMENT FIELD
         STB,B4   STLIST,B1
         LI,B2    48
         B        LOCLOP1-1
FLOAUG   AI,B9    17                EXPONENT
         STW,B9   SVXPRT
         BAL,B11  CKDEFLG           LOCATION
         BAL,11   SETA
         LW,B5    NAMENO            VALUE
         LI,B7    8
         LI,B1    24
         BAL,B3   STNUM11
         LW,B4    DATATX            'DATA'
         LW,B5    DATATX+1,B2       ',4' OR ',8'
         LW,B1    CSCT
         BEZ      %+3
         STD,B4   STLIST+18
         B        %+2
         STW,B4   STLIST+11
         STW,B5   STLIST+12
         CI,B2    0
         BCR,3    %+3
         LW,B4    FLTTEX
         B        %+2
         LW,B4    FLOTEX
         LW,B1    CSCT
         BEZ      %+4
         STW,B4   STLIST+20
         LI,B1    83
         B        %+3
         STW,B4   STLIST+13
         LI,B1    55
         LW,B4    NAMENO
         BCR,1    %+4
         LI,B4    X'60'             NEGATIVE SIGN
         STB,B4   STLIST,B1
         AI,B1    1
         LI,B7    1
         LW,B5    12
         BAL,B3   STNUM11
         LI,B4    X'4B'             DECIMAL POINT
         STB,B4   STLIST,B1
         AI,B1    1
         LI,B7    7
         BAL,B3   STNUM11
         CI,B2    1
         BCR,3    *B10
FLOAUG1  LI,B4    X'C5'             EXPONENT
         STB,B4   STLIST,B1
         AI,B1    1
         LW,B4    SVXPRT
         BCS,1    %+2
         B        %+5
         LI,B4    X'60'             EXPONENT SIGN
         STB,B4   STLIST,B1
         AI,B1    1
         LCW,B4   SVXPRT
         CVS,B4   CVRTBL
         SLS,B5   20
         LI,B7    2
         BAL,B3   STNUM11           NUMBER
         B        %+2
FLOAUG2  AI,B1    1
         LI,B4    X'7D'
         STB,B4   STLIST,B1
         CAL1,1   PLIST
         BAL,B1   STBLNK
         B        *B10
*        LOAD ABSOLUTE-FLOATING SHORT
LDABSO   RES      0                 C4 CLUSTER
         BAL,B11  OUTORG            OUTPUT 'ORG' IF NEEDED
         BAL,B3   GETCLUB
         LI,B5    0
         STD,B4   NAMENO
         BAL,B11  HEXTEN
         LI,B2    0
         BAL,B10  FLOAUG
         B        NXCLUS
*        LOAD ABSOLUTE-FLOATING LONG
LDABST   RES      0                 C5 CLUSTER
         BAL,B11  OUTORG            OUTPUT 'ORG' IF NEEDED
         LI,B6    8
         LI,B7    16
         STB,B6   B7
         LW,B6    B2
         MBS,B6   2
         STD,B4   NAMENO
         BAL,B11  HEXTEN
         LI,B2    1
         BAL,B10  FLOAUG
         LI,B7    8
         LW,B5    13
         BAL,B3   STNUM11
         BAL,B10  FLOAUG1
         MTW,1    LOCCNTR
         BAL,B9   LOCATNV
         LW,B5    NAMENO+1
         LI,B7    8
         LI,B1    24
         BAL,B3   STNUM11
         B        PRINT
HEXTEN   LI,12    0                 START CONVERTING
         LFI      0
         CW,12    NAMENO+1
         BCS,3    %+6
         CW,12    NAMENO
         BCS,3    %+4
         LI,B6    X'C'
         DL,4     B6
         B        *B11
         AND,B4   BITWD
         BCS,1    %+4
         LW,B4    NAMENO
         LI,B6    X'C'
         B        %+3
         LCD,B4   NAMENO
         LI,B6    X'D'
         DL,4     B6
         LI,B9    57
         CD,B4    POTSF
         BG       DIGFNF
         BNE      %+4
HEXTEN1  LI,B4    X'10'             EXACT NUMBER FINDED
         STB,B4   12
         B        DIGEND1+1
         LI,B3    0
         LI,B2    3
PWTFND   EXU      SUBPOT            FIND EXPONENT
         BG       PWTFND1
         BL       %+3
         EXU      SUBEXP-1,B2
         B        HEXTEN1
         EXU      SUBEXP-1,B2
         EXU      MULPOT
         B        PWTFND
PWTFND1  AI,B3    1                 FIND RANGE
         BDR,B2   PWTFND
         B        DIGFND
DIGFNF   FDL,B4   POTMU+4           FOR NUMBER > 10**75
         AI,B9    1
DIGFND   LI,B1    -2                FIND AND STORE DIGITS
         LI,B2    32
         LI,B3    3
         LI,B8    4
DIGFND1  BAL,B10  DIGFND2
         FML,B4   POTMU+4
         CI,B2    0
         BNE      DIGFND+2
         BIR,B1   %+2
         B        DIGEND1
         STW,B6   13,B1
         B        DIGFND+1          FOR NEXT EIGHT DIGITS
DIGFND2  CD,B4    POTSN,B3
         BE       DIGEND
         BL       %+4
         LW,B7    BITWD
         FSL,B4   POTSN,B3
         B        %+2
         LI,B7    0
         SLD,B6   1                 BIT SETTING
         AI,B2    -1
         AI,B3    -1
         BDR,B8   DIGFND2
         B        *B10
DIGEND   LW,B7    BITWD             END OF CONVERSION
         SLD,B6   1
         SLS,B6   -1,B2
         STW,B6   14,B1
         B        *11
DIGEND1  SLS,B6   -4                ELIMINATE EXTRANEOUS DIGIT
         SLS,B6   4
         STW,B6   13
         B        *B11
DYNOVL   RES      0
         LI,B7    BA(STLIST)
         LI,B6    31
         STB,B6   B7
         LI,B6    BA(ERRMSG2)
         MBS,B6   0
         LI,B1    %+3
         STW,B1   STB1
         B        PRINT
         B        PH62E
FIRSTREF DATA     0
AVAIL    DATA     BA(REFTBLE)
REFINDX  RES      300
REFTBLE  RES      700
         END
