         SYSTEM   SIG7FDP
*
*        GNRTBL   -   GENERATE REPORT TABLE
*        THIS SUBROUTINE TAKES FROM THE
*        01  DESCRIPTOR STRING THE DATA AND POINTERS TO
*        PROCEDURE DIV. GENERATED CODE AND PREPARES A
*        REPORT DESCRIPTION TABLE FROM OUTPUT TO POF.
*             LINKAGE  BAL,11  GNRTBL
*
*
         REF      RDI,WRPOF,PR01
         REF      USEPOINT
         REF      DIAG,PDBX
         DEF      GNRTBL
GNRTBL   STW,11   GRTXIT
         LI,2     0
         STW,2    CNTR
         LI,2     1
         LH,2     RDI+3,2
         AI,2     60
         STB,2    CNTR
*
*        SET UP THE PAGE FORMAT DATA IN RDI.
*
         LW,9     RDI+8
         STW,9    PDBX              LINE NUMBER FOR DIAGNOSTICS
         LH,9     RDI               TEST PAGE LIMITS
         BCS,3    PGLMOK
         LI,9     X'7FFE'           SET PAGE LIMITS TO 32000
         STH,9    RDI
PGLMOK   LI,2     1                 TEST HEADING
         LH,9     RDI,2
         BCS,3    HDOK
         LI,9     1                 SET HEADING TO 1
         STH,9    RDI,2
HDOK     LH,9     RDI+1             TEST FIRST DETAIL
         BCS,3    FDEOK
         LH,9     RDI,2             SET FIRST DETAIL TO HEADING
         STH,9    RDI+1
FDEOK    CH,9     RDI,2             IS FIRST DETAIL GE HEADING
         BCR,1    FDOK
         LI,1     197
         BAL,11   DIAG
FDOK     LH,9     RDI+1,2           TEST LAST DETAIL
         BCS,3    TGEFD
         LH,9     RDI+2             SET LAST DETAIL TO FOOTING
         STH,9    RDI+1,2
         BCS,3    TGEFD             IF NEITHER IS SET THEN
         LH,9     RDI               SET TO PAGE LIMITS
         STH,9    RDI+1,2
TGEFD    CH,9     RDI+1             TEST IF LAST DETAIL GE FIRST DETAIL
         BCR,1    FTG
         LI,1     197
         BAL,11   DIAG
FTG      LH,9     RDI+2             TEST FOOTING
         BCS,3    TFTG
         LH,9     RDI+1,2           SET TO LAST DETAIL
         STH,9    RDI+2
TFTG     CH,9     RDI               TEST AGAINST PAGE LIMIT
         BCR,2    CLRRTL            IS LE
         LI,1     197
         BAL,11   DIAG
*
*        SCAN THE 01 DESCRIPTORS, COUNT THE NUMBER OF DE'S
*        AND LOCATE THE RH,RF,OH,ETC. ALSO CF AND CH BY LEVELS.
*
*
*
CLRRTL   LI,3     RGTABL
         LI,9     0
CLRRGT   STW,9    *3
         AI,3     1
         CI,3     RGLAST
         BCR,2    CLRRGT
DORTBL   LI,3     PR01
         LI,9     0
         STW,9    NMBDES
NXX01    LW,3     *3
         LS,3     AMASK
         BCR,3    RTGEN             NO MORE 01'S
         LI,2     -23
         LB,4     *3,2              LOAD REP GRP TYPE
         CI,4     5
         BCS,2    CFCHDE            GREATER
         STW,3    RGTABL,4
         B        NXX01
CFCHDE   CI,4     8
         BCS,3    CFCH
         LI,9     1                 EQUAL TO DETAIL
         AWM,9    NMBDES
         B        NXX01
CFCH     LI,5     -7                STORE LOCATION OF CONTROL LEVELS
         LB,7     *3,5
         S,7      1
         CI,4     6
         BCS,3    CF2
         AI,7     1
CF2      STW,3    CF-2,7
         B        NXX01
*
*
*
*        THE ROUTINE RTGEN WAS CHANGED BY SIDR 1779 TO ELIMATE THE      COBOL34C
*        USING OF OV FOR PF ------------ --- THE LOGIC WOULD BE THE     COBOL34C
*        SAME AS THAT WHICH FOLLOWS                                     COBOL34C
*        NOTE THAT PF IS RGTABL+5 AND OV IS RGTABL+3                    COBOL34C
RTGEN    LW,9     RGTABL+2          TEST IF OH AND OV SHOULD
         BCS,3    OV                BE REPLACED WITH PH AND PF
         LW,9     RGTABL+4          AND VICE VERSA
         STW,9    RGTABL+2
OV       LW,9     RGTABL+3
         BCS,3     RTGEN2                                               COBOL34C
         LW,9     RGTABL+5
         STW,9    RGTABL+3
*    SIDR 1779 REMOVED THE CODE FOR EXCHANGING PH/OH  PF/OV             COBOL34C
*         WHICH WAS HERE BEFORE                                         COBOL34C
RTGEN2   LH,9     RDI+6             GENERATE HEAD OF REPORT TABLE
         LI,1     1                 STORE REMAINING CODE
         LI,3     3
         LH,10    RDI+5
         BAL,12   PROCRF
*        STORE ADD OF COMPARE OF CNTRL FLDS
*                                   COUNT NUMBER OF FD'S
         LW,9     RDI+7
         LI,2     1
FD2      LB,11    *9,2
         BCR,3    FD3
         CI,11    X'FF'
         BCR,3    FD3
         AI,2     1
         CI,2     3
         BCR,2    FD2
FD3      AI,2     -2
         LW,10    2
         AI,2     1
         S,2      2
         STW,2    FDOFST
*        STORE NUMBER OF FD'S LESS 1
FD4      BAL,12   GCONST
         LI,10    0
         BAL,12   GCONST
*        OUTPUT PRIVATE LINE COUNTER
         LH,10    RDI               GET PAGE LIMIT                      COBOL34C
         CI,10    X'7FFE'           IS NO PAGE LIMIT PRESENTED          COBOL34C
         BNE      SETPAG            JUMP, IF PAGE LIMIT EXIST           COBOL34C
         LI,10    0                 SET PAGE LIME`IT = 0, IF NO         COBOL34C
SETPAG   STW,10   CONST+2           SET PAGE LIMIT                      COBOL34C
         LW,10    NMBDES
         LI,2     2
         STB,10   CONST+2           NUMBER OF DE GROUPS
         LB,10    RDI+3
         STB,10   CONST+2,2
         LB,11    RDI+3,1
         AW,10    11
         STB,10   CONST+2,1         NUMBER OF CONTROL LEVELS
         STW,10   NOLVLS
         BAL,12   GCONT             OUTPUT WORD 3 OF RPWTAB             COBOL34C
*        OUTPUT WORD 3
         LW,4     CNTR
         STW,4    CNTR3
         LI,4     BA(XREF)
         BAL,11   WRPOF             OUTPUT WORD 4  B  C:RRK
         LI,4     4
         AWM,4    CNTR
         LI,10    0
         BAL,12   GCONST            OUTPUT WORD 5 (UNUSED)
         LW,9     NMBDES            GET OFFSET OF FD'S
         MI,9     32
         AI,9     232
         STW,9    CFOFST            BYTE OFFSET OF CONTROL DESCRIPTOR
         LW,9     NOLVLS
         MI,9     68
         AW,9     CFOFST
         STW,9    BASOFT            STORE OFFSET
         AWM,9    FDOFST
         LI,10    0
         STB,10   BASOFT-1
         LH,10    RDI+3,1           GET RDB NUMBER
         AI,10    10
         STW,10   BASE
         AI,10    50                TO GET BASE NUMBER
         STB,10   BASOFT
         BAL,12   WDREF             OUTPUT WORD 6 (LOC OF FD'S)
         LB,10    BASOFT
         LW,9     CFOFST
         STW,9    BASOFT
         STB,10   BASOFT
         BAL,12   WDREF             OUTPUT WORD 7(LOC OF CONTROL LVL'S)
         LW,10    RDI+4             BASE & DISPLACEMENT OF LINE COUNTER
         STW,10   BASOFT
         BAL,12   WDREF             OUTPUT WORD 8(LOC OF LINE-CONTR)
         LI,10    0
         BAL,12   GCONST            OUTPUT WORD 9 (LC-ISSUED)
*
*        GENERATE THE CODE FOR THE REPORT GROUP DESCRIPTORS
*        RH THROUGH PH - IF LOC OF DESCRIPTION IS 0
*        GENERATE 8 ZEROES.
*
         LI,4     0
NRG      LW,3     RGTABL,4
         STW,4    RTY
         BCS,3   NZRO               NO REPORT GROUP
         BAL,13   ZZRO              GENERATE ZEROES
         B        NRG2
NZRO     LI,2     -23
         STB,4    *3,2
         BAL,11   RGDES
NRG2     LW,4     RTY
         AI,4     1
         CI,4     5
         BCR,2    NRG
*        SCAN THROUGH PR01 STRING LOOKING FOR DE GROUPS
*
         LI,3     PR01
NXRG     LW,3     *3
         LS,3     AMASK
         BCR,3    GENCFS            NO MORE 01'S
         LI,2     -23
         LB,4     *3,2
         CI,4     8
         BCS,3    NXRG
         BAL,11   RGDES             GENERATE DETAIL REPORT GROUP
         B        NXRG
GENCFS   LI,15    0                 GENERATE CONTROL REPORT GROUPS
CW15     CW,15    NOLVLS
         STW,15   NUMCFS
         BCR,1    FDSNOW            ALL CONTROL GROUPS DONE
         LI,2     1
         LB,10    RDI+3
         AI,10    -1
         SW,10    15                REF NUMBER OF MOVE OF CONTROL FIELDS
         BCR,1    DOMOV
         LI,10    0
DOMOV    AH,10    RDI+5,2
         LI,9     0
         BAL,12   PROCRF
         LW,4     15
         S,4      1
         AI,4     CF
         LW,3     *4
         STW,4    RTY
         BCS,3    NZROCF
         BAL,13   ZZRO
         B        CHH
NZROCF   BAL,11   RGDES
CHH      LW,4     RTY
         AI,4     1
         LW,3     *4
         BCS,3    NZROCH
         BAL,13   ZZRO
         B        CNTLIM
NZROCH   BAL,11   RGDES
CNTLIM   LW,15    NUMCFS
         AI,15    1
         B        CW15
FDSNOW   LW,9     RDI+7
         LI,2     1
FDD2     LB,11    *9,2
         BCR,3    DONE
         CI,11    X'FF'
         BCR,3    DONE
         LI,10    0
         STW,10   BASOFT
         STB,10   BASOFT-1
* THE FOLLOWING INSTRUCTION CHANGES THE REPORT TABLE                    COBOL34C
* SO THAT THE FD POINTER ACTUALLY POINTS TO  I:FILENAME                 COBOL34C
* INSTEAD OF TO F:FILENAME                                              COBOL34C
* ORIGINAL INSTRUCTION WAS AI,11    110                                 COBOL34C
*                                                                       COBOL34C
         AI,11    60                                                    COBOL34C
         STB,11   BASOFT
         BAL,12   WDREF
         AI,2     1
         CI,2     3
         BCR,2    FDD2
DONE     LW,9     RDI+7
         LI,2     4
         LW,10    FDOFST
         STH,10   *9,2
         B        *GRTXIT
*
*        RGDES      REPORT GROUP DESCRIPTION
*        THIN SUBROUTINE OUTPUTS THE POF CLUSTERS REPRESENTING
*        A SINGLE REPORT GROUP IN THE REPORT DESCRIPTION TABLE.
*
*              LINKAGE  R3  CONTAINS LOC OF 01 DESCRIPTOR
*                       BAL,11  RGDES
*
RGDES    STW,11   RGEXIT
*        SEARCH THROUGH USETABLE FOR USE PROCEDURE NUMBERS
*        FOR ENTRANCE AND EXIT.
         LI,2     -8
         LB,9     *3,2              REPORT GROUP REF NUMBER
         LI,2     1
         STB,9    USETST,2
         LH,9     RDI+3,2           RDB NUMBER
         STB,9    USETST
         LH,9     USETST
         LI,10    USEPOINT          SET TO START OF USE TABLE
USLOOP   AI,10    1
         CW,10    USEPOINT
         BCR,1    W1                SEARCH ENDED
         CH,9 *10
         BCS,3    USLOOP
         LI,2     2                 MATCHING REPORT GROUP IS FOUND
         LB,9     *10,2             MOVE ENTRANCE AND EXIT
         LI,2     -5
         STH,9    *3,2
         LI,2     3
         LB,9     *10,2
         LI,2     -6
         STH,9    *3,2
W1       LI,2     -24               GENERATE DESCRIPTOR
         LB,9     *3,2              LOAD NUMBER OF LINE IMAGES
         LI,2     -6
         LH,10    *3,2              LOAD EXIT REF NUMBER
         BCR,3    NOXIT
         STB,9    BASOFT-1
         AI,10    -1
         S,10     2
         STW,10   BASOFT
         LI,11    5
         STB,11   BASOFT
         BAL,12   WDREF
         B        NOXIT2
NOXIT    BAL,12   PROCRF
NOXIT2   LI,2     -23
         LI,9     0
         LB,15    *3,2
         LI,2     -8
         CI,15    8
         BCR,3    DETL              THIS IS A DETAIL GROUP
         LI,2     -5
DETL     LH,10    *3,2
         BCR,3    NOUSE             THERE IS NO USE 0R GRP IND STATEMENT
         LI,9     1                 NON ZERO TO GRP IND
NOUSE    BAL,12   PROCRF
ADDP     LI,2     -3
         LH,10    *3,2
         LW,9     15
         BAL,12   PROCRF
MOVEP    LI,2     1                 COMPUTE J LEAST
         LH,9     RDI,2             LOAD HEADING
         CI,15    5
         BCR,2    J2
         LH,9     RDI+1             LOAD FIRST DETAIL
         CI,15    5
J2       BCS,3    J3
         LH,9     RDI+2
         AI,9     1
J3       CI,15    3
         BCS,3    J4
         LH,9     RDI+2
         AI,9     1
J4       LI,2     -10
         LH,10    *3,2
         BAL,12   PROCRF
         LI,2      1                OUTPUT NXT GP AND RESETS
         LB,9      *3,2
         S,9      X'7F'
         LI,2      -7
         CI,15     8
         BCR,3     DT
         LI,2      -9
DT       LH,10     *3,2
         BAL,12   PROCRF
*                 CODE FOR LARGEST ALLOWABLE LINE GOES HERE
         LI,9     0
         LI,2     -3                IS LINE TYPE RELATIVE (=2)
         LB,12    *3,2
         S,12     X'7F'             RIGHT ONE
         CI,12    2
         BCS,3    NOTREL            NOT RELATIVE
         LI,2     -23               GET REPORT TYPE
         LB,4     *3,2
         LW,7     HTABLE,4
         LS,7     AMASK
         LH,9     RDI,7
         S,4      2
         LB,7     HTABLE,4
         SW,9     7
         LI,2     -24               NUMBER OF LINE IMAGE
         LB,13    *3,2
         LW,7     3
         AI,7     -7
SUBLIN   AI,13    -1
         BCS,1    HINR9
         AI,7     -1
         LH,12    *7
         AND,12   LTYPP
         CI,12    4
         BCS,3    HINR9
         LB,12    *7
         SW,9     12                SUBTRACT REL LINE SPCNG
         LW,7     *7                LINK TO NEXT LINE IMG
         LS,7     AMASK
         B        SUBLIN
HINR9    RES      0
*        LINE COUNT (IF THERE IS ONE LINE IMAGE)
         LW,7     RDI+2             LOAD HISTORY BITS
         LS,7     LDFT              LAST DETAIL AND FOOTING BITS
         CW,7     LDFT
         BCS,3    NOTREL            LAST DETAIL AND FIG NOT EXPLICIT
         CI,4      24              CH=6 NOTE REG 4 WAS MULT BY 4 AT DT  COBOL34C
         BCR,3    CHANAL            CH ANALYSIS
         CI,4      28              CF=7 NOTE REG 4 WAS MULT BY 4 AT DT  COBOL34C
         BCS,3    NOTREL            NEITHER CF OR CH
CFANAL   LI,2     4                 OFFSET TO FOOTING
         LI,13    +1                LEVEL INCREMENTATION
         LI,10    1                 INITIAL LEVEL
         LI,7     -7
         LB,11    *3,7              TERMINAL LEVEL
         B        JOIN
CHANAL   LI,2     3                 OFFSET TO LAST DETAIL
         LI,13    -1
         LI,7     -7
         LB,10    *3,7              INITIAL LEVEL
         LI,11    1                 TERMINAL LEVEL
JOIN     LI,12    0
         STW,12   H
         STW,12   LASTDC            LAST DECR WAS LINE
*        LH,9     RDI,2             BASE                                COBOL34C
*                                   LOCATE CONTROL GROUP AT LEVEL OF R10
NXCFCH   LW,4     10
         S,4      1
         CI,13    1
         BCR,3    CFOFF
         AI,4     1
CFOFF    LW,4     CF-2,4            R4 NOW IN BASE OF CONTROL GROUP
         BCR,3    TLVL              NONEXISTANT
         LI,7     -3
         LB,7     *4,7
         S,7      X'7F'             RT SHIFT
         B        LTYPE,7
LTYPE    B        TLVL              NOT SPECIFIED
         B        ABSLIN            ABS
         B        RELLIN            REL
TLAST    LW,7     LASTDC            PAGE - WAS LAST DECR FROM LINE OR NXT GRP
         BCS,3    NXGPLT            NXGRP
         AI,9     -1                LINE
NXGPLT   SW,9     H
         B        NOTREL
ABSLIN   LI,7     -4
         LB,9     *4,7
         B        TLAST
RELLIN   LI,7     0
         STW,7    LASTDC
         LI,7     -4
         LB,7     *4,7              N
         AWM,7    H
TLVL     CW,10    11
         BCR,3    NXGPLT
         LI,7     +1                TRY NEXT GROUP
         LB,7     *4,7
         S,7      X'7F'             RT SHIFT
         B        NXTYP,7
NXTYP    B        NOTNG             NOT SPECIFIED
         B        ABSNX             ABS
         B        RELNX            REZ
         B        TLAST             NX PG
ABSNX    LB,9     *4
         B        TLAST
RELNX    STW,7    LASTDC
         LB,7     *4
         AWM,7    H
NOTNG    AW,10    13                INCREMENT LEVEL
         B        NXCFCH            LOOP
NOTREL   LB,10    *3
         LW,9     9
         BCR,1    PLSH
         LI,9     0
PLSH     RES      0
         STB,9    10
         BAL,12   GCONST            OUTPUT H AND INTEGER FOR NEXT GROUP
         LI,2     -24
         LB,15    *3,2              NUMBER OF LINE IMAGES
         LW,10    -7,3              0 OR 1 GET BASE AND OFFSET
         STW,10   BASOFT
         S,10     X'68'
         AI,10    -2
         STB,10   BASOFT-1
         CI,15    1
         BCR,2    L407
         LW,10    FDOFST            POINT TO 2-WORD DESCR FOR EXTRA LINE>
         STW,10   BASOFT
         LW,10    BASE
         AI,10    50
         B        L408
L407     LW,10    BASE
L408     STB,10   BASOFT
         BAL,12   WDREF
         LI,2     -32
         LB,10    *3,2
         LI,2     -31
         LB,9     *3,2
         S,9      X'7F'
         STB,9    10
         BAL,12   GCONST
         CI,15    1                 R15 IS NUMBER OF LINE IMAGE
         BCR,2    *RGEXIT
         LW,7     3
         AI,7     -7                R7 POINTS TO LINE DESCRIPTOR
         LW,10    CNTR
         STW,10   CNTRX
         LW,10    FDOFST
         LB,9     CNTR
         STW,10   CNTR
         STB,9    CNTR
MRLINS   LI,10    8
         AWM,10   FDOFST
         LW,10    0,7
         STW,10   BASOFT
         S,10     X'68'
         AI,10    -2
         STB,10   BASOFT-1
         LW,10    BASE
         STB,10   BASOFT
         BAL,12   WDREF
         LI,2     -4
         LB,10    *7,2
         LI,2     -3
         LB,9     *7,2
         S,9      X'7F'
         STB,9    10
         BAL,12   GCONST
         LW,7     -1,7
         LS,7     AMASK
         AI,15    -1
         BCS,2    MRLINS
         LW,10    CNTRX
         STW,10   CNTR
         B        *RGEXIT
*
*        GENERATE CONSTANT
*        R10 = CONSTANT
*        BAL,12       GCONST
*
GCONST   STW,10   CONST+2
         B        GCONT
*
*        GENERATE POF CLUSTER FOR PROCEDURE REFS OR CONSTANT IF REF IS ZERO
*        R9 IS FIRST BYTE OF GENERATED WORD
*        R10 IS PROC REF NUMBER
*        BAL,12   PROCRF
*
*
PROCRF   CI,10    0
         BCS,3    REFF
         STW,10   CONST+2           PROCEDURE REF IS 0
         STB,9    CONST+2
GCONT    LI,4     BA(CONST)
         B        REFG
REFF     STW,10   PRREF+2
         STB,9    PRREF+2
         LW,4     CNTR
         STW,4    CNTR2
         LI,4     BA(PRREF)
REFG     BAL,11   WRPOF
         LI,4     4
         AWM,4    CNTR
         B         *12
WDREF    LW,4     CNTR
         STW,4    CNTR4
         LI,4     BA(DREF)
         BAL,11   WRPOF
         LI,4     4
         AWM,4    CNTR
         B        *12
ZZRO     LI,9     8
ZRO      LI,10    0
         BAL,12   GCONST
         AI,9     -1
         BCS,2    ZRO
         B        *13
LTYPP    DATA     X'E'
USETST   DATA     0
FDOFST   DATA     0
CNTRX    DATA     0
AMASK    DATA     X'0001FFFF'
GRTXIT   DATA     0
RGEXIT   DATA     0
BASE     DATA     0
NUMCFS   DATA     0
NMBDES   DATA     0
NOLVLS   DATA     0
CFOFST   DATA     0
RTY      DATA     0
LDFT     DATA     X'00000300'
H        DATA     0
LASTDC   DATA     0
HTABLE   DATA     0                 THIS TABLE IS ARRANGED BY REPORT GROUP TYPE
         DATA     0                 BYTE 0 OF EACH WORD IS THE DECREMENT,
         DATA     3                 BYTES 1,2,3 POINT TO THE LINE NUMBER
         DATA     0                 USED AS BASE.
         DATA     3                 H=BASE-DECREMENT-N
         DATA     0
         DATA     3
         DATA     4
         DATA     3
RGTABL   DATA     0                 LOCATION OF RH        TYPE 0
         DATA     0                 LOCATION OF RF        TYPE 1
         DATA     0                 LOCATION OF OH        TYPE 2
         DATA     0                 LOCATION OF OV        TYPE 3
         DATA     0                 LOCATION OF PH        TYPE 4
         DATA     0                 LOCATION OF PF        TYPE 5
CF       DATA     0                 LOCATION OF MINOR  CF TYPE 7
         DATA     0                 LOCATION OF MINOR  CH TYPE 6
         DATA     0                 LOCATION OF LVL 2  CF TYPE 7
         DATA     0                 LOCATION OF LVL 2  CH TYPE 6
         DATA     0                 LOCATION OF LVL 3  CF
         DATA     0                 LOCATION OF LVL 3  CH
         DATA     0                 LOCATION OF LVL 4  CF
         DATA     0                 LOCATION OF LVL 4  CH
         DATA     0                 LOCATION OF LVL 5  CF
         DATA     0                 LOCATION OF LVL 5  CH
         DATA     0                 LOCATION OF LVL 6  CF
         DATA     0                 LOCATION OF LVL 6  CH
         DATA     0                 LOCATION OF LVL 7  CF
         DATA     0                 LOCATION OF LVL 7  CH
         DATA     0                 LOCATION OF LVL 8  CF
         DATA     0                 LOCATION OF LVL 8  CH
         DATA     0                 LOCATION OF LVL 9  CF
RGLAST   DATA     0                 LOCATION OF LVL 9  CH
         DATA,2   0                 FILLER
PRREF    DATA,2   X'0624'           PROCEDURE REFERENCE CLUSTER
CNTR2    DATA     0
         DATA,4   0
         DATA,2   X'0006'
CONST    DATA,2   X'0621'
CNTR     DATA     0
         DATA,4   0
         DATA,2   X'0006'
DREF     DATA,2   X'0829'           DATA REF
CNTR4    DATA     0
         DATA,4   X'00000002'
BASOFT   DATA,4   0                 BASE AND BYTE DISPLACEMENT
         DATA,2   X'0008'
XREF     DATA,2   X'0928'           EXTERNAL REFERENCE CLUSTER
CNTR3    DATA     16
         DATA,4   X'68000000'
         DATA,1   X'05'
         DATA,5   'C:RRK'
         DATA,2   X'0009'
         END
