*PURPOSE:  TO CONTROL THE STATE OF A FILE CPVEXCONTROL.
*          BY PUTTING EITHER 'RUN' OR 'WAIT'
*          IN THE FIRST RECORD OF THAT FILE.
*        THIS IS USED TO CONTROL THE STATE OF EXERCISERS
*        WHICH READ THAT FILE NAME FOR THE CONTROL
*METHOD: WHEN THE PROGRAM IS ACTIVATED, IT SETS CPVEXCONTROL
*        EQUAL TO 'WAIT' INTERRUPTING THIS PROGRAM THEN
*        CAUSES 'RUN' THEN 'WAIT' THEN 'RUN' ECT
*        TO BE WRITTEN TO THE FILE
*        THIS IS HERALDED ON THE OPERATOR CONSOLE
*        AT PROGRAM INITIATION OR WHENEVER THE PROGRAM IS
*        IS INTERRUPTED
         SYSTEM   BPM
         SYSTEM   SIG7FP
F:CP5    DSECT    1
F:CP5 M:DCB (FILE,'CPVEXCONTROL'),(CONSEC),(SEQUEN),;
         (OUT),(RECL,4),(TRIES,10),(SAVE)
         CSECT    0
START    M:PRINT  (MESS,SWMESS)
         M:TYPE   (MESS,SWMESS)
         M:INT    PUTON
SCAN     MTW,0    TURNON            WANTS IT ON
         BCR,3    ONT               NO IS IT ON
         BCS,3    BWAIT
WRTONAG  LI,7     0
         STW,7    READBUFF
         M:WRITE  F:CP5,(BUF,WRITBUFF),(SIZE,4),(ABN,SWAIT),;
          (ERR,SWAIT)
         M:CLOSE  F:CP5,(SAVE)
         M:INT    PUTOFF
         LI,7     1
         STW,7    RON
         B        BWAIT
WRITBUFF DATA 'RUN '
WRITBUFF1 DATA 'WAIT'
ONT MTW,0 RON
         BCR,3    BWAIT
         LI,7     0
         STW,7    READBUFF
         M:WRITE F:CP5,(BUF,WRITBUFF1),(SIZE,4),(ABN,SWAIT),;
          (ERR,SWAIT)
         M:CLOSE  F:CP5,(SAVE)
         M:INT    PUTON
         LI,7     0
         STW,7    RON
SWAIT EQU    $
    B SCAN
READBUFF RES 20
BWAIT    M:WAIT   25
         B        SCAN
TURNON   DATA     0
RON      DATA     1
PUTON    M:PRINT (MESS,ONMESS)
         M:TYPE   (MESS,ONMESS)
         LI,7     1
         STW,7    TURNON
         M:TRTN
PUTOFF   M:PRINT  (MESS,OFFMESS)
         M:TYPE   (MESS,OFFMESS)
         LI,7     0
         STW,7    TURNON
         M:TRTN
SWMESS TEXTC '*INT   ME TO CONTROL EXERCISERS, THEY CAN RUN OR SLEEP*'
ONMESS TEXTC '**AWAKEN GHOSTS..INT ME AND THEY WILL SLEEP'
OFFMESS TEXTC '**SLEEPY GHOSTS..INT ME TO AWAKEN THEM***'
         END      START
