         SYSTEM   SIG7FDP
         TITLE    'PHASE 4.1 POF, MCF GENERATORS'
* WRITE PROC                                                            APW
* LF     W---     R-,BA(CLOC)+/-BA OFFSET,RETURN                        APW 1
WPOF     CNAME    0                                                     APW00
WMCF     CNAME    1                                                     APW01
         PROC                                                           APW03
         DO       NUM(AF(2))                                            APW11
LF       LI,R4    AF(2)             LOAD BA(CLOC)                       APW12
         ELSE                                                           APW13
         DO       NUM(AF(1))                                            APW132
LF       LW,R4    AF(1)             LOAD,SET HA(CLOC) TO BA             APW14
         AW,R4    R4                                                    APW15
         FIN                                                            APW16
         FIN                                                            APW17
         DO       NAME                                                  APW80
         DO       NUM(AF(4))                                            APW810
         B        WRMCF             TO WRITE  MCF  CLUSTER              APW803
         ELSE                                                           APW804
         DO       NUM(AF(3))                                            APW801
         LI,L1    AF(3)             LOAD LINK REGISTER                  APW802
         B        WRMCF             WRITE MCF CLUSTER                   APW811
         ELSE                                                           APW812
         BAL,L1   WRMCF             WRITE MCF CLUSTER                   APW813
         FIN                                                            APW814
         FIN                                                            APW818
         ELSE                                                           APW82
         DO       NUM(AF(4))                                            APW840
         B        WRPOF             TO WRITE  POF  CLUSTER              APW823
         ELSE                                                           APW824
         DO       NUM(AF(3))                                            APW821
         LI,L1    AF(3)             LOAD LINK REGISTER                  APW822
         B        WRPOF             WRITE POF CLUSTER                   APW841
         ELSE                                                           APW842
         BAL,L1   WRPOF             WRITE POF CLUSTER                   APW843
         FIN                                                            APW844
         FIN                                                            APW848
         FIN                                                            APW85
         PEND                                                           APW90
* LINK(OR LOAD) AND BRANCH PROC                                         APL
* LF     LAB,L/R  BRANCH ADDRESS,LINK ADDRESS(OR LOAD VALUE)            APL  1
LAB      CNAME                                                          APL01
         PROC                                                           APL04
LF       LI,CF(2) AF(2)             SET LINK REGISTER                   APL12
         B        AF(1)             BRANCH                              APL14
         PEND                                                           APL90
* LOAD,BRANCH AND LINK                                                  PRL
LBAL     CNAME    0                                                     PRL01
         PROC                                                           PRL02
* LF     LBAL,L-  BRANCH,LOAD VALUE,V-                                  PRL09
         DO       NUM(AF(3))                                            PRL20
         LI,AF(3) AF(2)             LOAD VALUE                          PRL22
         ELSE                                                           PRL23
         LI,V0    AF(2)             LOAD VALUE                          PRL24
         FIN                                                            PRL28
         DO       NUM(CF(2))                                            PRL40
         BAL,CF(2) AF(1)            BRANCH                              PRL42
         ELSE                                                           PRL43
         BAL,L1   AF(1)             BRANCH                              PRL44
         FIN                                                            PRL48
         PEND                                                           PRL99
* EXTERNAL REFERENCES
         REF      JAIXC
         REF      JADXC
         REF      JAMOD
         REF      KCVTD
         REF      WRMCF
         REF      WRPOF
         REF      RDMCF
         REF      PDBS              NO. OF BYTES FOR BASE 4(HALF-WORD)
         REF      PDBX              LINE NO.                            AAC063
         REF      PDBZ              DDB ADCONS
*                                             +3 = WA(DBB BASE)
*                                             +4 = NO. OF DDB'S,
*                                                  WA(DBINDX)
         REF      GTMP              TEMP STG
         REF      GADNO             ADCON NO.
* REGISTER EQUIVALENCES
R0       EQU      0
R1       EQU      1
R2       EQU      2
R3       EQU      3
R4       EQU      4
R5       EQU      5
R6       EQU      6                                                     117
R7       EQU      7                                                     116
V0       EQU      8
V1       EQU      9
V2       EQU      10
L0       EQU      V2                                                    1212
L1       EQU      11                LINK REGISTER
D0       EQU      12                DECA
D1       EQU      13
D2       EQU      14
D3       EQU      15
RB       EQU      R6                BIN
RF       EQU      V2                FILE CNTL
RE       EQU      4                 EVEN
RO       EQU      5                 ODD
SR1      EQU      8                 SR1
SR3      EQU      X'A'              SR3
* BA(D-)                                                                CBD
CBD0     EQU      X'30'                                                 CBD0
CBD1     EQU      X'34'                                                 CBD1
CBD2     EQU      X'38'                                                 CBD2
CBD3     EQU      X'3C'
* INDEX REGISTERS                                                       CIR
CIR1     EQU      2                                                     CIR1
CIR2     EQU      4                                                     CIR2
CIR3     EQU      6                                                     CIR3
CIR4     EQU      8                                                     CIR4
CIR5     EQU      X'A'                                                  CIR5
CIR6     EQU      X'C'                                                  CIR6
CIR7     EQU      X'E'                                                  CIR7
* R REGISTERS                                                           CR
CRR1     EQU      X'10'                                                 CR01
CRR2     EQU      X'20'                                                 CR02
CRR3     EQU      X'30'                                                 CR03
CRR4     EQU      X'40'                                                 CR04
CRR5     EQU      X'50'                                                 CR05
CRR6     EQU      X'60'                                                 CR06
CRR7     EQU      X'70'                                                 CR07
CRV0     EQU      X'80'                                                 CR08
CRV1     EQU      X'90'                                                 CR09
CRV2     EQU      X'A0'                                                 CR10
CRL1     EQU      X'B0'                                                 CR11
CRD0     EQU      X'C0'                                                 CR12
CRD1     EQU      X'D0'                                                 CR13
CRD2     EQU      X'E0'                                                 CR14
CRD3     EQU      X'F0'                                                 CR15
CRE      EQU      X'40'             EVEN
CRO      EQU      X'50'             ODD
CRB      EQU      CRR6              BIN
CRF      EQU      CRV2              FILE CNTL
CSR1     EQU      X'80'             SR1                                 CR3
CSR3     EQU      X'A0'             SR3                                 CR3
* OP CODES                                                              C0
CCAL1    EQU      X'0400'           CAL1                                C04
CLI      EQU      X'2200'           LI                                  C22
CLW      EQU      X'3200'                                               C32
CSTW     EQU      X'3500'           STW                                 C35
CSTS     EQU      X'4700'           STS                                 C47
CEOR     EQU      X'4800'           EOR                                 C48
COR      EQU      X'4900'           OR                                  C49
CMBS     EQU      X'6100'           MBS                                 C61
CBDR     EQU      X'6400'                                               C64
CEXU     EQU      X'6700'                                               C67
CBR      EQU      X'6800'           B                                   C68
CBLE     EQU      X'6820'           BLE,BLEZ                            C682
CBEZ     EQU      X'6830'           BEZ                                 C683
CBAZ     EQU      X'6840'           BAZ                                 C684
CBAL     EQU      X'6AB0'           BAL,L1
CLB      EQU      X'7200'                                               C72
CIND     EQU      X'8000'           INDIRECT BIT                        C900
* POF CLUSTER CLNG,CNTL
* INSTRUCTION TYPE
DAIA     EQU      X'0401'           CONSTANT
DAID     EQU      X'0609'           DATA
DAII     EQU      X'0402'           INTERNAL LABEL
DAIL     EQU      X'0406'           LOC. CNTR
DAIP     EQU      X'0404'           PAR/SEC NAME
DAIX     EQU      X'0108'           XREF
* DATA REFERENCE
DARA     EQU      X'0410'           ADCONS
DARB     EQU      X'0417'           BRANCH TABLE
DARC     EQU      X'0419'           COMMON
DARE     EQU      X'0415'           EXIT TABLE
DARF     EQU      X'41A'            FILE LABEL
DARG     EQU      X'0414'           GLOBAL LITERALS
DARL     EQU      X'0418'           LOCAL LITERALS
DART     EQU      X'0416'           TEMP STG
* DATA DEF
DADB     EQU      X'0621'           BINARY
DADD     EQU      X'0829'           DATA REF
DADL     EQU      X'0626'           LOC. CNTR
* DEFINITIONS/DECLARATIONS
DAPI     EQU      X'0341'           INTERNAL LABEL
DAPP     EQU      X'0246'           PRIORITY SEGMENTATION
* ENTRY POINTS
         DEF      PIA00,PIA02,PIA06,PIA08,PIA20,PIA22,PIA26,PIA28
         DEF      PII00,PII02,PII20,PII22
         DEF      PIL00,PIL02,PIL06,PIL20,PIL22,PIL26
         DEF      PID10,PID11,PID12,PID14,PID16,PID18
         DEF      PIX02,PIX06,OIX02
         DEF      PRA00,PRA01,PRA02,PRA04,PRA20,PRA21,PRA22,PRA24
         DEF      PDB02,PDB06
         DEF      PDD00,PDD01,PDD02,PDD03,PDD04,PDD06,PDD08
         DEF      PDX02,PDX06
         DEF      PPI10,PPI12
         DEF      PPI30,PPI32
         DEF      PRT26
*
* POF CLUSTER GENERATORS                                                P
* INSTRUCTIONS                                                          PI
* ABSOLUTE VALUE                                                        PIA
* 4,DAIA M(,R,X)  ABS VAL                                               PIA0
PIA00    RES      0                                                     PIA00
*                        D0,D1 VOLATILE                                 PIA00 9
*                        V0 = OP CODE                                   PIA02 6
*                        D1 = ABS VAL                                   PIA02 7
PIA02    RES      0                                                     PIA020
         LAB,D0   PRA04,DAIA        LOAD ABS VAL CLNG,CNTL, WRITE       PIA024
PIA06    RES      0                                                     PIA060
         LI,D0    DAIA              LOAD ABS VAL CLNG,CNTL              PIA062
*                        *L1 = OP CODE,VALUE                            PIA08 7
*                        RETURN TO *L1+1                                PIA08 9
PIA08    RES      0                                                     PIA080
         LW,D1    *L1               LOAD INSTRUCTION                    PIA082
         AI,L1    1                 SET RETURN                          PIA084
         WMCF     ,CBD0+2,,0        WRITE MCF CLUSTER
*                        D2,D3 VOLATILE                                 PIA20 9
PIA20    RES      0                                                     PIA200
*                        V0 = OP CODE                                   PIA22 6
*                        D3 = ABS VAL                                   PIA22 7
PIA22    RES      0                                                     PIA220
         LAB,D2   PRA24,DAIA        LOAD ABS VAL CLNG,CNTL, WRITE       PIA224
PIA26    RES      0                                                     PIA260
         LI,D2    DAIA              LOAD ABS VAL CLNG,CNTL              PIA262
*                        *L1 = OP CODE,VALUE                            PIA28 7
*                        RETURN TO *L1+1                                PIA28 9
PIA28    RES      0                                                     PIA280
         LW,D3    *L1               LOAD INSTRUCTION                    PIA282
         AI,L1    1                 SET RETURN                          PIA284
         WMCF     ,CBD2+2,,0        WRITE MCF CLUSTER
* INTERNAL LABEL REFERENCE (IREF)                                       PII
* 4,DAII M(,R)    INTL NO.                                              PII0
PII00    RES      0                                                     PII00
*                        D0,D1 VOLATILE                                 PII00 9
         LI,V0    CBR               LOAD OP CODE - B                    PII004
*                        V0 = OP CODE                                   PII02 6
*                        D1 = INTL NO.                                  PII02 7
PII02    RES      0                                                     PII020
         LAB,D0   PRA04,DAII        LOAD ILREF CLNG,CNTL, WRITE         PII024
*                        D2,D3 VOLATILE                                 PII20 9
PII20    RES      0                                                     PII200
         LI,V0    CBR               LOAD OP CODE - B                    PII204
*                        V0 = OP CODE                                   PII22 6
*                        D3 = INTL NO.                                  PII22 7
PII22    RES      0                                                     PII220
         LAB,D2   PRA24,DAII        LOAD ILREF CLNG,CNTL, WRITE         PII224
* LOCATION COUNTER REFERENCE (LCREF)                                    PIL
* 4,DAIL M(,R)    (%)+/-OFFSET                                          PIL0
PIL00    RES      0                                                     PIL00
*                        D0,D1 VOLATILE                                 PIL00 9
*                        V0 = OP CODE                                   PIL02 6
*                        D1 = LOC CNTR OFFSET                           PIL02 7
PIL02    RES      0                                                     PIL020
         LAB,D0   PRA04,DAIL        LOAD LCREF CLNG,CNTL, WRITE         PIL024
PIL06    RES      0                                                     PIL060
         LAB,D0   PIA08,DAIL        LOAD LCREF CLNG,CNTL, WRITE         PIL064
*                        D2,D3 VOLATILE                                 PIL20 9
PIL20    RES      0                                                     PIL200
*                        V0 = OP CODE                                   PIL22 6
*                        D3 = LOC CNTR OFFSET                           PIL22 7
PIL22    RES      0                                                     PIL220
         LAB,D2   PRA24,DAIL        LOAD LCREF CLNG,CNTL, WRITE         PIL224
PIL26    RES      0                                                     PIL260
         LAB,D2   PIA28,DAIL        LOAD LCREF CLNG,CNTL, WRITE         PIL264
* DATA REFERENCE (DREF) - ADDRESS RESOLUTION (ADDR),BASE,DISPL          PID
* 6,DAID M(R,X)   ADDR RES. DATA BASE NO. BA(DISPL)                     PID0
PID00    RES      0                                                     PID00
*                        D3 = DATA BASE NO. DISPL                       PID10 7
*                        D1,D2 VOLATILE                                 PID10 9
PID10    RES      0                                                     PID100
* BA DATA REF                                                           PID1009
         LI,D2    0                 LOAD BA ADDR RES. IND.              PID102
         B        PID12                                                 PID103
* HA DATA REF                                                           PID1039
         LI,D2    1                 LOAD HA ADDR RES. IND.              PID104
         B        PID12                                                 PID105
* WA DATA REF                                                           PID11 9
PID11    RES      0                                                     PID110
         LI,D2    2                 LOAD WA ADDR RES. IND.              PID112
*                        V0 = CONSTANT PORTION                          PID12 6
*                        D2 = ADDR RES. IND.                            PID12 8
PID12    RES      0                                                     PID120
         LI,D1    DAID              LOAD DREF CLNG,CNTL                 PID122
PID14    RES      0                                                     PID140
         STH,V0   D2                STORE OP CODE                       PID142
         WMCF     ,CBD1+2,,0        WRITE MCF CLUSTER
*                                                                       PID16
PID16    RES      0                                                     PID160
         LI,D1    DAID              LOAD DREF CLNG,CNTL                 PID162
*                        *L1 = OP CODE,ADDR RES. IND.                   PID18 7
*                        RETURN TO *L1+1                                PID18 9
PID18    RES      0                                                     PID180
         LW,D2    *L1               LOAD OP CODE, ADDR RES. IND.        PID182
         AI,L1    1                 SET RETURN                          PID184
         B        PID14+1                                               PID186
*
*  C:---
*                        R6 = C:--- INDEX+X'C'
PIX02    RES      0
         LW,V0    KCVTD-X'C',R6     LOAD C:---
PIX04    RES      0
         STW,V0   JAIXC+2           STORE C:---
         WMCF     ,BA(JAIXC),,0     WRITE MCF CLUSTER
PIX06    RES      0
         LW,V0    *L1               LOAD C:---
         AI,L1    1
         B        PIX04
* WA DATA REFERENCE                                                     PR
* ADCONS                                                                PRA
* 4,DARA M(,R,X)  WA(ADCON)                                             PRA0
PRA00    RES      0                                                     PRA00
*                        D0,D1 VOLATILE                                 PRA00 9
         LW,D1    GADNO             LOAD ADCON NO.(BA)                  PRA004
*                        D1 = ADCON NO.(BA)                             PRA01 7
PRA01    RES      0                                                     PRA010
         SLS,D1   -2                ADCON NO.(BA) TO WA                 PRA014
*                        D1 = WA(ADCON)                                 PRA02 7
PRA02    RES      0                                                     PRA020
         LI,D0    DARA              LOAD ADREF CLNG,CNTL                PRA024
*                        V0 = OP CODE                                   PRA04 6
PRA04    RES      0                                                     PRA040
         STH,V0   D1                STORE OP CODE                       PRA044
         WMCF     ,CBD0+2,,0        WRITE MCF CLUSTER
*                        D2,D3 VOLATILE                                 PRA20 9
PRA20    RES      0                                                     PRA200
         LW,D3    GADNO             LOAD ADCON NO.(BA)                  PRA204
*                        D3 = ADCON NO(BA)                              PRA21 7
PRA21    RES      0                                                     PRA210
         SLS,D3   -2                ADCON NO.(BA) TO WA                 PRA214
*                        D3 = WA ADCON                                  PRA22 7
PRA22    RES      0                                                     PRA220
         LI,D2    DARA              LOAD ADREF CLNG,CNTL                PRA224
*                        V0 = OP CODE                                   PRA24 6
PRA24    RES      0                                                     PRA240
         STH,V0   D3                STORE OP CODE                       PRA244
         WMCF     ,CBD2+2,,0        WRITE MCF CLUSTER
* LITERALS                                                              PRL
* TEMP STORAGE                                                          PRT
* 4,DART M(,R)    WA(TEMP STG)
PRT26    RES      0
         LAB,D2   PIA28,DART        LOAD TREF CLNG,CNTL, WRITE
* DATA DEFINITION - ADCONS                                              PD
* AN/DISPLAY                                                            PDA
PDA00    RES      0                                                     PDA00
* BINARY/CONSTANT VALUE                                                 PDB
PDB00    RES      0                                                     PDB00
* 6,DADB BASE NO.,BA(DISPL) BIN/CONST VALUE                             PDB00
*                        V0,D2 = BIN/CONST VALUE                        PDB00 6
*                        D0,D1,D2 VOLATILE                              PDB00 9
PDB02    RES      0                                                     PDB020
         LAB,D0   PDD03,DADB        TO WRITE BIN/CONST VALUE CLUSTER    PDB02
*                        *L1 = OP CODE,ADDR RES. IND.                   PDB06 7
*                        RETURN TO *L1+1                                PDB06 9
PDB06    RES      0                                                     PDB060
         LAB,D0   PDD08,DADB        TO WRITE BIN/CONST VALUE CLUSTER    PDB062
* ** IF CONSTANT VALUE FORMED IN D2, USE ....                           PDB9 0
*        LBAL     PDD04,DADB,D0                                         PDB9 1
*                                       TO WRITE ADCON                  PDB9 2
* DATA                                                                  PDD
* 8,DADD ADCON BASE NO. BA(DISPL) OP CODE/CONST. ADDR RES, IND.         PDD0
*                 DATA BASE NO. BA(DISPL)                               PDD0 2
PDD00    RES      0                                                     PDD00
*                        D3 = DATA BASE NO.,DISPL                       PDD00 7
*                        D0,D1,D2 VOLATILE                              PDD00 9
         LI,D2    0                 LOAD BA ADDR RESOLUTION IND.        PDD002
         B        PDD02                                                 PDD024
         LI,D2    1                 LOAD HA ADDR RESOLUTION IND.        PDD004
         B        PDD02                                                 PDD004
PDD01    RES      0                                                     PDD010
         LI,D2    2                 LOAD WA ADDR RESOLUTION IND.        PDD012
PDD02    RES      0                                                     PDD020
         LI,D0    DADD              LOAD DREF ADCON CLNG,CNTL           PDD022
*                        V0 = OP CODE/CONST PORTION                     PDD03 6
PDD03    RES      0                                                     PDD030
         STH,V0   D2                STORE OP CODE/CONST PORTION         PDD032
PDD04    RES      0                                                     PDD040
         MTW,4    GADNO             ADCON NO. = ADCON NO.+4             PDD042
         LW,D1    GADNO             LOAD ADCON NO.(BA)                  PDD044
         WPOF     ,CBD0+2,,0        WRITE ADCON CLUSTER                 PDD054
PDD06    RES      0                                                     PDD060
         LI,D0    DADD              LOAD DREF ADCON CLNG,CNTL           PDD062
* LOAD COMPLETE CONST PORTION,ADDR RES.IND.                             PDD08
*                        *L1 = OP CODE,ADDR RES. IND.                   PDD08 7
*                        RETURN TO *L1+1                                PDD08 9
PDD08    RES      0                                                     PDD080
         LW,D2    *L1               LOAD CONST PORTION,ADDR RES.IND.    PDD082
         AI,L1    1                 SET RETURN                          PDD084
         B        PDD04                                                 PDD086
* PAR/SEC NAME                                                          PDP
PDP00    RES      0                                                     PDP00
* DEFINITIONS                                                           PP
* EXTERNAL NAME                                                        1
*                        V0 = CONSTANT PORTION
PDX02    RES      0
         STW,V0   JADXC+1           STORE CONSTANT PORTION
PDX06    RES      0                                                    2
         LW,D1    GADNO             LOAD ADCON NO.                     3
         AI,D1    4                 UPDATE,STORE ADCON NO.             5
         STH,D1   JADXC+1                                              6
         STW,D1   GADNO                                                7
         LW,R4    *L1               LOAD,STORE XNAM(':---')            8
         STW,R4   JADXC+3                                              9
         AI,L1    1                 SET RETURN                          PDD084
         WPOF     ,BA(JADXC),,0     WRITE ADCON  C:---                10
* SUBROUTINE CALL
*                        R6 = C: NAME INDEX +X'C'
*                        V0 = OP CODE
*                        R1,R4,V0 VOLATILE
OIX02    RES      0
         LI,R1    1                 LOAD INDEX REGISTER
         STH,V0   JAIXC,R1          STORE OP CODE
         BAL,L1   PIX02             WRITE OP CODE C:---
*                        R1 = 1
         LI,L1    CBAL              STORE BAL,L1
         STH,L1   JAIXC,R1
         B        *L0
* DEFINITIONS                                                           PP
* INTERNAL LABEL                                                        PPI
* 3,DAPI INTL NO.                                                       PPI1
*                        D1 = INTL NO.                                  PPI1 7
*                        V0 VOLATILE                                    PPI1 9
PPI10    RES      0                                                     PPI100
         MTW,1    JINTL             INTL NO. = INTL NO.+1
         LW,D1    JINTL
         B        PPI14
*                           D1 = INTL NO.
PPI12    RES      0                                                     PPI120
         LI,V0    DAPI              LOAD INTL DEF CLNG,CNTL             PPI122
         STH,V0   D1                STORE INTL DEF CLNG,CNTL            PPI124
PPI14    RES      0
         WMCF     ,CBD1,,0          WRITE INTL DEF
PPI30    RES      0                                                      3
         MTW,1    JINTL             INTL NO. = INTL NO.+1                4
         LW,D3    JINTL                                                  5
         B        PPI34                                                  6
*                        D3 = INTL NO.                                   7
PPI32    RES      0                                                      8
         LI,V0    DAPI              LOAD,STORE INTL DEF CLNG,VNTL        9
         STH,V0   D3                                                    10
PPI34    RES      0                                                     11
         WMCF     ,CBD3,,0          WRITE INTL DEF CLUSTER              12
JINTL    EQU      JAMOD+13          INTL DEF,NO.
         END
