         PCC      0                                                             
         SYSTEM   SIG9P                                                         
         SYSTEM   OPTIONS                                                       
*   ENTRY POINTS                                                                
         DEF      A:PRINT                                                       
         DEF      TYPE                                                          
         DEF      GENCHARS                                                      
*   EXIT POINTS                                                                 
         DEF      TYPREXIT                                                      
         DEF      GCEXIT                                                        
         DO       #ECB                                                          
         DEF      TYPREX1                                                       
         FIN      #ECB                                                          
OLAYFLAG EQU      'PRIN'                                                        
         SYSTEM   CPRMON                                                        
         TITLE    '** PRINT - PRINT AND TYPE CAL **'                            
*************                                                            0609000
*   PRINT   *                                                            0610000
*************                                                            0611000
*                                                                        0612000
*   THIS ROUTINE RECEIVES ALL PRINT CALLS                                0613000
*   ENTRY IS FROM THE CAL1 PROCESSOR                                     0614000
*                                                                        0615000
*   AT ENTRY:     R0    FPT ADDRESS                                      0616000
*                 R1    FPT CODE                           /SIG7-2064/*C5732 C01
*                 PSD IS ON TOP OF USER TEMP STACK                       0617000
*                                                                        0618000
PRINT    RES      0                                                             
A:PRINT  EQU      PRINT                                                         
         LI,R7    LL                DUMMY DCB WORD 1 (FOR GETDCTX)              
TYPEPRNT LB,R4    TCBPOINT          STI INDEX                                   
         LW,R4    STIPRIO,R4                                                    
         LB,R13   R4                                                            
         LI,R8    K3                DUMMY DCB WORD 0                            
         BAL,R4   GETDCTX           GET DCT INDEX IN R7                  0622000
         B        TYPREXIT                                                      
         CI,R7    0                 IS DEVICE = NULL?      /SIG7-2212/*C5732    
         BE       TYPREXIT          EXIT PRINT CAL                              
         CI,R7    X'80'             ASSIGNED TO RAD FILE                        
         BANZ     TYPREXIT          YES, EXIT                                   
         CI,R1    1                 IS THIS A PRINT                             
         BNE      TYPR0             NO, OC MUST BE SHARABLE                     
         DO       #SYMB                                                         
         BIFFGD   TYPR10            B IF FOREGROUND                             
         LB,R10   DCTSYM1,R7                                                    
         CI,R10   DCTSYMSM                                                      
         BANZ     TYPR0             B IF SYMBIONT DEVICE                        
TYPR10   RES      0                                                             
         FIN      #SYMB                                                         
         LB,R10   DCTJID,R7         GET JOB I.D. ENTRY                          
         BEZ      TYPR0             B IF SHARABLE DEVICE                        
         CI,R10   X'FF'             EXCLUSIVE, IS IT IN USE                     
         BE       TYPR0             NO, OK TO PRINT                             
         LB,R6    TCBPOINT          TASK I.D.                                   
         CB,R10   STIJID,R6         COMPARE JOB I.D.'S                          
         BNE      TYPREXIT          DIFFERENT JOBS, CANT PRINT                  
TYPR0    RES      0                 OK TO PRINT OR TYPE                         
         LB,R2    DCT4,R7           DEVICE TYPE                                 
         LB,R2    PRNTTBL,R2        FUNCTION CODE                               
         CI,R2    KFF                                                           
         BE       TYPREXIT          EXIT IF NOT ALLOWED                         
         LI,R15   K1                GET BUFFER ADDRESS                          
         BAL,R5   GETPII                                                        
         B        TYPREXIT          NOT PRESENT SO EXIT                         
         LW,R10   R14               R10= BUFFER ADDRESS                         
         LB,R11   *R10              BYTE COUNT TO R11                    0626000
         BEZ      TYPREXIT          ZERO BYTE COUNT, EXIT                       
         CI,R11   LPSIZE            COMPARE TO MAX SIZE                  0627000
         BLE      %+2               OK,BRANCH                            0628000
         LI,R11   LPSIZE            TRUNCATE TO MAX SIZE                 0629000
         SLS,R10  2                 MAKE BYTE ADDRESS                    0630000
         AI,R10   1                 SKIP OVER COUNT                      0631000
         CI,R1    1                                                             
         BNE      %E                B IF NOT PRINT                              
*                                                                               
*        TEST FOR BACKGROUND PAGE OUTPUT LIMIT                                  
*                                                                               
         BIFFGD   %E                                                            
         LI,R5    1                                                             
         MTH,0    K:BPGLIM,R5                                                   
         BEZ      %E                B IF NOT COUNTING                           
%C       LH,R4    K:BPGLIM                                                      
         SW,R4    R5                REMAINING LINES IN PAGE                     
         STH,R4   K:BPGLIM          SAVE                                        
         BGEZ     %E                B IF NOT NEW PAGE                           
         LI,R5    1                                                             
         MTH,-1   K:BPGLIM,R5       DECREMENT PAGE COUNT                        
         BLEZ     %D                B IF EXHAUSTED                              
         LCW,R5   R4                GET NR LINES INTO NEXT PAGE                 
         LB,R4    K:PAGE            GET NR LINES TOTAL FOR NEXT PAGE            
         STH,R4   K:BPGLIM          SET IT                                      
         B        %C                REPEAT ACCOUNTING FOR REMAINING LINES       
%D       LI,R5    -2                                                            
         STW,R5   K:ABTLOC          INDICATOR OF PAGE ABORT                     
         LW,R4    Y08                                                           
         LW,R5    R4                                                            
         AI,R5    4                                                             
         STS,R4   K:CTST            FLAGS TO RUN ABEX FOR BKG ABORT             
         PUSH     R11                                                           
         BAL,R11  CTRIG             FORCE REDISPATCH                            
         PULL     R11               WONT GET MUCH PAST HERE                     
%E       RES      0                                                             
*                                                                               
*                                                                               
         LI,R6    0                 RETRIES = 0            /SIG7-2064/*C5732 C01
         LW,R4    R2                FUNCION CODE                                
         AND,R10  M24               MASK BYTE COUNT                             
         LW,R8    CUPCOD4           CODE FOR NO FPT OR DCB                      
         DO       #SYMB                                                         
         BAL,R5   COOP              CALL COOPERATIVE                            
         B        TYPREXIT          +1..ERROR                                   
         B        TYPREXIT          +2..DONE                                    
         FIN      #SYMB                                                         
         LI,R15   -1                FLAG FOR NO REENTRANCE CHECK                
         LW,R0    1,R3              NON-SYMB DEVICE, GET FPT WORD 0             
         CI,R0    K10               IS REQUEST WITH WAIT                        
         BAZ      TYPR1             NO, BRANCH                                  
         BAL,R5   CALLQ                                                         
         NOP                        IGNORE ERRORS                               
         B        TYPREXIT                                                      
TYPR1    RES      0                 NO WAIT PRINT/TYPE                          
         BAL,R5   FMQUEUE           QUEUE THE REQUEST                           
         B        TYPREXIT          EXIT IF ERROR                               
         DO1      #ECB                                                          
TYPREX1  B        TESTWT4           D.P. ECB EXIT                               
*                                                                               
TYPREXIT B        CALEXIT                                                       
         PAGE                                                            0638000
************                                                             0639000
*   TYPE   *                                                             0640000
************                                                             0641000
*                                                                        0642000
*   THIS ROUTINE RECEIVES ALL TYPE CALLS                                 0643000
*   ENTRY IS FROM THE CAL1 PROCESSOR                                     0644000
*                                                                        0645000
*   AT ENTRY:     R0    FPT ADDRESS                                      0646000
*                 PSD IS ON TOP OF USER TEMP STACK                       0647000
*                                                                        0648000
TYPE     RES      0                                                             
         LI,R7    OC                DUMMY DCB WORD 1 (USED IN GETDCTX)          
         B        TYPEPRNT                                               0651000
         PAGE                                                                   
*                                                          /SIG7-7456/*C5732 145
*        PRINT FUNCTION CODE TABLE                         /SIG7-7456/*C5732 146
*        TO BE INDEXED BY DEVICE 'TYPE'                    /SIG7-7456/*C5732 147
*                                                          /SIG7-7456/*C5732 148
PRNTTBL  DATA,1   -1                IOEX    TYPE 0         /SIG7-7456/*C5732 149
         DATA,1   FCWKPWNL          TY      TYPE 1         /SIG7-7456/*C5732 150
         DATA,1   -1                PR      TYPE 2         /SIG7-7456/*C5732 151
         DATA,1   -1                PP      TYPE 3         /SIG7-7456/*C5732 152
         DATA,1   -1                CR      TYPE 4         /SIG7-7456/*C5732 153
         DATA,1   -1                CP      TYPE 5         /SIG7-7456/*C5732 154
         DATA,1   FCWLPWOF          LP      TYPE 6         /SIG7-7456/*C5732 156
         DATA,1   -1                DC      TYPE 7         /SIG7-7456/*C5732 160
         DATA,1   FCWMT             9T      TYPE 8         /SIG7-7456/*C5732 162
         DATA,1   FCWMT             7T      TYPE 9                              
         DATA,1   -1                CPLC    TYPE 10        /SIG7-7456/*C5732 168
         DATA,1   FCWLPWOF          LPLC    TYPE 11        /SIG7-7456/*C5732 170
         DATA,1   -1                DP      TYPE 12        /SIG7-7456/*C5732 174
         DATA,1   -1                PL      TYPE 13        /SIG7-7456/*C5732 175
         DATA,1   -1                        TYPE 14                             
         DATA,1   FCWLPWOF          LP,BDP  TYPE 15                             
         DATA,1   FCWMT             9T      TYPE 16                             
         DATA,1   -1                RB       TYPE 17                            
         DATA,1   1                 SP       TYPE 18                            
         DATA,1   1                 LD       TYPE 19                            
         BOUND    4                                                             
         TITLE    '** PRINT - SUB TO GENERATE BLOCK LETTERS **'                 
         SPACE    3                                                             
G1   COM,4,4             AF(1),AF(2)                                            
G2   COM,4,4,4,4         AF(1),AF(2),AF(3),AF(4)                                
G4   COM,4,4,4,4,4,4,4,4 AF(1),AF(2),AF(3),AF(4),AF(5),AF(6),AF(7),AF(8)        
G3     COM,4,4,4,4,4,4     AF(1),AF(2),AF(3),AF(4),AF(5),AF(6)                  
         SPACE    3                                                             
CHAR     CNAME    0                                                             
         PROC                                                                   
LF       RES      0                                                             
@        DO       12                                                            
@AF      SET      BA(AF(@))-BA(TBLR)                                            
         DATA,1   @AF                                                           
         FIN                                                                    
         PEND                                                                   
         PAGE                                                                   
*************************************************************                   
*                                                                               
*  ON ENTRY--                                                                   
*        R8  - LINK REGISTER                                                    
*        R1  - DCB ADDRESS                                                      
*        R10 - BUFFER ADDRESS (BUFFER MUST BE 34 WORDS LONG)                    
*        R11 - TEXT ADDRESS (8 BYTES OF TEXT)                                   
*                                                                               
*  ON EXIT---                                                                   
*    NO ERRORS:  ALL REGISTERS RESTORED                                         
*    ERRORS:  R11-R9 RESTORED                                                   
*             R10 = ERROR CODE AS RETURNED BY CALS OR GETTEMP                   
*                   OR 0 IF THERE WAS A TABLE ERROR                             
*                                                                               
*  CALLING SEQUENCE---                                                          
*        BAL,R8   GENCHARS                                                      
*        ---(ERROR RETURN)                                                      
*        ---(NORMAL RETURN)                                                     
*                                                                               
************************************************************                    
         PAGE                                                                   
**************                                                                  
** GENCHARS **                                                                  
**************                                                                  
         SPACE    2                                                             
GENCHARS EQU      %                 ..... GEN. BLOCK CHAR. SUBROUTINE ..        
         PUSH     13,R11            SAVE REGISTERS, R11-R7                      
         PUSH     R10                               R10                         
         PUSH     R8                                R8                          
         SPACE    1                                                             
         STD,R10  R12               SAVE R10-R11 BEFORE BAL                     
         LI,R7    TEMPEND-TTTT      GET TEMP SPACE                              
         BAL,R8   GETTEMP           FOR FPT'S                                   
         B        NOTS              CAN'T                                       
         BAL,R8   TISCHN            CHAIN UP TEMP SPACE, RET. ENABLED           
         LD,R10   R12               RESTORE R10-R11                             
         STW,R7   R0                SAVE PARAMETER                              
*                                                                               
         LI,R6    TEMPEND-TTTT-1    MOVE FPT'S                                  
         LW,R8    TTTT,R6           TO TEMP SPACE                               
         STW,R8   *R7,R6                                                        
         BDR,R6   %-2                                                           
*                                                                               
         STB,R6   R7                CLEAR LENGTH                                
*                                                                               
         AND,R1   M24               MASK ADDRESS                                
         LI,R12   GCERR             SWAP ERA                                    
         XW,R12   3,R1                AND ABA                                   
         LI,R13   GCERR               OF USER'S                                 
         XW,R13   4,R1                DCB                                       
*                                                                               
         AWM,R1   DFPT-TTTT,R7      INSERT DCB ADDRESS                          
         AWM,R1   RFPT-TTTT,R7       IN FPT'S                                   
*                                                                               
         CAL1,1   DFPT-TTTT,R7      DO VFC                                      
         SPACE    1                                                             
         LI,R4    0                 R4=  CURRENT ROW (LINE) NO.                 
LOOPR    LI,R2    0                 R2 = CHARACTER LOOP COUNT                   
         LI,R5    33                CLEAR ROW BUFFER                            
         LW,R6    BLANKS            ...                                         
         STW,R6   *R10,R5           ...                                         
         BDR,R5   %-1               ...                                         
         STW,R6   *R10                                                          
         SPACE    1                                                             
         CI,R4    0                 FOR FIRST ROW                               
         BNEZ     LOOPC               ONLY..                                    
         LI,R5    X'C4'             SET UP PRINT CONTROL FOR 4 SPACES           
         STB,R5   *R10              ...                                         
         SPACE    2                                                             
LOOPC    LB,R5    *R11,R2           R5  = EBCDIC CHAR                           
         LW,R8    R5                R5  = EBCDIC CHAR                           
         AND,R5   M6                FOLD CHARACTER INTO FIRST QUADRANT          
         MI,R5    3                 R5  = WA(CHAR DEF)                          
         AI,R5    TBLC              ...                                         
         SPACE    1                                                             
         LB,R5    *R5,R4            R5  = POS(CHAR ROW DEF)                     
         BEZ      GC25              IF NULL, JUMP                               
         SPACE    1                                                             
         LI,R6    -4                R6 = LEN (CHAR ROW DEF)                     
         CB,R5    TBLB+1,R6         ...                                         
         BL       %+2               ...                                         
         BIR,R6   %-2               ...                                         
         AI,R6    5                 .....                                       
         SPACE    1                                                             
         LW,R3    R2                ...                                         
         MI,R3    16                ...                                         
         AI,R3    3                 R3 = BA(CHAR STARTING POSITION)             
         SPACE    1                                                             
GC20     LB,R14   TBLR,R5           R14 = CHAR ROW DEF BYTE (#SKIPS, #INS       
         SLD,R14  -4                R14 = NO. OF SKIPS                          
         SLS,R15  -28               R15 = NO. OF INSERTS                        
         SPACE    1                                                             
         AW,R3    R14               PERFORM SKIPS                               
         SPACE    1                                                             
         CI,R3    133               PERFORM INSERTS                             
         BG       GCERR2            ... ****        TBLR ERROR                  
         STB,R8   *R10,R3           PERFORM INSERTS                             
         AI,R3    1                 ...                                         
         BDR,R15  %-4               ...                                         
         SPACE    1                                                             
         AI,R5    1                 BUMP CHAR ROW DEF POINTER                   
         BDR,R6   GC20              LOOP TO PERFORM MORE SKIPS & INSERTS        
         SPACE    1                                                             
GC25     AI,R2    1                 SEE IF MORE                                 
         CI,R2    8                 CHARACTERS TO DO                            
         BL       LOOPC             LOOP TO BUILD NEXT CHAR'S ROW               
         SPACE    1                                                             
         CAL1,1   RFPT-TTTT,R7      PRINT CURRENT ROW                           
         SPACE    1                                                             
         AI,R4    1                 BUMP CURRENT ROW POINTER                    
         CI,R4    12                HAS LAST ROW BEEN PRINTED...                
         BL       LOOPR               NO,LOOP                                   
         SPACE    2                                                             
         LI,R10   0                 FLAG, NO ERROR                              
*                                                                               
GC30     XW,R12   3,R1              RESTORE USER'S                              
         XW,R13   4,R1                ERA AND ABA                               
         LW,R7    R0                TEMP SPACE PARAMETER                        
         BAL,R8   TISDECHN          DECHAIN TEMP SPACE                          
         STW,R10  R12               (RELTEMP CLOBBERS R10)                      
         BAL,R8   RELTEMP           AND RELEASE IT                              
         LW,R10   R12                                                           
*                                                                               
GC32     PULL     R8                RESTORE R8                                  
         CI,R10   0                 WAS THERE AN ERROR-                         
         BE       GC33              NO,                                         
         PULL     R11               YES, THROW AWAY ORIG R10                    
         B        GC35                                                          
*                                                                               
GC33     AI,R8    1                 NO ERROR RETURN                             
         PULL     R10               RESTORE ORIG R10                            
GC35     PULL     13,R11            RESTORE R11-R7                              
GCEXIT   B        *R8               RETURN                                      
         SPACE    4                                                             
TTTT     EQU      %                 BEGINNING OF AREA TO MOVE TO TS             
         RES      1                 WASTE ONE WORD FOR MOVE                     
*                                   WILL BE USED FOR CHAINING TEMP SPACE        
DFPT     GEN,8,24 X'05',0           VFC FPT--DCB FILLED LATER                   
         GEN,27,1,4  0,1,0                                                      
*                                                                               
RFPT     GEN,8,24 X'11',0           WRITE FPT--DCB FILLED IN AT EXECUTION       
         DATA     P1+P2+P3+P4+F3                                                
         DATA     GCERR             ERROR ADDRESS                               
         DATA     GCERR             ABNORMAL ADDRESS                            
         GEN,1,31  1,R10            BUFFER                                      
         DATA     132               COUNT                                       
TEMPEND  EQU      %                                                             
         SPACE    2                                                             
GCERR2   EQU      %                                                             
         LI,R10   -1                TABLE ERROR                                 
GCERR    B        GC30              ERA AND ABA                                 
*                                                                               
*                                                                               
NOTS     STB,R15  R10               NO TEMP SPACE                               
         B        GC32                                                          
         PAGE                                                                   
**********                                                                      
** TBLR **                                                                      
**********                                                                      
         SPACE    2                                                             
*                 THE ENTRIES OF TBLR DEFINE ALL POSSIBLE CHARACTER             
*                 ROW.  THE LENGTH OF EACH ENTRY IS DEFIN BY ITS                
*                 POSITION IN THE TABLE - ITS POSITION BETWEEN 'BREAKS.'        
*                 EACH ENTRY IS DIVIDED INTO BYTE ELEMENTS: THE 1ST             
*                 FOUR BITS SPECIFYING THE NO. OF SKIPS (BLANKS) AND            
*                 THE LAST FOUR BITS SPECIFYING THE NO. OF INSERTS.             
*                                                                               
*                 NOTE:  THE COMBINED LENGTH OF ALL THE ENTRIES                 
*                        CANNOT EXCEED 256 BYTES.                               
         SPACE    2                                                             
TBLR     EQU      %                 ..... CHARACTER ROW DEFINATIONS ....        
         SPACE    1                                                             
@00      G1       0,0                                                           
@02      G1       0,2                                                           
@03      G1       0,3                                                           
@05      G1       0,5                                                           
@04      G1       0,4                                                           
@08      G1       0,8                                                           
@0B      G1       0,11                                                          
@0C      G1       0,12                                                          
@0D      G1       0,13                                                          
@12      G1       1,2                                                           
@17      G1       1,7                                                           
@1B      G1       1,11                                                          
@1C      G1       1,12                                                          
@22      G1       2,2                                                           
@24      G1       2,4                                                           
@28      G1       2,8                                                           
@29      G1       2,9                                                           
@32      G1       3,2                                                           
@34      G1       3,4                                                           
@37      G1       3,7                                                           
@42      G1       4,2                                                           
@43      G1       4,3                                                           
@44      G1       4,4                                                           
@52      G1       5,2                                                           
@53      G1       5,3                                                           
@54      G1       5,4                                                           
@61      G1       6,1                                                           
@62      G1       6,2                                                           
@63      G1       6,3                                                           
@72      G1       7,2                                                           
@82      G1       8,2                                                           
@84      G1       8,4                                                           
@85      G1       8,5                                                           
@92      G1       9,2                                                           
@94      G1       9,4                                                           
@A2      G1       10,2                                                          
@A3      G1       10,3                                                          
@B2      G1       11,2                                                          
         SPACE    1                                                             
BREAK1   EQU      BA(%)-BA(TBLR)                                                
         SPACE    3                                                             
@0222    G2       0,2,2,2                                                       
@0241    G2       0,2,4,1                                                       
@0242    G2       0,2,4,2                                                       
@0262    G2       0,2,6,2                                                       
@0263    G2       0,2,6,3                                                       
@0264    G2       0,2,6,4                                                       
@0265    G2       0,2,6,5                                                       
@0272    G2       0,2,7,2                                                       
@0273    G2       0,2,7,3                                                       
@0274    G2       0,2,7,4                                                       
@0282    G2       0,2,8,2                                                       
@0283    G2       0,2,8,3                                                       
@0292    G2       0,2,9,2                                                       
@0373    G2       0,3,7,3                                                       
@0382    G2       0,3,8,2                                                       
@0454    G2       0,4,5,4                                                       
@0472    G2       0,4,7,2                                                       
@0542    G2       0,5,4,2                                                       
@0562    G2       0,5,6,2                                                       
@0922    G2       0,9,2,2                                                       
@1242    G2       1,2,4,2                                                       
@1262    G2       1,2,6,2                                                       
@1272    G2       1,2,7,2                                                       
@1732    G2       1,7,3,2                                                       
@1912    G2       1,9,1,2                                                       
@2232    G2       2,2,3,2                                                       
@2242    G2       2,2,4,2                                                       
@2245    G2       2,2,4,5                                                       
@2252    G2       2,2,5,2                                                       
@2272    G2       2,2,7,2                                                       
@3222    G2       3,2,2,2                                                       
@3232    G2       3,2,3,2                                                       
@4212    G2       4,2,1,2                                                       
@6142    G2       6,1,4,2                                                       
         SPACE    1                                                             
BREAK2   EQU      BA(%)-BA(TBLR)                                                
         SPACE    3                                                             
@021252  G3       0,2,1,2,5,2                                                   
@021262  G3       0,2,1,2,6,2                                                   
@022252  G3       0,2,2,2,5,2                                                   
@023242  G3       0,2,3,2,4,2                                                   
@023332  G3       0,2,3,3,3,2                                                   
@024142  G3       0,2,4,1,4,2                                                   
@024232  G3       0,2,4,2,3,2                                                   
@025213  G3       0,2,5,2,1,3                                                   
@025222  G3       0,2,5,2,2,2                                                   
@026212  G3       0,2,6,2,1,2                                                   
@125212  G3       1,2,5,2,1,2                                                   
         SPACE    1                                                             
BREAK3   EQU      BA(%)-BA(TBLR)                                                
         SPACE    3                                                             
#2123212 G4       0,2,1,2,3,2,1,2                                               
#2221222 G4       0,2,2,2,1,2,2,2                                               
         SPACE    1                                                             
BREAK4   EQU      BA(%)-BA(TBLR)                                                
         BOUND    4                                                             
         SPACE    3                                                             
@L       EQU      @02               LEFT                                        
@C       EQU      @52               CENTER                                      
@R       EQU      @B2               RIGHT                                       
@B       EQU      @0292             LEFT & RIGHT                                
         SPACE    3                                                             
TBLB     EQU      %                                                             
         DATA,1   BREAK1,BREAK2,BREAK3,BREAK4                                   
         BOUND    4                                                             
         PAGE                                                                   
**********                                                                      
** TBLC **                                                                      
**********                                                                      
         SPACE    2                                                             
*                 TBLC CONSIST OF 64 ENTRIES; EACH ENTRY DEFINES A              
*                 BLOCKED CHARACTER.  THE ENTRIES CONTAIN 12 BYTES              
*                 (ONE FOR EACH OF THE 12 CHARACTER ROWS) WHICH                 
*                 REFERENCE TBLR.                                               
         SPACE    2                                                             
TBLC     EQU      %                 ..... CHARACTER DEFINATIONS .....           
         SPACE    1                                                             
:BLANK:  CHAR     @00,@00,@00,@00,@00,@00,;                                     
                  @00,@00,@00,@00,@00,@00                                       
:A:      CHAR     @37,@37,@3232,@2252,@2252,@29,;                               
                  @1B,@1272,@1272,@B,@B,@B                                      
:B:      CHAR     @0C,@0D,@B,@B,@B,@0C,;                                        
                  @0C,@B,@B,@B,@0D,@0C                                          
:C:      CHAR     @1B,@0D,@B,@L,@L,@L,;                                         
                  @L,@L,@L,@B,@0D,@1B                                           
:D:      CHAR     @0B,@0C,@B,@B,@B,@B,;                                         
                  @B,@B,@B,@B,@0C,@0B                                           
:E:      CHAR     @0D,@0D,@L,@L,@L,@08,;                                        
                  @08,@L,@L,@L,@0D,@0D                                          
:F:      CHAR     @0D,@0D,@L,@L,@L,@08,;                                        
                  @08,@L,@L,@L,@L,@L                                            
:G:      CHAR     @1B,@0D,@B,@B,@L,@L,;                                         
                  @0264,@0265,@B,@0283,@0D,@1912                                
:H:      CHAR     @B,@B,@B,@B,@B,@0D,;                                          
                  @0D,@B,@B,@B,@B,@B                                            
:I:      CHAR     @28,@28,@C,@C,@C,@C,;                                         
                  @C,@C,@C,@C,@28,@28                                           
:CENT:   CHAR     @00,@00,@00,@00,@00,@00,;                                     
                  @00,@00,@00,@00,@00,@00                                       
:PERIOD: CHAR     @00,@00,@00,@00,@00,@00,;                                     
                  @00,@00,@53,@53,@53,@00                                       
:LT:     CHAR     @00,@B2,@92,@72,@52,@32,;                                     
                  @12,@32,@52,@72,@92,@B2                                       
:LPAREN: CHAR     @94,@85,@82,@82,@82,@82,;                                     
                  @82,@82,@82,@82,@85,@94                                       
:PLUS:   CHAR     @00,@00,@53,@53,@53,@0D,;                                     
                  @0D,@53,@53,@53,@00,@00                                       
:CONCAT: CHAR     @53,@53,@53,@53,@53,@53,;                                     
                  @53,@53,@53,@53,@53,@53                                       
         PAGE                                                                   
*                                                                               
         SPACE    4                                                             
:AMP:    CHAR     @61,@1B,@0D,@B,@03,@17,;                                      
                  @17,@03,@B,@0D,@1B,@61                                        
:J:      CHAR     @R,@R,@R,@R,@R,@R,;                                           
                  @R,@R,@B,@B,@0D,@1B                                           
:K:      CHAR     @B,@0282,@0262,@0242,@0222,@04,;                              
                  @04,@0222,@0242,@0262,@0282,@B                                
:L:      CHAR     @L,@L,@L,@L,@L,@L,;                                           
                  @L,@L,@L,@B,@0D,@0D                                           
:M:      CHAR     @B,@0373,@0454,#2123212,#2221222,@023332,;                    
                  @024142,@B,@B,@B,@B,@B                                        
:N:      CHAR     @B,@0382,@0472,@021262,@022252,@023242,;                      
                  @024232,@025222,@026212,@0274,@0283,@B                        
:O:      CHAR     @1B,@0D,@B,@B,@B,@B,;                                         
                  @B,@B,@B,@B,@0D,@1B                                           
:P:      CHAR     @0C,@0D,@B,@B,@B,@0D,;                                        
                  @0C,@L,@L,@L,@L,@L                                            
:Q:      CHAR     @1B,@0D,@B,@B,@B,@B,;                                         
                  @B,@B,@024232,@025222,@0D,@1B                                 
:R:      CHAR     @0C,@0D,@B,@B,@B,@0D,;                                        
                  @0C,@0262,@0273,@B,@B,@B                                      
:EXCLAM: CHAR     @00,@00,@00,@00,@00,@00,;                                     
                  @00,@00,@00,@00,@00,@00                                       
:DOLLAR: CHAR     @61,@0D,@0D,@0241,@0241,@0D,;                                 
                  @0D,@6142,@6142,@0D,@0D,@61                                   
:STAR:   CHAR     @00,@00,@2252,@3232,@4212,@0D,;                               
                  @0D,@4212,@3232,@2252,@00,@00                                 
:RPEREN: CHAR     @04,@05,@32,@32,@32,@32,;                                     
                  @32,@32,@32,@32,@05,@04                                       
:SCOLON: CHAR     @00,@53,@53,@53,@00,@00,;                                     
                  @00,@00,@53,@53,@53,@43                                       
:NOT:    CHAR     @00,@00,@00,@00,@00,@00,;                                     
                  @00,@00,@00,@00,@00,@00                                       
         PAGE                                                                   
*                                                                               
         SPACE    4                                                             
:MINUS:  CHAR     @00,@00,@00,@00,@00,@0D,;                                     
                  @0D,@00,@00,@00,@00,@00                                       
:SLASH:  CHAR     @B2,@A2,@92,@82,@72,@62,;                                     
                  @52,@42,@32,@22,@12,@02                                       
:S:      CHAR     @1B,@0D,@B,@L,@L,@0C,;                                        
                  @1C,@R,@R,@B,@0D,@1B                                          
:T:      CHAR     @0C,@0C,@C,@C,@C,@C,;                                         
                  @C,@C,@C,@C,@C,@C                                             
:U:      CHAR     @B,@B,@B,@B,@B,@B,;                                           
                  @B,@B,@B,@B,@0D,@1B                                           
:V:      CHAR     @B,@B,@1272,@1272,@2252,@2252,;                               
                  @3232,@3232,@4212,@4212,@53,@61                               
:W:      CHAR     @B,@B,@B,@B,@B,@024142,;                                      
                  @023332,#2221222,#2123212,@0454,@0373,@B                      
:X:      CHAR     @B,@1272,@2252,@3232,@4212,@53,;                              
                  @53,@4212,@3232,@2252,@1272,@B                                
:Y:      CHAR     @0282,@1262,@2242,@3222,@44,@C,;                              
                  @C,@C,@C,@C,@C,@C                                             
:Z:      CHAR     @0D,@0C,@0272,@82,@72,@62,;                                   
                  @52,@42,@32,@2272,@1C,@0D                                     
:BOX:    CHAR     @00,@00,@00,@1B,@1B,@1B,;                                     
                  @1B,@1B,@1B,@00,@00,@00                                       
:COMMA:  CHAR     @00,@00,@00,@00,@00,@00,;                                     
                  @00,@00,@53,@53,@53,@43                                       
:PERCNT: CHAR     @0562,@021252,@0542,@82,@72,@62,;                             
                  @52,@42,@32,@2245,@125212,@0265                               
:UNDRSC: CHAR     @00,@00,@00,@00,@00,@00,;                                     
                  @00,@00,@00,@00,@00,@00                                       
:GT:     CHAR     @00,@02,@22,@42,@62,@82,;                                     
                  @A2,@82,@62,@42,@22,@02                                       
:QUEST:  CHAR     @00,@00,@00,@00,@00,@00,;                                     
                  @00,@00,@00,@00,@00,@00                                       
         PAGE                                                                   
*                                                                               
         SPACE    4                                                             
:0:      CHAR     @37,@29,@1272,@B,@B,@B,;                                      
                  @B,@B,@B,@1272,@29,@37                                        
:1:      CHAR     @C,@43,@34,@C,@C,@C,;                                         
                  @C,@C,@C,@C,@C,@C                                             
:2:      CHAR     @1B,@0D,@B,@R,@R,@A2,;                                        
                  @82,@62,@42,@22,@0D,@0D                                       
:3:      CHAR     @1B,@0D,@B,@R,@R,@84,;                                        
                  @84,@R,@R,@B,@0D,@1B                                          
:4:      CHAR     @72,@63,@54,@4212,@3222,@2232,;                               
                  @1242,@0D,@0D,@72,@72,@72                                     
:5:      CHAR     @0D,@0D,@L,@L,@L,@0C,;                                        
                  @0D,@R,@R,@B,@0D,@1B                                          
:6:      CHAR     @1C,@0D,@L,@L,@L,@0C,;                                        
                  @0D,@B,@B,@B,@0D,@1B                                          
:7:      CHAR     @0D,@0C,@0272,@82,@72,@62,;                                   
                  @62,@C,@C,@42,@42,@42                                         
:8:      CHAR     @1B,@0D,@B,@B,@B,@1B,;                                        
                  @1B,@B,@B,@B,@0D,@1B                                          
:9:      CHAR     @1B,@0D,@B,@B,@B,@0D,;                                        
                  @1C,@R,@R,@R,@0D,@0C                                          
:COLON:  CHAR     @00,@53,@53,@53,@00,@00,;                                     
                  @00,@00,@53,@53,@53,@00                                       
:LB:     CHAR     @3232,@3232,@0D,@0D,@3232,@3232,;                             
                  @3232,@0D,@0D,@3232,@3232,@00                                 
:AT:     CHAR     @00,@1B,@1C,@B,@R,@1732,;                                     
                  @0922,@025222,@025222,@025213,@0D,@1912                       
:QUOTE:  CHAR     @53,@53,@53,@43,@00,@00,;                                     
                  @00,@00,@00,@00,@00,@00                                       
:EQUALS: CHAR     @00,@00,@00,@0D,@0D,@00,;                                     
                  @00,@0D,@0D,@00,@00,@00                                       
:DQUOTE: CHAR     @00,@00,@00,@00,@00,@00,;                                     
                  @00,@00,@00,@00,@00,@00                                       
         OLAYEND                                                                
         END                                                                    
