*
*        ERREXIT---MODULE TO PRINT ERRMSG AND EXIT.
*
*        INPUT: R10 HAS CODE+SUBCODE (SR3 AT ERR/ABN ADDRESS).
         REF      M:SL
         DEF      ERREXIT,ERREPORT
ERREXIT  CSECT    1
         LI,15    EXIT              FUDGE RETURN ADDRESS
ERREPORT RES      0
         LW,2     10                CODE+SUBCODE
         SLS,2    -17               SUBCODE RT JUST.
         LI,1     1                 INDEX
         AND,2    L(X'7F')
         STB,2    10,1
         SLS,10   -16               CODE-SUB RT JUST.
         OR,10    L(X'03000000')    KEYLEN
         STW,10   %K                SAVE KEY
         M:READ   F:ER,(KEY,%K),(ABN,ERR),(ERR,ERR),WAIT
         LW,10    F:ER+4            ARS
         SLS,10   -17
         M:WRITE  M:SL,(BUF,%B2),(SIZE,*10),(BTD,0)
         B        *15               RETURN
EXIT     M:EXIT
ERR      M:ERR
         CSECT    0
%B2      RES,1    140
%K       DATA     0
F:ER     DSECT    2
F:ER     M:DCB    (FILE,'ERRMSG',':SYS'),KEYED,DIRECT,IN,;
                  (KEYM,4),(BUF,%B2),(ERR,ERR),(ABN,ERR),;
                  (RECL,140)
         END
