         SYSTEM   SIG7FDP
         TITLE    'PHASE 4.2 - POF GENERATORS'
* READ PROC                                                             APR
* LF     R---     R-,+/-HW OFFSET,INDIRECT ADDR.                        APR  1
RMCF     CNAME    1                                                     APR01
         PROC                                                           APR04
LF       BAL,L1   RDMCF             READ MCF CLUSTER
         SLS,R2   -1                BA(CLOC) TO HA
         DO       NUM(AF(1))                                            APR30
         LW,AF(1) R2                LOAD HA(CLOC)+/- HW OFFSET          APR31
         DO       NUM(AF(2))                                            APR40
         AI,AF(1) AF(2)                                                 APR41
         ELSE                                                           APR42
         AI,AF(1) -1                SET HA(CLOC)-1
         FIN                                                            APR44
         FIN                                                            APR44
         PEND                                                           APR50
* WRITE PROC                                                            APW
* LF     W---     R-,BA(CLOC)+/-BA OFFSET,RETURN                        APW 1
WPOF     CNAME    0                                                     APW00
         PROC                                                           APW03
         DO       NUM(AF(2))                                            APW11
LF       LI,R4    AF(2)             LOAD BA(CLOC)                       APW12
         ELSE                                                           APW13
         DO       NUM(AF(1))                                            APW132
LF       LW,R4    AF(1)             LOAD,SET HA(CLOC) TO BA             APW14
         AW,R4    R4                                                    APW15
         FIN                                                            APW16
         FIN                                                            APW17
         DO       NUM(AF(4))
         B        WRPOF             WRITE POF CLUSTER
         ELSE
         DO       NUM(AF(3))
         LI,L1     AF(3)
         B        WRPOF             WRITE POF CLUSTER                   APW841
         ELSE                                                           APW842
         BAL,L1   WRPOF             WRITE POF CLUSTER                   APW843
         FIN                                                            APW844
         FIN                                                            APW848
         PEND                                                           APW90
* DIAG PROC                                                             APD
DX       CNAME                                                          APD00
         PROC                                                           APD01
* AF     DX       DIAG CODE,LINK                                        APD02
LF       LI,R1    AF(1)             LOAD DIAG CODE                      APD10
         DO       NUM(AF(3))
         B        DIAG
         ELSE
         DO       NUM(AF(2))
         LI,L1    AF(2)             LOAD LINK REGISTER
         B        DIAG              WRITE DMF CLUSTER                   APD242
         ELSE                                                           APD243
         BAL,L1   DIAG              WRITE DMF CLUSTER                   APD244
         FIN                                                            APD248
         FIN                                                            APD29
         PEND                                                           APD40
* LINK(OR LOAD) AND BRANCH PROC                                         APL
* LF     LAB,L/R  BRANCH ADDRESS,LINK ADDRESS(OR LOAD VALUE)            APL  1
LAB      CNAME                                                          APL01
         PROC                                                           APL04
LF       LI,CF(2) AF(2)             SET LINK REGISTER                   APL12
         B        AF(1)             BRANCH                              APL14
         PEND                                                           APL90
* LOAD,BRANCH AND LINK                                                  PRL
LBAL     CNAME    0                                                     PRL01
         PROC                                                           PRL02
* LF     LBAL,L-  BRANCH,LOAD VALUE,V-                                  PRL09
         DO       NUM(AF(3))                                            PRL20
         LI,AF(3) AF(2)             LOAD VALUE                          PRL22
         ELSE                                                           PRL23
         LI,V0    AF(2)             LOAD VALUE                          PRL24
         FIN                                                            PRL28
         DO       NUM(CF(2))                                            PRL40
         BAL,CF(2) AF(1)            BRANCH                              PRL42
         ELSE                                                           PRL43
         BAL,L1   AF(1)             BRANCH                              PRL44
         FIN                                                            PRL48
         PEND                                                           PRL99
* EXTERNAL REFERENCES
         REF      JINTE             INTL NO.
         REF      JAIXC
         REF      JADXC
         REF      KCVTD
         REF      WRPOF
         REF      RDMCF
         REF      PDBS              NO. OF BYTES FOR BASE 4(HALF-WORD)
         REF      PDBX              LINE NO.                            AAC063
         REF      PDBZ              DDB ADCONS
*                                             +3 = WA(DBB BASE)
*                                             +4 = NO. OF DDB'S,
*                                                  WA(DBINDX)
         REF      GTMP              TEMP STG
         REF      GADNO             ADCON NO.
* REGISTER EQUIVALENCES
R0       EQU      0
R1       EQU      1
R2       EQU      2
R3       EQU      3
R4       EQU      4
R5       EQU      5
R6       EQU      6                                                     117
R7       EQU      7                                                     116
V0       EQU      8
V1       EQU      9
V2       EQU      10
L0       EQU      V2                                                    1212
L1       EQU      11                LINK REGISTER
D0       EQU      12                DECA
D1       EQU      13
D2       EQU      14
D3       EQU      15
RB       EQU      R6                BIN
RF       EQU      V2                FILE CNTL
RE       EQU      4                 EVEN
RO       EQU      5                 ODD
SR1      EQU      8                 SR1
SR3      EQU      X'A'              SR3
* BA(D-)                                                                CBD
CBD0     EQU      X'30'                                                 CBD0
CBD1     EQU      X'34'                                                 CBD1
CBD2     EQU      X'38'                                                 CBD2
CBD3     EQU      X'36'                                                 CBD3
* INDEX REGISTERS                                                       CIR
CIR1     EQU      2                                                     CIR1
CIR2     EQU      4                                                     CIR2
CIR3     EQU      6                                                     CIR3
CIR4     EQU      8                                                     CIR4
CIR5     EQU      X'A'                                                  CIR5
CIR6     EQU      X'C'                                                  CIR6
CIR7     EQU      X'E'                                                  CIR7
* R REGISTERS                                                           CR
CRR1     EQU      X'10'                                                 CR01
CRR2     EQU      X'20'                                                 CR02
CRR3     EQU      X'30'                                                 CR03
CRR4     EQU      X'40'                                                 CR04
CRR5     EQU      X'50'                                                 CR05
CRR6     EQU      X'60'                                                 CR06
CRR7     EQU      X'70'                                                 CR07
CRV0     EQU      X'80'                                                 CR08
CRV1     EQU      X'90'                                                 CR09
CRV2     EQU      X'A0'                                                 CR10
CRL1     EQU      X'B0'                                                 CR11
CRD0     EQU      X'C0'                                                 CR12
CRD1     EQU      X'D0'                                                 CR13
CRD2     EQU      X'E0'                                                 CR14
CRD3     EQU      X'F0'                                                 CR15
CRE      EQU      X'40'             EVEN
CRO      EQU      X'50'             ODD
CRB      EQU      CRR6              BIN
CRF      EQU      CRV2              FILE CNTL
CSR1     EQU      X'80'             SR1                                 CR3
CSR3     EQU      X'A0'             SR3                                 CR3
* OP CODES                                                              C0
CCAL1    EQU      X'0400'           CAL1                                C04
CLI      EQU      X'2200'           LI                                  C22
CLW      EQU      X'3200'                                               C32
CSTW     EQU      X'3500'           STW                                 C35
CSTS     EQU      X'4700'           STS                                 C47
CEOR     EQU      X'4800'           EOR                                 C48
COR      EQU      X'4900'           OR                                  C49
CMBS     EQU      X'6100'           MBS                                 C61
CBDR     EQU      X'6400'                                               C64
CEXU     EQU      X'6700'                                               C67
CBR      EQU      X'6800'           B                                   C68
CBLE     EQU      X'6820'           BLE,BLEZ                            C682
CBEZ     EQU      X'6830'           BEZ                                 C683
CBAZ     EQU      X'6840'           BAZ                                 C684
CBAL     EQU      X'6AB0'           BAL,L1
CLB      EQU      X'7200'                                               C72
CIND     EQU      X'8000'           INDIRECT BIT                        C900
* POF CLUSTER CLNG,CNTL
* INSTRUCTION TYPE
DAIA     EQU      X'0401'           CONSTANT
DAID     EQU      X'0609'           DATA
DAII     EQU      X'0402'           INTERNAL LABEL
DAIL     EQU      X'0406'           LOC. CNTR
DAIP     EQU      X'0404'           PAR/SEC NAME
DAIX     EQU      X'0108'           XREF
* DATA REFERENCE
DARA     EQU      X'0410'           ADCONS
DARB     EQU      X'0417'           BRANCH TABLE
DARC     EQU      X'0419'           COMMON
DARE     EQU      X'0415'           EXIT TABLE
DARF     EQU      X'41A'            FILE LABEL
DARG     EQU      X'0414'           GLOBAL LITERALS
DARL     EQU      X'0418'           LOCAL LITERALS
DART     EQU      X'0416'           TEMP STG
* DATA DEF
DADB     EQU      X'0621'           BINARY
DADD     EQU      X'0829'           DATA REF
DADL     EQU      X'0626'           LOC. CNTR
* DEFINITIONS/DECLARATIONS
DAPI     EQU      X'0341'           INTERNAL LABEL
DAPP     EQU      X'0246'           PRIORITY SEGMENTATION
* ENTRY POINTS
         DEF      PIA00,PIA02,PIA06,PIA08,PIA20,PIA22,PIA26,PIA28
         DEF      PII00,PII02,PII20,PII22
         DEF      PIL00,PIL02,PIL06,PIL20,PIL22,PIL26
         DEF      PID10,PID11,PID12,PID14,PID16,PID18
         DEF      PIP00,PIP02,PIP20,PIP22
         DEF      PIW02
         DEF      PIX02,PIX06,PIX08                                      4
         DEF      PRA00,PRA01,PRA02,PRA04,PRA20,PRA21,PRA22,PRA24
         DEF      PRB00,PRB02,PRB06,PRB20,PRB22,PRB26
         DEF      PRC02,PRC06
         DEF      PRE00,PRE01,PRE02,PRE20,PRE21,PRE22
         DEF      PRF00,PRF02,PRF06
         DEF      PRG00,PRG02,PRG06,PRG20,PRG22,PRG26
         DEF      PRL02,PRL22
         DEF      PRT00,PRT02,PRT06,PRT20,PRT22,PRT26
         DEF      PDB00,PDB02,PDB06
         DEF      PDD00,PDD01,PDD02,PDD03,PDD04,PDD06,PDD08
         DEF      PDL10,PDL12,PDL16
         DEF      PDX02,PDX06
         DEF      PPI10,PPI11,PPI12
         DEF      PIY00,PIY01,PIY02,PIY03
         DEF      PIY20,PIY21,PIY22,PIY23
         DEF      PIY30,PIY31,PIY32,PIY33
         DEF      PIZ30,PIZ32
         DEF      OII00,OII01,OII02
         DEF      OIX02,OIX06
         DEF      MTL20             ZERO,LIMITS TEST
*
* POF CLUSTER GENERATORS                                                P
* INSTRUCTIONS                                                          PI
* ABSOLUTE VALUE                                                        PIA
* 4,DAIA M(,R,X)  ABS VAL                                               PIA0
PIA00    RES      0                                                     PIA00
*                        D0,D1 VOLATILE                                 PIA00 9
*                        V0 = OP CODE                                   PIA02 6
*                        D1 = ABS VAL                                   PIA02 7
PIA02    RES      0                                                     PIA020
         LAB,D0   PRA04,DAIA        LOAD ABS VAL CLNG,CNTL, WRITE       PIA024
PIA06    RES      0                                                     PIA060
         LI,D0    DAIA              LOAD ABS VAL CLNG,CNTL              PIA062
*                        *L1 = OP CODE,VALUE                            PIA08 7
*                        RETURN TO *L1+1                                PIA08 9
PIA08    RES      0                                                     PIA080
         LW,D1    *L1               LOAD INSTRUCTION                    PIA082
         AI,L1    1                 SET RETURN                          PIA084
         WPOF     ,CBD0+2,,0        WRITE POF CLUSTER                   PIA088
*                        D2,D3 VOLATILE                                 PIA20 9
PIA20    RES      0                                                     PIA200
*                        V0 = OP CODE                                   PIA22 6
*                        D3 = ABS VAL                                   PIA22 7
PIA22    RES      0                                                     PIA220
         LAB,D2   PRA24,DAIA        LOAD ABS VAL CLNG,CNTL, WRITE       PIA224
PIA26    RES      0                                                     PIA260
         LI,D2    DAIA              LOAD ABS VAL CLNG,CNTL              PIA262
*                        *L1 = OP CODE,VALUE                            PIA28 7
*                        RETURN TO *L1+1                                PIA28 9
PIA28    RES      0                                                     PIA280
         LW,D3    *L1               LOAD INSTRUCTION                    PIA282
         AI,L1    1                 SET RETURN                          PIA284
         WPOF     ,CBD2+2,,0        WRITE POF CLUSTER                   PIA288
* INTERNAL LABEL REFERENCE (IREF)                                       PII
* 4,DAII M(,R)    INTL NO.                                              PII0
PII00    RES      0                                                     PII00
*                        D0,D1 VOLATILE                                 PII00 9
         LI,V0    CBR               LOAD OP CODE - B                    PII004
*                        V0 = OP CODE                                   PII02 6
*                        D1 = INTL NO.                                  PII02 7
PII02    RES      0                                                     PII020
         LAB,D0   PRA04,DAII        LOAD ILREF CLNG,CNTL, WRITE         PII024
*                        D2,D3 VOLATILE                                 PII20 9
PII20    RES      0                                                     PII200
         LI,V0    CBR               LOAD OP CODE - B                    PII204
*                        V0 = OP CODE                                   PII22 6
*                        D3 = INTL NO.                                  PII22 7
PII22    RES      0                                                     PII220
         LAB,D2   PRA24,DAII        LOAD ILREF CLNG,CNTL, WRITE         PII224
* LOCATION COUNTER REFERENCE (LCREF)                                    PIL
* 4,DAIL M(,R)    (%)+/-OFFSET                                          PIL0
PIL00    RES      0                                                     PIL00
*                        D0,D1 VOLATILE                                 PIL00 9
*                        V0 = OP CODE                                   PIL02 6
*                        D1 = LOC CNTR OFFSET                           PIL02 7
PIL02    RES      0                                                     PIL020
         LAB,D0   PRA04,DAIL        LOAD LCREF CLNG,CNTL, WRITE         PIL024
PIL06    RES      0                                                     PIL060
         LAB,D0   PIA08,DAIL        LOAD LCREF CLNG,CNTL, WRITE         PIL064
*                        D2,D3 VOLATILE                                 PIL20 9
PIL20    RES      0                                                     PIL200
*                        V0 = OP CODE                                   PIL22 6
*                        D3 = LOC CNTR OFFSET                           PIL22 7
PIL22    RES      0                                                     PIL220
         LAB,D2   PRA24,DAIL        LOAD LCREF CLNG,CNTL, WRITE         PIL224
PIL26    RES      0                                                     PIL260
         LAB,D2   PIA28,DAIL        LOAD LCREF CLNG,CNTL, WRITE         PIL264
* PAR/SEC NAME REFERENCE (PREF)                                         PIP
* 4,DAIP M(,R)    PDNO                                                  PIP0
PIP00    RES      0                                                     PIP00
*                        D0,D1 VOLATILE                                 PIP00 9
         LI,V0    CBAL              LOAD OP CODE - BAL,L1               PIP002
*                        V0 = OP CODE                                   PIP02 6
*                        D1 = PDNO                                      PIP02 7
PIP02    RES      0                                                     PIP020
         LAB,D0   PRA04,DAIP        LOAD PREF CLNG,CNTL, WRITE          PIP024
*                        D2,D3 VOLATILE                                 PIP20 9
PIP20    RES      0                                                     PIP200
         LI,V0    CBAL              LOAD OP CODE - BAL,L1               PIP202
*                        V0 = OP CODE                                   PIP22 6
*                        D3 = PDNO                                      PIP22 7
PIP22    RES      0                                                     PIP220
         LAB,D2   PRA24,DAIP        LOAD PREF CLNG,CNTL, WRITE          PIP224
* DATA REFERENCE (DREF) - ADDRESS RESOLUTION (ADDR),BASE,DISPL          PID
* 6,DAID M(R,X)   ADDR RES. DATA BASE NO. BA(DISPL)                     PID0
PID00    RES      0                                                     PID00
*                        D3 = DATA BASE NO. DISPL                       PID10 7
*                        D1,D2 VOLATILE                                 PID10 9
PID10    RES      0                                                     PID100
* BA DATA REF                                                           PID1009
         LI,D2    0                 LOAD BA ADDR RES. IND.              PID102
         B        PID12                                                 PID103
* HA DATA REF                                                           PID1039
         LI,D2    1                 LOAD HA ADDR RES. IND.              PID104
         B        PID12                                                 PID105
* WA DATA REF                                                           PID11 9
PID11    RES      0                                                     PID110
         LI,D2    2                 LOAD WA ADDR RES. IND.              PID112
*                        V0 = CONSTANT PORTION                          PID12 6
*                        D2 = ADDR RES. IND.                            PID12 8
PID12    RES      0                                                     PID120
         LI,D1    DAID              LOAD DREF CLNG,CNTL                 PID122
PID14    RES      0                                                     PID140
         STH,V0   D2                STORE OP CODE                       PID142
         WPOF     ,CBD1+2,,0        WRITE POF CLUSTER                   PID144
*                                                                       PID16
PID16    RES      0                                                     PID160
         LI,D1    DAID              LOAD DREF CLNG,CNTL                 PID162
*                        *L1 = OP CODE,ADDR RES. IND.                   PID18 7
*                        RETURN TO *L1+1                                PID18 9
PID18    RES      0                                                     PID180
         LW,D2    *L1               LOAD OP CODE, ADDR RES. IND.        PID182
         AI,L1    1                 SET RETURN                          PID184
         B        PID14+1                                               PID186
* DATA REFERENCE - WA(BASE,DISPL SET)
PIW02    RES      0
         STH,V0   JAIDW+1           STORE OPCODE
         WPOF     ,BA(JAIDW)+2,,0   WRITE POF CLUSTER
* EXTERNAL REFERENCE(XREF)
*  C:---
*                        R6 = C:--- INDEX+X'C'
PIX02    RES      0
         LW,V0    KCVTD-X'C',R6     LOAD C:---
PIX04    RES      0
         STW,V0   JAIXC+2           STORE C:---
         WPOF     ,BA(JAIXC),,0     WRITE POF CLUSTER
PIX06    RES      0
         LW,V0    *L1               LOAD C:---
         AI,L1    1
         B        PIX04
*  L:---
PIX08    RES      0                                                     12
         LW,V0    *L1               LOAD,STORE (L):---                  13
         STW,V0   JAIXL+2                                               14
         AI,L1    1                 SET LINK REGISTER                   15
         WPOF     ,BA(JAIXL),,0     WRITE POF CLUSTER                   16
* WA DATA REFERENCE                                                     PR
* ADCONS                                                                PRA
* 4,DARA M(,R,X)  WA(ADCON)                                             PRA0
PRA00    RES      0                                                     PRA00
*                        D0,D1 VOLATILE                                 PRA00 9
         LW,D1    GADNO             LOAD ADCON NO.(BA)                  PRA004
*                        D1 = ADCON NO.(BA)                             PRA01 7
PRA01    RES      0                                                     PRA010
         SLS,D1   -2                ADCON NO.(BA) TO WA                 PRA014
*                        D1 = WA(ADCON)                                 PRA02 7
PRA02    RES      0                                                     PRA020
         LI,D0    DARA              LOAD ADREF CLNG,CNTL                PRA024
*                        V0 = OP CODE                                   PRA04 6
PRA04    RES      0                                                     PRA040
         STH,V0   D1                STORE OP CODE                       PRA044
         WPOF     ,CBD0+2,,0        WRITE POF CLUSTER                   PRA044
*                        D2,D3 VOLATILE                                 PRA20 9
PRA20    RES      0                                                     PRA200
         LW,D3    GADNO             LOAD ADCON NO.(BA)                  PRA204
*                        D3 = ADCON NO(BA)                              PRA21 7
PRA21    RES      0                                                     PRA210
         SLS,D3   -2                ADCON NO.(BA) TO WA                 PRA214
*                        D3 = WA ADCON                                  PRA22 7
PRA22    RES      0                                                     PRA220
         LI,D2    DARA              LOAD ADREF CLNG,CNTL                PRA224
*                        V0 = OP CODE                                   PRA24 6
PRA24    RES      0                                                     PRA240
         STH,V0   D3                STORE OP CODE                       PRA244
         WPOF     ,CBD2+2,,0        WRITE POF CLUSTER                   PRA244
* BRANCH TABLE                                                          PRB
* 4,DARB M(,R,X)  PNO                                                   PRB0
PRB00    RES      0                                                     PRB00
*                        D0,D1 VOLATILE                                 PRB00 9
         LI,V0    CEXU+CIR2         LOAD OP CODE - EXU -,R2             PRB002
*                        V0 = OP CODE                                   PRB02 6
*                        D1 = PNO                                       PRB02 7
PRB02    RES      0                                                     PRB020
         LAB,D0   PRA04,DARB        LOAD BTREF CLNG,CNTL, WRITE         PRB024
PRB06    RES      0                                                     PRB060
*                        *L1 = OP CODE,BTBL NO.                         PRB0607
*                        RETURN TO *L1+1                                PRB0609
         LAB,D0   PIA08,DARB        LOAD BTREF CLNG,CNTL, WRITE         PRB062
*                        D2,D3 VOLATILE                                 PRB20 9
PRB20    RES      0                                                     PRB200
         LI,V0    CEXU+CIR2         LOAD OP CODE - EXU -,R2             PRB202
PRB22    RES      0                                                     PRB220
*                        V0 = OP CODE                                   PRB22 6
*                        D3 = PNO                                       PRB22 7
         LAB,D2   PRA24,DARB        LOAD BTREF CLNG,CNTL, WRITE         PRB224
PRB26    RES      0
         LAB,D2   PIA28,DARB        LOAD BTREF CLNG,CNTL, WRITE
* COMMON
PRC02    RES      0
         LAB,D0   PRA04,DARC        LOAD CREF CLNG,CNTL
PRC06    RES      0
         LAB,D0   PIA08,DARC        LOAD CREF CLNG,CNTL, WRITE
* EXIT TABLE                                                            PRE
* 4,DARE M(,R)    WA(XNO)                                               PRE0
PRE00    RES      0                                                     PRE00
*                        D0,D1 VOLATILE                                 PRE00 9
         LI,V0    CSTW+CRL1         LOAD OP CODE - STW,L1               PRE002
*                        D1 = XNO                                       PRE01 7
PRE01    RES      0                                                     PRE010
         AI,D1    -1                XNO = XNO-1(=WA(XNO))               PRE012
*                        V0 = OP CODE                                   PRE02 6
*                        D1 = WA(XNO)                                   PRE02 7
PRE02    RES      0                                                     PRE020
         LAB,D0   PRA04,DARE        LOAD ETREF CLNG,CNTL, WRITE         PRE024
*                        D2,D3 VOLATILE                                 PRE20 9
PRE20    RES      0                                                     PRE200
         LI,V0    CSTW+CRL1         LOAD OP CODE - STW,L1               PRE202
*                        D3 = XNO                                       PRE21 7
PRE21    RES      0                                                     PRE210
         AI,D3    -1                XNO = XNO-1(=WA(XNO))               PRE212
*                        V0 = OP CODE                                   PRE22 6
*                        D3 = WA(XNO)                                   PRE22 7
PRE22    RES      0                                                     PRE220
         LAB,D2   PRA24,DARE        LOAD ETREF CLNG,CNTL, WRITE         PRE224
* FILE LABEL                                                            PRF
* 4,DARF M(,R)    WA(FILE LABEL)                                        PRF0
PRF00    RES      0                                                     PRF000
         LI,V0    CLB+CRR2          LOAD OP CODE - LB,V1                PRF002
PRF02    RES      0                                                     PRF020
         LAB,D0   PRA04,DARF        LOAD-FLREF CLNG,CNTL, WRITE         PRF022
PRF06    RES      0                                                     PRF060
*                        *L1 = OP CODE,DISPL(WA)                        PRF0607
*                        RETURN TO *L1+1                                PRF0609
         LAB,D0   PIA08,DARF        LOAD-FLREF CLNG,CNTL, WRITE         PRF062
* GLOBAL LITERALS - EDIT MASK, CONDITIONAL, ETC.                        PRG
* 4,DARG  M(,R)   WA(GLOBAL LIT)                                        PRG0
PRG00    RES      0                                                     PRG000
*                        V0 = OP CODE                                   PRG02 6
*                        D1 = WA(GLOBAL LIT)                            PRG02 7
PRG02    RES      0                                                     PRG020
         LAB,D0   PRA04,DARG        LOAD GLUFF CLNG,CNTL, WRITE
PRG06    RES      0
         LAB,D0   PIA08,DARG        LOAD GLREF CLNG,CNTL, WRITE
PRG20    RES      0
*                        V0 = OP CODE                                   PRG22 6
*                        D3 = WA(GLOBAL LIT)                            PRG22 6
PRG22    RES      0                                                     PRG220
         LAB,D2   PRA24,DARG        LOAD GLUFF CLNG,CNTL, WRITE
PRG26    RES      0
         LAB,D2   PIA28,DARG        LOAD GLREF CLNG,CNTL, WRITE
* LITERALS                                                              PRL
PRL00    RES      0                                                     PRL00
PRL02    RES      0
         SLS,D1   -2                DISPL TO WA
         LAB,D0   PRA04,DARL        LOAD LLREF CLNG,CNTL, WRITE
PRL22    RES      0
         SLS,D3   -2                DISPL TO WA
         LAB,D2   PRA24,DARL        LOAD LLREF CLNG,CNTL, WRITE
* TEMP STORAGE                                                          PRT
* 4,DART M(,R)    WA(TEMP STG)
PRT00    RES      0                                                     PRT00
PRT02    RES      0
         LAB,D0   PRA04,DART        LOAD TREF CLNG,CNTL, WRITE
PRT06    RES      0
         LAB,D0   PIA08,DART        LOAD TREF CLNG,CNTL, WRITE
PRT20    RES      0
PRT22    RES      0
         LAB,D2   PRA24,DART        LOAD TREF CLNG,CNTL, WRITE
PRT26    RES      0
         LAB,D2   PIA28,DART        LOAD TREF CLNG,CNTL, WRITE
* DATA DEFINITION - ADCONS                                              PD
* AN/DISPLAY                                                            PDA
PDA00    RES      0                                                     PDA00
* BINARY/CONSTANT VALUE                                                 PDB
PDB00    RES      0                                                     PDB00
* 6,DADB BASE NO.,BA(DISPL) BIN/CONST VALUE                             PDB00
*                        V0,D2 = BIN/CONST VALUE                        PDB00 6
*                        D0,D1,D2 VOLATILE                              PDB00 9
PDB02    RES      0                                                     PDB020
         LAB,D0   PDD03,DADB        TO WRITE BIN/CONST VALUE CLUSTER    PDB02
*                        *L1 = OP CODE,ADDR RES. IND.                   PDB06 7
*                        RETURN TO *L1+1                                PDB06 9
PDB06    RES      0                                                     PDB060
         LAB,D0   PDD08,DADB        TO WRITE BIN/CONST VALUE CLUSTER    PDB062
* ** IF CONSTANT VALUE FORMED IN D2, USE ....                           PDB9 0
*        LBAL     PDD04,DADB,D0                                         PDB9 1
*                                       TO WRITE ADCON                  PDB9 2
* DATA                                                                  PDD
* 8,DADD ADCON BASE NO. BA(DISPL) OP CODE/CONST. ADDR RES, IND.         PDD0
*                 DATA BASE NO. BA(DISPL)                               PDD0 2
PDD00    RES      0                                                     PDD00
*                        D3 = DATA BASE NO.,DISPL                       PDD00 7
*                        D0,D1,D2 VOLATILE                              PDD00 9
         LI,D2    0                 LOAD BA ADDR RESOLUTION IND.        PDD002
         B        PDD02                                                 PDD024
         LI,D2    1                 LOAD HA ADDR RESOLUTION IND.        PDD004
         B        PDD02                                                 PDD004
PDD01    RES      0                                                     PDD010
         LI,D2    2                 LOAD WA ADDR RESOLUTION IND.        PDD012
PDD02    RES      0                                                     PDD020
         LI,D0    DADD              LOAD DREF ADCON CLNG,CNTL           PDD022
*                        V0 = OP CODE/CONST PORTION                     PDD03 6
PDD03    RES      0                                                     PDD030
         STH,V0   D2                STORE OP CODE/CONST PORTION         PDD032
PDD04    RES      0                                                     PDD040
         MTW,4    GADNO             ADCON NO. = ADCON NO.+4             PDD042
         LW,D1    GADNO             LOAD ADCON NO.(BA)                  PDD044
         WPOF     ,CBD0+2,,0        WRITE ADCON CLUSTER                 PDD054
PDD06    RES      0                                                     PDD060
         LI,D0    DADD              LOAD DREF ADCON CLNG,CNTL           PDD062
* LOAD COMPLETE CONST PORTION,ADDR RES.IND.                             PDD08
*                        *L1 = OP CODE,ADDR RES. IND.                   PDD08 7
*                        RETURN TO *L1+1                                PDD08 9
PDD08    RES      0                                                     PDD080
         LW,D2    *L1               LOAD CONST PORTION,ADDR RES.IND.    PDD082
         AI,L1    1                 SET RETURN                          PDD084
         B        PDD04                                                 PDD086
* INTERNAL LABEL                                                        PDI
PDI00    RES      0                                                     PDI00
* LOCATION COUNTER                                                      PDL
PDL00    RES      0                                                     PDL00
PDL10    RES      0                                                     PDL100
* 6,DADL+1 ADCON BASE NO. BA(DISPL) CONST PORTION OFFSET                PDL1
PDL12    RES      0                                                     PDL120
*                        V0 = CONSTANT PORTION                          PDL1206
*                        D2 = OFFSET                                    PDL1208
         LAB,D0   PDD03,DADL+1      LOAD LCREF OFFSET CLNG,CNTL, WRITE  PDL122
*                        *L1 = OP CODE,ADDR RES. IND.                   PDL06 7
*                        RETURN TO *L1+1                                PDL06 9
PDL16    RES      0                                                     PDL160
         LAB,D0   PDD08,DADL+1      LOAD LCREF OFFSET CLNG,CNTL, WRITE  PDL162
* PAR/SEC NAME                                                          PDP
PDP00    RES      0                                                     PDP00
* EXTERNAL NAME                                                        1
*                        V0 = CONSTANT PORTION
PDX02    RES      0
         STW,V0   JADXC+1           STORE CONSTANT PORTION
PDX06    RES      0                                                    2
         LW,D1    GADNO             LOAD ADCON NO.                     3
         AI,D1    4                 UPDATE,STORE ADCON NO.             5
         STH,D1   JADXC+1                                              6
         STW,D1   GADNO                                                7
         LW,R4    *L1               LOAD,STORE XNAM(':---')            8
         STW,R4   JADXC+3                                              9
         AI,L1    1                 SET RETURN                          PDD084
         WPOF     ,BA(JADXC),,0     WRITE ADCON  C:---                10
* DEFINITIONS                                                           PP
* INTERNAL LABEL                                                        PPI
PPI00    RES      0                                                     PPI00
* 3,DAPI INTL NO.                                                       PPI1
*                        D1 = INTL NO.                                  PPI1 7
*                        V0 VOLATILE                                    PPI1 9
PPI10    RES      0                                                     PPI100
         MTW,1    JINTE             INTL NO. = INTL NO. +1
PPI11    RES      0
         LW,D1    JINTE             LOAD INTL NO.
PPI12    RES      0                                                     PPI120
         LI,V0    DAPI              LOAD INTL DEF CLNG,CNTL             PPI122
         STH,V0   D1                STORE INTL DEF CLNG,CNTL            PPI124
         WPOF     ,CBD1,,0          WRITE INTL DEF                      PPI142
* MODIFY,WRITE                                                          PIY
*                        R4 = BA(CLOC)                                  PIY00 4
*                        V0 = HALF-WORD MODIFIER                        PIY0008
PIY00    RES      0                                                     PIY000
         STH,V0   D0                MODIFY CLUSTER                      PIY002
         B        WRPOF             WRITE CLUSTER                       PIY004
PIY01    RES      0                                                     PIY010
         STH,V0   D1                MODIFY CLUSTER                      PIY012
         B        WRPOF             WRITE CLUSTER                       PIY014
PIY02    RES      0                                                     PIY020
         STH,V0   D2                MODIFY CLUSTER                      PIY022
         B        WRPOF             WRITE CLUSTER                       PIY024
PIY03    RES      0                                                     PIY030
         STH,V0   D3                MODIFY CLUSTER                      PIY032
         B        WRPOF             WRITE CLUSTER                       PIY034
*                        V0 = FULL WORD MODIFIER                        PIY2008
PIY20    RES      0                                                     PIY200
         STW,V0   D0                MODIFY CLUSTER                      PIY202
         B        WRPOF             WRITE CLUSTER                       PIY204
PIY21    RES      0                                                     PIY210
         STW,V0   D1                MODIFY CLUSTER                      PIY212
         B        WRPOF             WRITE CLUSTER                       PIY214
PIY22    RES      0                                                     PIY220
         STW,V0   D2                MODIFY CLUSTER                      PIY222
         B        WRPOF             WRITE CLUSTER                       PIY224
PIY23    RES      0                                                     PIY230
         STW,V0   D3                MODIFY CLUSTER                      PIY232
         B        WRPOF             WRITE CLUSTER                       PIY234
*                        *L1 = MODIFIER                                 PIY3007
*                        RETURN TO *L1+1                                PIY3009
PIY30    RES      0                                                     PIY300
         LW,D0    *L1               LOAD MODIFIER                       PIY302
         B        PIY33+1                                               PIY304
PIY31    RES      0                                                     PIY310
         LW,D1    *L1                                                   PIY312
         B        PIY33+1                                               PIY314
PIY32    RES      0                                                     PIY320
         LW,D2    *L1                                                   PIY322
         B        PIY33+1                                               PIY324
PIY33    RES      0                                                     PIY330
         LW,D3    *L1                                                   PIY332
         AI,L1    1                 SET RETURN                          PIY334
         B        WRPOF             WRITE CLUSTER                       PIY336
* WRITE SERIES OF LIKE INSTRUCTIONS                                     PIZ
*                        R1 = -NO. OF LIKE INSTRUCTIONS(I)              PIZ00 1
*                        R4 = BA(CLOC)                                  PIZ00 4
*                        L0 = LINK REGISTER                             PIZ00 8
PIZ30    RES      0                                                     PIZ300
         SW,L0    R1                SET RETURN                          PIZ302
PIZ32    RES      0                                                     PIZ320
         LW,D3    *L0,R1            LOAD VARIABLE I                     PIZ322
         BAL,L1   WRPOF             WRITE CLUSTER                       PIZ323
         BIR,R1   PIZ32             I = I+1                             PIZ324
         B        *L0               RETURN                              PIZ344
* INTL REF
OII00    RES      0
         LI,V0    CBR               LOAD B
OII01    RES      0
*                        V0 = OP CODE
         MTW,1    JINTE             INTL NO. = INTL NO.+ 1
OII02    RES      0
         STH,V0   JINTE             STORE OP CODE
         WPOF     ,BA(JINTE)-2,,0   WRITE - INTL
* SUBROUTINE CALL
*                        R6 = C: NAME INDEX +X'C'
*                        V0 = OP CODE
*                        R1,R4,V0 VOLATILE
OIX02    RES      0
         LI,R1    1                 LOAD INDEX REGISTER
         STH,V0   JAIXC,R1          STORE OP CODE
         BAL,L1   PIX02             WRITE OP CODE C:---
*                        R1 = 1
OIX04    RES      0
         LI,L1    CBAL              STORE BAL,L1
         STH,L1   JAIXC,R1
         B        *L0
OIX06    RES      0
         LI,R1    1                 LOAD INDEX REGISTER
         STH,V0   JAIXC,R1          STORE OPCODE
         LW,V0    *L0               LOAD C:---
         AI,L0    1                 SET LINK REGISTER
         LAB,L1   PIX04,OIX04       WRITE -,R- C:---
* TEST ZERO < VALUE (< LIMIT)                                           MTL
MTL00    RES      0                                                     MTL00
* INTERNAL LABEL                                                        MTL20
MTL20    RES      0                                                     MTL20
* *** ROUTINE NO LONGER USED *****
*
         REF      JAIDW             DATA REF
JAIXL    EQU      JINTE+8           L:--- CLUSTER                       18
         END
