         SYSTEM   SIG7FDP
         TITLE    'PHASE 4.1 - I/O'
* REGISTER EQUIVALENCES
R0       EQU      0
R1       EQU      1
R2       EQU      2
R3       EQU      3
R4       EQU      4
R5       EQU      5
R6       EQU      6                                                     117
R7       EQU      7                                                     116
V0       EQU      8
V1       EQU      9
V2       EQU      10
L0       EQU      V2                                                    1212
L1       EQU      11                LINK REGISTER
D0       EQU      12                DECA
D1       EQU      13
D2       EQU      14
D3       EQU      15
RB       EQU      R4
LL       EQU      D3
*                                                                       AA0
         DEF      ABO00             OPEN
         DEF      ABQ00             CLOSE
         DEF      ABR00             READ
         DEF      ABW00             WRITE
         DEF      ABS00             SEEK
         DEF      ABB00             USE
         DEF      ABO02,ABQ10
         DEF      ADO00,ADO10,ADO30,ADO50
         REF      JMCRD             SORT RETURN SWITCH
         REF      RDCRF
         REF      WRPOF
         REF      WRMCF
         REF      DIAG
         REF      PDBS              NO. OF BYTES FOR BASE 4(HALF-WORD)
         REF      PDBZ              DDB ADCONS
*                                             +3 = WA(DBB BASE)
*                                             +4 = NO. OF DDB'S,
*                                                  WA(DBINDX)
         REF      AA01,AA02,AA03    M.C. RETURNS
         REF      AA09,AA092        DIAG RETURNS
         REF      AA10,AA11,AA12    WRITE MCF RETURNS/SUBR.
         REF      AA15,AA16,AA17    INTL DEF
         REF      AA18,AA19         INTL REF
         REF      AA30              REGISTER LOAD
         REF      AA46              BIN ADCON
         REF      AA49,AA50,AA51,AA52  ADCON
         REF      AA60,AA61         ADCON REF
         REF      AAC00             READ
         REF      ADI00,ADI02       REF
         REF      PIA22                                                  2
         REF      PIA26
         REF      PDD06,PRA01
         REF      PII20,PII22
         REF      JAKON             CONSTANTS
         REF      JADAT             DATA
         REF      JASAV             SAVE AREA
         REF      JAMOD             MODEL CLUSTERS,BUFFER
         REF      MAIOC,KABCG
         REF      STBAS             DATA STACK
         REF      ADV00,ADS00,ADW00
         REF      SORTFG,SRTOC      SORT FLAG/OPEN SRT FILE MCF         COBOL41C
* READ PROC                                                             APR
* LF     R---     R-,+/-HW OFFSET,INDIRECT ADDR.                        APR  1
RCRF     CNAME    2                                                     APR02
         PROC                                                           APR04
         DO       NAME>1                                                APR10
LF       BAL,L1   AAC00             READ CRF CLUSTER                    APR11
         ELSE                                                           APR12
         DO       NAME                                                  APR13
LF       BAL,L1   AAE00             READ ECF CLUSTER                    APR14
         ELSE                                                           APR15
LF       BAL,L1   *AF(3)            READ CRF/ECF CLUSTER                APR16
         FIN                                                            APR17
         FIN                                                            APR18
         DO       NUM(AF(1))                                            APR30
         LW,AF(1) R2                LOAD HA(CLOC)+/- HW OFFSET          APR31
         DO       NUM(AF(2))                                            APR40
         AI,AF(1) AF(2)                                                 APR41
         ELSE                                                           APR42
         AI,AF(1) 1                                                     APR43
         FIN                                                            APR44
         FIN                                                            APR44
         PEND                                                           APR50
* WRITE PROC                                                            APW
* LF     W---     R-,BA(CLOC)+/-BA OFFSET,RETURN                        APW 1
WMCF     CNAME    1                                                     APW01
         PROC                                                           APW03
         DO       NUM(AF(2))                                            APW11
LF       LI,R4    AF(2)             LOAD BA(CLOC)                       APW12
         ELSE                                                           APW13
         DO       NUM(AF(1))                                            APW132
LF       LW,R4    AF(1)             LOAD,SET HA(CLOC) TO BA             APW14
         AW,R4    R4                                                    APW15
         FIN                                                            APW16
         FIN                                                            APW17
         DO       NAME                                                  APW80
         DO       NUM(AF(4))
         B        WRMCF             WRITE MCF CLUSTER
         ELSE
         DO       NUM(AF(3))
         LI,L1    AF(3)             LOAD LINK REGISTER
         B        WRMCF             TO WRITE MCF CLUSTER
         ELSE                                                           APW812
         BAL,L1   WRMCF             WRITE MCF CLUSTER                   APW813
         FIN                                                            APW814
         FIN                                                            APW818
         ELSE                                                           APW82
         DO       NUM(AF(4))
         B        WRPOF             WRITE POF CLUSTER
         ELSE
         DO       NUM(AF(3))
         LI,L1    AF(3)             LOAD LINK REGISTER
         B        WRPOF             TO WRITE POF CLUSTER
         ELSE                                                           APW842
         BAL,L1   WRPOF             WRITE POF CLUSTER                   APW843
         FIN                                                            APW844
         FIN                                                            APW848
         FIN                                                            APW85
         PEND                                                           APW90
* DIAG PROC                                                             APD
DX       CNAME                                                          APD00
         PROC                                                           APD01
* AF     DX       DIAG CODE,LINK                                        APD02
LF       LI,R1    AF(1)             LOAD DIAG CODE                      APD10
         DO       NUM(AF(3))
         B        DIAG              WRITE DMF CLUSTER
         ELSE
         DO       NUM(AF(2))
         LI,L1    AF(2)             LOAD LINK REGISTER
         B        DIAG              WRITE DMF CLUSTER                   APD242
         ELSE                                                           APD243
         BAL,L1   DIAG              WRITE DMF CLUSTER                   APD244
         FIN                                                            APD248
         FIN                                                            APD29
         PEND                                                           APD40
* LINK(OR LOAD) AND BRANCH PROC                                         APL
* LF     LAB,L/R  BRANCH ADDRESS,LINK ADDRESS(OR LOAD VALUE)            APL  1
LAB      CNAME                                                          APL01
         PROC                                                           APL04
LF       LI,CF(2) AF(2)             SET LINK REGISTER                   APL12
         B        AF(1)             BRANCH                              APL14
         PEND                                                           APL90
* LOAD,BRANCH AND LINK                                                  PRL
LBAL     CNAME    0                                                     PRL01
         PROC                                                           PRL02
* LF     LBAL,L-  BRANCH,LOAD VALUE,V-                                  PRL09
         DO       NUM(AF(3))                                            PRL20
         LI,AF(3) AF(2)             LOAD VALUE                          PRL22
         ELSE                                                           PRL23
         LI,V0    AF(2)             LOAD VALUE                          PRL24
         FIN                                                            PRL28
         DO       NUM(CF(2))                                            PRL40
         BAL,CF(2) AF(1)            BRANCH                              PRL42
         ELSE                                                           PRL43
         BAL,L1   AF(1)             BRANCH                              PRL44
         FIN                                                            PRL48
         PEND                                                           PRL99
* DIAG CODE BASE EQUIVALENCES
XFS      EQU      148               S DIAG CODE BASE - FILE,RECORD
XFW      EQU      159               W DIAG CODE BASE - FILE,RECORD
*
CABO     EQU      X'360'            OPEN - OPTION ONLY
CBATE    EQU      X'FE300'          AT END
CBORV    EQU      8                 REVERSED OPTION
CBSDN    EQU      X'F9200'        A SUBSCRIPT DATA NAME                 ADJ142
CDIM     EQU      7                 NDIM MASK
CISAV    EQU      X'80000'          SAVE REF FLAG                       ADI455
CLOP     EQU      X'80'           A LAST OPERAND                        A
CMI      EQU      4                 MISCELLANEOUS SEG INCREMENT
CJINT    EQU      X'60B9D'          INTEGER                              5
DFCOS    EQU      X'800'            OUTSORT LABEL FLAG                   6
* MCF CLUSTER CLNG,CNTL
DABC     EQU      X'04C4'           MOVE
DABO     EQU      X'9C2'            I/O CALL
* POF CLUSTER CLNG,CNTL
DAII     EQU      X'0402'           INTERNAL LABEL
* OP CODES
CBR      EQU      X'6800'
DBBR     EQU      X'6800'         P OP CODE - B                         ABT123
CBEZ     EQU      X'6830'
DBCAL    EQU      X'0410'           OP CODE - CAL1,1
DBLI     EQU      X'2200'                                                8
* R REGISTERS                                                            9
CRB      EQU      X'40'                                                 10
CRR1     EQU      X'10'                                                 11
* REF DATA TYPE CONTROL SETTINGS
IBCG     EQU      X'2000'                GROUP                          ABC032
IBCS     EQU      X'9000'           MOVE SFLD                           ABC001
IBCI     EQU      X'60'             INTEGER ONLY                        ABP131
*
IPBU     EQU      X'620'            PREF CNTL
COB41CDB EQU      %                 BEGINNING OF MODULE                 COBOL41C
LAST%OPT RES      1                 OPTIONS FROM PREVIOS CLUSTER        COBOL41C
         REF      TBL%INDX,DECL%TBL                                     COBOL41C
FLG%BFOR EQU      2                 USE BEFORE...                       COBOL41C
FLG%ERR  EQU      4                 USE ....ERROR                       COBOL41C
FLG%BGIN EQU      X'10'             USE ... BEGINNING                   COBOL41C
FLG%FILE EQU      2                 USE ....FILE                        COBOL41C
DDB%CUR  RES      1                                                     COBOL41C
BYTE%NO  RES      1                                                     COBOL41C
CUR%OPTN RES      1                                                     COBOL41C
FLG%RL%F EQU      X'7'
FLG%B%E  EQU      X'30'
IO%I%O   EQU      X'38'
FLG%RL%U EQU      1                                                     COBOL41C
FLG%INP  EQU      8                                                     COBOL41C
FLG%OUT  EQU      X'10'                                                 COBOL41C
FLG%IO   EQU      X'20'                                                 COBOL41C
         DEF      USEBRP            DEF USE BEF REPORT FG       EL27275 COBOL41C
         DEF      COB41CDB          DEF START C.W. 4-7-76               COBOL41C
USEBRP   DATA     0                 SET > 0 IF FOR USE BEFORE REPORT    EL2725 C
KMAST    DATA     X'04C4'           MOVE MASTER CLUSTER                 COBOL41C
KCONV    DATA     X'0004'           AN RFLD                             COBOL41C
*
* USE                               TYPE = X'6C'                        ABB
*                        R6 = STMT OPTION                                1
ABB00    RES      0                                                     ABB00
         CI,R6    8                 CHECK REPORTING FLAG                 3
         BAZ      ABB02             JUMP IF NO USE BEF REPORTING EL27275 COBOL41
         MTW,1    USEBRP            SET USEBRP > 0              EL27275 COBOL41C
         B        AA02
ABB02    LI,R3    0                 IF NOT USE BEF REPORTING, SET EL27275 COBOL4
         STW,R3   USEBRP            USEBRP = 0                  EL27275 COBOL41C
         LW,V2    JSTYP             LOAD,COMBINE DECLA. XNO,PDNO         2
         LW,V1    JPTYP                                                  3
         STH,V2   V1                                                     4
         STW,R3   CUR%OPTN
ABB04    RES      0                                                     17
         RCRF     R5                READ NEXT CLUSTER                   18
         LH,R3    0,R2              IF                                  COBOL41C
         AND,R3   K3FF               NOT A 'USE'                        COBOL41C
         CI,R3    X'6C'              CLUSTER                            COBOL41C
         BNE      AA03              GO BACK TO PROCESS                  COBOL41C
         LH,R7    0,R5                                                  COBOL41C
         OR,R7    CUR%OPTN
         LI,R3    0                 INDEX SET 0                         COBOL41C
         CI,R6    FLG%BFOR                                              COBOL41C
         BANZ     CHK%BGIN          IF NOT BEFORE                       COBOL41C
         LI,R3    -4                 SET -1                             COBOL41C
         CI,R6    FLG%ERR                                               COBOL41C
         BANZ     CHK%FNM            IF ERROR (ALSO BYPASS CHECKING)    COBOL41C
         LI,R3    1                   OR +1 IF AFTER                    COBOL41C
CHK%BGIN EQU      %                                                     COBOL41C
         CI,R6    FLG%BGIN          IF                                  COBOL41C
         BANZ     CHK%FILE           ENDING                             COBOL41C
         AI,R3    2                  ADD 2                              COBOL41C
CHK%FILE EQU      %                                                     COBOL41C
         CI,R7    FLG%FILE          IF                                  COBOL41C
         BANZ     CHK%FNM            NOT FILE  (IE, REEL/UNIT)          COBOL41C
         AI,R3    4                  ADD 4                              COBOL41C
* R3 VALUE IS NOW SET AS FOLLOWS... 0=BEFORE BEGINNING FILE, 1=AFTER    COBOL41C
* BEGINNING FILE, 2=BEFORE ENDING FILE, 3=AFTER ENDING FILE, 4=BEFORE   COBOL41C
* BEGINNING REEL, 5=AFTER BEGINNING REEL, 6=BEFORE ENDING REEL, 7=AFTER COBOL41C
* ENDING REEL, -4= AFTER ERROR                                          COBOL41C
CHK%FNM  EQU      %                                                     COBOL41C
         STW,R3   BYTE%NO           SAVE BYTE NUMBER                    COBOL41C
         STW,R7   CUR%OPTN
         STW,R6   LAST%OPT          SAVE CLUSTER #1 OPTIONS             COBOL41C
         CI,R7    IO%I%O            IF INPUT OUTPUT OR I/O OPTION
         BANZ     NOT%FNM           BRANCH
         LH,R7    1,R2              LOAD DDB NO.                        COBOL41C
         BAL,L0   ADO10             CHECK FILE                          COBOL41C
         B        ABB04
* VALID FILE      NOTE R7 HAS DDB WORD ADDRESS IN IT                    COBOL41C
         LW,R3    BYTE%NO                                               COBOL41C
         CI,R3    0
         BL       NOT%LBLD          NOT  LABEL DECLARATIVE
         LW,R5    *R7
         CI,R5    X'30000'          ARE LABEL RECORDS  OMITTED
         BAZ      DEC%INV           YES
NOT%LBLD EQU      %
         AI,R7    6                 POINY TO WORD SIX OF DDB
         LW,R5    TBL%INDX                                              COBOL41C
         CI,R5    X'FF'                                                 COBOL41C
         BG       XS%DECL                                               COBOL41C
TST%OLD  LB,R4    *R7,R3            IS THERE A PREVIOUS DECL
         BEZ      STOR%PTR          NO
         CI,R4    27                IS IT A FILE DECL
         BL       STOR%PTR          NO  OVERIDE IT
         LI,R1    220
         BAL,L1   DIAG           ISSUE DIAG
         B        STOR%PTR+1
STOR%PTR EQU      %
         STB,R5   *R7,R3            STORE  INDEX
         CI,R3    0                 ERROR  PROCEDURE
         BL       UPDT%PTR          YES
         LI,R4    FLG%B%E           BEGINNING OR ENDING FLAG SET
         CW,R4    LAST%OPT
         BANZ     CHK%RL%F          YES
         CI,R3    2                 HAS BEGINING BEEN STORED
         BAZ      SETPT%UP          YES
         AI,R3    -2                SET TO BEGINNING
         B        TST%OLD           GO STORE IT
SETPT%UP AI,R3    2                 RESET TO ENDING
CHK%RL%F LI,R4    FLG%RL%F          REEL UNIT  FILE  FLAG SET
         CW,R4    CUR%OPTN
         BANZ     UPDT%PTR          YES
         CI,R3    4                 HAS FILE  BEEN STORED
         BAZ      UPDT%PTR          YES
         AI,R3    -4                SET TO FILE
         B        TST%OLD           GO STORE IT
UPDT%PTR EQU      %                                                     COBOL41C
         MTW,1    TBL%INDX                                              COBOL41C
         STW,V1   *DECL%TBL,R5                                          COBOL41C
         B        ABB04                                                 COBOL41C
DEC%INV  EQU      %                 DECL INVALID  LABEL ARE OMITTED
XS%DECL  EQU      %                 NOT CORRECT MESSAGE
         DX       XFS+69,ABB04
*                                                                       COBOL41C
* DECLARATIVE FOR INPUT, OUTPUT OR I-O...APPLY TO ALL FILES             COBOL41C
NOT%FNM  EQU      %                                                     COBOL41C
         LW,R5    CUR%OPTN                                              COBOL41C
         CI,R5    FLG%INP                                               COBOL41C
         BAZ      NOT%IN
         LI,R5    1                                                     COBOL41C
         B        MODE%SET                                              COBOL41C
NOT%IN   EQU      %                                                     COBOL41C
         CI,R5    FLG%OUT                                               COBOL41C
         BAZ      NOT%OUT
         LI,R5    2                                                     COBOL41C
         B        MODE%SET                                              COBOL41C
NOT%OUT  EQU      %                                                     COBOL41C
         LI,R5    4
MODE%SET EQU      %
         LB,R4    PDBZ+4            NO OF DESCRIPTION BLOCKS
         LI,R2    1                 CONSTANT
NEXT%DDB EQU      %
         LH,R7    *PDBZ+4,R4        DISPLACEMENT BYTE OF LAST  DB
         SLS,R7   -2
         AW,R7    PDBZ+3            WORD ADD OF DB BASE
         STW,R7   DDB%CUR           SAVE DDB ADDR
         CB,R2    *DDB%CUR          IS IT AN FD
         BNE      MORE%DDB          NO--BRANCH
         LW,R3    BYTE%NO           GET INDEX
         CI,R3    0
         BL       NOT%LABD          NOT  LABEL  DECLARATIVE
         LW,R7    *DDB%CUR
         CI,R7    X'30000'         ARE LABEL RECORDS OMITTED
         BAZ      MORE%DDB
NOT%LABD RES      0
         MTW,6    DDB%CUR           INCREMENT  DDB TO DDB+6
OPT%LOOP LB,R7    *DDB%CUR,R3       GET OLD INDEX
         BEZ      STUFF%IT          NONE---OK--BRANCH
         CI,R7    X'07'             FILE INDEX
         BG       CHK%DFLT
         CW,R7    R5                SAME AS THIS ONE
         BAZ      NO%PRED           NO PREVIOUS  CLASS DECLARATIVE
         LI,R1    220
         BAL,L1   DIAG           ISSUE DIAG
         B        CHK%DFLT
NO%PRED  RES      0
         OR,R7    R5                NO  COMBINE  THEM
         STB,R7   *DDB%CUR,R3       STORE
         B        CHK%DFLT
STUFF%IT EQU      %
         STB,R5   *DDB%CUR,R3       STORE INDEX
CHK%DFLT EQU      %
         CI,R3    0
         BL       MORE%DDB
         LI,R7    FLG%B%E           IS BEGINING OR ENDING PRESENT
         CW,R7    LAST%OPT
         BANZ     CHK%F%RL          YES--BRANCH
         CI,R3    2                 HAS BEGINING BEEN STORED
         BAZ      SET%PTUP          YES-- BRANCH
         AI,R3    -2                SET TO  BEGINNING
         B        OPT%LOOP          GO STORE IT
SET%PTUP AI,R3    2                 RESET  TO ENDING
CHK%F%RL LI,R7    FLG%RL%F          IS REEL UNIT  FILE PRESENT
         CW,R7    CUR%OPTN
         BANZ     MORE%DDB          YES--BRANCH
         CI,R3    4                 HAS FILE BEEN STORED
         BAZ      INCRBY4
         AI,R3    -4                SET TO FILE
         B        OPT%LOOP          GO STORE IT
INCRBY4  AI,R3    4
MORE%DDB EQU      %
         BDR,R4   NEXT%DDB          LOOP  THROUGH  DDB'S
         LW,R2    R3
         CI,R3    -4                ERROR PROCEDURE
         BNE      %+2               NO
         LI,R3    8                 YES-- SET TO 8
         SLS,R5   -1              CHANGE TO 0/1/2
         MI,R5    9             MULT BY NUMBER OF ENTRIES
PNOLOOP  RES      0
         AW,R3    R5
         STW,V1   *DECL%TBL,R3      STORE
         CI,R2    0
         BL       AA02
         LI,R7    FLG%B%E
         CW,R7    LAST%OPT
         BANZ     CHKABC2
         CI,R2    2
         BAZ      CHKABC1
         AI,R2    -2
         LW,R3    R2
         B        PNOLOOP
CHKABC1  AI,R2    2
CHKABC2  LI,R7    FLG%RL%F
         CW,R7    CUR%OPTN
         BANZ     AA02
         CI,R2    4
         BAZ      AA02
         AI,R2    -4
         LW,R3    R2
         B        PNOLOOP
ABO00    RES      0                                                     ABO00
         BAL,L0   ADO00             CHECK FILE                          ABO002
         B        ABO40             INVALID FILE                        ABO003
* VALID FILE                                                            ABO10
ABO02    RES      0
         LI,D2    3                 MASK,SET FUNCTION MODE              ABO101
         AND,D2   R6                                                    ABO102
         AI,D2    1                                                     ABO103
         CI,D0    X'8000'           CHECK FOR LABELS                    ABO107
         BAZ      ABO20             LABELS OMITTED                      ABO108
* LABELLED FILE                                                         ABO12
         LW,V1    6,R7              LOAD DECLA. STDEC INDEX,OPTION BITS  2
         CW,D2    V1                CHECK AFTER LABEL OPTION             3
         BANZ     ABO12             SET. USE AFTER ...                   4
         CH,D2    V1                CHECK BEFORE LABEL OPTION            5
         BAZ      ABO18             NOT SET. NO DECLA.                   6
* LABEL DECLARATIVE                                                     ABO13
ABO12    RES      0                                                      8
         LB,R1    JFDEC             CHECK DECLA FLAG                     9
         BEZ      ABO14             DOWN NOT DECLARATIVE SECTION        ABO132
* S*****LABEL CHECK IN DECLARATIVE SECTION***                           ABO133
* LABELLED FILE - DECLARATIVE                                           ABO14
         DX       XFS+2,ABO18       WRITE DMF CLUSTER                   ABO135
ABO14    RES      0                                                     ABO140
         LW,R1    D2                LOAD,SET OPTION INDEX               11
         SLS,R1   -1
         AI,D2    X'1000'           RAISE DECLARATIVE AFTER FLAG        ABO141
         CW,D2    V1                CHECK AFTER LABEL OPTION            14
         BANZ     ABO16             SET. USE AFTER ...                  15
* USE BEFORE ...                                                        16
         AI,D2    X'1000'           RAISE DECLARATIVE BEFORE FLAG       ABO144
*                                                                       ABO16
ABO16    RES      0                                                     ABO160
         LB,V1    V1                SET STDEC INDEX                     18
         AW,R1    V1                                                    19
*                                                                       ABO18
ABO18    RES      0                                                     ABO180
         AI,D2    X'8000'           RAISE LABELLED FLAG                 ABO181
         CI,R6    DFCOS             CHECK OUTSORT FLAG
         BAZ      ABO20             DOWN. NOT OUTSORT.
* OUTSORT
         AI,D2    DFCOS             RAISE OUTSORT FLAG
*                                                                       ABO20
ABO20    RES      0                                                     ABO200
         CI,R6    X'C'              CHK REVERSED/NO REWIND OPTION FLAGS ABO202
         BAZ      ABO28             DOWN                                ABO203
* REVERSED/NO REWIND OPTION                                             ABO22
         CI,D0    X'400'            CHECK FOR RANDOM ACCESS             ABO222
         BAZ      ABO24             NO. SEQUENTIAL                      ABO223
* S*****INVALID REVERSED/NO REWIND OPTION***                            ABO227
ABO23    RES      0                                                     ABO230
         DX       XFS+3,ABO28       WRITE DMF CLUSTER                   ABO235
*                                                                       ABO24
ABO24    RES      0                                                     ABO240
         CI,R6    8                 CHECK FOR REVERSED OPTION           ABO241
         BAZ      ABO26             NO. NO REWIND
* REVERSED OPTION                                                       ABO25
         CI,D2    2                 CHECK FUNCTION MODE                 ABO251
         BANZ     ABO23             OUTPUT, INVALID REVERSED            ABO252
         AI,D2    X'20'             RAISE REVERSED FLAG                 ABO253
         B        ABO30                                                 ABO254
* NO REWIND
ABO26    RES      0
         AI,D2    8                 RAISE NO REWIND FLAG
ABO28    RES      0                                                     ABO280
         CI,D2    2                 CHECK FUNCTION MODE                 ABO281
         BANZ     ABO32             OUTPUT                              ABO282
*                                                                       ABO30
ABO30    RES      0                                                     ABO300
         CI,D0    X'80'             CHECK FOR OPTIONAL FILE             ABO302
         BAZ      ABO32                                                 ABO303
* OPTIONAL FILE                                                         ABO31
         AI,D2    X'80'             RAISE OPTIONAL FLAG                 ABO312
         STW,D1   JINTL             UPDATE INTL NO.                     ABO322
ABO32    RES      0
         STH,D2   MAIOC+1           STORE OPEN OPTIONS                  ABO341
ABO34    OR,D2    1,R7              SET OPTIONS TO FILE STATS           COBOL41C
         STW,D2   1,R7                                                  ABO343
         WMCF     ,BA(MAIOC)+2      WRITE OPEN CLUSTER                  ABO344
*                                                                       ABO36
ABO40    RES      0                                                     ABO400
         CI,R6    CLOP              CHECK LAST OP FLAG                  ABO402
         BANZ     *JMCRD            UP. E-O-STMT.
* ANOTHER FILE                                                          ABO42
         LH,R6    0,R5              LOAD REF OPTION                     ABO422
         LH,R7    1,R2              LOAD DDB NO.                        ABO424
         B        ADO00             PROCESS NEXT FILE                   ABO426
* WRITE                             TYPE = X'6D'                        ABP
ABW00    RES      0                                                     ABP00
         LH,D2    1,R5              LOAD,CHECK RECORD TYPE              ABP001
         CI,D2    X'5000'                                               ABP002
         BGE      ABW02             VALID NORMAL/LABEL RECORD           ABP003
* S*****INVALID RECORD NAME*********                                    ABP01
         DX       XFS+1,AA02        WRITE DMF CLUSTER                   ABP012
* VALID RECORD                                                          ABP02
ABW02    RES      0                                                     ABP020
         BAL,L1   ADS00             SAVE VAR REC PARAM
         AND,D2   K2F00F            SET TO GROUP                        ABP021
         STH,D2   1,R5                                                  ABP022
         LI,V2    IBCG+CISAV        LOAD REF CNTL(GRP ONLY)             ABP023
         BAL,L1   ADI02             CHECK RREF                          ABP024
         B        AA03              INVALID RREF                        ABP025
*                                                                       ABP04
*                        R6 = RECORD(GRP) CLNG,CNTL(LAST OP BIT SET)    ABP04 6
         LH,R7    JTDB              LOAD DDB NO.                        ABP041
         BAL,L0   ADO30-1           CHECK FILE                          ABP044
         B        AA03              INVALID FILE                        ABP046
* VALID FILE                                                            ABP06
*                                                                       ABP06
*                        R7 = WA(DDB)                                   ABP06 5
*                        D0 = DB TYPE,FILE DESCRIPTOR                   ABP06 6
*                        D1 = INTL NO.                                  ABP06 7
*                        D3 = DCB BASE NO.,0                            ABP06 9
         STH,V1   MAIOC+4           STORE SIZE                          ABP062
         LI,R5    X'200'            LOAD ERROR OUTPUT BIT
         BAL,L0   ABR04             TO CHECK FOR KEY,DECLARATIVE        ABP063
         LI,D2    X'1000'           LOAD WRITE OPTION                   ABP064
         LW,D3    R7                SAVE WA(DDB)                        ABP069
*                                                                       ABP08
ABW08    RES      0                                                     ABP080
         LI,V0    0                 N.S. INTL = 0
         LI,R5    1                 SET HA(CLOC)+1                      ABP081
         AW,R5    R2                                                    ABP082
         LH,V1    0,R2              CHECK FOR NEW STMT                  ABP083
         CI,V1    CLOP                                                  ABP084
         BANZ     ABR27             YES. NEW STMT.
* OPTIONS                                                               ABP10
         LH,R7    0,R5              LOAD,CHECK OPTION                   ABP101
         CI,R7    X'F'                                                  ABP102
         BAZ      ABR26               INVALID KEY OPTION
         CI,R7    1                 CHECK FOR FROM                      ABP104
         BAZ      ABW20             NOT FROM - BEFORE/AFTER             ABP105
* FROM OPTION                                                           ABP12
         LI,V2    IBCS+CISAV        LOAD REF CNTL                       COBOL41C
         BAL,L1   ADI02             CHECK FROM DREF                     ABP122
         B        ABW08             INVALID DREF                        ABP123
* VALID FROM DREF                                                       ABP14
         LW,R5    R4                SAVE HA(FROM DREF)                  ABP141
         LH,R7    R6                LOAD SFLD TYPE                      COBOL41C
         CI,R7    -2                SEE IF GROUP                        COBOL41C
         BE       ABW09             YES DO GROUP TO GROUP MOVE          COBOL41C
         STH,R7   KCONV             NO DO TYPE OF MOVE REQUIRED         COBOL41C
         WMCF     ,BA(KMAST)+2      WRITE MOVE MASTER CLUSTER           COBOL41C
         B        ABW10             CONTINUE                            COBOL41C
ABW09    EQU      %                                                     COBOL41C
         WMCF     ,BA(KABCG)+2      WRITE MOVE GRP CLUSTER              ABP142
ABW10    EQU      %                                                     COBOL41C
         LW,R4    R5
         AW,R4    R4
         BAL,L1   ADV00             RESOLVE VAR PARAM
         BAL,L1   WRMCF             FROM DREF CLUSTER
         LI,R4    BA(STBAS)+2
         BAL,L1   ADV00
         BAL,L1   WRMCF             RECORD CLUSTER
         B        ABW08                                                 ABP148
* BEFORE/AFTER OPTION                                                   ABP20
ABW20    RES      0                                                     ABP200
         LI,V2    IBCI+CISAV+X'20000' LOAD REF CNTL                     16
         BAL,L1   ADI00             CHECK BEFORE/AFTER FLD              17
         B        ABW08             INVALID BEFORE/AFTER FLD            18
         B        ABW21             BEFORE/AFTER ZERO/INTEGER/DATA NAME 19
* BEFORE/AFTER MNEMONIC NAME                                            20
*                        V0 = VALUE FLAG,VALUE                          21
         AI,V0    -X'300'           CLEAR VALUE FLAG
         B        ABW25                                                 23
* BEFORE/AFTER ZERO/INTEGER/DREF                                        24
ABW21    RES      0
         CI,R6    CJINT             CHECK TYPE                          26
         BL       ABW26             DATA NAME                           27
         BG       ABW23             ZERO                                28
* BEFORE/AFTER INTEGER                                                  ABP22
         LH,V0    5,R5              LOAD,CHECK INTEGER VALUE            31
         BLZ      ABW22             < 0                                 32
         CI,V0    X'10'                                                 33
         BLE      ABW24             </= MAX. VFC VALUE                  34
* > MAX. VFC VALUE                                                      40
         AI,V0    X'F'              INTEGER(I) = I-1 + X'10'            41
         SLD,V0   -4                I = I/16, SAVE MOD(16,I)            42
         LW,D3    V0                LOAD I                              43
         LBAL     PIA22,DBLI+CRB    WRITE LI,RB I                       44
*                        V1 = MOD(16,I),0 - DSIZ(=10) SHIFTED OFF       46
         SCS,V1   4                 POSITION MOD(16,I)                  47
         AI,V1    X'C0'             VFC CHAR. = MOD(16,I)+X'C0'         48
         LW,D3    V1                LOAD VFC CHAR.                      49
         LBAL     PIA22,DBLI+CRR1   WRITE LI,R1 VFC CHAR.               50
         LD,D2    ADISAV+4          RESTORE REGISTERS                   51
         AI,D2    X'100'            SET BEFORE/AFTER INTEGER OPTION     ABP2226
         B        ABW28-1
* W*****BEFORE/AFTER INTEGER < 0 LINES***                               54
ABW22    RES      0                                                     55
         DX       XFW               WRITE DMF CLUSTER                   56
* = 0                                                                   57
ABW23    RES      0                                                     58
         LI,V0    X'60'-X'C0'+1     SET TO SUPPRESS SPACING(VFC = X'60')59
* </= MAX. VFC VALUE                                                    60
ABW24    RES      0                                                     61
         AI,V0    X'C0'-1           VFC = X'C0'+INTEGER-1               62
* BEFORE/AFTER MNEMONIC NAME                                            63
*                        V0 = MNEMONIC NAME VALUE(VFC CHAR.)            64
ABW25    RES      0                                                     65
         AW,D2    V0                                                    66
         B        ABW28                                                 ABP234
* BEFORE/AFTER DATA NAME                                                ABP26
ABW26    RES      0                                                     ABP260
         AI,D2    X'200'            SET BEFORE/AFTER DREF OPTION        ABP271
         LI,V0    X'4D'             LOAD BIN LOAD REG,CLASS
         BAL,L1   AA30+1            WRITE BIN LOAD CLUSTER
         AI,D1    1                 INTL NO. = INTL NO.+1
*                        R7 = STMT OPTION                               70
ABW28    RES      0                                                     ABP280
         SLS,R7   9                 POSITION,STORE BEFORE/AFTER OPTIONS ABP281
         AW,D2    R7                                                    ABP283
         B        ABW08                                                 ABP287
* CLOSE                             TYPE = X'53'                        ABQ
ABQ00    RES      0                                                     ABQ00
         BAL,L0   ADO00             CHECK FILE                          ABQ001
         B        ABO40             INVALID FILE                        ABQ004
* VALID FILE                                                            ABQ02
*                        R7 = WA(DDB)                                   ABQ02 5
*                        D0 = DB TYPE,FILE DESCRIPTOR                   ABQ02 6
*                        D1 = INTL NO.                                  ABQ02 7
*                        D3 = DCB BASE NO.,0                            ABQ02 9
         CI,R6    3                 CHECK FOR REEL/UNIT OPTION          ABQ026
         BAZ      ABQ10             NO. CLOSE FILE                      ABQ027
* CLOSE REEL/UNIT                                                       ABQ04
* FOREIGN FILE
         LI,D2    X'220'            LOAD CLOSE REEL OPTION
         CI,R6    4                 CHECK NO REWIND FLAG
         BAZ      ABO30             DOWN. REWIND
* NO REWIND
         AI,D2    8                 RAISE NO REWIND FLAG
         B        ABO30
* NOT FOREIGN FILE
ABQ04    RES      0
         BAL,L1   PDD06             WRITE
         GEN,8,24 X'03',2           ****  FPT WORD 0 - CVOL,WA(DCB)
         LI,V0    DBCAL             LOAD OP CODE - CAL1,1               ABQ062
         LAB,L1   PRA01,ABO40       WRITE CAL1,1  FPT WORD 0
*                                                                       ABQ09
* CLOSE FILE                                                            ABQ1
ABQ10    RES      0                                                     ABQ100
         LI,D2    X'C'              MASK,SET LOCK/NO REWIND OPTIONS     ABQ102
         AND,D2   R6                                                    ABQ103
         AW,D2    D2                                                    ABQ104
         AI,D2    X'200'            SET CLOSE OPTION                    ABQ105
         MTW,0    SORTFG            IS FOR NON-RES SORT ?               COBOL41C
         BLZ      ABO30             JUMP IF NOT                         COBOL41C
         BEZ      ABO15             JUMP IF INPUT PROCEDURE             COBOL41C
         LI,R4    -10000            REINITIALIZE                        COBOL41C
         STW,R4   SORTFG             SORTFG TO IND NOT NON-RES SORT     COBOL41C
         LI,R4    X'240'            OPTION FOR CLOSE WITH RELEASE       COBOL41C
         STH,R4   MAIOC+1             SET IT TO I/O MCF                 COBOL41C
         B        ABO34                                                 COBOL41C
ABO15    STW,R5   SORTFG+1          SAVE R5                             COBOL41C
         LI,R4    BA(MAIOC)+2       GET BA(CLOSE MCF)                   COBOL41C
         LB,R4    0,R4              GET HALF COUNT                      COBOL41C
         AW,R4    R4                                                    COBOL41C
         LI,R5    BA(SRTOC)+2       GET BA(SAVE PLACE)                  COBOL41C
         STB,R4   R5                SET BYTE COUNT                      COBOL41C
         LI,R4    BA(MAIOC)+2       GET BA(CLOSE MCF)                   COBOL41C
         MBS,R4   0                 MOVE                                COBOL41C
         MTW,1    SORTFG            ADD 1 TO SORTFG                     COBOL41C
         LW,R5    SORTFG+1          RESTORE R5                          COBOL41C
         B        ABO30             COMPLETE,WRITE CLOSE CLUSTER        ABQ122
*                        L0 = LINK TO PROCESS ADDITIONAL FILES          ABQ1638
* READ                              TYPE = X'62'                        ABR
ABR00    RES      0                                                     ABR00
         BAL,L0   ADO10             CHECK FILE                          ABR002
         B        AA02              INVALID FILE                        ABR004
* VALID FILE                                                            ABR02
*                        R7 = WA(DDB)                                   ABR02 5
*                        D0 = DB TYPE,FILE DESCRIPTOR                   ABR02 6
*                        D1 = INTL NO.                                  ABR02 7
*                        D3 = DCB BASE NO.,0                            ABR02 9
         LI,L0    ABR12             SET LINK REGISTER                   ABR021
         LI,D2    X'400'            SET READ OPTION                     ABR022
         LI,R5    X'100'            LOAD ERROR INPUT BIT
ABR04    RES      0                                                     ABR040
         AND,R5   6,R7              CHECK ERROR OPTION BIT
         BEZ      ABR10             = 0, NO DECLARATIVE                 ABR063
* ERROR DECLARATIVE                                                     ABR08
         LB,R1    JFDEC             CHECK DECLARATIVE FLAG              ABR082
         BEZ      ABR10             = 0, NOT IN DECLARATIVE SECTION     ABR083
* S*****ERROR CHECK IN DECLARATIVE SECTION***                           ABR09
         LI,R5    0                 CLEAR XNO,PDNO                      ABR091
         DX       XFS+2             WRITE DMF CLUSTER                   ABR092
ABR10    RES      0                                                     ABR100
*                        R5 = 0/DECLA. XNO,PDNO                         ABR1005
         B        *L0               FALL THRU/RETURN(WRITE)             ABR108
*                        V1 PRESERVED                                   ABR1089
*                                                                       ABR109
ABR12    RES      0                                                     ABR120
         RCRF     R5                READ NEXT CLUSTER                   ABR122
         LH,V1    0,R5              LOAD,CHECK STMT OPTION              ABR123
         CI,V1    CBATE                                                 ABR124
         BGE      ABR20             AT END/INVALID KEY                  ABR125
* INTO OPTION                                                           ABR14
         LW,V2    2,R7              LOAD,STORE MAX.RECORD LNG.          ABR141
         STH,V2   MABCG+2                                               ABR1412
         SW,D3    K064              DCB TO RECORD BASE NO.              ABR1414
         STW,D3   MABCG+1                                               ABR1416
         LI,V2    IBCG+CISAV        LOAD REF CNTL - GROUP ONLY          ABR142
         BAL,L1   ADI02             CHECK INTO FLD                      ABR143
         B        ABR18             INVALID INTO                        ABR144
* VALID READ INTO                                                       ABR16
         AI,D2    1                 RAISE INTO FLAG                     ABR161
*                                                                       ABR18
ABR18    RES      0                                                     ABR180
         LI,R5    1                 SET HA(CLOC)+1                      ABR181
         AW,R5    R2                                                    ABR182
         LH,V1    0,R5              LOAD STMT OPTION(AT END/INVALID KEY)ABR183
*                                                                       ABR20
ABR20    RES      0                                                     ABR200
         CI,V1    CBATE             CHECK FOR AT END                    ABR203
         BE       ABR24             YES. AT END.                        ABR204
* INVALID KEY                                                           ABR22
ABR22    RES      0                                                     ABR220
         CI,D0    X'400'            CHECK ACCESS MODE                   ABR221
         BANZ     ABR26             RANDOM(KEYED)                       ABR222
         B        ABR25             CONSECUTIVE - ASSUME AT END         ABR223
* AT END                                                                ABR24
ABR24    RES      0                                                     ABR240
         CI,D0    X'400'            CHECK ACCESS MODE                   ABR221
         BAZ      ABR26             CONSECUTIVE(NOT KEYED)              ABR242
* S*****AT END OR INVALID KEY NOT SUITABLE FOR ACCESS MODE***           ABR25
ABR25    RES      0                                                     ABR250
         MTW,0    USEBRP            IS FOR USE BEF REPORTING ?  EL27275 COBOL41C
         BNE      ABR26             JUMP IF YES                 EL27275 COBOL41C
         DX       XFS+4             WRITE DMF CLUSTER                   ABR252
*                                                                       ABR26
ABR26    RES      0                                                     ABR260
         LH,V0    1,R2              LOAD INTL NO.(NEXT STMT)
         LI,R2    0                 CLEAR NLOC                          ABR262
*                        V0 = INTL NO.(NEXT STMT)                       ABR28 8
ABR27    RES      0
         STH,D2   MAIOC+1           STORE READ/WRITE OPTIONS            ABR281
         STH,V0   MAIOC+2           STORE INTL NO.(NEXT STMT)           ABR282
         STW,D1   JINTL             UPDATE INTL NO                      ABR283
         LI,R4    BA(MAIOC)+2       LOAD BA(CLOC)                       ABR284
         BAL,L1   ADW00             RESOLVE VAR REC PARAM
         BAL,L1   WRMCF             WRITE READ/WRITE CLUSRER
         BAL,L1   AA17              WRITE INTL DEF.                     ABR292
* READ/WRITE
*                        D2 = STMT OPTION
*                        D0 = FILE STATS
*                        V0 = 0/N.S. INTL NO.
         CI,D2    X'401'            CHECK READ INTO OPTION
         BE       ABR29             YES. READ INTO
* NOT READ INTO
         LI,L0    AA01              SET LINK REGISTER
         CI,D2    X'300'            CHECK B/A DATA/INTEGER FLAGS
         BAZ      ABR30             DOWN.
* B/A DATA/INTEGER LINES
         CI,D2    X'400'            CHECK BEFORE FLAG
         BANZ     ABR28             UP.  WRITE...BEFORE
* WRITE...AFTER
         BAL,L0   ABR28+1           WRITE BDR,RB  *LL
*                                   ****  CI,RB   0
         LW,D3    MAIOC+2           LOAD INTL NO.
         LI,V0    CBEZ              LOAD BEZ
         LAB,L1   PII22,ABR30-1     WRITE BEZ INTL
* WRITE...BEFORE
ABR28    RES      0
         LI,L0    PIA26             SET LINK REGISTER
         BAL,L1   PIA26             WRITE
         BDR,RB   *LL               ****     I = I-1
         BAL,L1   PIA26             WRITE
         CI,RB    0                 ****     CHECK I
         BAL,L1   *L0               RETURN/WRITE
         BEZ      *LL               ****     WRITE LAST LINE
         B        ABR30-1
* INTO OPTION                                                           ABR32
ABR29    RES      0
         WMCF     ,BA(MABCG)        WRITE SPECIAL MOVE CLUSTER          ABR323
         LI,R4    BA(STBAS)+2
         BAL,L1   ADV00
         BAL,L1   WRMCF
         LI,L0    ABR32             SET LINK REGISTER
*                        L0 = LINK REGISTER
ABR30    RES      0
         CI,D0    X'40'             CHECK RERUN FLAG
         BAZ      *L0               DOWN. NO RERUN.
* RERUN
         LI,R1    0                 CLEAR I/O OPTIONS
         STH,R1   MAIOC+1
         WMCF     ,BA(MAIOC)+2      WRITE RERUN CLUSTER
ABR32    RES      0
         LH,D3    MAIOC+2           LOAD,CHECK N.S. INTL NO.
         BEZ      AA15              = 0. FALL THRU, DEF ONLY.
* AT END/INVALID KEY
         LAB,L1   PII20,AA15        WRITE B  N.S.
*                                   ****  DEF INTL
*                                                                       ABR33
* SEEK                              TYPE = X'66'                        ABS
ABS00    RES      0                                                     ABS00
         BAL,L0   ADO10             CHECK FILE                          ABS002
         B        AA02              INVALID FILE                        ABS004
* VALID FILE                                                            ABS02
*                        R7 = WA(DDB)                                   ABS02 5
         LI,R2    0                 CLEAR NLOC
         LI,D2    X'100'            LOAD SEEK OPTION                    ABS021
         CI,D0    X'400'            CHECK ACCESS MODE                   ABR221
*        SEEK S/B IGNORED - S22547 - 10/2/74                            COBOL41C
         BANZ     AA02              KEYED,RANDOM ACCESS FILE            COBOL41C
* S*****SEEK ISSUED TO UNKEYED FILE***                                  ABS024
         LAB,R1   AA092,XFS+5       WRITE DMF CLUSTER
*                                                                       ABS04
* READ,COMBINE OPTION ONLY CLUSTERS                                     ADO
*                        R6 = REF TYPE,STMT OPTION                      ADO0 6
*                        R5 VOLATILE                                    ADO0 8
*                        L0 = LINK REGISTER                             ADO0 9
ADO00    RES      0                                                     ADO000
         RCRF     R5                READ NEXT CLUSTER                   ADO002
*                        L1 = CLNG,CNTL                                 ADO02 9
*                        R5 = HA(CLOC)+1                                ADO02 5
         CI,L1    X'80'             CHECK 1ST STMT CLUSTER FLAG
         BANZ     ADO10             UP. NEW STMT CLUSTER                ADO023
         LH,L1    0,R5              LOAD,CHECK REF TYPE                 ADO024
         CI,L1    X'FF00'                                               ADO025
         BANZ     ADO10             NOT OPTION ONLY                     ADO026
* OPTION ONLY                                                           ADO04
         OR,R6    L1                COMBINE OPTION                      ADO042
         B        AAC00+1           READ NEXT CLUSTER (LINK SET)        ADO046
*                        R2 = HA(NLOC)                                  ADO05 2
*                        R5 = HA(NLOC)+1                                ADO05 5
*                        R6 = REF TYPE,STMT OPTION                      ADO10 6
ADO10    RES      0                                                     ADO100
         CI,R6    CBSDN             CHECK FILE REF(FREF)                ADO104
         BG       ADO30-1           VALID FREF                          ADO105
* S*****INVALID FILE NAME***********                                    ADO20
ADO20    RES      0                                                     ADO200
         LI,R1    1                 RESET DDB I.D.
         STW,R1   JDOID
         LW,L1    L0                SET RETURN ADDRESS IN R11           COBOL41C
         LI,R1    148               INVALID FILE NAME DIAG              COBOL41C
         LH,R7    0,R2              GET 1ST HALF OF CRF                 COBOL41C
         AND,R7   =X'FF'            GET CONTROL BYTE                    COBOL41C
         CI,R7    X'FA'             IS DEF REPORT NAME ?                COBOL41C
         BNE      DIAG              ISSUE 'INVALID FILE' DIAG           COBOL41C
         LI,R1    281               'UNDEF/INVALID REPORT NAME' DIAG    COBOL41C
         B        DIAG              ISUUE DIAG AND RETURN TO A(R11)     COBOL41C
*                                                                       ADO28
         LI,L1    ADO40             SET LINK REGISTER                   ADO299
*                        R7 = DDB NO.,-                                 ADO30 5
*                        L1 = LINK REGISTER                             ADO30 7
*                        D0(,D1),D3 USED                                ADO30 8
*                        V0,V1,V2(=L0,LINK REGISTER) NOT USED           ADO30 9
ADO30    RES      0                                                     ADO300
         LI,R1    2                 LOAD DDB NO.                        ADO302
         LB,R7    R7,R1                                                 ADO303
         LH,R7    *PDBZ+4,R7        LOAD,SAVE DDB OFFSET                ADO304
         SLS,R7   -2
         STW,R7   MAIOC+1                                               ADO306
         AW,R7    PDBZ+3            SET WA(DDB)                         ADO308
         LW,D3    9,R7              LOAD,MASK DCB BASE NO.
         AND,D3   K0FF                                                  ADO323
         B        *L1               FALL THRU/RETURN                    ADO342
*                        R7 = WA(DDB)                                   ADO36 7
*                        D3 = DCB BASE NO.,0                            ADO36 9
*                                                                       ADO40
ADO40    RES      0                                                     ADO400
         LW,D0    JDOID             LOAD,CHECK DDB I.D.
         CB,D0    *R7
         BNE      ADO20             IMPROPER DDB
         LH,R1    JPNO              LOAD PNO                            ADO421
         OR,R1    D3                COMBINE DCB BASE NO.,PNO            ADO422
         STW,R1   MAIOC+4           STORE DCB BASE NO.,PNO              ADO423
*                        R7 = WA(DDB)
ADO50    RES      0
         LW,D0    1,R7              LOAD FILE STATS
         LW,D1    JINTL             LOAD INTL NO.                       ADO424
         AI,D1    1                 INTL NO. = INTL NO.+1               ADO425
         STW,D1   MAIOC+2           STORE INTL NO.                      ADO426
         LI,R1    1                 LOAD RETURN INDEX                   ADO442
         STW,R1   JDOID             RESET DDB I.D.
         B        *L0,R1            RETURN                              ADO444
*                        D0 = FILE STATS
*                        D1 = INTL NO.                                  ADO46 7
*                                                                       AA0
K064     EQU      JAKON             FILE,RECORD BASE ADJ.
K0FF     EQU      JAKON+1           1ST BYTE
K20F     EQU      JAKON+2           CLASS
K2F00F   EQU      JAKON+3           TYPE,NDIM
K2FFF    EQU      JAKON+4
K303     EQU      JAKON+5
K3FF     EQU      JAKON+6           BYTE MASK
JSTYP    EQU      JADAT
JFDEC    EQU      JADAT+2           DECLA.FLAG
JTDB     EQU      JADAT+3           TDB/DDB NO.,0
JDOID    EQU      JADAT+X'1E'       DDB I.D.
JPTYP    EQU      JAMOD+2
JPNO     EQU      JAMOD+3           CPNO
MABCG    EQU      JAMOD+8           SPECIAL MOVE,0
JINTL    EQU      JAMOD+13          INTL DEF,NO.
ADISAV   EQU      JASAV+10          L0-D3                               99
         END
