         SYSTEM   SIG7D
         SYSTEM   BPM
*
ACD      EQU      21
FLP      EQU      6
*
         REF,1    JB:PCW
         REF      M:SI,M:LO
*
BUFFER   RES,1    140               OUTPUT BUFFER
*
LISTACCOUNTS LI,1 BA(JB:PCW)       DISPLACEMENT TO PLATEN WIDTH IN JIT
         LB,1     0,1               GRAB PLATEN WIDTH
         CI,1     10                TOO SMALL?
         BGE      %+3               NO
         LI,1     10                FORCE
         B        OUT               INTO MAIN ROUTINE
         CI,1     140               TOO BIG?
         BLE      OUT               NO
         LI,1     140               FORCE
OUT      LI,0     0                 INITIALIZE FOR DIVIDE
         DW,0     =10               CALCULATE HOW MANY ACCOUNTS/LINE
         LW,15    1                 RECORD
         MI,15    10                 SIZE
*
LOOP     LW,0     1                 BEGIN MAIN DRIVER LOOP
         LI,5     BA(BUFFER)        SET UP FOR MBS
GETNXTA,OPENFPT M:OPEN M:SI,FILE,PASS,NXTA,(ABN,DONE),TEST
         USECT    OPENFPT           FIX
         ORG      OPENFPT+12         UP
         DATA     X'02010202'         SOME
ACCOUNT  EQU      %                    GENERATED
         DATA     0,0,'    '            DATA
         USECT    GETNXTA
         LW,2     M:SI+ACD          DISPLACEMENT OF ACCOUNT IN VLP'S
         LH,2     2                 ALIGN
         LCI      2                 GET
         LM,2     *M:SI+FLP,2        ACCOUNT
         STM,2    ACCOUNT           STUFF FPT
         AW,5     =X'0A000000'      COUNT FOR MBS
         LI,4     BA(ACCOUNT)       SOURCE ADDRESS
         MBS,4    0                 MOVE TO BUFFER
         BDR,0    GETNXTA          BACK FOR MORE
WRITE    M:WRITE  M:LO,(BUF,BUFFER),(SIZE,*15)
         B        LOOP              CONTINUE
*
*   ENTER HERE ON OPEN NXTA ABNORMAL
*
DONE     SW,1     0                 HOW FAR ALONG?
         BEZ      EXIT              NOT AT ALL
         MI,1     10                COMPUTE RECORD SIZE
         STW,1    15                INTO PROPER REGISTER
         EXU      WRITE             OUTPUT
EXIT     M:EXIT
         END      LISTACCOUNTS
