         SYSTEM   SIG7FDP
         SYSTEM   BPM
         TITLE    'PHASE 4.2 - VARIABLE RECORD'
* READ PROC                                                             APR
* LF     R---     R-,+/-HW OFFSET,INDIRECT ADDR.                        APR  1
RMCF     CNAME    1                                                     APR01
         PROC                                                           APR04
LF       BAL,L1   RDMCF             READ MCF CLUSTER
         SLS,R2   -1                BA(CLOC) TO HA
         DO       NUM(AF(1))                                            APR30
         LW,AF(1) R2                LOAD HA(CLOC)+/- HW OFFSET          APR31
         DO       NUM(AF(2))                                            APR40
         AI,AF(1) AF(2)                                                 APR41
         ELSE                                                           APR42
         AI,AF(1) -1                SET HA(CLOC)-1
         FIN                                                            APR44
         FIN                                                            APR44
         PEND                                                           APR50
* WRITE PROC                                                            APW
* LF     W---     R-,BA(CLOC)+/-BA OFFSET,RETURN                        APW 1
WPOF     CNAME    0                                                     APW00
         PROC                                                           APW03
         DO       NUM(AF(2))                                            APW11
LF       LI,R4    AF(2)             LOAD BA(CLOC)                       APW12
         ELSE                                                           APW13
         DO       NUM(AF(1))                                            APW132
LF       LW,R4    AF(1)             LOAD,SET HA(CLOC) TO BA             APW14
         AW,R4    R4                                                    APW15
         FIN                                                            APW16
         FIN                                                            APW17
         DO       NUM(AF(4))
         B        WRPOF             WRITE POF CLUSTER
         ELSE
         DO       NUM(AF(3))
         LI,L1     AF(3)
         B        WRPOF             WRITE POF CLUSTER                   APW841
         ELSE                                                           APW842
         BAL,L1   WRPOF             WRITE POF CLUSTER                   APW843
         FIN                                                            APW844
         FIN                                                            APW848
         PEND                                                           APW90
* DIAG PROC                                                             APD
DX       CNAME                                                          APD00
         PROC                                                           APD01
* AF     DX       DIAG CODE,LINK                                        APD02
LF       LI,R1    AF(1)             LOAD DIAG CODE                      APD10
         DO       NUM(AF(3))
         B        DIAG
         ELSE
         DO       NUM(AF(2))
         LI,L1    AF(2)             LOAD LINK REGISTER
         B        DIAG              WRITE DMF CLUSTER                   APD242
         ELSE                                                           APD243
         BAL,L1   DIAG              WRITE DMF CLUSTER                   APD244
         FIN                                                            APD248
         FIN                                                            APD29
         PEND                                                           APD40
* LINK(OR LOAD) AND BRANCH PROC                                         APL
* LF     LAB,L/R  BRANCH ADDRESS,LINK ADDRESS(OR LOAD VALUE)            APL  1
LAB      CNAME                                                          APL01
         PROC                                                           APL04
LF       LI,CF(2) AF(2)             SET LINK REGISTER                   APL12
         B        AF(1)             BRANCH                              APL14
         PEND                                                           APL90
* LOAD,BRANCH AND LINK                                                  PRL
LBAL     CNAME    0                                                     PRL01
         PROC                                                           PRL02
* LF     LBAL,L-  BRANCH,LOAD VALUE,V-                                  PRL09
         DO       NUM(AF(3))                                            PRL20
         LI,AF(3) AF(2)             LOAD VALUE                          PRL22
         ELSE                                                           PRL23
         LI,V0    AF(2)             LOAD VALUE                          PRL24
         FIN                                                            PRL28
         DO       NUM(CF(2))                                            PRL40
         BAL,CF(2) AF(1)            BRANCH                              PRL42
         ELSE                                                           PRL43
         BAL,L1   AF(1)             BRANCH                              PRL44
         FIN                                                            PRL48
         PEND                                                           PRL99
* EXTERNAL REFERENCES
         REF      BAA02             RETURN
         REF      BAA40             SAVE DATA
         REF      PIA00,PIA02,PIA06,PIA08,PIA20,PIA22,PIA26,PIA28
         REF      PII00,PII02,PII20,PII22
         REF      PIL00,PIL02,PIL06,PIL20,PIL22,PIL26
         REF      PID10,PID11,PID12,PID14,PID16,PID18
         REF      PIP00,PIP02,PIP20,PIP22
         REF      PRA00,PRA01,PRA02,PRA04,PRA20,PRA21,PRA22,PRA24
         REF      PRB00,PRB02,PRB06,PRB20,PRB22,PRB26
         REF      PRC06
         REF      PRE00,PRE01,PRE02,PRE20,PRE21,PRE22
         REF      PRF00,PRF02,PRF06
         REF      PRG00,PRG02,PRG06,PRG20,PRG22,PRG26
         REF      PRT00,PRT02,PRT06,PRT20,PRT22,PRT26
         REF      PDB00,PDB02,PDB06
         REF      PDD00,PDD01,PDD02,PDD03,PDD04,PDD06,PDD08
         REF      PDL10,PDL12,PDL16
         REF      PPI10,PPI11,PPI12
         REF      PIY00,PIY01,PIY02,PIY03
         REF      PIY20,PIY21,PIY22,PIY23
         REF      PIY30,PIY31,PIY32,PIY33
         REF      PIZ30,PIZ32
         REF      LRA00,LRA01,LRA02
         REF      LRR00,LRR01,LRR02
         REF      LRD00,LRD01
         REF      LRD10,LRD11,LRD20,LRD21
         REF      LRD40,LRD41,LRD42
         REF      LRD60,LRD61,LRD62,LRD80,LRD81,LRD82
         REF      LRL00,LRL01
         REF      MRR10,MRR11,MRR12
         REF      MRR40,MRR41,MRR42
         REF      MRR60,MRR61,MRR62,MRR80,MRR81,MRR82
         REF      NRR10,NRR11,NRR12
         REF      NRR40,NRR41,NRR42
         REF      NRR60,NRR61,NRR62,NRR80,NRR81,NRR82,NRR70
         REF      NRD00,NRD01,NRD02
         REF      ORR03,ORR04,ORR05,ORR06,ORR07,ORR08
         REF      ORD12,ORD22,ORD23,ORD24
         REF      ORD42,ORD44,ORD48
         REF      MTL20
         REF      SSB00,SSB01,SSB02
         REF      SSL00,SSL01,SSL02
         REF      SSS00,SSS01,SSS02
         REF      WRPOF
         REF      RDMCF
         REF      PDBS              NO. OF BYTES FOR BASE 4(HALF-WORD)
         REF      PDBX              LINE NO.                            AAC063
         REF      PDBZ              DDB ADCONS
*                                             +3 = WA(DBB BASE)
*                                             +4 = NO. OF DDB'S,
*                                                  WA(DBINDX)
         REF      GTMP              TEMP STG
         REF      GADNO             ADCON NO.
         REF      MCBUF,MDBUF
         REF      JDECP,JDSIZ       DECP,DSIZ
         DEF      VARF,VRPPD,VBIDX
         DEF      VPP00,VPP05,VPP10
         DEF      VPP20,VPP30,VAL00
         DEF      LBLVR,VPP50
         DEF      VPL00
         REF      DMVF
         REF      PDX06,PIX06,GRMVF
         REF      VRPF,VRPMD,SUBSF
         REF      AJAD,VEXBT,VMAD
         REF      RFLDF,LITF
* REGISTER EQUIVALENCES
R0       EQU      0
R1       EQU      1
R2       EQU      2
R3       EQU      3
R4       EQU      4
R5       EQU      5
R6       EQU      6                                                     117
R7       EQU      7                                                     116
V0       EQU      8
V1       EQU      9
V2       EQU      10
L0       EQU      V2                                                    1212
L1       EQU      11                LINK REGISTER
D0       EQU      12                DECA
D1       EQU      13
D2       EQU      14
D3       EQU      15
RE       EQU      4                 EVEN
RO       EQU      5                 ODD
RB       EQU      R6                BIN
RFL      EQU      V0                FLP
RF       EQU      V2                FILE CNTL
RS       EQU      V2                SIGN - EDIT
RC       EQU      L1                %
P1       EQU      V2                PREG 1
SR1      EQU      8                 SR1
SR3      EQU      X'A'              SR3
* BA(D-)
CBD0     EQU      X'30'
CBD1     EQU      X'34'                                                 CBD1
CBD2     EQU      X'38'                                                 CBD2
CBD3     EQU      X'36'                                                 CBD3
* INDEX REGISTERS                                                       CIR
CIR1     EQU      2                                                     CIR1
CIR2     EQU      4                                                     CIR2
CIR3     EQU      6                                                     CIR3
CIR4     EQU      8                                                     CIR4
CIR5     EQU      X'A'                                                  CIR5
CIR6     EQU      X'C'                                                  CIR6
CIR7     EQU      X'E'
* R REGISTERS
CRR1     EQU      X'10'                                                 CR01
CRR2     EQU      X'20'                                                 CR02
CRR3     EQU      X'30'                                                 CR03
CRR4     EQU      X'40'                                                 CR04
CRR5     EQU      X'50'                                                 CR05
CRR6     EQU      X'60'                                                 CR06
CRR7     EQU      X'70'                                                 CR07
CRV0     EQU      X'80'                                                 CR08
CRV1     EQU      X'90'                                                 CR09
CRV2     EQU      X'A0'                                                 CR10
CRL1     EQU      X'B0'                                                 CR11
CRD0     EQU      X'C0'                                                 CR12
CRD1     EQU      X'D0'                                                 CR13
CRD2     EQU      X'E0'                                                 CR14
CRD3     EQU      X'F0'                                                 CR15
CRE      EQU      X'40'             EVEN
CRO      EQU      X'50'             ODD
CRB      EQU      CRR6              BIN
CRFL     EQU      CRV0              FLP
CRF      EQU      CRV2              FILE CNTL
CRS      EQU      CRV2              SIGN - EDIT
CRC      EQU      CRL1              %
CP1      EQU      CRV2              PREG 1
CSR1     EQU      X'80'             SR1                                 CR3
CSR3     EQU      X'A0'             SR3                                 CR3
* OP CODES
CLCI     EQU      X'0220'
CCAL1    EQU      X'0400'           CAL1
CLD      EQU      X'1200'                                               C12
CSTD     EQU      X'1500'
CFAL     EQU      X'1D00'                                               C194
CAI      EQU      X'2000'                                               C20
CLI      EQU      X'2200'           LI                                  C22
CLI1     EQU      X'2210'           LI,1                                C221
CMI      EQU      X'2300'
CSF      EQU      X'2400'                                               C24
CS       EQU      X'2500'                                               C25
CAW      EQU      X'3000'
CSTW     EQU      X'3500'           STW                                 C35
CLW      EQU      X'3200'                                               C32
CSW      EQU      X'3800'
CSTS     EQU      X'4700'           STS                                 C47
CEOR     EQU      X'4800'           EOR                                 C48
CSAS     EQU      X'400'            RA SETING - SAS                     C484
CSDA     EQU      X'500'            RA SETTING - SAD                    C485
COR      EQU      X'4900'           OR                                  C49
CAND     EQU      X'4B00'
CLAH     EQU      X'5B00'
CMBS     EQU      X'6100'
CBDR     EQU      X'6400'                                               C64
CEXU     EQU      X'6700'                                               C67
CBR      EQU      X'6800'           B                                   C68
CBLE     EQU      X'6820'           BLE,BLEZ                            C682
CBEZ     EQU      X'6830'           BEZ                                 C683
CBAZ     EQU      X'6840'           BAZ                                 C684
CBL      EQU      X'6910'           BL                                  C691
CBNE     EQU      X'6930'           BNE,BNEZ
CBAL     EQU      X'6AB0'           BAL,L1
CLB      EQU      X'7200'                                               C72
CSTB     EQU      X'7500'                                               C75
CPACK    EQU      X'7600'                                               C76
CUNPK    EQU      X'7700'
CDSA     EQU      X'7C00'
CDL      EQU      X'7E00'                                               C795
CDST     EQU      X'7F00'
CIND     EQU      X'8000'           INDIRECT BIT                        C900
* POF CLUSTER CLNG,CNTL
* INSTRUCTION TYPE
DAIA     EQU      X'0401'           CONSTANT
DAID     EQU      X'0609'           DATA
DAII     EQU      X'0402'           INTERNAL LABEL
DAIL     EQU      X'0406'           LOC. CNTR
DAIP     EQU      X'0404'           PAR/SEC NAME
DAIX     EQU      X'0108'           XREF
* DATA REFERENCE
DARA     EQU      X'0410'           ADCONS
DARB     EQU      X'0417'           BRANCH TABLE
DARE     EQU      X'0415'           EXIT TABLE
DARF     EQU      X'41A'            FILE LABEL
DARG     EQU      X'0414'           GLOBAL LITERALS
DARL     EQU      X'0418'           LOCAL LITERALS
DART     EQU      X'0417'           TEMP STG
* DATA DEF
DADB     EQU      X'0621'           BINARY
DADD     EQU      X'0829'           DATA REF
DADL     EQU      X'0626'           LOC. CNTR
* DEFINITIONS/DECLARATIONS
DADX     EQU      X'0328'           EXTERNAL NAME
DAPI     EQU      X'0341'           INTERNAL LABEL
* GLOBAL LITERAL WA DISPL - BASE 4
DGDZ     EQU      4                 D'+0'
DGD1     EQU      3                 D'+1'
DGFZ     EQU      6                 FL'0.E8'
* GLOBAL LITERAL BA DISPL - BASE 4
DGZRO    EQU      0                 ZERO
DGSPC    EQU      1                 SPACE
DGQUO    EQU      2                 QUOTE
DGLV     EQU      3                 LOW-VALUE
DGHV     EQU      4                 HIGH-VALUE
DGAST    EQU      6                 ASTERISK
* REGISTER SAVE LEVELS
DSS      EQU      1                 SUBSCRIPT
DSL      EQU      2                 STORE
DSG      EQU      4                 GENERATOR
* TEMP REGISTER SAVE AREAS
DTB      EQU      9                 BIN
DTF      EQU      18                FLP
DTCSX    EQU      20                CORRESPONDING SXR1,SXR2
DTD1     EQU      10                DECA - SUBSCRIPT
DTD2     EQU      14                DECA - STORE
DTD4     EQU      22                DECA - GENERATORS
*
* ENTRY POINTS
*        REMOVE DEF OF BBH00
VPL00    RES      0                 PROCESS VAR REC PARAM
         STW,L1   VPRSV
         LW,R7    VRPF,R6
         LH,D2    R7
         BGEZ     VPLN1
         MTW,1    NSREF
         AND,D2   L(X'7FFF')
VPLN1    SLS,D2   -2
         AWM,D2   VRPPD             PARAM LNTH
         AI,D2    -1
         BGZ      VPL03
         AND,R7   L(X'FFFF')        REF NO. ONLY
         LW,R6    VREFC
VPL01    AI,R6    -2
         CH,R7    VREF,R6
         BE       VPL02
         MTW,0    R6                NOT SAME REF NO.
         BGZ      VPL01
         B        *VPRSV
VPL02    AI,R6    1
         LH,R7    VREF,R6           VAR REC FLAG
         STW,R7   VARF
         B        VPL05
VPL03    SLS,D2   -2                ENTRY COUNT
         STW,D2   RTEMP
         LBAL     PDD04,DADB,D0     WRITE PARAM WORD 0
         XW,D2    R7
         LW,R7    VREFC
         MTW,0    NSREF
         BEZ      VPLN2
         STH,D2   VREF,R7           SAVE REF NO.
VPLN2    SLS,R7   -1
         STW,D1   VPAD,R7
         MTW,0    VRPF+1,R6
         BLZ      VPL04
         MTW,-2   VARF              VAR LNTH
VPL04    LW,D2    VRPF+1,R6
         LBAL     PDD04,DADB,D0     WRITE PARAM WORD 1
         LI,V0    0
         LW,D3    VRPF+2,R6         WRITE PARAM WORD 2
         BAL,L1   PDD00
         LW,D2    VRPF+3,R6
         LBAL     PDD04,DADB,D0     WRITE PARAM WORD 3
         LW,D2    VRPF+4,R6
         LBAL     PDD04,DADB,D0     WRITE PARAM WORD 4
         AI,R6    4
         MTW,-1   RTEMP
         BGZ      VPL04             NEXT GROUP
         MTW,0    VRPF-3,R6
         BGEZ     %+2
         MTW,1    VARF
         LW,R6    VREFC
         MTW,0    NSREF
         BEZ      VPLN3             REF NO NOT SAVED
         MTW,-1   NSREF
         MTW,2    VREFC
         LW,R7    VARF
         AI,R6    1
         STH,R7   VREF,R6           SAVE VAR REC FLAG
VPL05    AI,R6    -1
VPLN3    SLS,R6   -1
         LW,D1    VPAD,R6           PARAM ADDR
         MTW,0    RFLDF
         BLEZ     VPL06
         STW,D1   SVPAD             SAVE PARAM ADDR
         LW,L1    VBIDX
         STW,L1   VBIDS
         MTW,-2   RFLDF
VPL06    RES      0
         LBAL     PRA01,CLI+CRR7
         MTW,0    DMVF
         BNEZ     *VPRSV            DATA MANIPULATION
         BAL,L1   PIX06
         TEXT     ':VPL'            ****    ADCON C:VPL
         B        *VPRSV            RETURN
VAL00    STW,L1   VPRSV
         LW,D1    V0
         LBAL     PIA02,CLB+CRV2    **** WRITE LB,V2  LNTH
         LI,V0    X'FFFF'
         AND,V0   D1                GET REGISTER NUMBER
         STW,V0   RTEMP
         LW,D1    VARF
         CI,D1    -2
         BE       VAL01             VAR LNTH ONLY
         BAL,L1   PIA06
         LI,R6    X'7FFFF'          **** WRITE LI,R6  X'7FFFF'
         SLS,V0   4
         LI,D1    R6
         AI,V0    CAND
         BAL,L1   PIA02             **** WRITE AND,SR  R6
VAL01    LW,V0    RTEMP
         B        %+2
VAP00    STW,L1   VPRSV
         SLS,V0   4
VAP01    AI,V0    CSW+CIR7
         B        *VPRSV
VPP00    BAL,L1   VPS0              BYTE,ADDR TYPE
         BAL,L1   VPP40
         LW,D1    VARF
         CI,D1    -2
         BE       VPP03
         LI,D1    1
         BAL,L1   PIA02             **** WRITE SW,SR  1,R7
VPP03    MTW,0    GRMVF
         BNEZ     VPP01
         LW,D1    RTEMP
VPP04    LI,V0    CSTB+CRV2
         BAL,L1   PIA02             **** WRITE STB,V2  SR
VPP01    LI,L0    0
         STW,L0   GRMVF             RESET FLAGS
         STW,L0   VBIDX
         LCI      15
         LM,R1    VRGR6
         B        *L0
VPP05    BAL,L1   VPS0
         MTW,0    VARF
         BLZ      VPP051
         AI,V0    -1                ADDRESS ONLY
         B        VPP11
VPP051   BAL,L1   VPP40
         LW,D1    VARF
         CI,D1    -2
         BE       VPP06             VAR LNTH ONLY
         AI,V0    -X'10'
         LI,D1    1
         BAL,L1   PIA02             **** WRITE SW,SR  1,R7
VPP06    LW,D1    VRG01             RE
         B        VPP04
VPP10    BAL,L1   VPS0              ADDRESS ONLY
         LW,D1    VARF
         CI,D1    -2
         BE       VPP01             VAR LNTH ONLY
VPP11    LI,D1    1
VPP12    BAL,L1   VAP00
         BAL,L1   PIA02             **** WRITE SW,SR  0/1,R7
         B        VPP01
         B        VPP06
VPP20    BAL,L1   VPS0              LENGTH ONLY
         MTW,0    VARF
         BGEZ     VPP01             NOT VAR LNTH
         LI,D1    0                 **** WRITE SW,SR  0,R7
         B        VPP12
VPP30    BAL,L1   VPS0
VPP3A    MTW,0    VBIDX
         BEZ      VPP31             BA
         BAL,L1   PIA06
         LCW,R7   1,R7              **** WRITE LCW,R7  1,R7
VPP31    AND,V0   L(X'E')
         STW,V0   VIRFL
         BNEZ     VPP32             INDEXING
         LI,V0    X'E'              R7 FOR INDEX REG
         OR,V0    VRG01
         STW,V0   VRG01             SET INDEX REG
VPP32    LW,R7    VBIDX             INDEX
         B        %+1,R7
         B        VPP35
         B        VPP34             HA ADJUSTMENT
         B        VPP36             WA ADJUSTMENT
         B        VPP38             DA ADJUSTMENT
VPP35    MTW,0    VIRFL
         BEZ      VPP33             R7 FOR INDEX REG
         SLS,V0   -1
         B        VPP11
VPP33    BAL,L1   PIA06
         LCW,R7   1,R7              **** WRITE LCW,R7  1,R7
         B        VPP01
VPP34    BAL,L1   PIA06
         SAS,R7   -1                **** WRITE SAS,R7  -1
         B        VPP39
VPP36    BAL,L1   PIA06
         SAS,R7   -2                **** WRITE SAS,R7  -2
         B        VPP39
VPP38    BAL,L1   PIA06
         SAS,R7   -3                **** WRITE SAS,R7  -3
VPP39    LW,V0    VIRFL
         BEZ      VPP01             NO INDEX
         SLS,V0   3
         AI,V0    CAW
         LI,D1    R7
         BAL,L1   PIA02             **** WRITE AW,SR  R7
         B        VPP01
VPP40    STW,L1   SAVV0
         BAL,L1   VAL00
         MTW,0    VARF
         BGEZ     *SAVV0            NOT VAR LNTH
         MTW,0    GRMVF
         BNEZ     *SAVV0
         BAL,L1   PIA06
         SW,V2    0,R7              **** WRITE SW,V2  0,R7
         B        *SAVV0
VPP50    LCI      15
         STM,R1   VRGR6
         LW,D1    VBIDS
         STW,D1   VBIDX
         LW,D1    SVPAD
         LBAL     PRA01,CLI+CRR7    **** WRITE LI,R7  PARAM ADDR
         BAL,L1   PIX06
         TEXT     ':VPL'            **** WRITE BAL,11 C:VPL
         LW,V0    VRG01
         MTW,1    RFLDF
         B        VPP3A
LBLVR    LCI      15                FOR ANJR MOVE
         STM,R1   VRGR6
         LW,R6    VRPPD
         CW,R6    VRPMD
         BGE      VPP01             NO VAR REC
         MTW,0    LITF
         BEZ      LBLVR0
         LI,R5    0                 LITERAL SFLD
         B        LBLVR2
LBLVR0   MTW,0    VRPF,R6
         BNEZ     LBLVR1
         LI,R5    1                 SFLD NOT VAR REC
         B        LBLVR2
LBLVR1   LW,R7    VRPF,R6
         LH,R5    R7
         SLS,R5   -2
LBLVR2   STW,R5   TMPR5             SAVE PARAM LNTH
         AWM,R5   VRPPD
         LW,R6    VRPPD
         STW,R6   TMPR6
         MTW,0    VRPF,R6
         BEZ      LBLVR3            NOT VAR RFLD
         LI,R7    0
         STW,R7   VARF
         BAL,L1   VPL00             RESOLVE RFLD VAR REC
LBLVR3   LW,R6    TMPR6
         STW,R6   VRPMD             SET DISP OF PARAM
         SW,R6    TMPR5
         STW,R6   VRPPD             SFLD PARAM DISP
         MTW,0    VARF
         BEZ      VPP01             NO VAR REC - RFLD
         LI,V0    R1
         BAL,L1   VAL00
         B        VPP00+2
VPS0     LCI      15
         STM,R1   VRGR6
         MTW,0    SUBSF
         BNEZ     VPP01             SUBSCRIPT OR INDEX
         LI,R6    0
         STW,R6   VARF
         LW,R6    VRPPD
         CW,R6    VRPMD
         BGE      VPS1
         MTW,0    VRPF,R6
         BNEZ     VPS4
         MTW,1    VRPPD             NOT VAR REC
VPS1     MTW,0    RFLDF
         BLEZ     VPP01
         MTW,-1   RFLDF
         B        VPP01
VPS4     BAL,L1   VPL00             WRITE VAR REC PARAM
         MTW,0    VEXBT
         BEZ      VPS2              NO
         MTW,0    VEXBT+1
         BNEZ     VPS2              VAR REC ENCOUNTERED
         LW,D1    VARF
         BGEZ     VPS2              NO VAR LNTH
         STW,D1   VEXBT+1
         MTW,1    VEXBT+2
         LW,D1    AJAD              ADCON FOR VAR REC
         BNEZ     VPS2
         MTW,4    GADNO
         LW,D1    GADNO
         STW,D1   AJAD              SAVE ADCON
VPS2     LW,V0    VRG01
         B        *VRG01+3
VARF     DATA     0
VREFC    DATA     0
VBIDX    DATA     0                 VAR REC INDEX
VBIDS    DATA     0
NSREF    DATA     0                 SAVE REF NO FLAG
VIRFL    DATA     0                 INDEX REG FLAG
VRPPD    DATA     0
SVPAD    RES      1
TMPR5    RES      1
TMPR6    RES      1
SAVV0    RES      1
VRGR6    RES      7
VRG01    RES      8
VPRSV    RES      1
VREF     RES      200
VPAD     RES      201
RTEMP    RES      1
         END
